Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use vars qw(@ISA @EXPORT_OK);
  25 BEGIN {
  26     require Exporter;
  27     @ISA = qw(Exporter);
  28
  29     @EXPORT_OK = qw(
  30         dt_from_string
  31         output_pref
  32         format_sqldatetime
  33     );
  34 }
  35
  36 =head1 DateUtils
  37
  38 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  39
  40 =head1 DESCRIPTION
  41
  42 Koha has historically only used dates not datetimes and been content to
  43 handle these as strings. It also has confused formatting with actual dates
  44 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  45
  46 =cut
  47
  48 =head2 dt_ftom_string
  49
  50 $dt = dt_from_string($date_string, [$format, $timezone ]);
  51
  52 Passed a date string returns a DateTime object format and timezone default
  53 to the system preferences. If the date string is empty DateTime->now is returned
  54
  55 =cut
  56
  57 sub dt_from_string {
  58     my ( $date_string, $date_format, $tz ) = @_;
  59
  60     return if $date_string and $date_string =~ m|^0000-0|;
  61
  62     my $do_fallback = defined($date_format) ? 0 : 1;
  63     my $server_tz = C4::Context->tz;
  64     $tz = C4::Context->tz unless $tz;
  65
  66     return DateTime->now( time_zone => $tz ) unless $date_string;
  67
  68     $date_format = C4::Context->preference('dateformat') unless $date_format;
  69
  70     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  71         return $date_string;
  72     }
  73
  74     my $regex;
  75
  76     # The fallback format is sql/iso
  77     my $fallback_re = qr|
  78         (?<year>\d{4})
  79         -
  80         (?<month>\d{2})
  81         -
  82         (?<day>\d{2})
  83     |xms;
  84
  85     if ( $date_format eq 'metric' ) {
  86         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  87         $regex = qr|
  88             (?<day>\d{2})
  89             /
  90             (?<month>\d{2})
  91             /
  92             (?<year>\d{4})
  93         |xms;
  94     }
  95     elsif ( $date_format eq 'dmydot' ) {
  96         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  97         $regex = qr|
  98             (?<day>\d{2})
  99             .
 100             (?<month>\d{2})
 101             .
 102             (?<year>\d{4})
 103         |xms;
 104     }
 105     elsif ( $date_format eq 'us' ) {
 106         # us format is "mm/dd/yyyy[ hh:mm:ss]"
 107         $regex = qr|
 108             (?<month>\d{2})
 109             /
 110             (?<day>\d{2})
 111             /
 112             (?<year>\d{4})
 113         |xms;
 114     }
 115     elsif ( $date_format eq 'rfc3339' ) {
 116         $regex = qr/
 117             (?<year>\d{4})
 118             -
 119             (?<month>\d{2})
 120             -
 121             (?<day>\d{2})
 122             ([Tt\s])
 123             (?<hour>\d{2})
 124             :
 125             (?<minute>\d{2})
 126             :
 127             (?<second>\d{2})
 128             (\.\d{1,3})?(([Zz]$)|((?<offset>[\+|\-])(?<hours>[01][0-9]|2[0-3]):(?<minutes>[0-5][0-9])))
 129         /xms;
 130
 131         # Default to UTC (when 'Z' is passed) for inbound timezone.
 132         # The regex above succeeds for both 'z', 'Z' and '+/-' offset.
 133         # We set tz as though Z was passed by default and then correct it later if an offset is detected
 134         # by the presence fo the <offset> variable.
 135         $tz = DateTime::TimeZone->new( name => 'UTC' );
 136     }
 137     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 138         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 139         $regex = $fallback_re;
 140     }
 141     else {
 142         die "Invalid dateformat parameter ($date_format)";
 143     }
 144
 145     # Add the faculative time part [hh:mm[:ss]]
 146     my $time_re .= qr|
 147             (
 148                 \s*
 149                 (?<hour>\d{2})
 150                 :
 151                 (?<minute>\d{2})
 152                 (
 153                     :
 154                     (?<second>\d{2})
 155                 )?
 156                 (
 157                     \s
 158                     (?<ampm>\w{2})
 159                 )?
 160             )?
 161     |xms;
 162     $regex .= $time_re unless ( $date_format eq 'rfc3339' );
 163     $fallback_re .= $time_re;
 164
 165     # Ensure we only accept date strings and not other characters.
 166     $regex = '^' . $regex . '$';
 167     $fallback_re = '^' . $fallback_re . '$';
 168
 169     my %dt_params;
 170     my $ampm;
 171     if ( $date_string =~ $regex ) {
 172         %dt_params = (
 173             year   => $+{year},
 174             month  => $+{month},
 175             day    => $+{day},
 176             hour   => $+{hour},
 177             minute => $+{minute},
 178             second => $+{second},
 179         );
 180         $ampm = $+{ampm};
 181         if ( $+{offset} ) {
 182             # If offset given, set inbound timezone using it.
 183             $tz = DateTime::TimeZone->new( name => $+{offset} . $+{hours} . $+{minutes} );
 184         }
 185     } elsif ( $do_fallback && $date_string =~ $fallback_re ) {
 186         %dt_params = (
 187             year   => $+{year},
 188             month  => $+{month},
 189             day    => $+{day},
 190             hour   => $+{hour},
 191             minute => $+{minute},
 192             second => $+{second},
 193         );
 194         $ampm = $+{ampm};
 195     }
 196     else {
 197         die "The given date ($date_string) does not match the date format ($date_format)";
 198     }
 199
 200     # system allows the 0th of the month
 201     $dt_params{day} = '01' if $dt_params{day} eq '00';
 202
 203     # Set default hh:mm:ss to 00:00:00
 204     my $date_only = ( !defined( $dt_params{hour} )
 205         && !defined( $dt_params{minute} )
 206         && !defined( $dt_params{second} ) );
 207     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 208     $dt_params{minute} = 00 unless defined $dt_params{minute};
 209     $dt_params{second} = 00 unless defined $dt_params{second};
 210
 211     if ( $ampm ) {
 212         if ( $ampm eq 'AM' ) {
 213             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 214         } elsif ( $dt_params{hour} != 12 ) { # PM
 215             $dt_params{hour} += 12;
 216             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 217         }
 218     }
 219
 220     my $floating = 0;
 221     my $dt = eval {
 222         DateTime->new(
 223             %dt_params,
 224             # No TZ for dates 'infinite' => see bug 13242
 225             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 226         );
 227     };
 228     if ($@) {
 229         $tz = DateTime::TimeZone->new( name => 'floating' );
 230         $floating = 1;
 231         $dt = DateTime->new(
 232             %dt_params,
 233             # No TZ for dates 'infinite' => see bug 13242
 234             ( $dt_params{year} < 9999 ? ( time_zone => $tz ) : () ),
 235         );
 236     }
 237
 238     # Convert to configured timezone (unless we started with a dateonly string or had to drop to floating time)
 239     $dt->set_time_zone($server_tz) unless ( $date_only || $floating );
 240
 241     return $dt;
 242 }
 243
 244 =head2 output_pref
 245
 246 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 247 $date_string = output_pref( $dt );
 248
 249 Returns a string containing the time & date formatted as per the C4::Context setting,
 250 or C<undef> if C<undef> was provided.
 251
 252 This routine can either be passed a DateTime object or or a hashref.  If it is
 253 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 254 an optional 'dateformat' to override the dateformat system preference, an
 255 optional 'timeformat' to override the TimeFormat system preference value,
 256 and an optional 'dateonly' to specify that only the formatted date string
 257 should be returned without the time.
 258
 259 =cut
 260
 261 sub output_pref {
 262     my $params = shift;
 263     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 264     if ( ref $params eq 'HASH' ) {
 265         $dt         = $params->{dt};
 266         $str        = $params->{str};
 267         $force_pref = $params->{dateformat};         # if testing we want to override Context
 268         $force_time = $params->{timeformat};
 269         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 270         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 271     } else {
 272         $dt = $params;
 273     }
 274
 275     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 276
 277     if ( $str ) {
 278         local $@;
 279         $dt = eval { dt_from_string( $str ) };
 280         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 281     }
 282
 283     return if !defined $dt; # NULL date
 284     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 285
 286     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 287     if ( $dt->ymd !~ /^9999/ ) {
 288         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 289         $dt->set_time_zone( $tz );
 290     }
 291
 292     my $pref =
 293       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 294
 295     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 296     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 297     my $date;
 298     if ( $pref =~ m/^iso/ ) {
 299         $date = $dateonly
 300           ? $dt->strftime("%Y-%m-%d")
 301           : $dt->strftime("%Y-%m-%d $time");
 302     }
 303     elsif ( $pref =~ m/^rfc3339/ ) {
 304         if (!$dateonly) {
 305             $date = $dt->strftime('%FT%T%z');
 306             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 307         }
 308         else {
 309             $date = $dt->strftime("%Y-%m-%d");
 310         }
 311     }
 312     elsif ( $pref =~ m/^metric/ ) {
 313         $date = $dateonly
 314           ? $dt->strftime("%d/%m/%Y")
 315           : $dt->strftime("%d/%m/%Y $time");
 316     }
 317     elsif ( $pref =~ m/^dmydot/ ) {
 318         $date = $dateonly
 319           ? $dt->strftime("%d.%m.%Y")
 320           : $dt->strftime("%d.%m.%Y $time");
 321     }
 322
 323     elsif ( $pref =~ m/^us/ ) {
 324         $date = $dateonly
 325           ? $dt->strftime("%m/%d/%Y")
 326           : $dt->strftime("%m/%d/%Y $time");
 327     }
 328     else {
 329         $date = $dateonly
 330           ? $dt->strftime("%Y-%m-%d")
 331           : $dt->strftime("%Y-%m-%d $time");
 332     }
 333
 334     if ( $as_due_date ) {
 335         $time_format eq '12hr'
 336             ? $date =~ s| 11:59 PM$||
 337             : $date =~ s| 23:59$||;
 338     }
 339
 340     return $date;
 341 }
 342
 343 =head2 format_sqldatetime
 344
 345 $string = format_sqldatetime( $string_as_returned_from_db );
 346
 347 a convenience routine for calling dt_from_string and formatting the result
 348 with output_pref as it is a frequent activity in scripts
 349
 350 =cut
 351
 352 sub format_sqldatetime {
 353     my $str        = shift;
 354     my $force_pref = shift;    # if testing we want to override Context
 355     my $force_time = shift;
 356     my $dateonly   = shift;
 357
 358     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 359         my $dt = dt_from_string( $str, 'sql' );
 360         return q{} unless $dt;
 361         $dt->truncate( to => 'minute' );
 362         return output_pref({
 363             dt => $dt,
 364             dateformat => $force_pref,
 365             timeformat => $force_time,
 366             dateonly => $dateonly
 367         });
 368     }
 369     return q{};
 370 }
 371
 372 1;