t/db_dependent/Members.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 47;
  21 use Test::MockModule;
  22 use Test::Exception;
  23
  24 use Data::Dumper qw/Dumper/;
  25 use C4::Context;
  26 use Koha::Database;
  27 use Koha::Holds;
  28 use Koha::List::Patron;
  29 use Koha::Patrons;
  30
  31 use t::lib::Mocks;
  32 use t::lib::TestBuilder;
  33
  34 BEGIN {
  35         use_ok('C4::Members');
  36 }
  37
  38 my $schema = Koha::Database->schema;
  39 $schema->storage->txn_begin;
  40 my $builder = t::lib::TestBuilder->new;
  41 my $dbh = C4::Context->dbh;
  42
  43 # Remove invalid guarantorid's as long as we have no FK
  44 $dbh->do("UPDATE borrowers b1 LEFT JOIN borrowers b2 ON b2.borrowernumber=b1.guarantorid SET b1.guarantorid=NULL where b1.guarantorid IS NOT NULL AND b2.borrowernumber IS NULL");
  45
  46 my $library1 = $builder->build({
  47     source => 'Branch',
  48 });
  49 my $library2 = $builder->build({
  50     source => 'Branch',
  51 });
  52 my $patron_category = $builder->build({ source => 'Category' });
  53 my $CARDNUMBER   = 'TESTCARD01';
  54 my $FIRSTNAME    = 'Marie';
  55 my $SURNAME      = 'Mcknight';
  56 my $BRANCHCODE   = $library1->{branchcode};
  57
  58 my $CHANGED_FIRSTNAME = "Marry Ann";
  59 my $EMAIL             = "Marie\@email.com";
  60 my $EMAILPRO          = "Marie\@work.com";
  61 my $PHONE             = "555-12123";
  62
  63 # XXX should be randomised and checked against the database
  64 my $IMPOSSIBLE_CARDNUMBER = "XYZZZ999";
  65
  66 #my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
  67 my @USERENV = (
  68     1,
  69     'test',
  70     'MASTERTEST',
  71     'Test',
  72     'Test',
  73     't',
  74     'Test',
  75     0,
  76 );
  77 my $BRANCH_IDX = 5;
  78
  79 C4::Context->_new_userenv ('DUMMY_SESSION_ID');
  80 C4::Context->set_userenv ( @USERENV );
  81
  82 my $userenv = C4::Context->userenv
  83   or BAIL_OUT("No userenv");
  84
  85 # Make a borrower for testing
  86 my %data = (
  87     cardnumber => $CARDNUMBER,
  88     firstname =>  $FIRSTNAME . q{ },
  89     surname => $SURNAME,
  90     categorycode => $patron_category->{categorycode},
  91     branchcode => $BRANCHCODE,
  92     dateofbirth => '',
  93     dateexpiry => '9999-12-31',
  94     userid => 'tomasito'
  95 );
  96
  97 my $addmem=Koha::Patron->new(\%data)->store->borrowernumber;
  98 ok($addmem, "Koha::Patron->store()");
  99
 100 my $patron = Koha::Patrons->find( { cardnumber => $CARDNUMBER } )
 101   or BAIL_OUT("Cannot read member with card $CARDNUMBER");
 102 my $member = $patron->unblessed;
 103
 104 ok ( $member->{firstname}    eq $FIRSTNAME    &&
 105      $member->{surname}      eq $SURNAME      &&
 106      $member->{categorycode} eq $patron_category->{categorycode} &&
 107      $member->{branchcode}   eq $BRANCHCODE
 108      , "Got member")
 109   or diag("Mismatching member details: ".Dumper(\%data, $member));
 110
 111 is($member->{dateofbirth}, undef, "Empty dates handled correctly");
 112
 113 $member->{firstname} = $CHANGED_FIRSTNAME . q{ };
 114 $member->{email}     = $EMAIL;
 115 $member->{phone}     = $PHONE;
 116 $member->{emailpro}  = $EMAILPRO;
 117 $patron->set($member)->store;
 118 my $changedmember = Koha::Patrons->find( { cardnumber => $CARDNUMBER } )->unblessed;
 119 ok ( $changedmember->{firstname} eq $CHANGED_FIRSTNAME &&
 120      $changedmember->{email}     eq $EMAIL             &&
 121      $changedmember->{phone}     eq $PHONE             &&
 122      $changedmember->{emailpro}  eq $EMAILPRO
 123      , "Member Changed")
 124   or diag("Mismatching member details: ".Dumper($member, $changedmember));
 125
 126 t::lib::Mocks::mock_preference( 'CardnumberLength', '' );
 127 C4::Context->clear_syspref_cache();
 128
 129 my $checkcardnum=C4::Members::checkcardnumber($CARDNUMBER, "");
 130 is ($checkcardnum, "1", "Card No. in use");
 131
 132 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 133 is ($checkcardnum, "0", "Card No. not used");
 134
 135 t::lib::Mocks::mock_preference( 'CardnumberLength', '4' );
 136 C4::Context->clear_syspref_cache();
 137
 138 $checkcardnum=C4::Members::checkcardnumber($IMPOSSIBLE_CARDNUMBER, "");
 139 is ($checkcardnum, "2", "Card number is too long");
 140
 141
 142 # Add a new borrower
 143 %data = (
 144     cardnumber   => "123456789",
 145     firstname    => "Tomasito",
 146     surname      => "None",
 147     categorycode => $patron_category->{categorycode},
 148     branchcode   => $library2->{branchcode},
 149     dateofbirth  => '',
 150     debarred     => '',
 151     dateexpiry   => '',
 152     dateenrolled => '',
 153 );
 154 my $borrowernumber = Koha::Patron->new( \%data )->store->borrowernumber;
 155 $patron = Koha::Patrons->find( $borrowernumber );
 156 my $borrower = $patron->unblessed;
 157 is( $borrower->{dateofbirth}, undef, 'Koha::Patron->store should undef dateofbirth if empty string is given');
 158 is( $borrower->{debarred}, undef, 'Koha::Patron->store should undef debarred if empty string is given');
 159 isnt( $borrower->{dateexpiry}, '0000-00-00', 'Koha::Patron->store should not set dateexpiry to 0000-00-00 if empty string is given');
 160 isnt( $borrower->{dateenrolled}, '0000-00-00', 'Koha::Patron->store should not set dateenrolled to 0000-00-00 if empty string is given');
 161
 162 $patron->set({ dateofbirth => '', debarred => '', dateexpiry => '', dateenrolled => '' })->store;
 163 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 164 is( $borrower->{dateofbirth}, undef, 'Koha::Patron->store should undef dateofbirth if empty string is given');
 165 is( $borrower->{debarred}, undef, 'Koha::Patron->store should undef debarred if empty string is given');
 166 isnt( $borrower->{dateexpiry}, '0000-00-00', 'Koha::Patron->store should not set dateexpiry to 0000-00-00 if empty string is given');
 167 isnt( $borrower->{dateenrolled}, '0000-00-00', 'Koha::Patron->store should not set dateenrolled to 0000-00-00 if empty string is given');
 168
 169 $patron->set({ dateofbirth => '1970-01-01', debarred => '2042-01-01', dateexpiry => '9999-12-31', dateenrolled => '2015-09-06' })->store;
 170 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 171 is( $borrower->{dateofbirth}, '1970-01-01', 'Koha::Patron->store should correctly set dateofbirth if a valid date is given');
 172 is( $borrower->{debarred}, '2042-01-01', 'Koha::Patron->store should correctly set debarred if a valid date is given');
 173 is( $borrower->{dateexpiry}, '9999-12-31', 'Koha::Patron->store should correctly set dateexpiry if a valid date is given');
 174 is( $borrower->{dateenrolled}, '2015-09-06', 'Koha::Patron->store should correctly set dateenrolled if a valid date is given');
 175
 176 subtest 'Koha::Patron->store should not update userid if not true' => sub {
 177     plan tests => 3;
 178
 179     $data{ cardnumber } = "234567890";
 180     $data{userid} = 'a_user_id';
 181     $borrowernumber = Koha::Patron->new( \%data )->store->borrowernumber;
 182     my $patron = Koha::Patrons->find( $borrowernumber );
 183     my $borrower = $patron->unblessed;
 184
 185     $patron->set( { firstname => 'Tomas', userid => '' } )->store;
 186     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 187     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an empty string' );
 188     $patron->set( { firstname => 'Tomas', userid => 0 } )->store;
 189     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 190     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an 0');
 191     $patron->set( { firstname => 'Tomas', userid => undef } )->store;
 192     $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 193     is ( $borrower->{userid}, $data{userid}, 'Koha::Patron->store should not update the userid with an undefined value');
 194 };
 195
 196 #Regression tests for bug 10612
 197 my $library3 = $builder->build({
 198     source => 'Branch',
 199 });
 200 $builder->build({
 201         source => 'Category',
 202         value => {
 203             categorycode         => 'STAFFER',
 204             description          => 'Staff dont batch del',
 205             category_type        => 'S',
 206         },
 207 });
 208
 209 $builder->build({
 210         source => 'Category',
 211         value => {
 212             categorycode         => 'CIVILIAN',
 213             description          => 'Civilian batch del',
 214             category_type        => 'A',
 215         },
 216 });
 217
 218 $builder->build({
 219         source => 'Category',
 220         value => {
 221             categorycode         => 'KIDclamp',
 222             description          => 'Kid to be guaranteed',
 223             category_type        => 'C',
 224         },
 225 });
 226
 227 my $borrower1 = $builder->build({
 228         source => 'Borrower',
 229         value  => {
 230             categorycode=>'STAFFER',
 231             branchcode => $library3->{branchcode},
 232             dateexpiry => '2015-01-01',
 233             guarantorid=> undef,
 234         },
 235 });
 236 my $bor1inlist = $borrower1->{borrowernumber};
 237 my $borrower2 = $builder->build({
 238         source => 'Borrower',
 239         value  => {
 240             categorycode=>'STAFFER',
 241             branchcode => $library3->{branchcode},
 242             dateexpiry => '2015-01-01',
 243             guarantorid=> undef,
 244         },
 245 });
 246
 247 my $guarantee = $builder->build({
 248         source => 'Borrower',
 249         value  => {
 250             categorycode=>'KIDclamp',
 251             branchcode => $library3->{branchcode},
 252             dateexpiry => '2015-01-01',
 253             guarantorid=> undef, # will be filled later
 254         },
 255 });
 256
 257 my $bor2inlist = $borrower2->{borrowernumber};
 258
 259 $builder->build({
 260         source => 'OldIssue',
 261         value  => {
 262             borrowernumber => $bor2inlist,
 263             timestamp => '2016-01-01',
 264         },
 265 });
 266
 267 # The following calls to GetBorrowersToExpunge are assuming that the pref
 268 # IndependentBranches is off.
 269 t::lib::Mocks::mock_preference('IndependentBranches', 0);
 270
 271 my $owner = Koha::Patron->new({ categorycode => 'STAFFER', branchcode => $library2->{branchcode} })->store->borrowernumber;
 272 my $list1 = AddPatronList( { name => 'Test List 1', owner => $owner } );
 273 my @listpatrons = ($bor1inlist, $bor2inlist);
 274 AddPatronsToList(  { list => $list1, borrowernumbers => \@listpatrons });
 275 my $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id() } );
 276 is( scalar(@$patstodel),0,'No staff deleted from list of all staff');
 277 Koha::Patrons->find($bor2inlist)->set({ categorycode => 'CIVILIAN' })->store;
 278 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 279 ok( scalar(@$patstodel)== 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted from list');
 280 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 281 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by branchcode and list');
 282 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02', patron_list_id => $list1->patron_list_id() } );
 283 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by expirationdate and list');
 284 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 285 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Staff patron not deleted by last issue date');
 286
 287 Koha::Patrons->find($bor1inlist)->set({ categorycode => 'CIVILIAN' })->store;
 288 Koha::Patrons->find($guarantee->{borrowernumber})->set({ guarantorid => $bor1inlist })->store;
 289
 290 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 291 ok( scalar(@$patstodel)== 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted from list');
 292 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 293 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by branchcode and list');
 294 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02', patron_list_id => $list1->patron_list_id() } );
 295 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by expirationdate and list');
 296 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 297 ok( scalar(@$patstodel) == 1 && $patstodel->[0]->{'borrowernumber'} eq $bor2inlist,'Guarantor patron not deleted by last issue date');
 298 Koha::Patrons->find($guarantee->{borrowernumber})->set({ guarantorid => undef })->store;
 299
 300 $builder->build({
 301         source => 'Issue',
 302         value  => {
 303             borrowernumber => $bor2inlist,
 304         },
 305 });
 306 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 307 is( scalar(@$patstodel),1,'Borrower with issue not deleted from list');
 308 $patstodel = GetBorrowersToExpunge( {branchcode => $library3->{branchcode},patron_list_id => $list1->patron_list_id() } );
 309 is( scalar(@$patstodel),1,'Borrower with issue not deleted by branchcode and list');
 310 $patstodel = GetBorrowersToExpunge( {category_code => 'CIVILIAN',patron_list_id => $list1->patron_list_id() } );
 311 is( scalar(@$patstodel),1,'Borrower with issue not deleted by category_code and list');
 312 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02',patron_list_id => $list1->patron_list_id() } );
 313 is( scalar(@$patstodel),1,'Borrower with issue not deleted by expiration_date and list');
 314 $builder->schema->resultset( 'Issue' )->delete_all;
 315 $patstodel = GetBorrowersToExpunge( {patron_list_id => $list1->patron_list_id()} );
 316 ok( scalar(@$patstodel)== 2,'Borrowers without issue deleted from list');
 317 $patstodel = GetBorrowersToExpunge( {category_code => 'CIVILIAN',patron_list_id => $list1->patron_list_id() } );
 318 is( scalar(@$patstodel),2,'Borrowers without issues deleted by category_code and list');
 319 $patstodel = GetBorrowersToExpunge( {expired_before => '2015-01-02',patron_list_id => $list1->patron_list_id() } );
 320 is( scalar(@$patstodel),2,'Borrowers without issues deleted by expiration_date and list');
 321 $patstodel = GetBorrowersToExpunge( {not_borrowed_since => '2016-01-02', patron_list_id => $list1->patron_list_id() } );
 322 is( scalar(@$patstodel),2,'Borrowers without issues deleted by last issue date');
 323
 324 # Test GetBorrowersToExpunge and TrackLastPatronActivity
 325 $dbh->do(q|UPDATE borrowers SET lastseen=NULL|);
 326 $builder->build({ source => 'Borrower', value => { lastseen => '2016-01-01 01:01:01', categorycode => 'CIVILIAN', guarantorid => undef } } );
 327 $builder->build({ source => 'Borrower', value => { lastseen => '2016-02-02 02:02:02', categorycode => 'CIVILIAN', guarantorid => undef } } );
 328 $builder->build({ source => 'Borrower', value => { lastseen => '2016-03-03 03:03:03', categorycode => 'CIVILIAN', guarantorid => undef } } );
 329 $patstodel = GetBorrowersToExpunge( { last_seen => '1999-12-12' });
 330 is( scalar @$patstodel, 0, 'TrackLastPatronActivity - 0 patrons must be deleted' );
 331 $patstodel = GetBorrowersToExpunge( { last_seen => '2016-02-15' });
 332 is( scalar @$patstodel, 2, 'TrackLastPatronActivity - 2 patrons must be deleted' );
 333 $patstodel = GetBorrowersToExpunge( { last_seen => '2016-04-04' });
 334 is( scalar @$patstodel, 3, 'TrackLastPatronActivity - 3 patrons must be deleted' );
 335 my $patron2 = $builder->build({ source => 'Borrower', value => { lastseen => undef } });
 336 t::lib::Mocks::mock_preference( 'TrackLastPatronActivity', '0' );
 337 Koha::Patrons->find( $patron2->{borrowernumber} )->track_login;
 338 is( Koha::Patrons->find( $patron2->{borrowernumber} )->lastseen, undef, 'Lastseen should not be changed' );
 339 Koha::Patrons->find( $patron2->{borrowernumber} )->track_login({ force => 1 });
 340 isnt( Koha::Patrons->find( $patron2->{borrowernumber} )->lastseen, undef, 'Lastseen should be changed now' );
 341
 342 # Regression tests for BZ13502
 343 ## Remove all entries with userid='' (should be only 1 max)
 344 $dbh->do(q|DELETE FROM borrowers WHERE userid = ''|);
 345 ## And create a patron with a userid=''
 346 $borrowernumber = Koha::Patron->new({ categorycode => $patron_category->{categorycode}, branchcode => $library2->{branchcode} })->store->borrowernumber;
 347 $dbh->do(q|UPDATE borrowers SET userid = '' WHERE borrowernumber = ?|, undef, $borrowernumber);
 348 # Create another patron and verify the userid has been generated
 349 $borrowernumber = Koha::Patron->new({ categorycode => $patron_category->{categorycode}, branchcode => $library2->{branchcode} })->store->borrowernumber;
 350 ok( $borrowernumber > 0, 'Koha::Patron->store should have inserted the patron even if no userid is given' );
 351 $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 352 ok( $borrower->{userid},  'A userid should have been generated correctly' );
 353
 354 subtest 'purgeSelfRegistration' => sub {
 355     plan tests => 2;
 356
 357     #purge unverified
 358     my $d=360;
 359     C4::Members::DeleteUnverifiedOpacRegistrations($d);
 360     foreach(1..3) {
 361         $dbh->do("INSERT INTO borrower_modifications (timestamp, borrowernumber, verification_token) VALUES ('2014-01-01 01:02:03',0,?)", undef, (scalar localtime)."_$_");
 362     }
 363     is( C4::Members::DeleteUnverifiedOpacRegistrations($d), 3, 'Test for DeleteUnverifiedOpacRegistrations' );
 364
 365     #purge members in temporary category
 366     my $c= 'XYZ';
 367     $dbh->do("INSERT IGNORE INTO categories (categorycode) VALUES ('$c')");
 368     t::lib::Mocks::mock_preference('PatronSelfRegistrationDefaultCategory', $c );
 369     t::lib::Mocks::mock_preference('PatronSelfRegistrationExpireTemporaryAccountsDelay', 360);
 370     C4::Members::DeleteExpiredOpacRegistrations();
 371     $dbh->do("INSERT INTO borrowers (surname, address, city, branchcode, categorycode, dateenrolled) VALUES ('Testaabbcc', 'Street 1', 'CITY', ?, '$c', '2014-01-01 01:02:03')", undef, $library1->{branchcode});
 372     is( C4::Members::DeleteExpiredOpacRegistrations(), 1, 'Test for DeleteExpiredOpacRegistrations');
 373 };
 374
 375 sub _find_member {
 376     my ($resultset) = @_;
 377     my $found = $resultset && grep( { $_->{cardnumber} && $_->{cardnumber} eq $CARDNUMBER } @$resultset );
 378     return $found;
 379 }
 380
 381 $schema->storage->txn_rollback;
 382
 383 subtest 'Koha::Patron->store (invalid categorycode) tests' => sub {
 384     plan tests => 1;
 385
 386     $schema->storage->txn_begin;
 387
 388     my $category    = $builder->build_object({ class => 'Koha::Patron::Categories' });
 389     my $category_id = $category->id;
 390     # Remove category to make sure the id is not on the DB
 391     $category->delete;
 392
 393     my $patron_data = {
 394         categorycode => $category_id
 395     };
 396
 397     throws_ok
 398         { Koha::Patron->new( $patron_data )->store; }
 399         'Koha::Exceptions::Object::FKConstraint',
 400         'AddMember raises an exception on invalid categorycode';
 401
 402     $schema->storage->txn_rollback;
 403 };