t/db_dependent/Items.t

   1 #!/usr/bin/perl
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use Data::Dumper;
  20
  21 use MARC::Record;
  22 use C4::Items
  23     qw( ModItemTransfer SearchItems AddItemFromMarc ModItemFromMarc get_hostitemnumbers_of Item2Marc ModDateLastSeen CartToShelf );
  24 use C4::Biblio qw( GetMarcFromKohaField AddBiblio );
  25 use C4::Circulation qw( AddIssue );
  26 use Koha::BackgroundJobs;
  27 use Koha::Items;
  28 use Koha::Database;
  29 use Koha::DateUtils qw( dt_from_string );
  30 use Koha::Library;
  31 use Koha::DateUtils;
  32 use Koha::MarcSubfieldStructures;
  33 use Koha::Caches;
  34 use Koha::AuthorisedValues;
  35
  36 use t::lib::Mocks;
  37 use t::lib::TestBuilder;
  38
  39 use Test::More tests => 13;
  40
  41 use Test::Warn;
  42
  43 my $schema = Koha::Database->new->schema;
  44 my $location = 'My Location';
  45
  46 subtest 'General Add, Get and Del tests' => sub {
  47
  48     plan tests => 16;
  49
  50     $schema->storage->txn_begin;
  51
  52     my $builder = t::lib::TestBuilder->new;
  53     my $library = $builder->build({
  54         source => 'Branch',
  55     });
  56     my $itemtype = $builder->build({
  57         source => 'Itemtype',
  58     });
  59
  60     # Create a biblio instance for testing
  61     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
  62     my $biblio = $builder->build_sample_biblio();
  63
  64     # Add an item.
  65     my $item = $builder->build_sample_item(
  66         {
  67             biblionumber => $biblio->biblionumber,
  68             library      => $library->{branchcode},
  69             location     => $location,
  70             itype        => $itemtype->{itemtype}
  71         }
  72     );
  73     my $itemnumber = $item->itemnumber;
  74     cmp_ok($item->biblionumber, '==', $biblio->biblionumber, "New item is linked to correct biblionumber.");
  75     cmp_ok($item->biblioitemnumber, '==', $biblio->biblioitem->biblioitemnumber, "New item is linked to correct biblioitemnumber.");
  76
  77     # Get item.
  78     my $getitem = Koha::Items->find($itemnumber);
  79     cmp_ok($getitem->itemnumber, '==', $itemnumber, "Retrieved item has correct itemnumber.");
  80     cmp_ok($getitem->biblioitemnumber, '==', $item->biblioitemnumber, "Retrieved item has correct biblioitemnumber."); # We are not testing anything useful here
  81     is( $getitem->location, $location, "The location should not have been modified" );
  82     is( $getitem->permanent_location, $location, "The permanent_location should have been set to the location value" );
  83
  84
  85     # Do not modify anything, and do not explode!
  86     $getitem->set({})->store;
  87
  88     # Modify item; setting barcode.
  89     $getitem->barcode('987654321')->store;
  90     my $moditem = Koha::Items->find($itemnumber);
  91     cmp_ok($moditem->barcode, '==', '987654321', 'Modified item barcode successfully to: '.$moditem->barcode . '.');
  92
  93     # Delete item.
  94     $moditem->delete;
  95     my $getdeleted = Koha::Items->find($itemnumber);
  96     is($getdeleted, undef, "Item deleted as expected.");
  97
  98     $itemnumber = $builder->build_sample_item(
  99         {
 100             biblionumber => $biblio->biblionumber,
 101             library      => $library->{branchcode},
 102             location     => $location,
 103             permanent_location => 'my permanent location',
 104             itype        => $itemtype->{itemtype}
 105         }
 106     )->itemnumber;
 107     $getitem = Koha::Items->find($itemnumber);
 108     is( $getitem->location, $location, "The location should not have been modified" );
 109     is( $getitem->permanent_location, 'my permanent location', "The permanent_location should not have modified" );
 110
 111     my $new_location = "New location";
 112     $getitem->location($new_location)->store;
 113     $getitem = Koha::Items->find($itemnumber);
 114     is( $getitem->location, $new_location, "The location should have been set to correct location" );
 115     is( $getitem->permanent_location, $new_location, "The permanent_location should have been set to location" );
 116
 117     $getitem->location('CART')->store;
 118     $getitem = Koha::Items->find($itemnumber);
 119     is( $getitem->location, 'CART', "The location should have been set to CART" );
 120     is( $getitem->permanent_location, $new_location, "The permanent_location should not have been set to CART" );
 121
 122     t::lib::Mocks::mock_preference('item-level_itypes', '1');
 123     $getitem = Koha::Items->find($itemnumber);
 124     is( $getitem->effective_itemtype, $itemtype->{itemtype}, "Itemtype set correctly when using item-level_itypes" );
 125     t::lib::Mocks::mock_preference('item-level_itypes', '0');
 126     $getitem = Koha::Items->find($itemnumber);
 127     is( $getitem->effective_itemtype, $biblio->biblioitem->itemtype, "Itemtype set correctly when not using item-level_itypes" );
 128
 129     $schema->storage->txn_rollback;
 130 };
 131
 132 subtest 'ModItemTransfer tests' => sub {
 133     plan tests => 8;
 134
 135     $schema->storage->txn_begin;
 136
 137     my $builder = t::lib::TestBuilder->new;
 138     my $item    = $builder->build_sample_item();
 139
 140     my $library1 = $builder->build(
 141         {
 142             source => 'Branch',
 143         }
 144     );
 145     my $library2 = $builder->build(
 146         {
 147             source => 'Branch',
 148         }
 149     );
 150
 151     ModItemTransfer( $item->itemnumber, $library1->{branchcode},
 152         $library2->{branchcode}, 'Manual' );
 153
 154     my $transfers = Koha::Item::Transfers->search(
 155         {
 156             itemnumber => $item->itemnumber
 157         }
 158     );
 159
 160     is( $transfers->count, 1, "One transfer created with ModItemTransfer" );
 161     $item->discard_changes;
 162     is($item->holdingbranch, $library1->{branchcode}, "Items holding branch was updated to frombranch");
 163
 164     ModItemTransfer( $item->itemnumber, $library2->{branchcode},
 165         $library1->{branchcode}, 'Manual' );
 166     $transfers = Koha::Item::Transfers->search(
 167         { itemnumber => $item->itemnumber, },
 168         { order_by   => { '-asc' => 'branchtransfer_id' } }
 169     );
 170
 171     is($transfers->count, 2, "Second transfer recorded on second call of ModItemTransfer");
 172     my $transfer1 = $transfers->next;
 173     my $transfer2 = $transfers->next;
 174     isnt($transfer1->datecancelled, undef, "First transfer marked as cancelled by ModItemTransfer");
 175     like($transfer1->cancellation_reason,qr/^Manual/, "First transfer contains cancellation_reason 'Manual'");
 176     is($transfer2->datearrived, undef, "Second transfer is now the active transfer");
 177     $item->discard_changes;
 178     is($item->holdingbranch, $library2->{branchcode}, "Items holding branch was updated to frombranch");
 179
 180     # Check 'reason' is populated when passed
 181     ModItemTransfer( $item->itemnumber, $library2->{branchcode},
 182         $library1->{branchcode}, "Manual" );
 183
 184     $transfers = Koha::Item::Transfers->search(
 185         { itemnumber => $item->itemnumber, },
 186         { order_by   => { '-desc' => 'branchtransfer_id' } }
 187     );
 188
 189     my $transfer3 = $transfers->next;
 190     is($transfer3->reason, 'Manual', "Reason set via ModItemTransfer");
 191
 192     $schema->storage->txn_rollback;
 193 };
 194
 195 subtest q{Test Koha::Database->schema()->resultset('Item')->itemtype()} => sub {
 196
 197     plan tests => 4;
 198
 199     $schema->storage->txn_begin;
 200
 201     my $biblio = $schema->resultset('Biblio')->create({
 202         title       => "Test title",
 203         datecreated => dt_from_string,
 204         biblioitems => [ { itemtype => 'BIB_LEVEL' } ],
 205     });
 206     my $biblioitem = $biblio->biblioitems->first;
 207     my $item = $schema->resultset('Item')->create({
 208         biblioitemnumber => $biblioitem->biblioitemnumber,
 209         biblionumber     => $biblio->biblionumber,
 210         itype            => "ITEM_LEVEL",
 211     });
 212
 213     t::lib::Mocks::mock_preference( 'item-level_itypes', 0 );
 214     is( $item->effective_itemtype(), 'BIB_LEVEL', '$item->itemtype() returns biblioitem.itemtype when item-level_itypes is disabled' );
 215
 216     t::lib::Mocks::mock_preference( 'item-level_itypes', 1 );
 217     is( $item->effective_itemtype(), 'ITEM_LEVEL', '$item->itemtype() returns items.itype when item-level_itypes is enabled' );
 218
 219     # If itemtype is not defined and item-level_level item types are set
 220     # fallback to biblio-level itemtype (Bug 14651) and warn
 221     $item->itype( undef );
 222     $item->update();
 223     my $effective_itemtype;
 224     warning_is { $effective_itemtype = $item->effective_itemtype() }
 225                 "item-level_itypes set but no itemtype set for item (".$item->itemnumber.")",
 226                 '->effective_itemtype() raises a warning when falling back to bib-level';
 227
 228     ok( defined $effective_itemtype &&
 229                 $effective_itemtype eq 'BIB_LEVEL',
 230         '$item->effective_itemtype() falls back to biblioitems.itemtype when item-level_itypes is enabled but undef' );
 231
 232     $schema->storage->txn_rollback;
 233 };
 234
 235 subtest 'SearchItems test' => sub {
 236     plan tests => 20;
 237
 238     $schema->storage->txn_begin;
 239     my $dbh = C4::Context->dbh;
 240     my $builder = t::lib::TestBuilder->new;
 241
 242     my $library1 = $builder->build({
 243         source => 'Branch',
 244     });
 245     my $library2 = $builder->build({
 246         source => 'Branch',
 247     });
 248     my $itemtype = $builder->build({
 249         source => 'Itemtype',
 250     });
 251
 252     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 253     my ($cpl_items_before) = SearchItems( { field => 'homebranch', query => $library1->{branchcode} } );
 254
 255     my $biblio = $builder->build_sample_biblio({ title => 'Silence in the library' });
 256     $builder->build_sample_biblio({ title => 'Silence in the shadow' });
 257
 258     my (undef, $initial_items_count) = SearchItems(undef, {rows => 1});
 259
 260     # Add two items
 261     my $item1 = $builder->build_sample_item(
 262         {
 263             biblionumber => $biblio->biblionumber,
 264             library      => $library1->{branchcode},
 265             itype        => $itemtype->{itemtype}
 266         }
 267     );
 268     my $item1_itemnumber = $item1->itemnumber;
 269     my $item2_itemnumber = $builder->build_sample_item(
 270         {
 271             biblionumber => $biblio->biblionumber,
 272             library      => $library2->{branchcode},
 273             itype        => $itemtype->{itemtype}
 274         }
 275     )->itemnumber;
 276
 277     my ($items, $total_results);
 278
 279     ($items, $total_results) = SearchItems();
 280
 281     is($total_results, $initial_items_count + 2, "Created 2 new items");
 282     is(scalar @$items, $total_results, "SearchItems() returns all items");
 283
 284     ($items, $total_results) = SearchItems(undef, {rows => 1});
 285     is($total_results, $initial_items_count + 2);
 286     is(scalar @$items, 1, "SearchItems(undef, {rows => 1}) returns only 1 item");
 287
 288     # Search all items where homebranch = 'CPL'
 289     my $filter = {
 290         field => 'homebranch',
 291         query => $library1->{branchcode},
 292         operator => '=',
 293     };
 294     ($items, $total_results) = SearchItems($filter);
 295     ok($total_results > 0, "There is at least one CPL item");
 296     my $all_items_are_CPL = 1;
 297     foreach my $item (@$items) {
 298         if ($item->{homebranch} ne $library1->{branchcode}) {
 299             $all_items_are_CPL = 0;
 300             last;
 301         }
 302     }
 303     ok($all_items_are_CPL, "All items returned by SearchItems are from CPL");
 304
 305     # Search all items where homebranch != 'CPL'
 306     $filter = {
 307         field => 'homebranch',
 308         query => $library1->{branchcode},
 309         operator => '!=',
 310     };
 311     ($items, $total_results) = SearchItems($filter);
 312     ok($total_results > 0, "There is at least one non-CPL item");
 313     my $all_items_are_not_CPL = 1;
 314     foreach my $item (@$items) {
 315         if ($item->{homebranch} eq $library1->{branchcode}) {
 316             $all_items_are_not_CPL = 0;
 317             last;
 318         }
 319     }
 320     ok($all_items_are_not_CPL, "All items returned by SearchItems are not from CPL");
 321
 322     # Search all items where biblio title (245$a) is like 'Silence in the %'
 323     $filter = {
 324         field => 'marc:245$a',
 325         query => 'Silence in the %',
 326         operator => 'like',
 327     };
 328     ($items, $total_results) = SearchItems($filter);
 329     ok($total_results >= 2, "There is at least 2 items with a biblio title like 'Silence in the %'");
 330
 331     # Search all items where biblio title is 'Silence in the library'
 332     # and homebranch is 'CPL'
 333     $filter = {
 334         conjunction => 'AND',
 335         filters => [
 336             {
 337                 field => 'marc:245$a',
 338                 query => 'Silence in the %',
 339                 operator => 'like',
 340             },
 341             {
 342                 field => 'homebranch',
 343                 query => $library1->{branchcode},
 344                 operator => '=',
 345             },
 346         ],
 347     };
 348     ($items, $total_results) = SearchItems($filter);
 349     my $found = 0;
 350     foreach my $item (@$items) {
 351         if ($item->{itemnumber} == $item1_itemnumber) {
 352             $found = 1;
 353             last;
 354         }
 355     }
 356     ok($found, "item1 found");
 357
 358     my $frameworkcode = q||;
 359     my ($itemfield) = GetMarcFromKohaField( 'items.itemnumber' );
 360
 361     # Create item subfield 'z' without link
 362     $dbh->do('DELETE FROM marc_subfield_structure WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 363     $dbh->do('INSERT INTO marc_subfield_structure (tagfield, tagsubfield, frameworkcode) VALUES (?, "z", ?)', undef, $itemfield, $frameworkcode);
 364
 365     # Clear cache
 366     my $cache = Koha::Caches->get_instance();
 367     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 368     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 369     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 370
 371     my $item3_record = MARC::Record->new;
 372     $item3_record->append_fields(
 373         MARC::Field->new(
 374             $itemfield, '', '',
 375             'z' => 'foobar',
 376             'y' => $itemtype->{itemtype}
 377         )
 378     );
 379     my (undef, undef, $item3_itemnumber) = AddItemFromMarc($item3_record,
 380         $biblio->biblionumber);
 381
 382     # Search item where item subfield z is "foobar"
 383     $filter = {
 384         field => 'marc:' . $itemfield . '$z',
 385         query => 'foobar',
 386         operator => 'like',
 387     };
 388     ($items, $total_results) = SearchItems($filter);
 389     ok(scalar @$items == 1, 'found 1 item with $z = "foobar"');
 390
 391     # Link $z to items.itemnotes (and make sure there is no other subfields
 392     # linked to it)
 393     $dbh->do('DELETE FROM marc_subfield_structure WHERE kohafield="items.itemnotes" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 394     $dbh->do('UPDATE marc_subfield_structure SET kohafield="items.itemnotes" WHERE tagfield=? AND tagsubfield="z" AND frameworkcode=?', undef, $itemfield, $frameworkcode);
 395
 396     # Clear cache
 397     $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 398     $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 399     $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 400
 401     ModItemFromMarc($item3_record, $biblio->biblionumber, $item3_itemnumber);
 402
 403     # Make sure the link is used
 404     my $item3 = Koha::Items->find($item3_itemnumber);
 405     is($item3->itemnotes, 'foobar', 'itemnotes eq "foobar"');
 406
 407     # Do the same search again.
 408     # This time it will search in items.itemnotes
 409     ($items, $total_results) = SearchItems($filter);
 410     is(scalar(@$items), 1, 'found 1 item with itemnotes = "foobar"');
 411
 412     my ($cpl_items_after) = SearchItems( { field => 'homebranch', query => $library1->{branchcode} } );
 413     is( ( scalar( @$cpl_items_after ) - scalar ( @$cpl_items_before ) ), 1, 'SearchItems should return something' );
 414
 415     # Issues count = 0
 416     $filter = {
 417         conjunction => 'AND',
 418         filters => [
 419             {
 420                 field => 'issues',
 421                 query => 0,
 422                 operator => '=',
 423             },
 424             {
 425                 field => 'homebranch',
 426                 query => $library1->{branchcode},
 427                 operator => '=',
 428             },
 429         ],
 430     };
 431     ($items, $total_results) = SearchItems($filter);
 432     is($total_results, 1, "Search items.issues issues = 0 returns result (items.issues defaults to 0)");
 433
 434     # Is null
 435     $filter = {
 436         conjunction => 'AND',
 437         filters     => [
 438             {
 439                 field    => 'new_status',
 440                 query    => 0,
 441                 operator => '='
 442             },
 443             {
 444                 field    => 'homebranch',
 445                 query    => $library1->{branchcode},
 446                 operator => '=',
 447             },
 448         ],
 449     };
 450     ($items, $total_results) = SearchItems($filter);
 451     is($total_results, 0, 'found no item with new_status=0 without ifnull');
 452
 453     $filter->{filters}[0]->{ifnull} = 0;
 454     ($items, $total_results) = SearchItems($filter);
 455     is($total_results, 1, 'found all items of library1 with new_status=0 with ifnull = 0');
 456
 457     t::lib::Mocks::mock_userenv({ branchcode => $item1->homebranch });
 458     my $patron = $builder->build_object({ class => 'Koha::Patrons' });
 459     AddIssue( $patron, $item1->barcode );
 460     # Search item where item is checked out
 461     $filter = {
 462         conjunction => 'AND',
 463         filters => [
 464             {
 465                 field => 'onloan',
 466                 query => 'not null',
 467                 operator => 'is',
 468             },
 469             {
 470                 field => 'homebranch',
 471                 query => $item1->homebranch,
 472                 operator => '=',
 473             },
 474         ],
 475     };
 476     ($items, $total_results) = SearchItems($filter);
 477     ok(scalar @$items == 1, 'found 1 checked out item');
 478
 479     # When sorting by descending availability, checked out item should show first
 480     my $params = {
 481         sortby => 'availability',
 482         sortorder => 'DESC',
 483     };
 484     $filter = {
 485         field => 'homebranch',
 486         query => $item1->homebranch,
 487         operator => '=',
 488     };
 489     ($items, $total_results) = SearchItems($filter,$params);
 490     is($items->[0]->{barcode}, $item1->barcode, 'Items sorted as expected by availability');
 491
 492     subtest 'Search items by ISSN and ISBN with variations' => sub {
 493         plan tests => 4;
 494
 495         my $marc_record = MARC::Record->new;
 496         # Prepare ISBN for biblio:
 497         $marc_record->append_fields( MARC::Field->new( '020', '', '', 'a' => '9780136019701' ) );
 498         # Prepare ISSN for biblio:
 499         $marc_record->append_fields( MARC::Field->new( '022', '', '', 'a' => '2434561X' ) );
 500         my ( $isbnissn_biblionumber ) = AddBiblio( $marc_record, '' );
 501         my $isbnissn_biblio = Koha::Biblios->find($isbnissn_biblionumber);
 502
 503         my $item = $builder->build_sample_item(
 504             {
 505                 biblionumber => $isbnissn_biblio->biblionumber,
 506             }
 507         );
 508         my $item_itemnumber = $item->itemnumber;
 509
 510         my $filter_isbn = {
 511             field => 'isbn',
 512             query => '978013-6019701',
 513             operator => 'like',
 514         };
 515
 516         t::lib::Mocks::mock_preference('SearchWithISBNVariations', 0);
 517         ($items, $total_results) = SearchItems($filter_isbn);
 518         is($total_results, 0, "Search items finds ISBN, no variations");
 519
 520         t::lib::Mocks::mock_preference('SearchWithISBNVariations', 1);
 521         ($items, $total_results) = SearchItems($filter_isbn);
 522         is($total_results, 1, "Search items finds ISBN with variations");
 523
 524         my $filter_issn = {
 525             field => 'issn',
 526             query => '2434-561X',
 527             operator => 'like',
 528         };
 529
 530         t::lib::Mocks::mock_preference('SearchWithISSNVariations', 0);
 531         ($items, $total_results) = SearchItems($filter_issn);
 532         is($total_results, 0, "Search items finds ISSN, no variations");
 533
 534         t::lib::Mocks::mock_preference('SearchWithISSNVariations', 1);
 535         ($items, $total_results) = SearchItems($filter_issn);
 536         is($total_results, 1, "Search items finds ISSN with variations");
 537     };
 538
 539     $schema->storage->txn_rollback;
 540 };
 541
 542 subtest 'Koha::Item(s) tests' => sub {
 543
 544     plan tests => 7;
 545
 546     $schema->storage->txn_begin();
 547
 548     my $builder = t::lib::TestBuilder->new;
 549     my $library1 = $builder->build({
 550         source => 'Branch',
 551     });
 552     my $library2 = $builder->build({
 553         source => 'Branch',
 554     });
 555     my $itemtype = $builder->build({
 556         source => 'Itemtype',
 557     });
 558
 559     # Create a biblio and item for testing
 560     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 561     my $biblio = $builder->build_sample_biblio();
 562     my $itemnumber = $builder->build_sample_item(
 563         {
 564             biblionumber  => $biblio->biblionumber,
 565             homebranch    => $library1->{branchcode},
 566             holdingbranch => $library2->{branchcode},
 567             itype         => $itemtype->{itemtype}
 568         }
 569     )->itemnumber;
 570
 571     # Get item.
 572     my $item = Koha::Items->find( $itemnumber );
 573     is( ref($item), 'Koha::Item', "Got Koha::Item" );
 574
 575     my $homebranch = $item->home_branch();
 576     is( ref($homebranch), 'Koha::Library', "Got Koha::Library from home_branch method" );
 577     is( $homebranch->branchcode(), $library1->{branchcode}, "Home branch code matches homebranch" );
 578
 579     my $holdingbranch = $item->holding_branch();
 580     is( ref($holdingbranch), 'Koha::Library', "Got Koha::Library from holding_branch method" );
 581     is( $holdingbranch->branchcode(), $library2->{branchcode}, "Home branch code matches holdingbranch" );
 582
 583     $biblio = $item->biblio();
 584     is( ref($item->biblio), 'Koha::Biblio', "Got Koha::Biblio from biblio method" );
 585     is( $item->biblio->title(), $biblio->title, 'Title matches biblio title' );
 586
 587     $schema->storage->txn_rollback;
 588 };
 589
 590 subtest 'get_hostitemnumbers_of' => sub {
 591     plan tests => 3;
 592
 593     $schema->storage->txn_begin;
 594     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 595     my $builder = t::lib::TestBuilder->new;
 596
 597     # Host item field without 0 or 9
 598     my $bib1 = MARC::Record->new();
 599     $bib1->append_fields(
 600         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 601         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 602         MARC::Field->new('773', ' ', ' ', b => 'b without 0 or 9'),
 603     );
 604     my ($biblionumber1, $bibitemnum1) = AddBiblio($bib1, '');
 605     my @itemnumbers1 = C4::Items::get_hostitemnumbers_of( $biblionumber1 );
 606     is( scalar @itemnumbers1, 0, '773 without 0 or 9');
 607
 608     # Correct host item field, analytical records on
 609     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 1);
 610     my $hostitem = $builder->build_sample_item();
 611     my $bib2 = MARC::Record->new();
 612     $bib2->append_fields(
 613         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 614         MARC::Field->new('245', ' ', ' ', a => 'Silence in the library'),
 615         MARC::Field->new('773', ' ', ' ', 0 => $hostitem->biblionumber , 9 => $hostitem->itemnumber, b => 'b' ),
 616     );
 617     my ($biblionumber2, $bibitemnum2) = AddBiblio($bib2, '');
 618     my @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 619     is( scalar @itemnumbers2, 1, '773 with 0 and 9, EasyAnalyticalRecords on');
 620
 621     # Correct host item field, analytical records off
 622     t::lib::Mocks::mock_preference('EasyAnalyticalRecords', 0);
 623     @itemnumbers2 = C4::Items::get_hostitemnumbers_of( $biblionumber2 );
 624     is( scalar @itemnumbers2, 0, '773 with 0 and 9, EasyAnalyticalRecords off');
 625
 626     $schema->storage->txn_rollback;
 627 };
 628
 629 subtest 'Test logging for ModItem' => sub {
 630
 631     plan tests => 3;
 632
 633     t::lib::Mocks::mock_preference('CataloguingLog', 1);
 634
 635     $schema->storage->txn_begin;
 636
 637     my $builder = t::lib::TestBuilder->new;
 638     my $library = $builder->build({
 639         source => 'Branch',
 640     });
 641     my $itemtype = $builder->build({
 642         source => 'Itemtype',
 643     });
 644
 645     # Create a biblio instance for testing
 646     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 647     my $biblio = $builder->build_sample_biblio();
 648
 649     # Add an item.
 650     my $item = $builder->build_sample_item(
 651         {
 652             biblionumber => $biblio->biblionumber,
 653             library      => $library->{homebranch},
 654             location     => $location,
 655             itype        => $itemtype->{itemtype}
 656         }
 657     );
 658
 659     # False means no logging
 660     $schema->resultset('ActionLog')->search()->delete();
 661     $item->location($location)->store({ log_action => 0 });
 662     is( $schema->resultset('ActionLog')->count(), 0, 'False value does not trigger logging' );
 663
 664     # True means logging
 665     $schema->resultset('ActionLog')->search()->delete();
 666     $item->location('new location')->store({ log_action => 1 });
 667     is( $schema->resultset('ActionLog')->count(), 1, 'True value does trigger logging' );
 668
 669     # Undefined defaults to true
 670     $schema->resultset('ActionLog')->search()->delete();
 671     $item->location($location)->store();
 672     is( $schema->resultset('ActionLog')->count(), 1, 'Undefined value defaults to true, triggers logging' );
 673
 674     $schema->storage->txn_rollback;
 675 };
 676
 677 subtest 'Check stockrotationitem relationship' => sub {
 678     plan tests => 1;
 679
 680     $schema->storage->txn_begin();
 681
 682     my $builder = t::lib::TestBuilder->new;
 683     my $item = $builder->build_sample_item;
 684
 685     $builder->build({
 686         source => 'Stockrotationitem',
 687         value  => { itemnumber_id => $item->itemnumber }
 688     });
 689
 690     my $sritem = Koha::Items->find($item->itemnumber)->stockrotationitem;
 691     isa_ok( $sritem, 'Koha::StockRotationItem', "Relationship works and correctly creates Koha::Object." );
 692
 693     $schema->storage->txn_rollback;
 694 };
 695
 696 subtest 'Check add_to_rota method' => sub {
 697     plan tests => 2;
 698
 699     $schema->storage->txn_begin();
 700
 701     my $builder = t::lib::TestBuilder->new;
 702     my $item = $builder->build_sample_item;
 703     my $rota = $builder->build({ source => 'Stockrotationrota' });
 704     my $srrota = Koha::StockRotationRotas->find($rota->{rota_id});
 705
 706     $builder->build({
 707         source => 'Stockrotationstage',
 708         value  => { rota_id => $rota->{rota_id} },
 709     });
 710
 711     my $sritem = Koha::Items->find($item->itemnumber);
 712     $sritem->add_to_rota($rota->{rota_id});
 713
 714     is(
 715         Koha::StockRotationItems->find($item->itemnumber)->stage_id,
 716         $srrota->stockrotationstages->next->stage_id,
 717         "Adding to a rota a new sritem item being assigned to its first stage."
 718     );
 719
 720     my $newrota = $builder->build({ source => 'Stockrotationrota' });
 721
 722     my $srnewrota = Koha::StockRotationRotas->find($newrota->{rota_id});
 723
 724     $builder->build({
 725         source => 'Stockrotationstage',
 726         value  => { rota_id => $newrota->{rota_id} },
 727     });
 728
 729     $sritem->add_to_rota($newrota->{rota_id});
 730
 731     is(
 732         Koha::StockRotationItems->find($item->itemnumber)->stage_id,
 733         $srnewrota->stockrotationstages->next->stage_id,
 734         "Moving an item results in that sritem being assigned to the new first stage."
 735     );
 736
 737     $schema->storage->txn_rollback;
 738 };
 739
 740 subtest 'Split subfields in Item2Marc (Bug 21774)' => sub {
 741     plan tests => 3;
 742     $schema->storage->txn_begin;
 743
 744     my $builder = t::lib::TestBuilder->new;
 745     my $item = $builder->build_sample_item({ ccode => 'A|B' });
 746
 747     Koha::MarcSubfieldStructures->search({ tagfield => '952', tagsubfield => '8' })->delete; # theoretical precaution
 748     Koha::MarcSubfieldStructures->search({ kohafield => 'items.ccode' })->delete;
 749     my $mapping = Koha::MarcSubfieldStructure->new(
 750         {
 751             frameworkcode => q{},
 752             tagfield      => '952',
 753             tagsubfield   => '8',
 754             kohafield     => 'items.ccode',
 755             repeatable    => 1
 756         }
 757     )->store;
 758     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 759
 760     # Start testing
 761     my $marc = C4::Items::Item2Marc( $item->unblessed, $item->biblionumber );
 762     my @subs = $marc->subfield( $mapping->tagfield, $mapping->tagsubfield );
 763     is( @subs, 2, 'Expect two subfields' );
 764     is( $subs[0], 'A', 'First subfield matches' );
 765     is( $subs[1], 'B', 'Second subfield matches' );
 766
 767     $schema->storage->txn_rollback;
 768 };
 769
 770 subtest 'ModItemFromMarc' => sub {
 771     plan tests => 8;
 772     $schema->storage->txn_begin;
 773
 774     my $builder = t::lib::TestBuilder->new;
 775     my ($itemfield) = GetMarcFromKohaField( 'items.itemnumber' );
 776     my $itemtype = $builder->build_object({ class => 'Koha::ItemTypes' });
 777     my $biblio = $builder->build_sample_biblio;
 778     my ( $lost_tag, $lost_sf ) = GetMarcFromKohaField( 'items.itemlost' );
 779     my $item_record = MARC::Record->new;
 780     $item_record->append_fields(
 781         MARC::Field->new(
 782             $itemfield, '', '',
 783             'y' => $itemtype->itemtype,
 784         ),
 785         MARC::Field->new(
 786             $itemfield, '', '',
 787             $lost_sf => '1',
 788         ),
 789     );
 790     my (undef, undef, $itemnumber) = AddItemFromMarc($item_record,
 791         $biblio->biblionumber);
 792
 793     my $item = Koha::Items->find($itemnumber);
 794     is( $item->itemlost, 1, 'itemlost picked from the item marc');
 795
 796     $item->new_status("this is something")->store;
 797
 798     my $updated_item_record = MARC::Record->new;
 799     $updated_item_record->append_fields(
 800         MARC::Field->new(
 801             $itemfield, '', '',
 802             'y' => $itemtype->itemtype,
 803         )
 804     );
 805
 806     my $updated_item = ModItemFromMarc($updated_item_record, $biblio->biblionumber, $itemnumber);
 807     is( $updated_item->{itemlost}, 0, 'itemlost should have been reset to the default value in DB' );
 808     is( $updated_item->{new_status}, "this is something", "Non mapped field has not been reset" );
 809     is( Koha::Items->find($itemnumber)->new_status, "this is something" );
 810
 811     subtest 'cn_sort' => sub {
 812         plan tests => 3;
 813
 814         my $item = $builder->build_sample_item;
 815         $item->set({ cn_source => 'ddc', itemcallnumber => 'xxx' })->store;
 816         is( $item->cn_sort, 'XXX', 'init values set are expected' );
 817
 818         my $marc = C4::Items::Item2Marc( $item->get_from_storage->unblessed, $item->biblionumber );
 819         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 820         is( $item->get_from_storage->cn_sort, 'XXX', 'cn_sort has not been updated' );
 821
 822         $marc = C4::Items::Item2Marc( { %{$item->unblessed}, itemcallnumber => 'yyy' }, $item->biblionumber );
 823         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 824         is( $item->get_from_storage->cn_sort, 'YYY', 'cn_sort has been updated' );
 825     };
 826
 827     subtest 'onloan' => sub {
 828         plan tests => 3;
 829
 830         my $item = $builder->build_sample_item;
 831         $item->set({ onloan => '2022-03-19' })->store;
 832         is( $item->onloan, '2022-03-19', 'init values set are expected' );
 833
 834         my $marc = C4::Items::Item2Marc( $item->get_from_storage->unblessed, $item->biblionumber );
 835         my ( $MARCfield, $MARCsubfield ) = GetMarcFromKohaField( 'items.onloan' );
 836         $marc->field($MARCfield)->delete_subfield( code => $MARCsubfield );
 837         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 838         is( $item->get_from_storage->onloan, '2022-03-19', 'onloan has not been updated if not passed' );
 839
 840         $marc = C4::Items::Item2Marc( { %{$item->unblessed}, onloan => '2022-03-26' }, $item->biblionumber );
 841         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 842         is( $item->get_from_storage->onloan, '2022-03-26', 'onloan has been updated when passed in' );
 843     };
 844
 845     subtest 'dateaccessioned' => sub {
 846         plan tests => 3;
 847
 848         my $item = $builder->build_sample_item;
 849         $item->set({ dateaccessioned => '2022-03-19' })->store->discard_changes;
 850         is( $item->dateaccessioned, '2022-03-19', 'init values set are expected' );
 851
 852         my $marc = C4::Items::Item2Marc( $item->get_from_storage->unblessed, $item->biblionumber );
 853         my ( $MARCfield, $MARCsubfield ) = GetMarcFromKohaField( 'items.dateaccessioned' );
 854         $marc->field($MARCfield)->delete_subfield( code => $MARCsubfield );
 855         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 856         is( $item->get_from_storage->dateaccessioned, '2022-03-19', 'dateaccessioned has not been updated if not passed' );
 857
 858         $marc = C4::Items::Item2Marc( { %{$item->unblessed}, dateaccessioned => '2022-03-26' }, $item->biblionumber );
 859         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 860         is( $item->get_from_storage->dateaccessioned, '2022-03-26', 'dateaccessioned has been updated when passed in' );
 861     };
 862
 863     subtest 'permanent_location' => sub {
 864         plan tests => 10;
 865
 866         # Make sure items.permanent_location is not mapped
 867         Koha::MarcSubfieldStructures->search(
 868             {
 869                 frameworkcode => q{},
 870                 kohafield     => 'items.permanent_location',
 871             }
 872         )->delete;
 873         Koha::MarcSubfieldStructures->search(
 874             {
 875                 frameworkcode => q{},
 876                 tagfield     => '952',
 877                 tagsubfield     => 'C',
 878             }
 879         )->delete;
 880         Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 881
 882         my $item = $builder->build_sample_item;
 883
 884         # By default, setting location to something new should set permanent location to the same thing
 885         # with the usual exceptions
 886         $item->set({ location => 'A', permanent_location => 'A' })->store;
 887         is( $item->location, 'A', 'initial location set as expected' );
 888         is( $item->permanent_location, 'A', 'initial permanent location set as expected' );
 889
 890         $item->location('B');
 891         my $marc = C4::Items::Item2Marc( $item->unblessed, $item->biblionumber );
 892         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 893
 894         $item = $item->get_from_storage;
 895         is( $item->location, 'B', 'new location set as expected' );
 896         is( $item->permanent_location, 'B', 'new permanent location set as expected' );
 897
 898         # Added a marc mapping for permanent location, allows it to be edited independently
 899         my $mapping = Koha::MarcSubfieldStructure->new(
 900             {
 901                 frameworkcode => q{},
 902                 tagfield      => '952',
 903                 tagsubfield   => 'C',
 904                 kohafield     => 'items.permanent_location',
 905                 repeatable    => 0,
 906                 tab           => 10,
 907                 hidden        => 0,
 908             }
 909         )->store;
 910         Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 911
 912         # Now if we change location, and also pass in a permanent location
 913         # the permanent_location will not be overwritten by location
 914         $item->location('C');
 915         $marc = C4::Items::Item2Marc( $item->unblessed, $item->biblionumber );
 916         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 917         $item = $item->get_from_storage;
 918         is( $item->location, 'C', 'next new location set as expected' );
 919         is( $item->permanent_location, 'B', 'permanent location remains unchanged as expected' );
 920
 921         $item->permanent_location(undef)->more_subfields_xml(undef)->store;
 922         # Clear values from the DB
 923         $item = $item->get_from_storage;
 924
 925         # Update the location
 926         $item->location('D');
 927         $marc = C4::Items::Item2Marc( $item->unblessed, $item->biblionumber );
 928         # Remove the permanent_location field from the form
 929         $marc->field('952')->delete_subfield("C");
 930         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 931         $item = $item->get_from_storage;
 932         is( $item->location, 'D', 'next new location set as expected' );
 933         is( $item->permanent_location, 'D', 'permanent location is updated if not previously set and no value passed' );
 934
 935         # Clear values from the DB
 936         $item->permanent_location(undef)->more_subfields_xml(undef)->store;
 937         $item = $item->get_from_storage;
 938
 939         # This time nothing is set, but we pass an empty string
 940         $item->permanent_location("");
 941         $item->location('E');
 942         $marc = C4::Items::Item2Marc( $item->unblessed, $item->biblionumber );
 943         $marc->field('952')->add_subfields( "C", "" );
 944         ModItemFromMarc( $marc, $item->biblionumber, $item->itemnumber );
 945         $item = $item->get_from_storage;
 946         is( $item->location, 'E', 'next new location set as expected' );
 947         is( $item->permanent_location, undef, 'permanent location is not updated if previously set as blank string' );
 948     };
 949
 950     $schema->storage->txn_rollback;
 951     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 952 };
 953
 954 subtest 'ModDateLastSeen' => sub {
 955     plan tests => 5;
 956     $schema->storage->txn_begin;
 957
 958     my $builder = t::lib::TestBuilder->new;
 959     my $item = $builder->build_sample_item;
 960     t::lib::Mocks::mock_preference('CataloguingLog', '1');
 961     my $logs_before = Koha::ActionLogs->search({ module => 'CATALOGUING', action => 'MODIFY', object => $item->itemnumber })->count;
 962     ModDateLastSeen($item->itemnumber);
 963     my $logs_after = Koha::ActionLogs->search({ module => 'CATALOGUING', action => 'MODIFY', object => $item->itemnumber })->count;
 964     is( $logs_after, $logs_before, "ModDateLastSeen doesn't log if item not lost");
 965     $item->itemlost(1)->store({ log_action => 0 });
 966     ModDateLastSeen($item->itemnumber, 1);
 967     $item->discard_changes;
 968     $logs_after = Koha::ActionLogs->search({ module => 'CATALOGUING', action => 'MODIFY', object => $item->itemnumber })->count;
 969     is( $item->itemlost, 1, "Item left lost when parameter is passed");
 970     is( $logs_after, $logs_before, "ModDateLastSeen doesn't log if item not lost");
 971     ModDateLastSeen($item->itemnumber);
 972     $item->discard_changes;
 973     $logs_after = Koha::ActionLogs->search({ module => 'CATALOGUING', action => 'MODIFY', object => $item->itemnumber })->count;
 974     is( $item->itemlost, 0, "Item no longer lost when no parameter is passed");
 975     is( $logs_after, $logs_before + 1, "ModDateLastSeen logs if item was lost and now found");
 976 };
 977
 978 subtest 'CartToShelf test' => sub {
 979     plan tests => 2;
 980
 981     $schema->storage->txn_begin;
 982     my $dbh     = C4::Context->dbh;
 983     my $builder = t::lib::TestBuilder->new;
 984
 985     my $item = $builder->build_sample_item();
 986
 987     $item->permanent_location('BANANA')->location('CART')->store();
 988
 989     CartToShelf( $item->id );
 990
 991     $item->discard_changes;
 992
 993     is( $item->location, 'BANANA', 'Item is correctly returned to permanent location' );
 994
 995     my $mock_RTHQ = Test::MockModule->new("Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue");
 996     $mock_RTHQ->mock( enqueue => sub { warn "RTHQ" } );
 997     t::lib::Mocks::mock_preference( 'RealTimeHoldsQueue', '1' );
 998
 999     $item->location('CART')->store( { skip_holds_queue => 1 } );
1000     warnings_are {
1001         CartToShelf( $item->id );
1002     }
1003     [], 'No RTHQ update triggered by CartToShelf';
1004
1005     $schema->storage->txn_rollback;
1006
1007 };