t/db_dependent/Koha/Item.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2019 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 7;
  23
  24 use C4::Biblio;
  25 use C4::Circulation;
  26
  27 use Koha::Items;
  28 use Koha::Database;
  29 use Koha::Old::Items;
  30
  31 use List::MoreUtils qw(all);
  32
  33 use t::lib::TestBuilder;
  34 use t::lib::Mocks;
  35
  36 my $schema  = Koha::Database->new->schema;
  37 my $builder = t::lib::TestBuilder->new;
  38
  39 subtest 'hidden_in_opac() tests' => sub {
  40
  41     plan tests => 4;
  42
  43     $schema->storage->txn_begin;
  44
  45     my $item  = $builder->build_sample_item({ itemlost => 2 });
  46     my $rules = {};
  47
  48     # disable hidelostitems as it interteres with OpachiddenItems for the calculation
  49     t::lib::Mocks::mock_preference( 'hidelostitems', 0 );
  50
  51     ok( !$item->hidden_in_opac, 'No rules passed, shouldn\'t hide' );
  52     ok( !$item->hidden_in_opac({ rules => $rules }), 'Empty rules passed, shouldn\'t hide' );
  53
  54     # enable hidelostitems to verify correct behaviour
  55     t::lib::Mocks::mock_preference( 'hidelostitems', 1 );
  56     ok( $item->hidden_in_opac, 'Even with no rules, item should hide because of hidelostitems syspref' );
  57
  58     # disable hidelostitems
  59     t::lib::Mocks::mock_preference( 'hidelostitems', 0 );
  60     my $withdrawn = $item->withdrawn + 1; # make sure this attribute doesn't match
  61
  62     $rules = { withdrawn => [$withdrawn], itype => [ $item->itype ] };
  63
  64     ok( $item->hidden_in_opac({ rules => $rules }), 'Rule matching itype passed, should hide' );
  65
  66
  67
  68     $schema->storage->txn_rollback;
  69 };
  70
  71 subtest 'has_pending_hold() tests' => sub {
  72
  73     plan tests => 2;
  74
  75     $schema->storage->txn_begin;
  76
  77     my $dbh = C4::Context->dbh;
  78     my $item  = $builder->build_sample_item({ itemlost => 0 });
  79     my $itemnumber = $item->itemnumber;
  80
  81     $dbh->do("INSERT INTO tmp_holdsqueue (surname,borrowernumber,itemnumber) VALUES ('Clamp',42,$itemnumber)");
  82     ok( $item->has_pending_hold, "Yes, we have a pending hold");
  83     $dbh->do("DELETE FROM tmp_holdsqueue WHERE itemnumber=$itemnumber");
  84     ok( !$item->has_pending_hold, "We don't have a pending hold if nothing in the tmp_holdsqueue");
  85
  86     $schema->storage->txn_rollback;
  87 };
  88
  89 subtest "as_marc_field() tests" => sub {
  90
  91     my $mss = C4::Biblio::GetMarcSubfieldStructure( '', { unsafe => 1 } );
  92
  93     my @schema_columns = $schema->resultset('Item')->result_source->columns;
  94     my @mapped_columns = grep { exists $mss->{'items.'.$_} } @schema_columns;
  95
  96     plan tests => 2 * (scalar @mapped_columns + 1) + 2;
  97
  98     $schema->storage->txn_begin;
  99
 100     my $item = $builder->build_sample_item;
 101     # Make sure it has at least one undefined attribute
 102     $item->set({ replacementprice => undef })->store->discard_changes;
 103
 104     # Tests with the mss parameter
 105     my $marc_field = $item->as_marc_field({ mss => $mss });
 106
 107     is(
 108         $marc_field->tag,
 109         $mss->{'items.itemnumber'}[0]->{tagfield},
 110         'Generated field set the right tag number'
 111     );
 112
 113     foreach my $column ( @mapped_columns ) {
 114         my $tagsubfield = $mss->{ 'items.' . $column }[0]->{tagsubfield};
 115         is( $marc_field->subfield($tagsubfield),
 116             $item->$column, "Value is mapped correctly for column $column" );
 117     }
 118
 119     # Tests without the mss parameter
 120     $marc_field = $item->as_marc_field();
 121
 122     is(
 123         $marc_field->tag,
 124         $mss->{'items.itemnumber'}[0]->{tagfield},
 125         'Generated field set the right tag number'
 126     );
 127
 128     foreach my $column (@mapped_columns) {
 129         my $tagsubfield = $mss->{ 'items.' . $column }[0]->{tagsubfield};
 130         is( $marc_field->subfield($tagsubfield),
 131             $item->$column, "Value is mapped correctly for column $column" );
 132     }
 133
 134     my $unmapped_subfield = Koha::MarcSubfieldStructure->new(
 135         {
 136             frameworkcode => '',
 137             tagfield      => $mss->{'items.itemnumber'}[0]->{tagfield},
 138             tagsubfield   => 'X',
 139         }
 140     )->store;
 141
 142     $mss = C4::Biblio::GetMarcSubfieldStructure( '', { unsafe => 0 } );
 143     my @unlinked_subfields;
 144     push @unlinked_subfields, X => 'Something weird';
 145     $item->more_subfields_xml( C4::Items::_get_unlinked_subfields_xml( \@unlinked_subfields ) )->store;
 146
 147     $marc_field = $item->as_marc_field;
 148
 149     my @subfields = $marc_field->subfields;
 150     my $result = all { defined $_->[1] } @subfields;
 151     ok( $result, 'There are no undef subfields' );
 152
 153     is( scalar $marc_field->subfield('X'), 'Something weird', 'more_subfield_xml is considered' );
 154
 155     $schema->storage->txn_rollback;
 156 };
 157
 158 subtest 'pickup_locations' => sub {
 159     plan tests => 119;
 160
 161     $schema->storage->txn_begin;
 162
 163     my $dbh = C4::Context->dbh;
 164
 165     # Cleanup database
 166     Koha::Holds->search->delete;
 167     $dbh->do('DELETE FROM issues');
 168     Koha::Patrons->search->delete;
 169     Koha::Items->search->delete;
 170     Koha::Libraries->search->delete;
 171     Koha::CirculationRules->search->delete;
 172     Koha::CirculationRules->set_rules(
 173         {
 174             categorycode => undef,
 175             itemtype     => undef,
 176             branchcode   => undef,
 177             rules        => {
 178                 reservesallowed => 25,
 179             }
 180         }
 181     );
 182
 183     my $root1 = $builder->build_object( { class => 'Koha::Library::Groups', value => { ft_local_hold_group => 1, branchcode => undef } } );
 184     my $root2 = $builder->build_object( { class => 'Koha::Library::Groups', value => { ft_local_hold_group => 1, branchcode => undef } } );
 185     my $library1 = $builder->build_object( { class => 'Koha::Libraries', value => { pickup_location => 1, } } );
 186     my $library2 = $builder->build_object( { class => 'Koha::Libraries', value => { pickup_location => 1, } } );
 187     my $library3 = $builder->build_object( { class => 'Koha::Libraries', value => { pickup_location => 0, } } );
 188     my $library4 = $builder->build_object( { class => 'Koha::Libraries', value => { pickup_location => 1, } } );
 189     my $group1_1 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root1->id, branchcode => $library1->branchcode } } );
 190     my $group1_2 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root1->id, branchcode => $library2->branchcode } } );
 191
 192     my $group2_1 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root2->id, branchcode => $library3->branchcode } } );
 193     my $group2_2 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root2->id, branchcode => $library4->branchcode } } );
 194
 195     my $itemtype = $builder->build_object( { class => 'Koha::ItemTypes', value => { itemtype => 'test' } } );
 196     my $item1 = $builder->build_sample_item(
 197         {
 198             homebranch    => $library1->branchcode,
 199             holdingbranch => $library2->branchcode,
 200             barcode       => '1',
 201             itype         => 'test',
 202             ccode         => 'Gollum'
 203         }
 204     )->store;
 205
 206     my $item3 = $builder->build_sample_item(
 207         {
 208             homebranch    => $library3->branchcode,
 209             holdingbranch => $library4->branchcode,
 210             barcode       => '3',
 211             itype         => 'test',
 212         }
 213     )->store;
 214
 215     my $patron1 = $builder->build_object( { class => 'Koha::Patrons', value => { branchcode => $library1->branchcode, firstname => '1' } } );
 216     my $patron4 = $builder->build_object( { class => 'Koha::Patrons', value => { branchcode => $library4->branchcode, firstname => '4' } } );
 217
 218     my $results = {
 219         "1-1-1-any"           => 3,
 220         "1-1-1-holdgroup"     => 2,
 221         "1-1-1-patrongroup"   => 2,
 222         "1-1-1-homebranch"    => 1,
 223         "1-1-1-holdingbranch" => 1,
 224         "1-1-2-any"           => 3,
 225         "1-1-2-holdgroup"     => 2,
 226         "1-1-2-patrongroup"   => 2,
 227         "1-1-2-homebranch"    => 1,
 228         "1-1-2-holdingbranch" => 1,
 229         "1-1-3-any"           => 3,
 230         "1-1-3-holdgroup"     => 2,
 231         "1-1-3-patrongroup"   => 2,
 232         "1-1-3-homebranch"    => 1,
 233         "1-1-3-holdingbranch" => 1,
 234         "1-4-1-any"           => 0,
 235         "1-4-1-holdgroup"     => 0,
 236         "1-4-1-patrongroup"   => 0,
 237         "1-4-1-homebranch"    => 0,
 238         "1-4-1-holdingbranch" => 0,
 239         "1-4-2-any"           => 3,
 240         "1-4-2-holdgroup"     => 2,
 241         "1-4-2-patrongroup"   => 1,
 242         "1-4-2-homebranch"    => 1,
 243         "1-4-2-holdingbranch" => 1,
 244         "1-4-3-any"           => 0,
 245         "1-4-3-holdgroup"     => 0,
 246         "1-4-3-patrongroup"   => 0,
 247         "1-4-3-homebranch"    => 0,
 248         "1-4-3-holdingbranch" => 0,
 249         "3-1-1-any"           => 0,
 250         "3-1-1-holdgroup"     => 0,
 251         "3-1-1-patrongroup"   => 0,
 252         "3-1-1-homebranch"    => 0,
 253         "3-1-1-holdingbranch" => 0,
 254         "3-1-2-any"           => 3,
 255         "3-1-2-holdgroup"     => 1,
 256         "3-1-2-patrongroup"   => 2,
 257         "3-1-2-homebranch"    => 0,
 258         "3-1-2-holdingbranch" => 1,
 259         "3-1-3-any"           => 0,
 260         "3-1-3-holdgroup"     => 0,
 261         "3-1-3-patrongroup"   => 0,
 262         "3-1-3-homebranch"    => 0,
 263         "3-1-3-holdingbranch" => 0,
 264         "3-4-1-any"           => 0,
 265         "3-4-1-holdgroup"     => 0,
 266         "3-4-1-patrongroup"   => 0,
 267         "3-4-1-homebranch"    => 0,
 268         "3-4-1-holdingbranch" => 0,
 269         "3-4-2-any"           => 3,
 270         "3-4-2-holdgroup"     => 1,
 271         "3-4-2-patrongroup"   => 1,
 272         "3-4-2-homebranch"    => 0,
 273         "3-4-2-holdingbranch" => 1,
 274         "3-4-3-any"           => 3,
 275         "3-4-3-holdgroup"     => 1,
 276         "3-4-3-patrongroup"   => 1,
 277         "3-4-3-homebranch"    => 0,
 278         "3-4-3-holdingbranch" => 1
 279     };
 280
 281     sub _doTest {
 282         my ( $item, $patron, $ha, $hfp, $results ) = @_;
 283
 284         Koha::CirculationRules->set_rules(
 285             {
 286                 branchcode => undef,
 287                 itemtype   => undef,
 288                 rules => {
 289                     holdallowed => $ha,
 290                     hold_fulfillment_policy => $hfp,
 291                     returnbranch => 'any'
 292                 }
 293             }
 294         );
 295         my @pl = $item->pickup_locations( { patron => $patron} )->as_list;
 296         my $ha_value=$ha==3?'holdgroup':($ha==2?'any':'homebranch');
 297
 298         foreach my $pickup_location (@pl) {
 299             is( ref($pickup_location), 'Koha::Library', 'Object type is correct' );
 300         }
 301         ok(
 302             scalar(@pl) == $results->{
 303                     $item->barcode . '-'
 304                   . $patron->firstname . '-'
 305                   . $ha . '-'
 306                   . $hfp
 307             },
 308             'item'
 309               . $item->barcode
 310               . ', patron'
 311               . $patron->firstname
 312               . ', holdallowed: '
 313               . $ha_value
 314               . ', hold_fulfillment_policy: '
 315               . $hfp
 316               . ' should return '
 317               . $results->{
 318                     $item->barcode . '-'
 319                   . $patron->firstname . '-'
 320                   . $ha . '-'
 321                   . $hfp
 322               }
 323               . ' and returns '
 324               . scalar(@pl)
 325         );
 326
 327     }
 328
 329
 330     foreach my $item ($item1, $item3) {
 331         foreach my $patron ($patron1, $patron4) {
 332             #holdallowed 1: homebranch, 2: any, 3: holdgroup
 333             foreach my $ha (1, 2, 3) {
 334                 foreach my $hfp ('any', 'holdgroup', 'patrongroup', 'homebranch', 'holdingbranch') {
 335                     _doTest($item, $patron, $ha, $hfp, $results);
 336                 }
 337             }
 338         }
 339     }
 340
 341     # Now test that branchtransferlimits will further filter the pickup locations
 342     t::lib::Mocks::mock_preference('UseBranchTransferLimits', 1);
 343     t::lib::Mocks::mock_preference('BranchTransferLimitsType', 'itemtype');
 344     Koha::CirculationRules->set_rules(
 345         {
 346             branchcode => undef,
 347             itemtype   => $item1->itype,
 348             rules      => {
 349                 holdallowed             => 1,
 350                 hold_fulfillment_policy => 1,
 351                 returnbranch            => 'any'
 352             }
 353         }
 354     );
 355     $builder->build_object(
 356         {
 357             class => 'Koha::Item::Transfer::Limits',
 358             value => {
 359                 toBranch   => $library1->branchcode,
 360                 fromBranch => $library2->branchcode,
 361                 itemtype   => $item1->itype,
 362                 ccode      => undef,
 363             }
 364         }
 365     );
 366
 367     my $pickup_locations = $item1->pickup_locations( { patron => $patron1 } )->as_list;
 368     is( scalar @$pickup_locations, 2, "With a transfer limits we get back the libraries that are pickup locations minus 1 limited library");
 369
 370     $builder->build_object(
 371         {
 372             class => 'Koha::Item::Transfer::Limits',
 373             value => {
 374                 toBranch   => $library4->branchcode,
 375                 fromBranch => $library2->branchcode,
 376                 itemtype   => $item1->itype,
 377                 ccode      => undef,
 378             }
 379         }
 380     );
 381
 382     $pickup_locations = $item1->pickup_locations( { patron => $patron1 } )->as_list;
 383     is( scalar @$pickup_locations, 1, "With 2 transfer limits we get back the libraries that are pickup locations minus 2 limited libraries");
 384
 385     t::lib::Mocks::mock_preference('BranchTransferLimitsType', 'ccode');
 386     $pickup_locations = $item1->pickup_locations( { patron => $patron1 } )->as_list;
 387     is( scalar @$pickup_locations, 3, "With no transfer limits of type ccode we get back the libraries that are pickup locations");
 388
 389     $builder->build_object(
 390         {
 391             class => 'Koha::Item::Transfer::Limits',
 392             value => {
 393                 toBranch   => $library2->branchcode,
 394                 fromBranch => $library2->branchcode,
 395                 itemtype   => undef,
 396                 ccode      => $item1->ccode,
 397             }
 398         }
 399     );
 400
 401     $pickup_locations = $item1->pickup_locations( { patron => $patron1 } )->as_list;
 402     is( scalar @$pickup_locations, 2, "With a transfer limits we get back the libraries that are pickup locations minus 1 limited library");
 403
 404     $builder->build_object(
 405         {
 406             class => 'Koha::Item::Transfer::Limits',
 407             value => {
 408                 toBranch   => $library4->branchcode,
 409                 fromBranch => $library2->branchcode,
 410                 itemtype   => undef,
 411                 ccode      => $item1->ccode,
 412             }
 413         }
 414     );
 415
 416     $pickup_locations = $item1->pickup_locations( { patron => $patron1 } )->as_list;
 417     is( scalar @$pickup_locations, 1, "With 2 transfer limits we get back the libraries that are pickup locations minus 2 limited libraries");
 418
 419     t::lib::Mocks::mock_preference('UseBranchTransferLimits', 0);
 420
 421     $schema->storage->txn_rollback;
 422 };
 423
 424 subtest 'deletion' => sub {
 425     plan tests => 12;
 426
 427     $schema->storage->txn_begin;
 428
 429     my $biblio = $builder->build_sample_biblio();
 430
 431     my $item = $builder->build_sample_item(
 432         {
 433             biblionumber => $biblio->biblionumber,
 434         }
 435     );
 436
 437     is( ref( $item->move_to_deleted ), 'Koha::Schema::Result::Deleteditem', 'Koha::Item->move_to_deleted should return the Deleted item' )
 438       ;    # FIXME This should be Koha::Deleted::Item
 439     is( Koha::Old::Items->search({itemnumber => $item->itemnumber})->count, 1, '->move_to_deleted must have moved the item to deleteditem' );
 440     $item = $builder->build_sample_item(
 441         {
 442             biblionumber => $biblio->biblionumber,
 443         }
 444     );
 445     $item->delete;
 446     is( Koha::Old::Items->search({itemnumber => $item->itemnumber})->count, 0, '->move_to_deleted must not have moved the item to deleteditem' );
 447
 448
 449     my $library   = $builder->build_object({ class => 'Koha::Libraries' });
 450     my $library_2 = $builder->build_object({ class => 'Koha::Libraries' });
 451     t::lib::Mocks::mock_userenv({ branchcode => $library->branchcode });
 452
 453     my $patron = $builder->build_object({class => 'Koha::Patrons'});
 454     $item = $builder->build_sample_item({ library => $library->branchcode });
 455
 456     # book_on_loan
 457     C4::Circulation::AddIssue( $patron->unblessed, $item->barcode );
 458
 459     is(
 460         $item->safe_to_delete,
 461         'book_on_loan',
 462         'Koha::Item->safe_to_delete reports item on loan',
 463     );
 464
 465     is(
 466         $item->safe_delete,
 467         'book_on_loan',
 468         'item that is on loan cannot be deleted',
 469     );
 470
 471     AddReturn( $item->barcode, $library->branchcode );
 472
 473     # book_reserved is tested in t/db_dependent/Reserves.t
 474
 475     # not_same_branch
 476     t::lib::Mocks::mock_preference('IndependentBranches', 1);
 477     my $item_2 = $builder->build_sample_item({ library => $library_2->branchcode });
 478
 479     is(
 480         $item_2->safe_to_delete,
 481         'not_same_branch',
 482         'Koha::Item->safe_to_delete reports IndependentBranches restriction',
 483     );
 484
 485     is(
 486         $item_2->safe_delete,
 487         'not_same_branch',
 488         'IndependentBranches prevents deletion at another branch',
 489     );
 490
 491     # linked_analytics
 492
 493     { # codeblock to limit scope of $module->mock
 494
 495         my $module = Test::MockModule->new('C4::Items');
 496         $module->mock( GetAnalyticsCount => sub { return 1 } );
 497
 498         $item->discard_changes;
 499         is(
 500             $item->safe_to_delete,
 501             'linked_analytics',
 502             'Koha::Item->safe_to_delete reports linked analytics',
 503         );
 504
 505         is(
 506             $item->safe_delete,
 507             'linked_analytics',
 508             'Linked analytics prevents deletion of item',
 509         );
 510
 511     }
 512
 513     { # last_item_for_hold
 514         C4::Reserves::AddReserve({ branchcode => $patron->branchcode, borrowernumber => $patron->borrowernumber, biblionumber => $item->biblionumber });
 515         is( $item->safe_to_delete, 'last_item_for_hold', 'Item cannot be deleted if a biblio-level is placed on the biblio and there is only 1 item attached to the biblio' );
 516
 517         # With another item attached to the biblio, the item can be deleted
 518         $builder->build_sample_item({ biblionumber => $item->biblionumber });
 519     }
 520
 521     is(
 522         $item->safe_to_delete,
 523         1,
 524         'Koha::Item->safe_to_delete shows item safe to delete'
 525     );
 526
 527     $item->safe_delete,
 528
 529     my $test_item = Koha::Items->find( $item->itemnumber );
 530
 531     is( $test_item, undef,
 532         "Koha::Item->safe_delete should delete item if safe_to_delete returns true"
 533     );
 534
 535     $schema->storage->txn_rollback;
 536 };
 537
 538 subtest 'renewal_branchcode' => sub {
 539     plan tests => 13;
 540
 541     $schema->storage->txn_begin;
 542
 543     my $item = $builder->build_sample_item();
 544     my $branch = $builder->build_object({ class => 'Koha::Libraries' });
 545     my $checkout = $builder->build_object({
 546         class => 'Koha::Checkouts',
 547         value => {
 548             itemnumber => $item->itemnumber,
 549         }
 550     });
 551
 552
 553     C4::Context->interface( 'intranet' );
 554     t::lib::Mocks::mock_userenv({ branchcode => $branch->branchcode });
 555
 556     is( $item->renewal_branchcode, $branch->branchcode, "If interface not opac, we get the branch from context");
 557     is( $item->renewal_branchcode({ branch => "PANDA"}), $branch->branchcode, "If interface not opac, we get the branch from context even if we pass one in");
 558     C4::Context->set_userenv(51, 'userid4tests', undef, 'firstname', 'surname', undef, undef, 0, undef, undef, undef ); #mock userenv doesn't let us set null branch
 559     is( $item->renewal_branchcode({ branch => "PANDA"}), "PANDA", "If interface not opac, we get the branch we pass one in if context not set");
 560
 561     C4::Context->interface( 'opac' );
 562
 563     t::lib::Mocks::mock_preference('OpacRenewalBranch', undef);
 564     is( $item->renewal_branchcode, 'OPACRenew', "If interface opac and OpacRenewalBranch undef, we get OPACRenew");
 565     is( $item->renewal_branchcode({branch=>'COW'}), 'OPACRenew', "If interface opac and OpacRenewalBranch undef, we get OPACRenew even if branch passed");
 566
 567     t::lib::Mocks::mock_preference('OpacRenewalBranch', 'none');
 568     is( $item->renewal_branchcode, '', "If interface opac and OpacRenewalBranch is none, we get blank string");
 569     is( $item->renewal_branchcode({branch=>'COW'}), '', "If interface opac and OpacRenewalBranch is none, we get blank string even if branch passed");
 570
 571     t::lib::Mocks::mock_preference('OpacRenewalBranch', 'checkoutbranch');
 572     is( $item->renewal_branchcode, $checkout->branchcode, "If interface opac and OpacRenewalBranch set to checkoutbranch, we get branch of checkout");
 573     is( $item->renewal_branchcode({branch=>'MONKEY'}), $checkout->branchcode, "If interface opac and OpacRenewalBranch set to checkoutbranch, we get branch of checkout even if branch passed");
 574
 575     t::lib::Mocks::mock_preference('OpacRenewalBranch','patronhomebranch');
 576     is( $item->renewal_branchcode, $checkout->patron->branchcode, "If interface opac and OpacRenewalBranch set to patronbranch, we get branch of patron");
 577     is( $item->renewal_branchcode({branch=>'TURKEY'}), $checkout->patron->branchcode, "If interface opac and OpacRenewalBranch set to patronbranch, we get branch of patron even if branch passed");
 578
 579     t::lib::Mocks::mock_preference('OpacRenewalBranch','itemhomebranch');
 580     is( $item->renewal_branchcode, $item->homebranch, "If interface opac and OpacRenewalBranch set to itemhomebranch, we get homebranch of item");
 581     is( $item->renewal_branchcode({branch=>'MANATEE'}), $item->homebranch, "If interface opac and OpacRenewalBranch set to itemhomebranch, we get homebranch of item even if branch passed");
 582
 583     $schema->storage->txn_rollback;
 584 };
 585
 586 subtest 'Tests for itemtype' => sub {
 587     plan tests => 2;
 588     $schema->storage->txn_begin;
 589
 590     my $biblio = $builder->build_sample_biblio;
 591     my $itemtype = $builder->build_object({ class => 'Koha::ItemTypes' });
 592     my $item = $builder->build_sample_item({ biblionumber => $biblio->biblionumber, itype => $itemtype->itemtype });
 593
 594     t::lib::Mocks::mock_preference('item-level_itypes', 1);
 595     is( $item->itemtype->itemtype, $item->itype, 'Pref enabled' );
 596     t::lib::Mocks::mock_preference('item-level_itypes', 0);
 597     is( $item->itemtype->itemtype, $biblio->biblioitem->itemtype, 'Pref disabled' );
 598
 599     $schema->storage->txn_rollback;
 600 };