t/db_dependent/Koha/REST/Plugin/PluginRoutes.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 2;
  21 use Test::Mojo;
  22 use Test::Warn;
  23
  24 use File::Basename;
  25 use t::lib::Mocks;
  26
  27 use JSON::Validator::OpenAPI::Mojolicious;
  28
  29 # Dummy app for testing the plugin
  30 use Mojolicious::Lite;
  31
  32 BEGIN {
  33     # Mock pluginsdir before loading Plugins module
  34     my $path = dirname(__FILE__) . '/../../../../lib';
  35     t::lib::Mocks::mock_config( 'pluginsdir', $path );
  36 }
  37
  38 use Koha::Database;
  39 use Koha::Plugins;
  40
  41 my $schema = Koha::Database->new->schema;
  42
  43 subtest 'Bad plugins tests' => sub {
  44
  45     plan tests => 3;
  46
  47     $schema->storage->txn_begin;
  48
  49     # enable plugins
  50     t::lib::Mocks::mock_config( 'enable_plugins', 1 );
  51
  52     # remove any existing plugins that might interfere
  53     Koha::Plugins::Methods->search->delete;
  54     my $plugins = Koha::Plugins->new;
  55     $plugins->InstallPlugins;
  56
  57     my @plugins = $plugins->GetPlugins( { all => 1 } );
  58     foreach my $plugin (@plugins) {
  59         $plugin->enable;
  60     }
  61
  62     # initialize Koha::REST::V1 after mocking
  63     my $t;
  64     warning_is
  65         { $t = Test::Mojo->new('Koha::REST::V1'); }
  66         'The resulting spec is invalid. Skipping Bad API Route Plugin',
  67         'Bad plugins raise warning';
  68
  69     my $routes = get_defined_routes($t);
  70     # Support placeholders () and <>  (latter style used starting with Mojolicious::Plugin::OpenAPI@1.28)
  71     # TODO: remove () if minimum version is bumped to at least 1.28.
  72     ok( !exists $routes->{'/contrib/badass/patrons/(:patron_id)/bother_wrong'} && !exists $routes->{'/contrib/badass/patrons/<:patron_id>/bother_wrong'}, 'Route doesn\'t exist' );
  73     ok( exists $routes->{'/contrib/testplugin/patrons/(:patron_id)/bother'} || exists $routes->{'/contrib/testplugin/patrons/<:patron_id>/bother'}, 'Route exists' );
  74
  75     $schema->storage->txn_rollback;
  76 };
  77
  78 subtest 'Disabled plugins tests' => sub {
  79
  80     plan tests => 2;
  81
  82     $schema->storage->txn_begin;
  83
  84     # enable plugins
  85     t::lib::Mocks::mock_config( 'enable_plugins', 1 );
  86
  87     my $good_plugin;
  88
  89     my $plugins = Koha::Plugins->new;
  90     $plugins->InstallPlugins;
  91
  92     my @plugins = $plugins->GetPlugins( { all => 1 } );
  93     foreach my $plugin (@plugins) {
  94         $plugin->disable;
  95         $good_plugin = $plugin
  96             if $plugin->{metadata}->{description} eq 'Test plugin';
  97     }
  98
  99     # initialize Koha::REST::V1 after mocking
 100     my $t = Test::Mojo->new('Koha::REST::V1');
 101
 102     my $routes = get_defined_routes($t);
 103     # Support placeholders () and <>  (latter style used starting with Mojolicious::Plugin::OpenAPI@1.28)
 104     # TODO: remove () if minimum version is bumped to at least 1.28.
 105     ok( !exists $routes->{'/contrib/testplugin/patrons/(:patron_id)/bother'} && !exists $routes->{'/contrib/testplugin/patrons/<:patron_id>/bother'},
 106         'Plugin disabled, route not defined' );
 107
 108     $good_plugin->enable;
 109
 110     $t      = Test::Mojo->new('Koha::REST::V1');
 111     $routes = get_defined_routes($t);
 112
 113     # Support placeholders () and <>  (latter style used starting with Mojolicious::Plugin::OpenAPI@1.28)
 114     # TODO: remove () if minimum version is bumped to at least 1.28.
 115     ok( exists $routes->{'/contrib/testplugin/patrons/(:patron_id)/bother'} || exists $routes->{'/contrib/testplugin/patrons/<:patron_id>/bother'},
 116         'Plugin enabled, route defined' );
 117
 118     $schema->storage->txn_rollback;
 119 };
 120
 121 sub get_defined_routes {
 122     my ($t) = @_;
 123     my $routes = {};
 124     traverse_routes( $_, 0, $routes ) for @{ $t->app->routes->children };
 125
 126     return $routes;
 127 }
 128
 129 sub traverse_routes {
 130     my ( $route, $depth, $routes ) = @_;
 131
 132     # Pattern
 133     my $path = $route->pattern->unparsed || '/';
 134
 135     # Methods
 136     my $via = $route->via;
 137     my $verb = !$via ? '*' : uc join ',', @$via;
 138     $routes->{$path}->{$verb} = 1;
 139
 140     $depth++;
 141     traverse_routes( $_, $depth, $routes ) for @{ $route->children };
 142     $depth--;
 143 }