Koha/REST/V1.pm

   1 package Koha::REST::V1;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious';
  21
  22 use C4::Context;
  23 use Koha::Logger;
  24 use Koha::Auth::Identity::Providers;
  25
  26 use Mojolicious::Plugin::OAuth2;
  27 use JSON::Validator::Schema::OpenAPIv2;
  28
  29 use Try::Tiny qw( catch try );
  30 use JSON qw( decode_json );
  31
  32 =head1 NAME
  33
  34 Koha::REST::V1 - Main v.1 REST api class
  35
  36 =head1 API
  37
  38 =head2 Class Methods
  39
  40 =head3 startup
  41
  42 Overloaded Mojolicious->startup method. It is called at application startup.
  43
  44 =cut
  45
  46 sub startup {
  47     my $self = shift;
  48
  49     my $logger = Koha::Logger->get({ interface => 'api' });
  50     $self->log($logger);
  51
  52     $self->hook(
  53         before_dispatch => sub {
  54             my $c = shift;
  55
  56             # Remove /api/v1/app.pl/ from the path
  57             $c->req->url->base->path('/');
  58
  59             # Handle CORS
  60             $c->res->headers->header( 'Access-Control-Allow-Origin' =>
  61                   C4::Context->preference('AccessControlAllowOrigin') )
  62               if C4::Context->preference('AccessControlAllowOrigin');
  63         }
  64     );
  65
  66     # Force charset=utf8 in Content-Type header for JSON responses
  67     $self->types->type( json    => 'application/json; charset=utf8' );
  68     # MARC-related types
  69     $self->types->type( marcxml => 'application/marcxml+xml' );
  70     $self->types->type( mij     => 'application/marc-in-json' );
  71     $self->types->type( marc    => 'application/marc' );
  72
  73     my $secret_passphrase = C4::Context->config('api_secret_passphrase');
  74     if ($secret_passphrase) {
  75         $self->secrets([$secret_passphrase]);
  76     }
  77
  78     my $spec_file = $self->home->rel_file("api/v1/swagger/swagger_bundle.json");
  79     if (!-f $spec_file) {
  80         $spec_file = $self->home->rel_file("api/v1/swagger/swagger.yaml");
  81     }
  82
  83     push @{$self->routes->namespaces}, 'Koha::Plugin';
  84
  85     # Try to load and merge all schemas first and validate the result just once.
  86     try {
  87
  88         my $schema = JSON::Validator::Schema::OpenAPIv2->new;
  89
  90         $schema->resolve( $spec_file );
  91
  92         my $spec = $schema->bundle->data;
  93
  94         $self->plugin(
  95             'Koha::REST::Plugin::PluginRoutes' => {
  96                 spec     => $spec,
  97                 validate => 0,
  98             }
  99         ) unless C4::Context->needs_install; # load only if Koha is installed
 100
 101         $self->plugin(
 102             OpenAPI => {
 103                 spec  => $spec,
 104                 route => $self->routes->under('/api/v1')->to('Auth#under'),
 105             }
 106         );
 107
 108         $self->plugin('RenderFile');
 109     }
 110     catch {
 111         # Validation of the complete spec failed. Resort to validation one-by-one
 112         # to catch bad ones.
 113
 114         # JSON::Validator uses confess, so trim call stack from the message.
 115         $self->app->log->error("Warning: Could not load REST API spec bundle: " . $_);
 116
 117         try {
 118
 119             my $schema = JSON::Validator::Schema::OpenAPIv2->new;
 120             $schema->resolve( $spec_file );
 121
 122             my $spec = $schema->bundle->data;
 123
 124             $self->plugin(
 125                 'Koha::REST::Plugin::PluginRoutes' => {
 126                     spec     => $spec,
 127                     validate => 1
 128                 }
 129             )  unless C4::Context->needs_install; # load only if Koha is installed
 130
 131             $self->plugin(
 132                 OpenAPI => {
 133                     spec  => $spec,
 134                     route => $self->routes->under('/api/v1')->to('Auth#under'),
 135                 }
 136             );
 137         }
 138         catch {
 139             # JSON::Validator uses confess, so trim call stack from the message.
 140             $self->app->log->error("Warning: Could not load REST API spec bundle: " . $_);
 141         };
 142     };
 143
 144     my $oauth_configuration = {};
 145     try {
 146         my $search_options = { protocol => [ "OIDC", "OAuth" ] };
 147
 148         my $providers = Koha::Auth::Identity::Providers->search($search_options);
 149         while ( my $provider = $providers->next ) {
 150             $oauth_configuration->{ $provider->code } = decode_json( $provider->config );
 151         }
 152     } catch {
 153         $self->app->log->warn( "Warning: Failed to fetch oauth configuration: " . $_ );
 154     };
 155
 156     $self->plugin('Koha::REST::Plugin::Pagination');
 157     $self->plugin('Koha::REST::Plugin::Query');
 158     $self->plugin('Koha::REST::Plugin::Objects');
 159     $self->plugin('Koha::REST::Plugin::Exceptions');
 160     $self->plugin('Koha::REST::Plugin::Responses');
 161     $self->plugin('Koha::REST::Plugin::Auth::IdP');
 162     $self->plugin( 'Mojolicious::Plugin::OAuth2' => $oauth_configuration );
 163 }
 164
 165 1;