C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use Koha::Cache::Memory::Lite;
  30 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  31
  32 BEGIN {
  33     require Exporter;
  34     @ISA    = qw(Exporter);
  35     @EXPORT = qw(
  36         &getFrameworkLanguages
  37         &getTranslatedLanguages
  38         &getLanguages
  39         &getAllLanguages
  40     );
  41     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage);
  42     $DEBUG = 0;
  43 }
  44
  45 =head1 NAME
  46
  47 C4::Languages - Perl Module containing language list functions for Koha
  48
  49 =head1 SYNOPSIS
  50
  51 use C4::Languages;
  52
  53 =head1 DESCRIPTION
  54
  55 =cut
  56
  57 =head1 FUNCTIONS
  58
  59 =head2 getFrameworkLanguages
  60
  61 Returns a reference to an array of hashes:
  62
  63  my $languages = getFrameworkLanguages();
  64  for my $language(@$languages) {
  65     print "$language->{language_code}\n"; # language code in iso 639-2
  66     print "$language->{language_name}\n"; # language name in native script
  67     print "$language->{language_locale_name}\n"; # language name in current locale
  68  }
  69
  70 =cut
  71
  72 sub getFrameworkLanguages {
  73     # get a hash with all language codes, names, and locale names
  74     my $all_languages = getAllLanguages();
  75     my @languages;
  76
  77     # find the available directory names
  78     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  79     opendir (MYDIR,$dir);
  80     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  81     closedir MYDIR;
  82
  83     # pull out all data for the dir names that exist
  84     for my $dirname (@listdir) {
  85         for my $language_set (@$all_languages) {
  86
  87             if ($dirname eq $language_set->{language_code}) {
  88                 push @languages, {
  89                     'language_code'=>$dirname,
  90                     'language_description'=>$language_set->{language_description},
  91                     'native_descrition'=>$language_set->{language_native_description} }
  92             }
  93         }
  94     }
  95     return \@languages;
  96 }
  97
  98 =head2 getTranslatedLanguages
  99
 100 Returns a reference to an array of hashes:
 101
 102  my $languages = getTranslatedLanguages();
 103  print "Available translated languages:\n";
 104  for my $language(@$trlanguages) {
 105     print "$language->{language_code}\n"; # language code in iso 639-2
 106     print "$language->{language_name}\n"; # language name in native script
 107     print "$language->{language_locale_name}\n"; # language name in current locale
 108  }
 109
 110 =cut
 111
 112 sub getTranslatedLanguages {
 113     my ($interface, $theme, $current_language, $which) = @_;
 114     my @languages;
 115     my @enabled_languages =
 116       ( $interface && $interface eq 'intranet' )
 117       ? split ",", C4::Context->preference('language')
 118       : split ",", C4::Context->preference('opaclanguages');
 119
 120     if ($interface && $interface eq 'opac' ) {
 121         my $htdocs = C4::Context->config('opachtdocs');
 122         @languages = _get_opac_language_dirs( $htdocs, $theme );
 123     }
 124     elsif ($interface && $interface eq 'intranet' ) {
 125         my $htdocs = C4::Context->config('intrahtdocs');
 126         @languages = _get_intranet_language_dirs( $htdocs, $theme );
 127     }
 128     else {
 129         my $htdocs = C4::Context->config('intrahtdocs');
 130         push @languages, _get_intranet_language_dirs( $htdocs );
 131
 132         $htdocs = C4::Context->config('opachtdocs');
 133         push @languages, _get_opac_language_dirs( $htdocs );
 134
 135         my %seen;
 136         $seen{$_}++ for @languages;
 137         @languages = keys %seen;
 138     }
 139     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 140 }
 141
 142 =head2 getAllLanguages
 143
 144 Returns a reference to an array of hashes:
 145
 146  my $alllanguages = getAllLanguages();
 147  print "Available translated languages:\n";
 148  for my $language(@$alllanguages) {
 149     print "$language->{language_code}\n";
 150     print "$language->{language_name}\n";
 151     print "$language->{language_locale_name}\n";
 152  }
 153
 154 This routine is a wrapper for getLanguages().
 155
 156 =cut
 157
 158 sub getAllLanguages {
 159     return getLanguages(shift);
 160 }
 161
 162 =head2 getLanguages
 163
 164     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 165
 166 Returns a reference to an array of hashes of languages.
 167
 168 - If no parameter is passed to the function, it returns english languages names
 169 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 170   If a language name is not translated in $lang in database, the function returns english language name
 171 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 172
 173 =cut
 174
 175 sub getLanguages {
 176     my $lang = shift;
 177     my $isFiltered = shift;
 178
 179     my @languages_loop;
 180     my $dbh=C4::Context->dbh;
 181     my $default_language = 'en';
 182     my $current_language = $default_language;
 183     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 184     if ($lang) {
 185         $current_language = regex_lang_subtags($lang)->{'language'};
 186     }
 187     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 188     $sth->execute();
 189     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 190         my $desc;
 191         # check if language name is stored in current language
 192         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 193         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 194         while (my $language_desc = $sth4->fetchrow_hashref) {
 195              $desc=$language_desc->{description};
 196         }
 197         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 198         if ($desc) {
 199             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 200         }
 201         else {
 202             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 203         }
 204         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 205         # add the correct description info
 206         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 207             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 208             my $native_description;
 209             while (my $description = $sth3->fetchrow_hashref) {
 210                 $native_description = $description->{description};
 211             }
 212
 213             # fill in the ISO6329 code
 214             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 215             # fill in the native description of the language, as well as the current language's translation of that if it exists
 216             if ($native_description) {
 217                 $language_subtag_registry->{language_description} = $native_description;
 218                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 219             }
 220             else {
 221                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 222             }
 223         }
 224         # Do not push unless valid iso639-2 code
 225         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 226             push @languages_loop, $language_subtag_registry;
 227         }
 228     }
 229     return \@languages_loop;
 230 }
 231
 232 sub _get_opac_language_dirs {
 233     my ( $htdocs, $theme ) = @_;
 234
 235     my @languages;
 236     if ( $theme and -d "$htdocs/$theme" ) {
 237         (@languages) = _get_language_dirs($htdocs,$theme);
 238     }
 239     else {
 240         for my $theme ( _get_themes('opac') ) {
 241             push @languages, _get_language_dirs($htdocs,$theme);
 242         }
 243     }
 244     return @languages;
 245 }
 246
 247
 248 sub _get_intranet_language_dirs {
 249     my ( $htdocs, $theme ) = @_;
 250
 251     my @languages;
 252     if ( $theme and -d "$htdocs/$theme" ) {
 253         @languages = _get_language_dirs($htdocs,$theme);
 254     }
 255     else {
 256         foreach my $theme ( _get_themes('intranet') ) {
 257             push @languages, _get_language_dirs($htdocs,$theme);
 258         }
 259     }
 260     return @languages;
 261 }
 262
 263 =head2 _get_themes
 264
 265 Internal function, returns an array of all available themes.
 266
 267   (@themes) = &_get_themes('opac');
 268   (@themes) = &_get_themes('intranet');
 269
 270 =cut
 271
 272 sub _get_themes {
 273     my $interface = shift;
 274     my $htdocs;
 275     my @themes;
 276     if ( $interface && $interface eq 'intranet' ) {
 277         $htdocs = C4::Context->config('intrahtdocs');
 278     }
 279     else {
 280         $htdocs = C4::Context->config('opachtdocs');
 281     }
 282     opendir D, "$htdocs";
 283     my @dirlist = readdir D;
 284     foreach my $directory (@dirlist) {
 285         # if there's an en dir, it's a valid theme
 286         -d "$htdocs/$directory/en" and push @themes, $directory;
 287     }
 288     return @themes;
 289 }
 290
 291 =head2 _get_language_dirs
 292
 293 Internal function, returns an array of directory names, excluding non-language directories
 294
 295 =cut
 296
 297 sub _get_language_dirs {
 298     my ($htdocs,$theme) = @_;
 299     $htdocs //= '';
 300     $theme //= '';
 301     my @lang_strings;
 302     opendir D, "$htdocs/$theme";
 303     for my $lang_string ( readdir D ) {
 304         next if $lang_string =~/^\./;
 305         next if $lang_string eq 'all';
 306         next if $lang_string =~/png$/;
 307         next if $lang_string =~/js$/;
 308         next if $lang_string =~/css$/;
 309         next if $lang_string =~/CVS$/;
 310         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 311         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 312         push @lang_strings, $lang_string;
 313     }
 314         return (@lang_strings);
 315 }
 316
 317 =head2 _build_languages_arrayref
 318
 319 Internal function for building the ref to array of hashes
 320
 321 FIXME: this could be rewritten and simplified using map
 322
 323 =cut
 324
 325 sub _build_languages_arrayref {
 326         my ($translated_languages,$current_language,$enabled_languages) = @_;
 327         $current_language //= '';
 328         my @translated_languages = @$translated_languages;
 329         my @languages_loop; # the final reference to an array of hashrefs
 330         my @enabled_languages = @$enabled_languages;
 331         # how many languages are enabled, if one, take note, some contexts won't need to display it
 332         my %seen_languages; # the language tags we've seen
 333         my %found_languages;
 334         my $language_groups;
 335         my $track_language_groups;
 336         my $current_language_regex = regex_lang_subtags($current_language);
 337         # Loop through the translated languages
 338         for my $translated_language (@translated_languages) {
 339             # separate the language string into its subtag types
 340             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 341
 342             # is this language string 'enabled'?
 343             for my $enabled_language (@enabled_languages) {
 344                 #warn "Checking out if $translated_language eq $enabled_language";
 345                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 346             }
 347
 348             # group this language, key by langtag
 349             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 350             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 351             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 352             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 353             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 354             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 355             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 356             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 357         }
 358         # $key is a language subtag like 'en'
 359
 360         my %idx = map { $enabled_languages->[$_] => $_ } reverse 0 .. @$enabled_languages-1;
 361         my @ordered_keys = sort {
 362             my $aa = $language_groups->{$a}->[0]->{rfc4646_subtag};
 363             my $bb = $language_groups->{$b}->[0]->{rfc4646_subtag};
 364             ( exists $idx{$aa} and exists $idx{$bb} and ( $idx{$aa} cmp $idx{$bb} ) )
 365             || ( exists $idx{$aa} and exists $idx{$bb} )
 366             || exists $idx{$bb}
 367         } keys %$language_groups;
 368
 369         for my $key ( @ordered_keys ) {
 370             my $value = $language_groups->{$key};
 371             # is this language group enabled? are any of the languages within it enabled?
 372             my $enabled;
 373             for my $enabled_language (@enabled_languages) {
 374                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 375                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 376             }
 377             push @languages_loop,  {
 378                             # this is only use if there is one
 379                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 380                             native_description => language_get_description($key,$key,'language'),
 381                             language => $key,
 382                             sublanguages_loop => $value,
 383                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 384                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 385                             group_enabled => $enabled,
 386                            };
 387         }
 388         return \@languages_loop;
 389 }
 390
 391 sub language_get_description {
 392     my ($script,$lang,$type) = @_;
 393     my $dbh = C4::Context->dbh;
 394     my $desc;
 395     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 396     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 397     $sth->execute($script,$lang,$type);
 398     while (my $descriptions = $sth->fetchrow_hashref) {
 399         $desc = $descriptions->{'description'};
 400     }
 401     unless ($desc) {
 402         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 403         $sth->execute($script,'en',$type);
 404         while (my $descriptions = $sth->fetchrow_hashref) {
 405             $desc = $descriptions->{'description'};
 406         }
 407     }
 408     return $desc;
 409 }
 410 =head2 regex_lang_subtags
 411
 412 This internal sub takes a string composed according to RFC 4646 as
 413 an input and returns a reference to a hash containing keys and values
 414 for ( language, script, region, variant, extension, privateuse )
 415
 416 =cut
 417
 418 sub regex_lang_subtags {
 419     my $string = shift;
 420
 421     # Regex for recognizing RFC 4646 well-formed tags
 422     # http://www.rfc-editor.org/rfc/rfc4646.txt
 423
 424     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 425     # The structure requires no forward references, so it reverses the order.
 426     # The uppercase comments are fragments copied from RFC 4646
 427     #
 428     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 429
 430     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 431     my $digit   = qr/[0-9]/ ;   # DIGIT
 432     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 433     my $x   = qr/[xX]/ ;    # private use singleton
 434     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 435     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 436
 437     # Now do the components. The structure is slightly different to allow for capturing the right components.
 438     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 439
 440     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 441     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 442     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 443
 444     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 445
 446     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 447
 448     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 449     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 450
 451     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 452     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 453
 454     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 455
 456     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 457     # Since these are limited, this is safe even later changes to the registry --
 458     # the only oddity is that it might change the type of the tag, and thus
 459     # the results from the capturing groups.
 460     # http://www.iana.org/assignments/language-subtag-registry
 461     # Note that these have to be compared case insensitively, requiring (?i) below.
 462
 463     my $grandfathered   = qr{(?: (?i)
 464         en $s GB $s oed
 465     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 466     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 467 )}x;
 468
 469     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 470
 471     #   |   art $s lojban
 472     #   |   cel $s gaulish
 473     #   |   en $s (?: boont | GB $s oed | scouse )
 474     #   |   no $s (?: bok | nyn)
 475     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 476
 477     # Here is the final breakdown, with capturing groups for each of these components
 478     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 479
 480     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 481
 482     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 483     my %subtag = (
 484         'rfc4646_subtag' => $string,
 485         'language' => $1,
 486         'script' => $2,
 487         'region' => $3,
 488         'variant' => $4,
 489         'extension' => $5,
 490         'privateuse' => $6,
 491     );
 492     return \%subtag;
 493 }
 494
 495 # Script Direction Resources:
 496 # http://www.w3.org/International/questions/qa-scripts
 497 sub get_bidi {
 498     my ($language_script)= @_;
 499     my $dbh = C4::Context->dbh;
 500     my $bidi;
 501     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 502     $sth->execute($language_script);
 503     while (my $result = $sth->fetchrow_hashref) {
 504         $bidi = $result->{'bidi'};
 505     }
 506     return $bidi;
 507 };
 508
 509 sub accept_language {
 510     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 511     my ($clientPreferences,$supportedLanguages) = @_;
 512     my @languages = ();
 513     if ($clientPreferences) {
 514         # There should be no whitespace anways, but a cleanliness/sanity check
 515         $clientPreferences =~ s/\s//g;
 516         # Prepare the list of client-acceptable languages
 517         foreach my $tag (split(/,/, $clientPreferences)) {
 518             my ($language, $quality) = split(/\;/, $tag);
 519             $quality =~ s/^q=//i if $quality;
 520             $quality = 1 unless $quality;
 521             next if $quality <= 0;
 522             # We want to force the wildcard to be last
 523             $quality = 0 if ($language eq '*');
 524             # Pushing lowercase language here saves processing later
 525             push(@languages, { quality => $quality,
 526                language => $language,
 527                lclanguage => lc($language) });
 528         }
 529     } else {
 530         carp "accept_language(x,y) called with no clientPreferences (x).";
 531     }
 532     # Prepare the list of server-supported languages
 533     my %supportedLanguages = ();
 534     my %secondaryLanguages = ();
 535     foreach my $language (@$supportedLanguages) {
 536         # warn "Language supported: " . $language->{language};
 537         my $subtag = $language->{rfc4646_subtag};
 538         $supportedLanguages{lc($subtag)} = $subtag;
 539         if ( $subtag =~ /^([^-]+)-?/ ) {
 540             $secondaryLanguages{lc($1)} = $subtag;
 541         }
 542     }
 543
 544     # Reverse sort the list, making best quality at the front of the array
 545     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 546     my $secondaryMatch = '';
 547     foreach my $tag (@languages) {
 548         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 549             # Client en-us eq server en-us
 550             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 551             return $supportedLanguages{$tag->{lclanguage}};
 552         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 553             # Client en eq server en-us
 554             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 555             return $supportedLanguages{$tag->{lclanguage}};
 556         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 557             # Client en-gb eq server en-us
 558             $secondaryMatch = $secondaryLanguages{$1};
 559         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 560             # FIXME: We just checked the exact same conditional!
 561             # Client en-us eq server en
 562             $secondaryMatch = $supportedLanguages{$1};
 563         } elsif ($tag->{lclanguage} eq '*') {
 564         # * matches every language not already specified.
 565         # It doesn't care which we pick, so let's pick the default,
 566         # if available, then the first in the array.
 567         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 568         return $supportedLanguages->[0];
 569         }
 570     }
 571     # No primary matches. Secondary? (ie, en-us requested and en supported)
 572     return $secondaryMatch if $secondaryMatch;
 573     return undef;   # else, we got nothing.
 574 }
 575
 576 =head2 getlanguage
 577
 578     Select a language based on the URL parameter 'language', a cookie,
 579     syspref available languages & browser
 580
 581 =cut
 582
 583 sub getlanguage {
 584     my ($cgi) = @_;
 585
 586     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 587     my $cache_key = "getlanguage";
 588     unless ( $cgi and $cgi->param('language') ) {
 589         my $cached = $memory_cache->get_from_cache($cache_key);
 590         return $cached if $cached;
 591     }
 592
 593     $cgi //= new CGI;
 594     my $interface = C4::Context->interface;
 595     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 596     my $language;
 597
 598     my $preference_to_check =
 599       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 600     # Get the available/valid languages list
 601     my @languages;
 602     my $preference_value = C4::Context->preference($preference_to_check);
 603     if ($preference_value) {
 604         @languages = split /,/, $preference_value;
 605     }
 606
 607     # Chose language from the URL
 608     my $cgi_param_language = $cgi->param( 'language' );
 609     if ( defined $cgi_param_language && any { $_ eq $cgi_param_language } @languages) {
 610         $language = $cgi_param_language;
 611     }
 612
 613     # cookie
 614     if (not $language and my $cgi_cookie_language = $cgi->cookie('KohaOpacLanguage') ) {
 615         ( $language = $cgi_cookie_language ) =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 616     }
 617
 618     # HTTP_ACCEPT_LANGUAGE
 619     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 620         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 621             getTranslatedLanguages( $interface, $theme ) );
 622     }
 623
 624     # Ignore a lang not selected in sysprefs
 625     if ( $language && not any { $_ eq $language } @languages ) {
 626         $language = undef;
 627     }
 628
 629     # Pick the first selected syspref language
 630     $language = shift @languages unless $language;
 631
 632     # Fall back to English if necessary
 633     $language ||= 'en';
 634
 635     $memory_cache->set_in_cache( $cache_key, $language );
 636     return $language;
 637 }
 638
 639 =head2 get_rfc4646_from_iso639
 640
 641     Select a language rfc4646 code given an iso639 code
 642
 643 =cut
 644
 645 sub get_rfc4646_from_iso639 {
 646
 647     my $iso_code = shift;
 648     my $rfc_subtag = Koha::Database->new()->schema->resultset('LanguageRfc4646ToIso639')->find({iso639_2_code=>$iso_code});
 649     if ( $rfc_subtag ) {
 650         return $rfc_subtag->rfc4646_subtag;
 651     } else {
 652         return;
 653     }
 654
 655 }
 656
 657 1;
 658
 659 __END__
 660
 661 =head1 AUTHOR
 662
 663 Joshua Ferraro
 664
 665 =cut