circ/renew.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2013 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use C4::Context;
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26 use C4::Circulation qw( barcodedecode CanBookBeRenewed GetLatestAutoRenewDate AddRenewal );
  27 use Koha::DateUtils qw( dt_from_string );
  28 use Koha::Database;
  29 use Koha::BiblioFrameworks;
  30
  31 my $cgi = CGI->new;
  32
  33 my ( $template, $librarian, $cookie, $flags ) = get_template_and_user(
  34     {
  35         template_name   => "circ/renew.tt",
  36         query           => $cgi,
  37         type            => "intranet",
  38         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  39     }
  40 );
  41
  42 my $schema = Koha::Database->new()->schema();
  43
  44 my $op      = $cgi->param('op') || q{};
  45 my $barcode = $cgi->param('barcode') // '';
  46 my $unseen  = $cgi->param('unseen') || 0;
  47 $barcode = barcodedecode($barcode) if $barcode;
  48 my $override_limit = $cgi->param('override_limit');
  49 my $override_holds = $cgi->param('override_holds');
  50 my $hard_due_date  = $cgi->param('hard_due_date');
  51
  52 my ( $item, $checkout, $patron );
  53 my $error = q{};
  54 my ( $soonest_renew_date, $latest_auto_renew_date );
  55
  56 if ($op eq 'cud-renew' && $barcode) {
  57     $barcode = barcodedecode($barcode) if $barcode;
  58     $item = Koha::Items->find({ barcode => $barcode });
  59
  60     if ($item) {
  61
  62         $checkout = $item->checkout;
  63
  64         if ($checkout) {
  65
  66             $patron = $checkout->patron;
  67
  68             if ( ( $patron->is_debarred || q{} ) lt dt_from_string()->ymd() ) {
  69                 my $can_renew;
  70                 my $info;
  71                 ( $can_renew, $error, $info ) =
  72                   CanBookBeRenewed( $patron, $checkout, $override_limit );
  73
  74                 if ( $error && ($error eq 'on_reserve') ) {
  75                     if ($override_holds) {
  76                         $can_renew = 1;
  77                         $error     = undef;
  78                     }
  79                     else {
  80                         $can_renew = 0;
  81                     }
  82                 }
  83
  84                 if ( $error && ($error eq 'too_soon' or $error eq 'auto_too_soon') ) {
  85                     $soonest_renew_date = $info->{soonest_renew_date};
  86                 }
  87                 if ( $error && ( $error eq 'auto_too_late' ) ) {
  88                     $latest_auto_renew_date = GetLatestAutoRenewDate(
  89                         $patron,
  90                         $checkout,
  91                     );
  92                 }
  93                 if ($can_renew) {
  94                     my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
  95                     my $date_due =
  96                       ( C4::Context->preference('SpecifyDueDate')
  97                           && $hard_due_date )
  98                       ? $hard_due_date
  99                       : $cgi->param('renewonholdduedate');
 100
 101                     $date_due = AddRenewal(
 102                         {
 103                             itemnumber => $item->itemnumber(),
 104                             branch     => $branchcode,
 105                             datedue    => $date_due,
 106                             seen       => !$unseen
 107                         }
 108                     );
 109                     $template->param( date_due => $date_due );
 110                 }
 111             }
 112             else {
 113                 $error = "patron_restricted";
 114             }
 115         }
 116         else {
 117             $error = "no_checkout";
 118         }
 119     }
 120     else {
 121         $error = "no_item";
 122     }
 123
 124     $template->param(
 125         item     => $item,
 126         issue    => $checkout,
 127         borrower => $patron,
 128         error    => $error,
 129         soonestrenewdate => $soonest_renew_date,
 130         latestautorenewdate => $latest_auto_renew_date,
 131     );
 132 }
 133
 134 $template->param( hard_due_date => $hard_due_date );
 135 # Checking if there is a Fast Cataloging Framework
 136 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 137
 138 output_html_with_http_headers( $cgi, $cookie, $template->output );