Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Auth qw( checkpw_hash );
  29 use C4::Context;
  30 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  31 use C4::Log qw( logaction );
  32 use Koha::Account;
  33 use Koha::ArticleRequests;
  34 use Koha::AuthUtils;
  35 use Koha::Checkouts;
  36 use Koha::CirculationRules;
  37 use Koha::Club::Enrollments;
  38 use Koha::CurbsidePickups;
  39 use Koha::Database;
  40 use Koha::DateUtils qw( dt_from_string );
  41 use Koha::Encryption;
  42 use Koha::Exceptions::Password;
  43 use Koha::Holds;
  44 use Koha::Old::Checkouts;
  45 use Koha::OverdueRules;
  46 use Koha::Patron::Attributes;
  47 use Koha::Patron::Categories;
  48 use Koha::Patron::Debarments;
  49 use Koha::Patron::HouseboundProfile;
  50 use Koha::Patron::HouseboundRole;
  51 use Koha::Patron::Images;
  52 use Koha::Patron::Messages;
  53 use Koha::Patron::Modifications;
  54 use Koha::Patron::MessagePreferences;
  55 use Koha::Patron::Relationships;
  56 use Koha::Patron::Restrictions;
  57 use Koha::Patrons;
  58 use Koha::Plugins;
  59 use Koha::Recalls;
  60 use Koha::Result::Boolean;
  61 use Koha::Subscription::Routinglists;
  62 use Koha::Token;
  63 use Koha::Virtualshelves;
  64
  65 use base qw(Koha::Object);
  66
  67 use constant ADMINISTRATIVE_LOCKOUT => -1;
  68
  69 our $RESULTSET_PATRON_ID_MAPPING = {
  70     Accountline          => 'borrowernumber',
  71     Aqbasketuser         => 'borrowernumber',
  72     Aqbudget             => 'budget_owner_id',
  73     Aqbudgetborrower     => 'borrowernumber',
  74     ArticleRequest       => 'borrowernumber',
  75     BorrowerDebarment    => 'borrowernumber',
  76     BorrowerFile         => 'borrowernumber',
  77     BorrowerModification => 'borrowernumber',
  78     ClubEnrollment       => 'borrowernumber',
  79     Issue                => 'borrowernumber',
  80     ItemsLastBorrower    => 'borrowernumber',
  81     Linktracker          => 'borrowernumber',
  82     Message              => 'borrowernumber',
  83     MessageQueue         => 'borrowernumber',
  84     OldIssue             => 'borrowernumber',
  85     OldReserve           => 'borrowernumber',
  86     Rating               => 'borrowernumber',
  87     Reserve              => 'borrowernumber',
  88     Review               => 'borrowernumber',
  89     SearchHistory        => 'userid',
  90     Statistic            => 'borrowernumber',
  91     Suggestion           => 'suggestedby',
  92     TagAll               => 'borrowernumber',
  93     Virtualshelfcontent  => 'borrowernumber',
  94     Virtualshelfshare    => 'borrowernumber',
  95     Virtualshelve        => 'owner',
  96 };
  97
  98 =head1 NAME
  99
 100 Koha::Patron - Koha Patron Object class
 101
 102 =head1 API
 103
 104 =head2 Class Methods
 105
 106 =head3 new
 107
 108 =cut
 109
 110 sub new {
 111     my ( $class, $params ) = @_;
 112
 113     return $class->SUPER::new($params);
 114 }
 115
 116 =head3 fixup_cardnumber
 117
 118 Autogenerate next cardnumber from highest value found in database
 119
 120 =cut
 121
 122 sub fixup_cardnumber {
 123     my ( $self ) = @_;
 124
 125     my $max = $self->cardnumber;
 126     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 127
 128     $max ||= Koha::Patrons->search({
 129         cardnumber => {-regexp => '^-?[0-9]+$'}
 130     }, {
 131         select => \'CAST(cardnumber AS SIGNED)',
 132         as => ['cast_cardnumber']
 133     })->_resultset->get_column('cast_cardnumber')->max;
 134     $self->cardnumber(($max || 0) +1);
 135 }
 136
 137 =head3 trim_whitespace
 138
 139 trim whitespace from data which has some non-whitespace in it.
 140 Could be moved to Koha::Object if need to be reused
 141
 142 =cut
 143
 144 sub trim_whitespaces {
 145     my( $self ) = @_;
 146
 147     my $schema  = Koha::Database->new->schema;
 148     my @columns = $schema->source($self->_type)->columns;
 149
 150     for my $column( @columns ) {
 151         my $value = $self->$column;
 152         if ( defined $value ) {
 153             $value =~ s/^\s*|\s*$//g;
 154             $self->$column($value);
 155         }
 156     }
 157     return $self;
 158 }
 159
 160 =head3 plain_text_password
 161
 162 $patron->plain_text_password( $password );
 163
 164 stores a copy of the unencrypted password in the object
 165 for use in code before encrypting for db
 166
 167 =cut
 168
 169 sub plain_text_password {
 170     my ( $self, $password ) = @_;
 171     if ( $password ) {
 172         $self->{_plain_text_password} = $password;
 173         return $self;
 174     }
 175     return $self->{_plain_text_password}
 176         if $self->{_plain_text_password};
 177
 178     return;
 179 }
 180
 181 =head3 store
 182
 183 Patron specific store method to cleanup record
 184 and do other necessary things before saving
 185 to db
 186
 187 =cut
 188
 189 sub store {
 190     my ($self) = @_;
 191
 192     $self->_result->result_source->schema->txn_do(
 193         sub {
 194             if (
 195                 C4::Context->preference("autoMemberNum")
 196                 and ( not defined $self->cardnumber
 197                     or $self->cardnumber eq '' )
 198               )
 199             {
 200                 # Warning: The caller is responsible for locking the members table in write
 201                 # mode, to avoid database corruption.
 202                 # We are in a transaction but the table is not locked
 203                 $self->fixup_cardnumber;
 204             }
 205
 206             unless( $self->category->in_storage ) {
 207                 Koha::Exceptions::Object::FKConstraint->throw(
 208                     broken_fk => 'categorycode',
 209                     value     => $self->categorycode,
 210                 );
 211             }
 212
 213             $self->trim_whitespaces;
 214
 215             my $new_cardnumber = $self->cardnumber;
 216             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 217             $self->cardnumber( $new_cardnumber );
 218
 219             # Set surname to uppercase if uppercasesurname is true
 220             $self->surname( uc($self->surname) )
 221                 if C4::Context->preference("uppercasesurnames");
 222
 223             $self->relationship(undef) # We do not want to store an empty string in this field
 224               if defined $self->relationship
 225                      and $self->relationship eq "";
 226
 227             unless ( $self->in_storage ) {    #AddMember
 228
 229                 # Generate a valid userid/login if needed
 230                 $self->generate_userid unless $self->userid;
 231                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 232                     unless $self->has_valid_userid;
 233
 234                 # Add expiration date if it isn't already there
 235                 unless ( $self->dateexpiry ) {
 236                     $self->dateexpiry( $self->category->get_expiry_date );
 237                 }
 238
 239                 # Add enrollment date if it isn't already there
 240                 unless ( $self->dateenrolled ) {
 241                     $self->dateenrolled(dt_from_string);
 242                 }
 243
 244                 # Set the privacy depending on the patron's category
 245                 my $default_privacy = $self->category->default_privacy || q{};
 246                 $default_privacy =
 247                     $default_privacy eq 'default' ? 1
 248                   : $default_privacy eq 'never'   ? 2
 249                   : $default_privacy eq 'forever' ? 0
 250                   :                                                   undef;
 251                 $self->privacy($default_privacy);
 252
 253                 # Call any check_password plugins if password is passed
 254                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 255                     my @plugins = Koha::Plugins->new()->GetPlugins({
 256                         method => 'check_password',
 257                     });
 258                     foreach my $plugin ( @plugins ) {
 259                         # This plugin hook will also be used by a plugin for the Norwegian national
 260                         # patron database. This is why we need to pass both the password and the
 261                         # borrowernumber to the plugin.
 262                         my $ret = $plugin->check_password(
 263                             {
 264                                 password       => $self->password,
 265                                 borrowernumber => $self->borrowernumber
 266                             }
 267                         );
 268                         if ( $ret->{'error'} == 1 ) {
 269                             Koha::Exceptions::Password::Plugin->throw();
 270                         }
 271                     }
 272                 }
 273
 274                 # Make a copy of the plain text password for later use
 275                 $self->plain_text_password( $self->password );
 276
 277                 $self->password_expiration_date( $self->password
 278                     ? $self->category->get_password_expiry_date || undef
 279                     : undef );
 280                 # Create a disabled account if no password provided
 281                 $self->password( $self->password
 282                     ? Koha::AuthUtils::hash_password( $self->password )
 283                     : '!' );
 284
 285                 $self->borrowernumber(undef);
 286
 287                 $self = $self->SUPER::store;
 288
 289                 $self->add_enrolment_fee_if_needed(0);
 290
 291                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 292                   if C4::Context->preference("BorrowersLog");
 293             }
 294             else {    #ModMember
 295
 296                 my $self_from_storage = $self->get_from_storage;
 297
 298                 # Do not accept invalid userid here
 299                 $self->generate_userid unless $self->userid;
 300                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 301                       unless $self->has_valid_userid;
 302
 303                 # If a borrower has set their privacy to never we should immediately anonymize
 304                 # their checkouts
 305                 if( $self->privacy() == 2 && $self_from_storage->privacy() != 2 ){
 306                     try{
 307                         $self->old_checkouts->anonymize;
 308                     }
 309                     catch {
 310                         Koha::Exceptions::Patron::FailedAnonymizing->throw(
 311                             error => @_
 312                         );
 313                     };
 314                 }
 315
 316                 # Password must be updated using $self->set_password
 317                 $self->password($self_from_storage->password);
 318
 319                 if ( $self->category->categorycode ne
 320                     $self_from_storage->category->categorycode )
 321                 {
 322                     # Add enrolement fee on category change if required
 323                     $self->add_enrolment_fee_if_needed(1)
 324                       if C4::Context->preference('FeeOnChangePatronCategory');
 325
 326                     # Clean up guarantors on category change if required
 327                     $self->guarantor_relationships->delete
 328                       unless ( $self->category->can_be_guarantee );
 329
 330                 }
 331
 332                 # Actionlogs
 333                 if ( C4::Context->preference("BorrowersLog") ) {
 334                     my $info;
 335                     my $from_storage = $self_from_storage->unblessed;
 336                     my $from_object  = $self->unblessed;
 337                     my @skip_fields  = (qw/lastseen updated_on/);
 338                     for my $key ( keys %{$from_storage} ) {
 339                         next if any { /$key/ } @skip_fields;
 340                         if (
 341                             (
 342                                   !defined( $from_storage->{$key} )
 343                                 && defined( $from_object->{$key} )
 344                             )
 345                             || ( defined( $from_storage->{$key} )
 346                                 && !defined( $from_object->{$key} ) )
 347                             || (
 348                                    defined( $from_storage->{$key} )
 349                                 && defined( $from_object->{$key} )
 350                                 && ( $from_storage->{$key} ne
 351                                     $from_object->{$key} )
 352                             )
 353                           )
 354                         {
 355                             $info->{$key} = {
 356                                 before => $from_storage->{$key},
 357                                 after  => $from_object->{$key}
 358                             };
 359                         }
 360                     }
 361
 362                     if ( defined($info) ) {
 363                         logaction(
 364                             "MEMBERS",
 365                             "MODIFY",
 366                             $self->borrowernumber,
 367                             to_json(
 368                                 $info,
 369                                 { utf8 => 1, pretty => 1, canonical => 1 }
 370                             )
 371                         );
 372                     }
 373                 }
 374
 375                 # Final store
 376                 $self = $self->SUPER::store;
 377             }
 378         }
 379     );
 380     return $self;
 381 }
 382
 383 =head3 delete
 384
 385 $patron->delete
 386
 387 Delete patron's holds, lists and finally the patron.
 388
 389 Lists owned by the borrower are deleted or ownership is transferred depending on the
 390 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 391
 392 =cut
 393
 394 sub delete {
 395     my ($self) = @_;
 396
 397     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 398     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 399
 400     $self->_result->result_source->schema->txn_do(
 401         sub {
 402             # Cancel Patron's holds
 403             my $holds = $self->holds;
 404             while( my $hold = $holds->next ){
 405                 $hold->cancel;
 406             }
 407
 408             # Handle lists (virtualshelves)
 409             $self->virtualshelves->disown_or_delete;
 410
 411             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 412             # for patron selfreg
 413             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 414
 415             $self->SUPER::delete;
 416
 417             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 418         }
 419     );
 420     return $self;
 421 }
 422
 423 =head3 category
 424
 425 my $patron_category = $patron->category
 426
 427 Return the patron category for this patron
 428
 429 =cut
 430
 431 sub category {
 432     my ( $self ) = @_;
 433     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 434 }
 435
 436 =head3 image
 437
 438 =cut
 439
 440 sub image {
 441     my ( $self ) = @_;
 442
 443     return Koha::Patron::Images->find( $self->borrowernumber );
 444 }
 445
 446 =head3 library
 447
 448 Returns a Koha::Library object representing the patron's home library.
 449
 450 =cut
 451
 452 sub library {
 453     my ( $self ) = @_;
 454     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 455 }
 456
 457 =head3 sms_provider
 458
 459 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 460
 461 =cut
 462
 463 sub sms_provider {
 464     my ( $self ) = @_;
 465     my $sms_provider_rs = $self->_result->sms_provider;
 466     return unless $sms_provider_rs;
 467     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 468 }
 469
 470 =head3 guarantor_relationships
 471
 472 Returns Koha::Patron::Relationships object for this patron's guarantors
 473
 474 Returns the set of relationships for the patrons that are guarantors for this patron.
 475
 476 Note that a guarantor should exist as a patron in Koha; it was not possible
 477 to add them without a guarantor_id in the interface for some time. Bug 30472
 478 restricts it on db level.
 479
 480 =cut
 481
 482 sub guarantor_relationships {
 483     my ($self) = @_;
 484
 485     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 486 }
 487
 488 =head3 guarantee_relationships
 489
 490 Returns Koha::Patron::Relationships object for this patron's guarantors
 491
 492 Returns the set of relationships for the patrons that are guarantees for this patron.
 493
 494 The method returns Koha::Patron::Relationship objects for the sake
 495 of consistency with the guantors method.
 496 A guarantee by definition must exist as a patron in Koha.
 497
 498 =cut
 499
 500 sub guarantee_relationships {
 501     my ($self) = @_;
 502
 503     return Koha::Patron::Relationships->search(
 504         { guarantor_id => $self->id },
 505         {
 506             prefetch => 'guarantee',
 507             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 508         }
 509     );
 510 }
 511
 512 =head3 relationships_debt
 513
 514 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 515
 516 =cut
 517
 518 sub relationships_debt {
 519     my ($self, $params) = @_;
 520
 521     my $include_guarantors  = $params->{include_guarantors};
 522     my $only_this_guarantor = $params->{only_this_guarantor};
 523     my $include_this_patron = $params->{include_this_patron};
 524
 525     my @guarantors;
 526     if ( $only_this_guarantor ) {
 527         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 528         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 529     } elsif ( $self->guarantor_relationships->count ) {
 530         # I am a guarantee, just get all my guarantors
 531         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 532     } else {
 533         # I am a guarantor, I need to get all the guarantors of all my guarantees
 534         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 535     }
 536
 537     my $non_issues_charges = 0;
 538     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 539     foreach my $guarantor (@guarantors) {
 540         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 541
 542         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 543         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 544         my $guarantees_non_issues_charges = 0;
 545         foreach my $guarantee (@guarantees) {
 546             next if $seen->{ $guarantee->id };
 547             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 548             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 549             $seen->{ $guarantee->id } = 1;
 550         }
 551
 552         $non_issues_charges += $guarantees_non_issues_charges;
 553         $seen->{ $guarantor->id } = 1;
 554     }
 555
 556     return $non_issues_charges;
 557 }
 558
 559 =head3 housebound_profile
 560
 561 Returns the HouseboundProfile associated with this patron.
 562
 563 =cut
 564
 565 sub housebound_profile {
 566     my ( $self ) = @_;
 567     my $profile = $self->_result->housebound_profile;
 568     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 569         if ( $profile );
 570     return;
 571 }
 572
 573 =head3 housebound_role
 574
 575 Returns the HouseboundRole associated with this patron.
 576
 577 =cut
 578
 579 sub housebound_role {
 580     my ( $self ) = @_;
 581
 582     my $role = $self->_result->housebound_role;
 583     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 584     return;
 585 }
 586
 587 =head3 siblings
 588
 589 Returns the siblings of this patron.
 590
 591 =cut
 592
 593 sub siblings {
 594     my ($self) = @_;
 595
 596     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 597
 598     return unless @guarantors;
 599
 600     my @siblings =
 601       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 602
 603     return unless @siblings;
 604
 605     my %seen;
 606     @siblings =
 607       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 608
 609     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 610 }
 611
 612 =head3 merge_with
 613
 614     my $patron = Koha::Patrons->find($id);
 615     $patron->merge_with( \@patron_ids );
 616
 617     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 618     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 619     of the keeper patron.
 620
 621 =cut
 622
 623 sub merge_with {
 624     my ( $self, $patron_ids ) = @_;
 625
 626     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 627     return if $anonymous_patron && $self->id eq $anonymous_patron;
 628
 629     my @patron_ids = @{ $patron_ids };
 630
 631     # Ensure the keeper isn't in the list of patrons to merge
 632     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 633
 634     my $schema = Koha::Database->new()->schema();
 635
 636     my $results;
 637
 638     $self->_result->result_source->schema->txn_do( sub {
 639         foreach my $patron_id (@patron_ids) {
 640
 641             next if $patron_id eq $anonymous_patron;
 642
 643             my $patron = Koha::Patrons->find( $patron_id );
 644
 645             next unless $patron;
 646
 647             # Unbless for safety, the patron will end up being deleted
 648             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 649
 650             my $attributes = $patron->extended_attributes;
 651             my $new_attributes = [
 652                 map { { code => $_->code, attribute => $_->attribute } }
 653                     $attributes->as_list
 654             ];
 655             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 656             for my $attribute ( @$new_attributes ) {
 657                 try {
 658                     $self->add_extended_attribute($attribute);
 659                 } catch {
 660                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 661                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 662                         $_->rethrow;
 663                     }
 664                 };
 665             }
 666
 667             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 668                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 669                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 670                 $rs->update({ $field => $self->id });
 671                 if ( $r eq 'BorrowerDebarment' ) {
 672                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 673                 }
 674             }
 675
 676             $patron->move_to_deleted();
 677             $patron->delete();
 678         }
 679     });
 680
 681     return $results;
 682 }
 683
 684
 685 =head3 messaging_preferences
 686
 687     my $patron = Koha::Patrons->find($id);
 688     $patron->messaging_preferences();
 689
 690 =cut
 691
 692 sub messaging_preferences {
 693     my ( $self ) = @_;
 694
 695     return Koha::Patron::MessagePreferences->search({
 696         borrowernumber => $self->borrowernumber,
 697     });
 698 }
 699
 700 =head3 wants_check_for_previous_checkout
 701
 702     $wants_check = $patron->wants_check_for_previous_checkout;
 703
 704 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 705
 706 =cut
 707
 708 sub wants_check_for_previous_checkout {
 709     my ( $self ) = @_;
 710     my $syspref = C4::Context->preference("checkPrevCheckout");
 711
 712     # Simple cases
 713     ## Hard syspref trumps all
 714     return 1 if ($syspref eq 'hardyes');
 715     return 0 if ($syspref eq 'hardno');
 716     ## Now, patron pref trumps all
 717     return 1 if ($self->checkprevcheckout eq 'yes');
 718     return 0 if ($self->checkprevcheckout eq 'no');
 719
 720     # More complex: patron inherits -> determine category preference
 721     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 722     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 723     return 0 if ($checkPrevCheckoutByCat eq 'no');
 724
 725     # Finally: category preference is inherit, default to 0
 726     if ($syspref eq 'softyes') {
 727         return 1;
 728     } else {
 729         return 0;
 730     }
 731 }
 732
 733 =head3 do_check_for_previous_checkout
 734
 735     $do_check = $patron->do_check_for_previous_checkout($item);
 736
 737 Return 1 if the bib associated with $ITEM has previously been checked out to
 738 $PATRON, 0 otherwise.
 739
 740 =cut
 741
 742 sub do_check_for_previous_checkout {
 743     my ( $self, $item ) = @_;
 744
 745     my @item_nos;
 746     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 747     if ( $biblio->is_serial ) {
 748         push @item_nos, $item->{itemnumber};
 749     } else {
 750         # Get all itemnumbers for given bibliographic record.
 751         @item_nos = $biblio->items->get_column( 'itemnumber' );
 752     }
 753
 754     # Create (old)issues search criteria
 755     my $criteria = {
 756         borrowernumber => $self->borrowernumber,
 757         itemnumber => \@item_nos,
 758     };
 759
 760     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 761     if ($delay) {
 762         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 763         my $newer_than = dt_from_string()->subtract( days => $delay );
 764         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 765     }
 766
 767     # Check current issues table
 768     my $issues = Koha::Checkouts->search($criteria);
 769     return 1 if $issues->count; # 0 || N
 770
 771     # Check old issues table
 772     my $old_issues = Koha::Old::Checkouts->search($criteria);
 773     return $old_issues->count;  # 0 || N
 774 }
 775
 776 =head3 is_debarred
 777
 778 my $debarment_expiration = $patron->is_debarred;
 779
 780 Returns the date a patron debarment will expire, or undef if the patron is not
 781 debarred
 782
 783 =cut
 784
 785 sub is_debarred {
 786     my ($self) = @_;
 787
 788     return unless $self->debarred;
 789     return $self->debarred
 790       if $self->debarred =~ '^9999'
 791       or dt_from_string( $self->debarred ) > dt_from_string;
 792     return;
 793 }
 794
 795 =head3 is_expired
 796
 797 my $is_expired = $patron->is_expired;
 798
 799 Returns 1 if the patron is expired or 0;
 800
 801 =cut
 802
 803 sub is_expired {
 804     my ($self) = @_;
 805     return 0 unless $self->dateexpiry;
 806     return 0 if $self->dateexpiry =~ '^9999';
 807     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 808     return 0;
 809 }
 810
 811 =head3 password_expired
 812
 813 my $password_expired = $patron->password_expired;
 814
 815 Returns 1 if the patron's password is expired or 0;
 816
 817 =cut
 818
 819 sub password_expired {
 820     my ($self) = @_;
 821     return 0 unless $self->password_expiration_date;
 822     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 823     return 0;
 824 }
 825
 826 =head3 is_going_to_expire
 827
 828 my $is_going_to_expire = $patron->is_going_to_expire;
 829
 830 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 831
 832 =cut
 833
 834 sub is_going_to_expire {
 835     my ($self) = @_;
 836
 837     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 838
 839     return 0 unless $delay;
 840     return 0 unless $self->dateexpiry;
 841     return 0 if $self->dateexpiry =~ '^9999';
 842     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 843     return 0;
 844 }
 845
 846 =head3 set_password
 847
 848     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 849
 850 Set the patron's password.
 851
 852 =head4 Exceptions
 853
 854 The passed string is validated against the current password enforcement policy.
 855 Validation can be skipped by passing the I<skip_validation> parameter.
 856
 857 Exceptions are thrown if the password is not good enough.
 858
 859 =over 4
 860
 861 =item Koha::Exceptions::Password::TooShort
 862
 863 =item Koha::Exceptions::Password::WhitespaceCharacters
 864
 865 =item Koha::Exceptions::Password::TooWeak
 866
 867 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 868
 869 =back
 870
 871 =cut
 872
 873 sub set_password {
 874     my ( $self, $args ) = @_;
 875
 876     my $password = $args->{password};
 877
 878     unless ( $args->{skip_validation} ) {
 879         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 880
 881         if ( !$is_valid ) {
 882             if ( $error eq 'too_short' ) {
 883                 my $min_length = $self->category->effective_min_password_length;
 884                 $min_length = 3 if not $min_length or $min_length < 3;
 885
 886                 my $password_length = length($password);
 887                 Koha::Exceptions::Password::TooShort->throw(
 888                     length => $password_length, min_length => $min_length );
 889             }
 890             elsif ( $error eq 'has_whitespaces' ) {
 891                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 892             }
 893             elsif ( $error eq 'too_weak' ) {
 894                 Koha::Exceptions::Password::TooWeak->throw();
 895             }
 896         }
 897     }
 898
 899     if ( C4::Context->config("enable_plugins") ) {
 900         # Call any check_password plugins
 901         my @plugins = Koha::Plugins->new()->GetPlugins({
 902             method => 'check_password',
 903         });
 904         foreach my $plugin ( @plugins ) {
 905             # This plugin hook will also be used by a plugin for the Norwegian national
 906             # patron database. This is why we need to pass both the password and the
 907             # borrowernumber to the plugin.
 908             my $ret = $plugin->check_password(
 909                 {
 910                     password       => $password,
 911                     borrowernumber => $self->borrowernumber
 912                 }
 913             );
 914             # This plugin hook will also be used by a plugin for the Norwegian national
 915             # patron database. This is why we need to call the actual plugins and then
 916             # check skip_validation afterwards.
 917             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 918                 Koha::Exceptions::Password::Plugin->throw();
 919             }
 920         }
 921     }
 922
 923     if ( C4::Context->preference('NotifyPasswordChange') ) {
 924         my $self_from_storage = $self->get_from_storage;
 925         if ( !C4::Auth::checkpw_hash( $password, $self_from_storage->password ) ) {
 926             my $emailaddr = $self_from_storage->notice_email_address;
 927
 928             # if we manage to find a valid email address, send notice
 929             if ($emailaddr) {
 930                 my $letter = C4::Letters::GetPreparedLetter(
 931                     module      => 'members',
 932                     letter_code => 'PASSWORD_CHANGE',
 933                     branchcode  => $self_from_storage->branchcode,
 934                     ,
 935                     lang   => $self_from_storage->lang || 'default',
 936                     tables => {
 937                         'branches'  => $self_from_storage->branchcode,
 938                         'borrowers' => $self_from_storage->borrowernumber,
 939                     },
 940                     want_librarian => 1,
 941                 ) or return;
 942
 943                 my $message_id = C4::Letters::EnqueueLetter(
 944                     {
 945                         letter                 => $letter,
 946                         borrowernumber         => $self_from_storage->id,
 947                         to_address             => $emailaddr,
 948                         message_transport_type => 'email'
 949                     }
 950                 );
 951                 C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 952             }
 953         }
 954     }
 955
 956     my $digest = Koha::AuthUtils::hash_password($password);
 957
 958     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 959
 960     # We do not want to call $self->store and retrieve password from DB
 961     $self->password($digest);
 962     $self->login_attempts(0);
 963     $self->SUPER::store;
 964
 965     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 966         if C4::Context->preference("BorrowersLog");
 967
 968     return $self;
 969 }
 970
 971
 972 =head3 renew_account
 973
 974 my $new_expiry_date = $patron->renew_account
 975
 976 Extending the subscription to the expiry date.
 977
 978 =cut
 979
 980 sub renew_account {
 981     my ($self) = @_;
 982     my $date;
 983     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 984         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 985     } else {
 986         $date =
 987             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 988             ? dt_from_string( $self->dateexpiry )
 989             : dt_from_string;
 990     }
 991     my $expiry_date = $self->category->get_expiry_date($date);
 992
 993     $self->dateexpiry($expiry_date);
 994     $self->date_renewed( dt_from_string() );
 995     $self->store();
 996
 997     $self->add_enrolment_fee_if_needed(1);
 998
 999     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
1000     return dt_from_string( $expiry_date )->truncate( to => 'day' );
1001 }
1002
1003 =head3 has_overdues
1004
1005 my $has_overdues = $patron->has_overdues;
1006
1007 Returns the number of patron's overdues
1008
1009 =cut
1010
1011 sub has_overdues {
1012     my ($self) = @_;
1013     my $date = dt_from_string();
1014     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1015     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime($date) } })->count;
1016 }
1017
1018
1019 =head3 has_restricting_overdues
1020
1021 my $has_restricting_overdues = $patron->has_restricting_overdues({ issue_branchcode => $branchcode });
1022
1023 Returns true if patron has overdues that would result in debarment.
1024
1025 =cut
1026
1027 sub has_restricting_overdues {
1028     my ($self, $params) = @_;
1029     $params //= {};
1030     my $date = dt_from_string()->truncate( to => 'day' );
1031
1032     # If ignoring unrestricted overdues, calculate which delay value for
1033     # overdue messages is set with restrictions. Then only include overdue
1034     # issues older than that date when counting.
1035     #TODO: bail out/throw exception if $params->{issue_branchcode} not set?
1036     my $debarred_delay = _get_overdue_debarred_delay($params->{issue_branchcode}, $self->categorycode());
1037     return 0 unless defined $debarred_delay;
1038
1039     # Emulate the conditions in overdue_notices.pl.
1040     # The overdue_notices-script effectively truncates both issues.date_due and current date
1041     # to days when selecting overdue issues.
1042     # Hours and minutes for issues.date_due is usually set to 23 and 59 respectively, though can theoretically
1043     # be set to any other value (truncated to minutes, except if CalcDateDue gets a $startdate)
1044     #
1045     # No matter what time of day date_due is set to, overdue_notices.pl will select all issues that are due
1046     # the current date or later. We can emulate this query by instead of truncating both to days in the SQL-query,
1047     # using the condition that date_due must be less then the current date truncated to days (time set to 00:00:00)
1048     # offset by one day in the future.
1049
1050     $date->add(days => 1);
1051
1052     my $calendar;
1053     if (C4::Context->preference('OverdueNoticeCalendar')) {
1054         $calendar = Koha::Calendar->new( branchcode => $params->{issue_branchcode} );
1055     }
1056
1057     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1058     my $issues = $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime($date) } });
1059     my $now = dt_from_string();
1060
1061     while (my $issue = $issues->next) {
1062         my $days_between = C4::Context->preference('OverdueNoticeCalendar') ?
1063             $calendar->days_between(dt_from_string($issue->date_due), $now)->in_units('days') :
1064             $now->delta_days(dt_from_string($issue->date_due))->in_units('days');
1065         if ($days_between >= $debarred_delay) {
1066             return 1;
1067         }
1068     }
1069     return 0;
1070 }
1071
1072 # Fetch first delayX value from overduerules where debarredX is set, or 0 for no delay
1073 sub _get_overdue_debarred_delay {
1074     my ($branchcode, $categorycode) = @_;
1075     my $dbh = C4::Context->dbh();
1076
1077     # We get default rules if there is no rule for this branch
1078     my $rule = Koha::OverdueRules->find(
1079         {
1080             branchcode   => $branchcode,
1081             categorycode => $categorycode
1082         }
1083       )
1084       || Koha::OverdueRules->find(
1085         {
1086             branchcode   => q{},
1087             categorycode => $categorycode
1088         }
1089       );
1090
1091     if ( $rule ) {
1092         return $rule->delay1 if $rule->debarred1;
1093         return $rule->delay2 if $rule->debarred2;
1094         return $rule->delay3 if $rule->debarred3;
1095     }
1096 }
1097
1098 =head3 track_login
1099
1100     $patron->track_login;
1101     $patron->track_login({ force => 1 });
1102
1103     Tracks a (successful) login attempt.
1104     The preference TrackLastPatronActivity must be enabled. Or you
1105     should pass the force parameter.
1106
1107 =cut
1108
1109 sub track_login {
1110     my ( $self, $params ) = @_;
1111     return if
1112         !$params->{force} &&
1113         !C4::Context->preference('TrackLastPatronActivity');
1114     $self->lastseen( dt_from_string() )->store;
1115 }
1116
1117 =head3 move_to_deleted
1118
1119 my $is_moved = $patron->move_to_deleted;
1120
1121 Move a patron to the deletedborrowers table.
1122 This can be done before deleting a patron, to make sure the data are not completely deleted.
1123
1124 =cut
1125
1126 sub move_to_deleted {
1127     my ($self) = @_;
1128     my $patron_infos = $self->unblessed;
1129     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
1130     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1131 }
1132
1133 =head3 can_request_article
1134
1135     if ( $patron->can_request_article( $library->id ) ) { ... }
1136
1137 Returns true if the patron can request articles. As limits apply for the patron
1138 on the same day, those completed the same day are considered as current.
1139
1140 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1141
1142 =cut
1143
1144 sub can_request_article {
1145     my ($self, $library_id) = @_;
1146
1147     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1148
1149     my $rule = Koha::CirculationRules->get_effective_rule(
1150         {
1151             branchcode   => $library_id,
1152             categorycode => $self->categorycode,
1153             rule_name    => 'open_article_requests_limit'
1154         }
1155     );
1156
1157     my $limit = ($rule) ? $rule->rule_value : undef;
1158
1159     return 1 unless defined $limit;
1160
1161     my $count = Koha::ArticleRequests->search(
1162         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1163             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1164         ]
1165     )->count;
1166     return $count < $limit ? 1 : 0;
1167 }
1168
1169 =head3 article_request_fee
1170
1171     my $fee = $patron->article_request_fee(
1172         {
1173           [ library_id => $library->id, ]
1174         }
1175     );
1176
1177 Returns the fee to be charged to the patron when it places an article request.
1178
1179 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1180
1181 =cut
1182
1183 sub article_request_fee {
1184     my ($self, $params) = @_;
1185
1186     my $library_id = $params->{library_id};
1187
1188     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1189
1190     my $rule = Koha::CirculationRules->get_effective_rule(
1191         {
1192             branchcode   => $library_id,
1193             categorycode => $self->categorycode,
1194             rule_name    => 'article_request_fee'
1195         }
1196     );
1197
1198     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1199
1200     return $fee;
1201 }
1202
1203 =head3 add_article_request_fee_if_needed
1204
1205     my $fee = $patron->add_article_request_fee_if_needed(
1206         {
1207           [ item_id    => $item->id,
1208             library_id => $library->id, ]
1209         }
1210     );
1211
1212 If an article request fee needs to be charged, it adds a debit to the patron's
1213 account.
1214
1215 Returns the fee line.
1216
1217 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1218
1219 =cut
1220
1221 sub add_article_request_fee_if_needed {
1222     my ($self, $params) = @_;
1223
1224     my $library_id = $params->{library_id};
1225     my $item_id    = $params->{item_id};
1226
1227     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1228
1229     my $amount = $self->article_request_fee(
1230         {
1231             library_id => $library_id,
1232         }
1233     );
1234
1235     my $debit_line;
1236
1237     if ( $amount > 0 ) {
1238         $debit_line = $self->account->add_debit(
1239             {
1240                 amount     => $amount,
1241                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1242                 interface  => C4::Context->interface,
1243                 library_id => $library_id,
1244                 type       => 'ARTICLE_REQUEST',
1245                 item_id    => $item_id,
1246             }
1247         );
1248     }
1249
1250     return $debit_line;
1251 }
1252
1253 =head3 article_requests
1254
1255     my $article_requests = $patron->article_requests;
1256
1257 Returns the patron article requests.
1258
1259 =cut
1260
1261 sub article_requests {
1262     my ($self) = @_;
1263
1264     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1265 }
1266
1267 =head3 add_enrolment_fee_if_needed
1268
1269 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1270
1271 Add enrolment fee for a patron if needed.
1272
1273 $renewal - boolean denoting whether this is an account renewal or not
1274
1275 =cut
1276
1277 sub add_enrolment_fee_if_needed {
1278     my ($self, $renewal) = @_;
1279     my $enrolment_fee = $self->category->enrolmentfee;
1280     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1281         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1282         $self->account->add_debit(
1283             {
1284                 amount     => $enrolment_fee,
1285                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1286                 interface  => C4::Context->interface,
1287                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1288                 type       => $type
1289             }
1290         );
1291     }
1292     return $enrolment_fee || 0;
1293 }
1294
1295 =head3 checkouts
1296
1297 my $checkouts = $patron->checkouts
1298
1299 =cut
1300
1301 sub checkouts {
1302     my ($self) = @_;
1303     my $checkouts = $self->_result->issues;
1304     return Koha::Checkouts->_new_from_dbic( $checkouts );
1305 }
1306
1307 =head3 pending_checkouts
1308
1309 my $pending_checkouts = $patron->pending_checkouts
1310
1311 This method will return the same as $self->checkouts, but with a prefetch on
1312 items, biblio and biblioitems.
1313
1314 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1315
1316 It should not be used directly, prefer to access fields you need instead of
1317 retrieving all these fields in one go.
1318
1319 =cut
1320
1321 sub pending_checkouts {
1322     my( $self ) = @_;
1323     my $checkouts = $self->_result->issues->search(
1324         {},
1325         {
1326             order_by => [
1327                 { -desc => 'me.timestamp' },
1328                 { -desc => 'issuedate' },
1329                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1330             ],
1331             prefetch => { item => { biblio => 'biblioitems' } },
1332         }
1333     );
1334     return Koha::Checkouts->_new_from_dbic( $checkouts );
1335 }
1336
1337 =head3 old_checkouts
1338
1339 my $old_checkouts = $patron->old_checkouts
1340
1341 =cut
1342
1343 sub old_checkouts {
1344     my ($self) = @_;
1345     my $old_checkouts = $self->_result->old_issues;
1346     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1347 }
1348
1349 =head3 overdues
1350
1351 my $overdue_items = $patron->overdues
1352
1353 Return the overdue items
1354
1355 =cut
1356
1357 sub overdues {
1358     my ($self) = @_;
1359     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1360     return $self->checkouts->search(
1361         {
1362             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1363         },
1364         {
1365             prefetch => { item => { biblio => 'biblioitems' } },
1366         }
1367     );
1368 }
1369
1370
1371 =head3 restrictions
1372
1373   my $restrictions = $patron->restrictions;
1374
1375 Returns the patron restrictions.
1376
1377 =cut
1378
1379 sub restrictions {
1380     my ($self) = @_;
1381     my $restrictions_rs = $self->_result->restrictions;
1382     return Koha::Patron::Restrictions->_new_from_dbic($restrictions_rs);
1383 }
1384
1385 =head3 get_routing_lists
1386
1387 my $routinglists = $patron->get_routing_lists
1388
1389 Returns the routing lists a patron is subscribed to.
1390
1391 =cut
1392
1393 sub get_routing_lists {
1394     my ($self) = @_;
1395     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1396     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1397 }
1398
1399 =head3 get_age
1400
1401     my $age = $patron->get_age
1402
1403 Return the age of the patron
1404
1405 =cut
1406
1407 sub get_age {
1408     my ($self)    = @_;
1409
1410     return unless $self->dateofbirth;
1411
1412     #Set timezone to floating to avoid any datetime math issues caused by DST
1413     my $date_of_birth = dt_from_string( $self->dateofbirth, undef, 'floating' );
1414     my $today         = dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
1415
1416     return $today->subtract_datetime( $date_of_birth )->years;
1417 }
1418
1419 =head3 is_valid_age
1420
1421 my $is_valid = $patron->is_valid_age
1422
1423 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1424
1425 =cut
1426
1427 sub is_valid_age {
1428     my ($self) = @_;
1429     my $age = $self->get_age;
1430
1431     my $patroncategory = $self->category;
1432     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1433
1434     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1435 }
1436
1437 =head3 account
1438
1439 my $account = $patron->account
1440
1441 =cut
1442
1443 sub account {
1444     my ($self) = @_;
1445     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1446 }
1447
1448 =head3 holds
1449
1450 my $holds = $patron->holds
1451
1452 Return all the holds placed by this patron
1453
1454 =cut
1455
1456 sub holds {
1457     my ($self) = @_;
1458     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1459     return Koha::Holds->_new_from_dbic($holds_rs);
1460 }
1461
1462 =head3 old_holds
1463
1464 my $old_holds = $patron->old_holds
1465
1466 Return all the historical holds for this patron
1467
1468 =cut
1469
1470 sub old_holds {
1471     my ($self) = @_;
1472     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1473     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1474 }
1475
1476 =head3 curbside_pickups
1477
1478 my $curbside_pickups = $patron->curbside_pickups;
1479
1480 Return all the curbside pickups for this patron
1481
1482 =cut
1483
1484 sub curbside_pickups {
1485     my ($self) = @_;
1486     my $curbside_pickups_rs = $self->_result->curbside_pickups_borrowernumbers->search;
1487     return Koha::CurbsidePickups->_new_from_dbic($curbside_pickups_rs);
1488 }
1489
1490 =head3 return_claims
1491
1492 my $return_claims = $patron->return_claims
1493
1494 =cut
1495
1496 sub return_claims {
1497     my ($self) = @_;
1498     my $return_claims = $self->_result->return_claims_borrowernumbers;
1499     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1500 }
1501
1502 =head3 notice_email_address
1503
1504   my $email = $patron->notice_email_address;
1505
1506 Return the email address of patron used for notices.
1507 Returns the empty string if no email address.
1508
1509 =cut
1510
1511 sub notice_email_address{
1512     my ( $self ) = @_;
1513
1514     my $which_address = C4::Context->preference("EmailFieldPrimary");
1515     # if syspref is set to 'first valid' (value == OFF), look up email address
1516     if ( $which_address eq 'OFF' ) {
1517         return $self->first_valid_email_address;
1518     }
1519
1520     return $self->$which_address || '';
1521 }
1522
1523 =head3 first_valid_email_address
1524
1525 my $first_valid_email_address = $patron->first_valid_email_address
1526
1527 Return the first valid email address for a patron.
1528 For now, the order  is defined as email, emailpro, B_email.
1529 Returns the empty string if the borrower has no email addresses.
1530
1531 =cut
1532
1533 sub first_valid_email_address {
1534     my ($self) = @_;
1535
1536     my $email = q{};
1537
1538     my @fields = split /\s*\|\s*/,
1539       C4::Context->preference('EmailFieldPrecedence');
1540     for my $field (@fields) {
1541         $email = $self->$field;
1542         last if ($email);
1543     }
1544
1545     return $email;
1546 }
1547
1548 =head3 get_club_enrollments
1549
1550 =cut
1551
1552 sub get_club_enrollments {
1553     my ( $self ) = @_;
1554
1555     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1556 }
1557
1558 =head3 get_enrollable_clubs
1559
1560 =cut
1561
1562 sub get_enrollable_clubs {
1563     my ( $self, $is_enrollable_from_opac ) = @_;
1564
1565     my $params;
1566     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1567       if $is_enrollable_from_opac;
1568     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1569
1570     $params->{borrower} = $self;
1571
1572     return Koha::Clubs->get_enrollable($params);
1573 }
1574
1575 =head3 account_locked
1576
1577 my $is_locked = $patron->account_locked
1578
1579 Return true if the patron has reached the maximum number of login attempts
1580 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1581 as an administrative lockout (independent of FailedLoginAttempts; see also
1582 Koha::Patron->lock).
1583 Otherwise return false.
1584 If the pref is not set (empty string, null or 0), the feature is considered as
1585 disabled.
1586
1587 =cut
1588
1589 sub account_locked {
1590     my ($self) = @_;
1591     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1592     return 1 if $FailedLoginAttempts
1593           and $self->login_attempts
1594           and $self->login_attempts >= $FailedLoginAttempts;
1595     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1596     return 0;
1597 }
1598
1599 =head3 can_see_patron_infos
1600
1601 my $can_see = $patron->can_see_patron_infos( $patron );
1602
1603 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1604
1605 =cut
1606
1607 sub can_see_patron_infos {
1608     my ( $self, $patron ) = @_;
1609     return unless $patron;
1610     return $self->can_see_patrons_from( $patron->branchcode );
1611 }
1612
1613 =head3 can_see_patrons_from
1614
1615 my $can_see = $patron->can_see_patrons_from( $branchcode );
1616
1617 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1618
1619 =cut
1620
1621 sub can_see_patrons_from {
1622     my ( $self, $branchcode ) = @_;
1623
1624     return $self->can_see_things_from(
1625         {
1626             branchcode => $branchcode,
1627             permission => 'borrowers',
1628             subpermission => 'view_borrower_infos_from_any_libraries',
1629         }
1630     );
1631 }
1632
1633 =head3 can_edit_items_from
1634
1635     my $can_edit = $patron->can_edit_items_from( $branchcode );
1636
1637 Return true if the I<Koha::Patron> can edit items from the given branchcode
1638
1639 =cut
1640
1641 sub can_edit_items_from {
1642     my ( $self, $branchcode ) = @_;
1643
1644     return 1 if C4::Context->IsSuperLibrarian();
1645
1646     my $userenv = C4::Context->userenv();
1647     if ( $userenv && C4::Context->preference('IndependentBranches') ) {
1648         return $userenv->{branch} eq $branchcode;
1649     }
1650
1651     return $self->can_see_things_from(
1652         {
1653             branchcode    => $branchcode,
1654             permission    => 'editcatalogue',
1655             subpermission => 'edit_any_item',
1656         }
1657     );
1658 }
1659
1660 =head3 libraries_where_can_edit_items
1661
1662     my $libraries = $patron->libraries_where_can_edit_items;
1663
1664 Return the list of branchcodes(!) of libraries the patron is allowed to items for.
1665 The branchcodes are arbitrarily returned sorted.
1666 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1667
1668 An empty array means no restriction, the user can edit any item.
1669
1670 =cut
1671
1672 sub libraries_where_can_edit_items {
1673     my ($self) = @_;
1674
1675     return $self->libraries_where_can_see_things(
1676         {
1677             permission    => 'editcatalogue',
1678             subpermission => 'edit_any_item',
1679             group_feature => 'ft_limit_item_editing',
1680         }
1681     );
1682 }
1683
1684 =head3 libraries_where_can_see_patrons
1685
1686 my $libraries = $patron->libraries_where_can_see_patrons;
1687
1688 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1689 The branchcodes are arbitrarily returned sorted.
1690 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1691
1692 An empty array means no restriction, the patron can see patron's infos from any libraries.
1693
1694 =cut
1695
1696 sub libraries_where_can_see_patrons {
1697     my ($self) = @_;
1698
1699     return $self->libraries_where_can_see_things(
1700         {
1701             permission    => 'borrowers',
1702             subpermission => 'view_borrower_infos_from_any_libraries',
1703             group_feature => 'ft_hide_patron_info',
1704         }
1705     );
1706 }
1707
1708 =head3 can_see_things_from
1709
1710 my $can_see = $patron->can_see_things_from( $branchcode );
1711
1712 Return true if the I<Koha::Patron> can perform some action on the given thing
1713
1714 =cut
1715
1716 sub can_see_things_from {
1717     my ( $self, $params ) = @_;
1718
1719     my $branchcode    = $params->{branchcode};
1720     my $permission    = $params->{permission};
1721     my $subpermission = $params->{subpermission};
1722
1723     return 1 if C4::Context->IsSuperLibrarian();
1724
1725     my $can = 0;
1726     if ( $self->branchcode eq $branchcode ) {
1727         $can = 1;
1728     } elsif ( $self->has_permission( { $permission => $subpermission } ) ) {
1729         $can = 1;
1730     } elsif ( my $library_groups = $self->library->library_groups ) {
1731         while ( my $library_group = $library_groups->next ) {
1732             if ( $library_group->parent->has_child( $branchcode ) ) {
1733                 $can = 1;
1734                 last;
1735             }
1736         }
1737     }
1738     return $can;
1739 }
1740
1741 =head3 can_log_into
1742
1743 my $can_log_into = $patron->can_log_into( $library );
1744
1745 Given a I<Koha::Library> object, it returns a boolean representing
1746 the fact the patron can log into a the library.
1747
1748 =cut
1749
1750 sub can_log_into {
1751     my ( $self, $library ) = @_;
1752
1753     my $can = 0;
1754
1755     if ( C4::Context->preference('IndependentBranches') ) {
1756         $can = 1
1757           if $self->is_superlibrarian
1758           or $self->branchcode eq $library->id;
1759     }
1760     else {
1761         # no restrictions
1762         $can = 1;
1763     }
1764
1765    return $can;
1766 }
1767
1768 =head3 libraries_where_can_see_things
1769
1770     my $libraries = $patron->libraries_where_can_see_things;
1771
1772 Returns a list of libraries where an aribitarary action is allowed to be taken by the logged in librarian
1773 against an object based on some branchcode related to the object ( patron branchcode, item homebranch, etc ).
1774
1775 We are supposing here that the object is related to the logged in librarian (use of C4::Context::only_my_library)
1776
1777 An empty array means no restriction, the thing can see thing's infos from any libraries.
1778
1779 =cut
1780
1781 sub libraries_where_can_see_things {
1782     my ( $self, $params ) = @_;
1783     my $permission    = $params->{permission};
1784     my $subpermission = $params->{subpermission};
1785     my $group_feature = $params->{group_feature};
1786
1787     my $userenv = C4::Context->userenv;
1788
1789     return () unless $userenv; # For tests, but userenv should be defined in tests...
1790
1791     my @restricted_branchcodes;
1792     if (C4::Context::only_my_library) {
1793         push @restricted_branchcodes, $self->branchcode;
1794     }
1795     else {
1796         unless (
1797             $self->has_permission(
1798                 { $permission => $subpermission }
1799             )
1800           )
1801         {
1802             my $library_groups = $self->library->library_groups({ $group_feature => 1 });
1803             if ( $library_groups->count )
1804             {
1805                 while ( my $library_group = $library_groups->next ) {
1806                     my $parent = $library_group->parent;
1807                     if ( $parent->has_child( $self->branchcode ) ) {
1808                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1809                     }
1810                 }
1811             }
1812
1813             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1814         }
1815     }
1816
1817     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1818     @restricted_branchcodes = uniq(@restricted_branchcodes);
1819     @restricted_branchcodes = sort(@restricted_branchcodes);
1820     return @restricted_branchcodes;
1821 }
1822
1823 =head3 has_permission
1824
1825 my $permission = $patron->has_permission($required);
1826
1827 See C4::Auth::haspermission for details of syntax for $required
1828
1829 =cut
1830
1831 sub has_permission {
1832     my ( $self, $flagsrequired ) = @_;
1833     return unless $self->userid;
1834     # TODO code from haspermission needs to be moved here!
1835     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1836 }
1837
1838 =head3 is_superlibrarian
1839
1840   my $is_superlibrarian = $patron->is_superlibrarian;
1841
1842 Return true if the patron is a superlibrarian.
1843
1844 =cut
1845
1846 sub is_superlibrarian {
1847     my ($self) = @_;
1848     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1849 }
1850
1851 =head3 is_adult
1852
1853 my $is_adult = $patron->is_adult
1854
1855 Return true if the patron has a category with a type Adult (A) or Organization (I)
1856
1857 =cut
1858
1859 sub is_adult {
1860     my ( $self ) = @_;
1861     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1862 }
1863
1864 =head3 is_child
1865
1866 my $is_child = $patron->is_child
1867
1868 Return true if the patron has a category with a type Child (C)
1869
1870 =cut
1871
1872 sub is_child {
1873     my( $self ) = @_;
1874     return $self->category->category_type eq 'C' ? 1 : 0;
1875 }
1876
1877 =head3 has_valid_userid
1878
1879 my $patron = Koha::Patrons->find(42);
1880 $patron->userid( $new_userid );
1881 my $has_a_valid_userid = $patron->has_valid_userid
1882
1883 my $patron = Koha::Patron->new( $params );
1884 my $has_a_valid_userid = $patron->has_valid_userid
1885
1886 Return true if the current userid of this patron is valid/unique, otherwise false.
1887
1888 Note that this should be done in $self->store instead and raise an exception if needed.
1889
1890 =cut
1891
1892 sub has_valid_userid {
1893     my ($self) = @_;
1894
1895     return 0 unless $self->userid;
1896
1897     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1898
1899     my $already_exists = Koha::Patrons->search(
1900         {
1901             userid => $self->userid,
1902             (
1903                 $self->in_storage
1904                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1905                 : ()
1906             ),
1907         }
1908     )->count;
1909     return $already_exists ? 0 : 1;
1910 }
1911
1912 =head3 generate_userid
1913
1914     $patron->generate_userid;
1915
1916     If you do not have a plugin for generating a userid, we will call
1917     the internal method here that returns firstname.surname[.number],
1918     where number is an optional suffix to make the userid unique.
1919     (Its behavior has not been changed on bug 32426.)
1920
1921     If you have plugin(s), the first valid response will be used.
1922     A plugin is assumed to return a valid userid as suggestion, but not
1923     assumed to save it already.
1924     Does not fallback to internal (you could arrange for that in your plugin).
1925     Clears userid when there are no valid plugin responses.
1926
1927 =cut
1928
1929 sub generate_userid {
1930     my ( $self ) = @_;
1931     my @responses = Koha::Plugins->call(
1932         'patron_generate_userid', { patron => $self },
1933     );
1934     unless( @responses ) {
1935         # Empty list only possible when there are NO enabled plugins for this method.
1936         # In that case we provide internal response.
1937         return $self->_generate_userid_internal;
1938     }
1939     # If a plugin returned false value or invalid value, we do however not return
1940     # internal response. The plugins should deal with that themselves. So we prevent
1941     # unexpected/unwelcome internal codes for plugin failures.
1942     foreach my $response ( grep { $_ } @responses ) {
1943         $self->userid( $response );
1944         return $self if $self->has_valid_userid;
1945     }
1946     $self->userid(undef);
1947     return $self;
1948 }
1949
1950 sub _generate_userid_internal { # as we always did
1951     my ($self) = @_;
1952     my $offset = 0;
1953     my $firstname = $self->firstname // q{};
1954     my $surname = $self->surname // q{};
1955     #The script will "do" the following code and increment the $offset until the generated userid is unique
1956     do {
1957       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1958       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1959       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1960       $userid = NFKD( $userid );
1961       $userid =~ s/\p{NonspacingMark}//g;
1962       $userid .= $offset unless $offset == 0;
1963       $self->userid( $userid );
1964       $offset++;
1965      } while (! $self->has_valid_userid );
1966
1967      return $self;
1968 }
1969
1970 =head3 add_extended_attribute
1971
1972 =cut
1973
1974 sub add_extended_attribute {
1975     my ($self, $attribute) = @_;
1976
1977     return Koha::Patron::Attribute->new(
1978         {
1979             %$attribute,
1980             ( borrowernumber => $self->borrowernumber ),
1981         }
1982     )->store;
1983
1984 }
1985
1986 =head3 extended_attributes
1987
1988 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1989
1990 Or setter FIXME
1991
1992 =cut
1993
1994 sub extended_attributes {
1995     my ( $self, $attributes ) = @_;
1996     if ($attributes) {    # setter
1997         my $schema = $self->_result->result_source->schema;
1998         $schema->txn_do(
1999             sub {
2000                 # Remove the existing one
2001                 $self->extended_attributes->filter_by_branch_limitations->delete;
2002
2003                 # Insert the new ones
2004                 my $new_types = {};
2005                 for my $attribute (@$attributes) {
2006                     $self->add_extended_attribute($attribute);
2007                     $new_types->{$attribute->{code}} = 1;
2008                 }
2009
2010                 # Check globally mandatory types
2011                 my @required_attribute_types =
2012                     Koha::Patron::Attribute::Types->search(
2013                         {
2014                             mandatory => 1,
2015                             category_code => [ undef, $self->categorycode ],
2016                             'borrower_attribute_types_branches.b_branchcode' =>
2017                               undef,
2018                         },
2019                         { join => 'borrower_attribute_types_branches' }
2020                     )->get_column('code');
2021                 for my $type ( @required_attribute_types ) {
2022                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
2023                         type => $type,
2024                     ) if !$new_types->{$type};
2025                 }
2026             }
2027         );
2028     }
2029
2030     my $rs = $self->_result->borrower_attributes;
2031     # We call search to use the filters in Koha::Patron::Attributes->search
2032     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
2033 }
2034
2035 =head3 messages
2036
2037     my $messages = $patron->messages;
2038
2039 Return the message attached to the patron.
2040
2041 =cut
2042
2043 sub messages {
2044     my ( $self ) = @_;
2045     my $messages_rs = $self->_result->messages_borrowernumbers->search;
2046     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
2047 }
2048
2049 =head3 lock
2050
2051     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
2052
2053     Lock and optionally expire a patron account.
2054     Remove holds and article requests if remove flag set.
2055     In order to distinguish from locking by entering a wrong password, let's
2056     call this an administrative lockout.
2057
2058 =cut
2059
2060 sub lock {
2061     my ( $self, $params ) = @_;
2062     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
2063     if( $params->{expire} ) {
2064         $self->dateexpiry( dt_from_string->subtract(days => 1) );
2065     }
2066     $self->store;
2067     if( $params->{remove} ) {
2068         $self->holds->delete;
2069         $self->article_requests->delete;
2070     }
2071     return $self;
2072 }
2073
2074 =head3 anonymize
2075
2076     Koha::Patrons->find($id)->anonymize;
2077
2078     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
2079     are randomized, other personal data is cleared too.
2080     Patrons with issues are skipped.
2081
2082 =cut
2083
2084 sub anonymize {
2085     my ( $self ) = @_;
2086     if( $self->_result->issues->count ) {
2087         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
2088         return;
2089     }
2090     # Mandatory fields come from the corresponding pref, but email fields
2091     # are removed since scrambled email addresses only generate errors
2092     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
2093         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
2094     $mandatory->{userid} = 1; # needed since sub store does not clear field
2095     my @columns = $self->_result->result_source->columns;
2096     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
2097     push @columns, 'dateofbirth'; # add this date back in
2098     foreach my $col (@columns) {
2099         $self->_anonymize_column($col, $mandatory->{lc $col} );
2100     }
2101     $self->anonymized(1)->store;
2102 }
2103
2104 sub _anonymize_column {
2105     my ( $self, $col, $mandatory ) = @_;
2106     my $col_info = $self->_result->result_source->column_info($col);
2107     my $type = $col_info->{data_type};
2108     my $nullable = $col_info->{is_nullable};
2109     my $val;
2110     if( $type =~ /char|text/ ) {
2111         $val = $mandatory
2112             ? Koha::Token->new->generate({ pattern => '\w{10}' })
2113             : $nullable
2114             ? undef
2115             : q{};
2116     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
2117         $val = $nullable ? undef : 0;
2118     } elsif( $type =~ /date|time/ ) {
2119         $val = $nullable ? undef : dt_from_string;
2120     }
2121     $self->$col($val);
2122 }
2123
2124 =head3 add_guarantor
2125
2126     my $relationship = $patron->add_guarantor(
2127         {
2128             borrowernumber => $borrowernumber,
2129             relationships  => $relationship,
2130         }
2131     );
2132
2133     Adds a new guarantor to a patron.
2134
2135 =cut
2136
2137 sub add_guarantor {
2138     my ( $self, $params ) = @_;
2139
2140     my $guarantor_id = $params->{guarantor_id};
2141     my $relationship = $params->{relationship};
2142
2143     return Koha::Patron::Relationship->new(
2144         {
2145             guarantee_id => $self->id,
2146             guarantor_id => $guarantor_id,
2147             relationship => $relationship
2148         }
2149     )->store();
2150 }
2151
2152 =head3 get_extended_attribute
2153
2154 my $attribute_value = $patron->get_extended_attribute( $code );
2155
2156 Return the attribute for the code passed in parameter.
2157
2158 It not exist it returns undef
2159
2160 Note that this will not work for repeatable attribute types.
2161
2162 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
2163 (which should be a real patron's attribute (not extended)
2164
2165 =cut
2166
2167 sub get_extended_attribute {
2168     my ( $self, $code, $value ) = @_;
2169     my $rs = $self->_result->borrower_attributes;
2170     return unless $rs;
2171     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
2172     return unless $attribute->count;
2173     return $attribute->next;
2174 }
2175
2176 =head3 set_default_messaging_preferences
2177
2178     $patron->set_default_messaging_preferences
2179
2180 Sets default messaging preferences on patron.
2181
2182 See Koha::Patron::MessagePreference(s) for more documentation, especially on
2183 thrown exceptions.
2184
2185 =cut
2186
2187 sub set_default_messaging_preferences {
2188     my ($self, $categorycode) = @_;
2189
2190     my $options = Koha::Patron::MessagePreferences->get_options;
2191
2192     foreach my $option (@$options) {
2193         # Check that this option has preference configuration for this category
2194         unless (Koha::Patron::MessagePreferences->search({
2195             message_attribute_id => $option->{message_attribute_id},
2196             categorycode         => $categorycode || $self->categorycode,
2197         })->count) {
2198             next;
2199         }
2200
2201         # Delete current setting
2202         Koha::Patron::MessagePreferences->search({
2203              borrowernumber => $self->borrowernumber,
2204              message_attribute_id => $option->{message_attribute_id},
2205         })->delete;
2206
2207         Koha::Patron::MessagePreference->new_from_default({
2208             borrowernumber => $self->borrowernumber,
2209             categorycode   => $categorycode || $self->categorycode,
2210             message_attribute_id => $option->{message_attribute_id},
2211         });
2212     }
2213
2214     return $self;
2215 }
2216
2217 =head3 to_api
2218
2219     my $json = $patron->to_api;
2220
2221 Overloaded method that returns a JSON representation of the Koha::Patron object,
2222 suitable for API output.
2223
2224 =cut
2225
2226 sub to_api {
2227     my ( $self, $params ) = @_;
2228
2229     my $json_patron = $self->SUPER::to_api( $params );
2230
2231     $json_patron->{restricted} = ( $self->is_debarred )
2232                                     ? Mojo::JSON->true
2233                                     : Mojo::JSON->false;
2234
2235     return $json_patron;
2236 }
2237
2238 =head3 to_api_mapping
2239
2240 This method returns the mapping for representing a Koha::Patron object
2241 on the API.
2242
2243 =cut
2244
2245 sub to_api_mapping {
2246     return {
2247         borrowernotes       => 'staff_notes',
2248         borrowernumber      => 'patron_id',
2249         branchcode          => 'library_id',
2250         categorycode        => 'category_id',
2251         checkprevcheckout   => 'check_previous_checkout',
2252         contactfirstname    => undef,                     # Unused
2253         contactname         => undef,                     # Unused
2254         contactnote         => 'altaddress_notes',
2255         contacttitle        => undef,                     # Unused
2256         dateenrolled        => 'date_enrolled',
2257         dateexpiry          => 'expiry_date',
2258         dateofbirth         => 'date_of_birth',
2259         debarred            => undef,                     # replaced by 'restricted'
2260         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
2261         emailpro            => 'secondary_email',
2262         flags               => undef,    # permissions manipulation handled in /permissions
2263         gonenoaddress       => 'incorrect_address',
2264         lastseen            => 'last_seen',
2265         lost                => 'patron_card_lost',
2266         opacnote            => 'opac_notes',
2267         othernames          => 'other_name',
2268         password            => undef,            # password manipulation handled in /password
2269         phonepro            => 'secondary_phone',
2270         relationship        => 'relationship_type',
2271         sex                 => 'gender',
2272         smsalertnumber      => 'sms_number',
2273         sort1               => 'statistics_1',
2274         sort2               => 'statistics_2',
2275         autorenew_checkouts => 'autorenew_checkouts',
2276         streetnumber        => 'street_number',
2277         streettype          => 'street_type',
2278         zipcode             => 'postal_code',
2279         B_address           => 'altaddress_address',
2280         B_address2          => 'altaddress_address2',
2281         B_city              => 'altaddress_city',
2282         B_country           => 'altaddress_country',
2283         B_email             => 'altaddress_email',
2284         B_phone             => 'altaddress_phone',
2285         B_state             => 'altaddress_state',
2286         B_streetnumber      => 'altaddress_street_number',
2287         B_streettype        => 'altaddress_street_type',
2288         B_zipcode           => 'altaddress_postal_code',
2289         altcontactaddress1  => 'altcontact_address',
2290         altcontactaddress2  => 'altcontact_address2',
2291         altcontactaddress3  => 'altcontact_city',
2292         altcontactcountry   => 'altcontact_country',
2293         altcontactfirstname => 'altcontact_firstname',
2294         altcontactphone     => 'altcontact_phone',
2295         altcontactsurname   => 'altcontact_surname',
2296         altcontactstate     => 'altcontact_state',
2297         altcontactzipcode   => 'altcontact_postal_code',
2298         password_expiration_date => undef,
2299         primary_contact_method => undef,
2300         secret              => undef,
2301         auth_method         => undef,
2302     };
2303 }
2304
2305 =head3 queue_notice
2306
2307     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
2308     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
2309     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
2310
2311     Queue messages to a patron. Can pass a message that is part of the message_attributes
2312     table or supply the transport to use.
2313
2314     If passed a message name we retrieve the patrons preferences for transports
2315     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
2316     we have no address/number for sending
2317
2318     $letter_params is a hashref of the values to be passed to GetPreparedLetter
2319
2320     test_mode will only report which notices would be sent, but nothing will be queued
2321
2322 =cut
2323
2324 sub queue_notice {
2325     my ( $self, $params ) = @_;
2326     my $letter_params = $params->{letter_params};
2327     my $test_mode = $params->{test_mode};
2328
2329     return unless $letter_params;
2330     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
2331
2332     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
2333     my $from_email_address = $library->from_email_address;
2334
2335     my @message_transports;
2336     my $letter_code;
2337     $letter_code = $letter_params->{letter_code};
2338     if( $params->{message_name} ){
2339         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
2340                 borrowernumber => $letter_params->{borrowernumber},
2341                 message_name => $params->{message_name}
2342         } );
2343         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2344         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2345     } else {
2346         @message_transports = @{$params->{message_transports}};
2347     }
2348     return unless defined $letter_code;
2349     $letter_params->{letter_code} = $letter_code;
2350     my $print_sent = 0;
2351     my %return;
2352     foreach my $mtt (@message_transports){
2353         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2354         # Notice is handled by TalkingTech_itiva_outbound.pl
2355         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2356             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2357             or ( $mtt eq 'phone' and not $self->phone ) )
2358         {
2359             push @{ $return{fallback} }, $mtt;
2360             $mtt = 'print';
2361         }
2362         next if $mtt eq 'print' && $print_sent;
2363         $letter_params->{message_transport_type} = $mtt;
2364         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2365         C4::Letters::EnqueueLetter({
2366             letter => $letter,
2367             borrowernumber => $self->borrowernumber,
2368             from_address   => $from_email_address,
2369             message_transport_type => $mtt
2370         }) unless $test_mode;
2371         push @{$return{sent}}, $mtt;
2372         $print_sent = 1 if $mtt eq 'print';
2373     }
2374     return \%return;
2375 }
2376
2377 =head3 safe_to_delete
2378
2379     my $result = $patron->safe_to_delete;
2380     if ( $result eq 'has_guarantees' ) { ... }
2381     elsif ( $result ) { ... }
2382     else { # cannot delete }
2383
2384 This method tells if the Koha:Patron object can be deleted. Possible return values
2385
2386 =over 4
2387
2388 =item 'ok'
2389
2390 =item 'has_checkouts'
2391
2392 =item 'has_debt'
2393
2394 =item 'has_guarantees'
2395
2396 =item 'is_anonymous_patron'
2397
2398 =back
2399
2400 =cut
2401
2402 sub safe_to_delete {
2403     my ($self) = @_;
2404
2405     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2406
2407     my $error;
2408
2409     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2410         $error = 'is_anonymous_patron';
2411     }
2412     elsif ( $self->checkouts->count ) {
2413         $error = 'has_checkouts';
2414     }
2415     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2416         $error = 'has_debt';
2417     }
2418     elsif ( $self->guarantee_relationships->count ) {
2419         $error = 'has_guarantees';
2420     }
2421
2422     if ( $error ) {
2423         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2424     }
2425
2426     return Koha::Result::Boolean->new(1);
2427 }
2428
2429 =head3 recalls
2430
2431     my $recalls = $patron->recalls;
2432
2433 Return the patron's recalls.
2434
2435 =cut
2436
2437 sub recalls {
2438     my ( $self ) = @_;
2439
2440     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2441 }
2442
2443 =head3 account_balance
2444
2445     my $balance = $patron->account_balance
2446
2447 Return the patron's account balance
2448
2449 =cut
2450
2451 sub account_balance {
2452     my ($self) = @_;
2453     return $self->account->balance;
2454 }
2455
2456 =head3 notify_library_of_registration
2457
2458 $patron->notify_library_of_registration( $email_patron_registrations );
2459
2460 Send patron registration email to library if EmailPatronRegistrations system preference is enabled.
2461
2462 =cut
2463
2464 sub notify_library_of_registration {
2465     my ( $self, $email_patron_registrations ) = @_;
2466
2467     if (
2468         my $letter = C4::Letters::GetPreparedLetter(
2469             module      => 'members',
2470             letter_code => 'OPAC_REG',
2471             branchcode  => $self->branchcode,
2472             lang        => $self->lang || 'default',
2473             tables      => {
2474                 'borrowers' => $self->borrowernumber
2475             },
2476         )
2477     ) {
2478         my $to_address;
2479         if ( $email_patron_registrations eq "BranchEmailAddress" ) {
2480             my $library = Koha::Libraries->find( $self->branchcode );
2481             $to_address = $library->inbound_email_address;
2482         }
2483         elsif ( $email_patron_registrations eq "KohaAdminEmailAddress" ) {
2484             $to_address = C4::Context->preference('ReplytoDefault')
2485             || C4::Context->preference('KohaAdminEmailAddress');
2486         }
2487         else {
2488             $to_address =
2489                 C4::Context->preference('EmailAddressForPatronRegistrations')
2490                 || C4::Context->preference('ReplytoDefault')
2491                 || C4::Context->preference('KohaAdminEmailAddress');
2492         }
2493
2494         my $message_id = C4::Letters::EnqueueLetter(
2495             {
2496                 letter                 => $letter,
2497                 borrowernumber         => $self->borrowernumber,
2498                 to_address             => $to_address,
2499                 message_transport_type => 'email'
2500             }
2501         ) or warn "can't enqueue letter $letter";
2502         if ( $message_id ) {
2503             return 1;
2504         }
2505     }
2506 }
2507
2508 =head3 has_messaging_preference
2509
2510 my $bool = $patron->has_messaging_preference({
2511     message_name => $message_name, # A value from message_attributes.message_name
2512     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2513     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2514 });
2515
2516 =cut
2517
2518 sub has_messaging_preference {
2519     my ( $self, $params ) = @_;
2520
2521     my $message_name           = $params->{message_name};
2522     my $message_transport_type = $params->{message_transport_type};
2523     my $wants_digest           = $params->{wants_digest};
2524
2525     return $self->_result->search_related_rs(
2526         'borrower_message_preferences',
2527         $params,
2528         {
2529             prefetch =>
2530               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2531         }
2532     )->count;
2533 }
2534
2535 =head3 can_patron_change_staff_only_lists
2536
2537 $patron->can_patron_change_staff_only_lists;
2538
2539 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2540 Otherwise, return 0.
2541
2542 =cut
2543
2544 sub can_patron_change_staff_only_lists {
2545     my ( $self, $params ) = @_;
2546     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2547     return 0;
2548 }
2549
2550 =head3 can_patron_change_permitted_staff_lists
2551
2552 $patron->can_patron_change_permitted_staff_lists;
2553
2554 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' and 'edit_public_list_contents' permissions.
2555 Otherwise, return 0.
2556
2557 =cut
2558
2559 sub can_patron_change_permitted_staff_lists {
2560     my ( $self, $params ) = @_;
2561     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1, lists => 'edit_public_list_contents' } );
2562     return 0;
2563 }
2564
2565 =head3 encode_secret
2566
2567   $patron->encode_secret($secret32);
2568
2569 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2570 You still need to call ->store.
2571
2572 =cut
2573
2574 sub encode_secret {
2575     my ( $self, $secret ) = @_;
2576     if( $secret ) {
2577         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2578     }
2579     return $self->secret($secret);
2580 }
2581
2582 =head3 decoded_secret
2583
2584   my $secret32 = $patron->decoded_secret;
2585
2586 Decode the patron secret. We expect to get back a base32 string, but this
2587 is not checked here. Caller of encode_secret is responsible for that.
2588
2589 =cut
2590
2591 sub decoded_secret {
2592     my ( $self ) = @_;
2593     if( $self->secret ) {
2594         return Koha::Encryption->new->decrypt_hex( $self->secret );
2595     }
2596     return $self->secret;
2597 }
2598
2599 =head3 virtualshelves
2600
2601     my $shelves = $patron->virtualshelves;
2602
2603 =cut
2604
2605 sub virtualshelves {
2606     my $self = shift;
2607     return Koha::Virtualshelves->_new_from_dbic( scalar $self->_result->virtualshelves );
2608 }
2609
2610 =head3 get_savings
2611
2612     my $savings = $patron->get_savings;
2613
2614 Use the replacement price of patron's old and current issues to calculate how much they have 'saved' by using the library.
2615
2616 =cut
2617
2618 sub get_savings {
2619     my ($self) = @_;
2620
2621     my @itemnumbers = grep { defined $_ } ( $self->old_checkouts->get_column('itemnumber'), $self->checkouts->get_column('itemnumber') );
2622
2623     return Koha::Items->search(
2624         { itemnumber => { -in => \@itemnumbers } },
2625         {   select => [ { sum => 'me.replacementprice' } ],
2626             as     => ['total_savings']
2627         }
2628     )->next->get_column('total_savings') // 0;
2629 }
2630
2631 =head2 Internal methods
2632
2633 =head3 _type
2634
2635 =cut
2636
2637 sub _type {
2638     return 'Borrower';
2639 }
2640
2641 =head1 AUTHORS
2642
2643 Kyle M Hall <kyle@bywatersolutions.com>
2644 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2645 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2646
2647 =cut
2648
2649 1;