C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp qw( croak );
  22
  23 use C4::Context;
  24 use C4::Members::Messaging;
  25 use C4::Auth qw( checkpw_internal );
  26 use C4::Letters qw( GetPreparedLetter EnqueueLetter );
  27 use Koha::Patrons;
  28 use Koha::AuthUtils qw( hash_password );
  29 use Net::LDAP;
  30 use Net::LDAP::Filter;
  31
  32 our (@ISA, @EXPORT_OK);
  33 BEGIN {
  34         require Exporter;
  35         @ISA    = qw(Exporter);
  36         @EXPORT_OK = qw( checkpw_ldap );
  37 }
  38
  39 # Redefine checkpw_ldap:
  40 # connect to LDAP (named or anonymous)
  41 # ~ retrieves $userid from KOHA_CONF mapping
  42 # ~ then compares $password with userPassword
  43 # ~ then gets the LDAP entry
  44 # ~ and calls the memberadd if necessary
  45
  46 sub ldapserver_error {
  47         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  48 }
  49
  50 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  51 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  52 # since Bug 28278 we need to skip id in <ldapserver id="ldapserver"> which generates additional hash level
  53 if ( exists $ldap->{ldapserver} ) {
  54     $ldap = $ldap->{ldapserver}         or die ldapserver_error('id="ldapserver"');
  55 }
  56 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  57 my $base      = $ldap->{base}           or die ldapserver_error('base');
  58 $ldapname     = $ldap->{user}           ;
  59 $ldappassword = $ldap->{pass}           ;
  60 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  61 my @mapkeys = keys %mapping;
  62 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  63 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  64 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  65
  66 my %categorycode_conversions;
  67 my $default_categorycode;
  68 if(defined $ldap->{categorycode_mapping}) {
  69     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  70     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  71         $categorycode_conversions{$cat->{value}} = $cat->{content};
  72     }
  73 }
  74
  75 my %config = (
  76     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  77     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  78     welcome   => defined($ldap->{welcome}) ? $ldap->{welcome} : 0,  #    send welcome notice when patron is added via replicate
  79     update    => defined($ldap->{update}) ? $ldap->{update} : 1,  # update from LDAP to Koha database for existing user
  80 );
  81
  82 sub description {
  83         my $result = shift or return;
  84         return "LDAP error #" . $result->code
  85                         . ": " . $result->error_name . "\n"
  86                         . "# " . $result->error_text . "\n";
  87 }
  88
  89 sub search_method {
  90     my $db     = shift or return;
  91     my $userid = shift or return;
  92         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  93         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  94         my $search = $db->search(
  95                   base => $base,
  96                 filter => $filter,
  97                 # attrs => ['*'],
  98     );
  99     die "LDAP search failed to return object : " . $search->error if $search->code;
 100
 101         my $count = $search->count;
 102         if ($search->code > 0) {
 103                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 104                 return 0;
 105         }
 106     if ($count == 0) {
 107         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 108         return 0;
 109     }
 110     return $search;
 111 }
 112
 113 sub checkpw_ldap {
 114     my ($userid, $password) = @_;
 115     my @hosts = split(',', $prefhost);
 116     my $db = Net::LDAP->new(\@hosts);
 117     unless ( $db ) {
 118         warn "LDAP connexion failed";
 119         return 0;
 120     }
 121
 122     my $userldapentry;
 123
 124     # first, LDAP authentication
 125     if ( $ldap->{auth_by_bind} ) {
 126         my $principal_name;
 127         if ( $config{anonymous} ) {
 128
 129             # Perform an anonymous bind
 130             my $res = $db->bind;
 131             if ( $res->code ) {
 132                 warn "Anonymous LDAP bind failed: " . description($res);
 133                 return 0;
 134             }
 135
 136             # Perform a LDAP search for the given username
 137             my $search = search_method( $db, $userid )
 138               or return 0;    # warnings are in the sub
 139             $userldapentry = $search->shift_entry;
 140             $principal_name = $userldapentry->dn;
 141         }
 142         else {
 143             $principal_name = $ldap->{principal_name};
 144             if ( $principal_name and $principal_name =~ /\%/ ) {
 145                 $principal_name = sprintf( $principal_name, $userid );
 146             }
 147             else {
 148                 $principal_name = $userid;
 149             }
 150         }
 151
 152         # Perform a LDAP bind for the given username using the matched DN
 153         my $res = $db->bind( $principal_name, password => $password );
 154         if ( $res->code ) {
 155             if ( $config{anonymous} ) {
 156                 # With anonymous_bind approach we can be sure we have found the correct user
 157                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 158                 # or password changed). We should not fall back to local accounts in this case.
 159                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 160                 return -1;
 161             } else {
 162                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 163                 # at all, and thus we should fall back to local logins to restore previous behaviour
 164                 # see bug 12831
 165                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 166                 return 0;
 167             }
 168         }
 169         if ( !defined($userldapentry)
 170             && ( $config{update} or $config{replicate} ) )
 171         {
 172             my $search = search_method( $db, $userid ) or return 0;
 173             $userldapentry = $search->shift_entry;
 174         }
 175     } else {
 176         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 177                 if ($res->code) {               # connection refused
 178                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 179                         return 0;
 180                 }
 181         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 182         # Handle multiple branches. Same login exists several times in different branches.
 183         my $bind_ok = 0;
 184         while (my $entry = $search->shift_entry) {
 185             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 186             unless ($user_ldap_bind_ret->code) {
 187                 $userldapentry = $entry;
 188                 $bind_ok = 1;
 189                 last;
 190             }
 191         }
 192
 193         unless ($bind_ok) {
 194             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 195             return -1;
 196         }
 197
 198
 199     }
 200
 201     # To get here, LDAP has accepted our user's login attempt.
 202     # But we still have work to do.  See perldoc below for detailed breakdown.
 203
 204     my (%borrower);
 205         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 206
 207     if (( $borrowernumber and $config{update}   ) or
 208         (!$borrowernumber and $config{replicate})   ) {
 209         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 210         #warn "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 211     }
 212
 213     if ($borrowernumber) {
 214         if ($config{update}) { # A1, B1
 215             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 216             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 217         } else { # C1, D1
 218             # maybe update just the password?
 219                 return(1, $cardnumber, $local_userid);
 220         }
 221     } elsif ($config{replicate}) { # A2, C2
 222         my @columns = Koha::Patrons->columns;
 223         my $patron = Koha::Patron->new(
 224             {
 225                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 226             }
 227         )->store;
 228         die "Insert of new patron failed" unless $patron;
 229         $borrowernumber = $patron->borrowernumber;
 230         C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 231             {
 232                 borrowernumber => $borrowernumber,
 233                 categorycode   => $borrower{'categorycode'}
 234             }
 235         );
 236
 237         # Send welcome email if enabled
 238         if ( $config{welcome} ) {
 239             my $emailaddr = $patron->notice_email_address;
 240
 241             # if we manage to find a valid email address, send notice
 242             if ($emailaddr) {
 243                 my $letter = C4::Letters::GetPreparedLetter(
 244                     module      => 'members',
 245                     letter_code => 'WELCOME',
 246                     branchcode  => $patron->branchcode,
 247                     lang        => $patron->lang || 'default',
 248                     tables      => {
 249                         'branches'  => $patron->branchcode,
 250                         'borrowers' => $patron->borrowernumber,
 251                     },
 252                     want_librarian => 1,
 253                 ) or return;
 254
 255                 my $message_id = C4::Letters::EnqueueLetter(
 256                     {
 257                         letter                 => $letter,
 258                         borrowernumber         => $patron->id,
 259                         to_address             => $emailaddr,
 260                         message_transport_type => 'email'
 261                     }
 262                 );
 263             }
 264         }
 265    } else {
 266         return 0;   # B2, D2
 267     }
 268     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 269         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 270         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 271         while ( my $attribute_type = $attribute_types->next ) {
 272             my $code = $attribute_type->code;
 273             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 274                 next;
 275             }
 276             my $patron = Koha::Patrons->find($borrowernumber);
 277             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 278                 eval {
 279                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 280                     $patron->extended_attributes([$attribute->unblessed]);
 281                 };
 282                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 283                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 284                 }
 285             }
 286         }
 287     }
 288     return(1, $cardnumber, $userid);
 289 }
 290
 291 # Pass LDAP entry object and local cardnumber (userid).
 292 # Returns borrower hash.
 293 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 294 # Ensure that mandatory fields are correctly filled!
 295 #
 296 sub ldap_entry_2_hash {
 297         my $userldapentry = shift;
 298         my %borrower = ( cardnumber => shift );
 299         my %memberhash;
 300         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 301     #foreach (keys %$userldapentry) {
 302     #    print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 303     #}
 304         my $x = $userldapentry->{attrs} or return;
 305         foreach (keys %$x) {
 306                 $memberhash{$_} = join ' ', @{$x->{$_}};
 307         #warn sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 308         }
 309     #warn "Finished \%memberhash has ", scalar(keys %memberhash), " keys\n", "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 310         foreach my $key (keys %mapping) {
 311                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 312         #warn "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 313                 unless (defined $data) {
 314             $data = $mapping{$key}->{content} || undef;
 315                 }
 316         $borrower{$key} = $data;
 317         }
 318         $borrower{initials} = $memberhash{initials} ||
 319                 ( substr($borrower{'firstname'},0,1)
 320                 . substr($borrower{ 'surname' },0,1)
 321                 . " ");
 322
 323     # categorycode conversions
 324     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 325         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 326     }
 327     elsif($default_categorycode) {
 328         $borrower{categorycode} = $default_categorycode;
 329     }
 330
 331         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 332         my $dbh = C4::Context->dbh;
 333         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 334         $sth->execute( uc($borrower{'categorycode'}) );
 335         unless ( my $row = $sth->fetchrow_hashref ) {
 336                 my $default = $mapping{'categorycode'}->{content};
 337         #warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 338                 $borrower{'categorycode'} = $default
 339         }
 340
 341         return %borrower;
 342 }
 343
 344 sub exists_local {
 345         my $arg = shift;
 346         my $dbh = C4::Context->dbh;
 347         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 348
 349         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 350         $sth->execute($arg);
 351     #warn "Userid '$arg' exists_local? %s\n", $sth->rows;
 352         ($sth->rows == 1) and return $sth->fetchrow;
 353
 354         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 355         $sth->execute($arg);
 356     #warn "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 357         ($sth->rows == 1) and return $sth->fetchrow;
 358         return 0;
 359 }
 360
 361 # This function performs a password update, given the userid, borrowerid,
 362 # and digested password. It will verify that things are correct and return the
 363 # borrowers cardnumber. The idea is that it is used to keep the local
 364 # passwords in sync with the LDAP passwords.
 365 #
 366 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 367 #
 368 # Note: if the LDAP config has the update_password tag set to a false value,
 369 # then this will not update the password, it will simply return the cardnumber.
 370 sub _do_changepassword {
 371     my ($userid, $borrowerid, $password) = @_;
 372
 373     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 374
 375         # We don't store the password in the database
 376         my $sth = C4::Context->dbh->prepare(
 377             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 378         $sth->execute($borrowerid);
 379         die "Unable to access borrowernumber "
 380             . "with userid=$userid, "
 381             . "borrowernumber=$borrowerid"
 382           if !$sth->rows;
 383         my ($cardnum) = $sth->fetchrow;
 384         $sth = C4::Context->dbh->prepare(
 385             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 386         $sth->execute($borrowerid);
 387         return $cardnum;
 388     }
 389
 390     my $digest = hash_password($password);
 391     #warn "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 392     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 393
 394     my ($ok, $cardnum) = checkpw_internal($userid, $password);
 395     return $cardnum if $ok;
 396
 397     warn "Password mismatch after update to borrowernumber=$borrowerid";
 398     return;
 399 }
 400
 401 sub update_local {
 402     my $userid     = shift or croak "No userid";
 403     my $password   = shift or croak "No password";
 404     my $borrowerid = shift or croak "No borrowerid";
 405     my $borrower   = shift or croak "No borrower record";
 406
 407     # skip extended patron attributes in 'borrowers' attribute update
 408     my @keys = keys %$borrower;
 409     if (C4::Context->preference('ExtendedPatronAttributes')) {
 410         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 411         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 412         while ( my $attribute_type = $attribute_types->next ) {
 413            my $code = $attribute_type->code;
 414            @keys = grep { $_ ne $code } @keys;
 415            #warn "ignoring extended patron attribute '%s' in update_local()\n", $code;
 416         }
 417     }
 418
 419     my $dbh = C4::Context->dbh;
 420     my $query = "UPDATE  borrowers\nSET     " .
 421         join(',', map {"$_=?"} @keys) .
 422         "\nWHERE   borrowernumber=? ";
 423     my $sth = $dbh->prepare($query);
 424     #warn $query, "\n", join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 425     #warn "\nuserid = $userid\n";
 426     $sth->execute(
 427         ((map {$borrower->{$_}} @keys), $borrowerid)
 428     );
 429
 430     # MODIFY PASSWORD/LOGIN if password was mapped
 431     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 432 }
 433
 434 1;
 435 __END__
 436
 437 =head1 NAME
 438
 439 C4::Auth - Authenticates Koha users
 440
 441 =head1 SYNOPSIS
 442
 443   use C4::Auth_with_ldap;
 444
 445 =head1 LDAP Configuration
 446
 447     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 448         working LDAP servers.
 449         To use it :
 450            * Modify ldapserver element in KOHA_CONF
 451            * Establish field mapping in <mapping> element.
 452
 453         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 454         the username would match the "uid" field, and the password should match the "userpassword" field.
 455
 456         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 457         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 458
 459         mysql> show COLUMNS from borrowers;
 460                 +---------------------+--------------+------+-----+---------+----------------+
 461                 | Field               | Type         | Null | Key | Default | Extra          |
 462                 +---------------------+--------------+------+-----+---------+----------------+
 463                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 464                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 465                 | surname             | mediumtext   | NO   |     | NULL    |                |
 466                 | firstname           | text         | YES  |     | NULL    |                |
 467                 | title               | mediumtext   | YES  |     | NULL    |                |
 468                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 469                 | initials            | text         | YES  |     | NULL    |                |
 470                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 471                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 472                 | address             | mediumtext   | NO   |     | NULL    |                |
 473                 | address2            | text         | YES  |     | NULL    |                |
 474                 | city                | mediumtext   | NO   |     | NULL    |                |
 475                 | state               | mediumtext   | YES  |     | NULL    |                |
 476                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 477                 | country             | text         | YES  |     | NULL    |                |
 478                 | email               | mediumtext   | YES  |     | NULL    |                |
 479                 | phone               | text         | YES  |     | NULL    |                |
 480                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 481                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 482                 | emailpro            | text         | YES  |     | NULL    |                |
 483                 | phonepro            | text         | YES  |     | NULL    |                |
 484                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 485                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 486                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 487                 | B_address2          | text         | YES  |     | NULL    |                |
 488                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 489                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 490                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 491                 | B_country           | text         | YES  |     | NULL    |                |
 492                 | B_email             | text         | YES  |     | NULL    |                |
 493                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 494                 | dateofbirth         | date         | YES  |     | NULL    |                |
 495                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 496                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 497                 | dateenrolled        | date         | YES  |     | NULL    |                |
 498                 | dateexpiry          | date         | YES  |     | NULL    |                |
 499                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 500                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 501                 | debarred            | date         | YES  |     | NULL    |                |
 502                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 503                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 504                 | contactfirstname    | text         | YES  |     | NULL    |                |
 505                 | contacttitle        | text         | YES  |     | NULL    |                |
 506                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 507                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 508                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 509                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 510                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 511                 | password            | varchar(30)  | YES  |     | NULL    |                |
 512                 | flags               | int(11)      | YES  |     | NULL    |                |
 513                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 514                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 515                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 516                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 517                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 518                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 519                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 520                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 521                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 522                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 523                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 524                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 525                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 526                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 527                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 528                 | privacy             | int(11)      | NO   |     | 1       |                |
 529                 +---------------------+--------------+------+-----+---------+----------------+
 530                 66 rows in set (0.00 sec)
 531                 Where Null="NO", the field is required.
 532
 533 =head1 KOHA_CONF and field mapping
 534
 535 Example XML stanza for LDAP configuration in KOHA_CONF.
 536
 537  <config>
 538   ...
 539   <useldapserver>1</useldapserver>
 540   <!-- LDAP SERVER (optional) -->
 541   <ldapserver id="ldapserver">
 542     <hostname>localhost</hostname>
 543     <base>dc=metavore,dc=com</base>
 544     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 545     <pass>metavore</pass>          <!-- password, if not anonymous -->
 546     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 547     <welcome>1</welcome>           <!-- send new users the welcome email when added via replicate -->
 548     <update>1</update>             <!-- update existing users in Koha database -->
 549     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 550                                         password comparison, e.g., to use Active Directory -->
 551     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 552                                             an anonymous bind, even when auth_by_bind is on -->
 553     <principal_name>%s@my_domain.com</principal_name>
 554                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 555                                         Not used with anonymous_bind. -->
 556     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 557                                               synced to the local database -->
 558     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 559       <firstname    is="givenname"      ></firstname>
 560       <surname      is="sn"             ></surname>
 561       <address      is="postaladdress"  ></address>
 562       <city         is="l"              >Athens, OH</city>
 563       <zipcode      is="postalcode"     ></zipcode>
 564       <branchcode   is="branch"         >MAIN</branchcode>
 565       <userid       is="uid"            ></userid>
 566       <password     is="userpassword"   ></password>
 567       <email        is="mail"           ></email>
 568       <categorycode is="employeetype"   >PT</categorycode>
 569       <phone        is="telephonenumber"></phone>
 570     </mapping>
 571   </ldapserver>
 572  </config>
 573
 574 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 575 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 576 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 577 patron).
 578
 579 =head1 CONFIGURATION
 580
 581 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 582 your configuration and the presence of a matching Koha user in your local DB:
 583
 584                          LOCAL_USER
 585  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 586    A1      1       1        1      OK : We're updating them anyway.
 587    A2      1       1        0      OK : We're adding them anyway.
 588    B1      1       0        1      OK : We update them.
 589    B2      1       0        0     FAIL: We cannot add new user.
 590    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 591    C2      0       1        0      OK : We add the new user.
 592    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 593    D2      0       0        0     FAIL: We cannot add new user.
 594
 595 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 596 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 597 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 598
 599 If you choose NOT to update local users, the borrowers table will not be affected at all.
 600 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 601 the local table never contained the LDAP values.
 602
 603 =head2 auth_by_bind
 604
 605 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 606
 607 =head2 principal_name
 608
 609 Provides an optional sprintf-style format for manipulating the userid before the bind.
 610 Even though the userPrincipalName is one intended target, any uniquely identifying
 611 attribute that the server allows to be used for binding could be used.
 612
 613 Currently, principal_name only operates when auth_by_bind is enabled.
 614
 615 =head2 update_password
 616
 617 If this tag is left out or set to a true value, then the user's LDAP password
 618 will be stored (hashed) in the local Koha database. If you don't want this
 619 to happen, then set the value of this to '0'. Note that if passwords are not
 620 stored locally, and the connection to the LDAP system fails, then the users
 621 will not be able to log in at all.
 622
 623 =head2 Active Directory
 624
 625 The auth_by_bind and principal_name settings are recommended for Active Directory.
 626
 627 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 628 we would typically under openldap.  Instead of:
 629
 630     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 631
 632 We might get:
 633
 634     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 635
 636 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 637 in Koha userids.  But the userPrincipalName should be consistent, something like:
 638
 639     userPrincipalName: barnes.7@my_company.com
 640
 641 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 642 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 643 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 644 like this:
 645     <principal_name>%s@core.my_company.com</principal_name>
 646
 647 The user of the previous example, barnes.7, would then attempt to bind as:
 648     barnes.7@core.my_company.com
 649
 650 =head1 SEE ALSO
 651
 652 CGI(3)
 653
 654 Net::LDAP()
 655
 656 XML::Simple()
 657
 658 Digest::MD5(3)
 659
 660 sprintf()
 661
 662 =cut
 663
 664 # For reference, here's an important difference in the data structure we rely on.
 665 # ========================================
 666 # Using attrs instead of {asn}->attributes
 667 # ========================================
 668 #
 669 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 670 #       LDAP key: ->{             cn}->{           sss} = sss
 671 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 672 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 673 #
 674 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 675 #       LDAP key: ->{      givenname}->{Steve} = Steve
 676 #