Koha/Item.pm

   1 package Koha::Item;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use List::MoreUtils qw( any );
  23 use Try::Tiny qw( catch try );
  24
  25 use Koha::Database;
  26 use Koha::DateUtils qw( dt_from_string output_pref );
  27
  28 use C4::Context;
  29 use C4::Circulation qw( barcodedecode GetBranchItemRule );
  30 use C4::Reserves;
  31 use C4::ClassSource qw( GetClassSort );
  32 use C4::Log qw( logaction );
  33
  34 use Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue;
  35 use Koha::Biblio::ItemGroups;
  36 use Koha::Checkouts;
  37 use Koha::CirculationRules;
  38 use Koha::CoverImages;
  39 use Koha::Exceptions;
  40 use Koha::Exceptions::Checkin;
  41 use Koha::Exceptions::Item::Bundle;
  42 use Koha::Exceptions::Item::Transfer;
  43 use Koha::Item::Attributes;
  44 use Koha::Exceptions::Item::Bundle;
  45 use Koha::Item::Transfer::Limits;
  46 use Koha::Item::Transfers;
  47 use Koha::ItemTypes;
  48 use Koha::Libraries;
  49 use Koha::Patrons;
  50 use Koha::Plugins;
  51 use Koha::Recalls;
  52 use Koha::Result::Boolean;
  53 use Koha::SearchEngine::Indexer;
  54 use Koha::StockRotationItem;
  55 use Koha::StockRotationRotas;
  56 use Koha::TrackedLinks;
  57
  58 use base qw(Koha::Object);
  59
  60 =head1 NAME
  61
  62 Koha::Item - Koha Item object class
  63
  64 =head1 API
  65
  66 =head2 Class methods
  67
  68 =cut
  69
  70 =head3 store
  71
  72     $item->store;
  73
  74 $params can take an optional 'skip_record_index' parameter.
  75 If set, the reindexation process will not happen (index_records not called)
  76 You should not turn it on if you do not understand what it is doing exactly.
  77
  78 =cut
  79
  80 sub store {
  81     my $self = shift;
  82     my $params = @_ ? shift : {};
  83
  84     my $log_action = $params->{log_action} // 1;
  85
  86     # We do not want to oblige callers to pass this value
  87     # Dev conveniences vs performance?
  88     unless ( $self->biblioitemnumber ) {
  89         $self->biblioitemnumber( $self->biblio->biblioitem->biblioitemnumber );
  90     }
  91
  92     # See related changes from C4::Items::AddItem
  93     unless ( $self->itype ) {
  94         $self->itype($self->biblio->biblioitem->itemtype);
  95     }
  96
  97     $self->barcode( C4::Circulation::barcodedecode( $self->barcode ) );
  98
  99     my $today  = dt_from_string;
 100     my $action = 'create';
 101
 102     unless ( $self->in_storage ) { #AddItem
 103
 104         unless ( $self->permanent_location ) {
 105             $self->permanent_location($self->location);
 106         }
 107
 108         my $default_location = C4::Context->preference('NewItemsDefaultLocation');
 109         unless ( $self->location || !$default_location ) {
 110             $self->permanent_location( $self->location || $default_location )
 111               unless $self->permanent_location;
 112             $self->location($default_location);
 113         }
 114
 115         unless ( $self->replacementpricedate ) {
 116             $self->replacementpricedate($today);
 117         }
 118         unless ( $self->datelastseen ) {
 119             $self->datelastseen($today);
 120         }
 121
 122         unless ( $self->dateaccessioned ) {
 123             $self->dateaccessioned($today);
 124         }
 125
 126         if (   $self->itemcallnumber
 127             or $self->cn_source )
 128         {
 129             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 130             $self->cn_sort($cn_sort);
 131         }
 132
 133     } else { # ModItem
 134
 135         $action = 'modify';
 136
 137         my %updated_columns = $self->_result->get_dirty_columns;
 138         return $self->SUPER::store unless %updated_columns;
 139
 140         # Retrieve the item for comparison if we need to
 141         my $pre_mod_item = (
 142                  exists $updated_columns{itemlost}
 143               or exists $updated_columns{withdrawn}
 144               or exists $updated_columns{damaged}
 145         ) ? $self->get_from_storage : undef;
 146
 147         # Update *_on  fields if needed
 148         # FIXME: Why not for AddItem as well?
 149         my @fields = qw( itemlost withdrawn damaged );
 150         for my $field (@fields) {
 151
 152             # If the field is defined but empty or 0, we are
 153             # removing/unsetting and thus need to clear out
 154             # the 'on' field
 155             if (   exists $updated_columns{$field}
 156                 && defined( $self->$field )
 157                 && !$self->$field )
 158             {
 159                 my $field_on = "${field}_on";
 160                 $self->$field_on(undef);
 161             }
 162             # If the field has changed otherwise, we much update
 163             # the 'on' field
 164             elsif (exists $updated_columns{$field}
 165                 && $updated_columns{$field}
 166                 && !$pre_mod_item->$field )
 167             {
 168                 my $field_on = "${field}_on";
 169                 $self->$field_on(dt_from_string);
 170             }
 171         }
 172
 173         if (   exists $updated_columns{itemcallnumber}
 174             or exists $updated_columns{cn_source} )
 175         {
 176             my $cn_sort = GetClassSort( $self->cn_source, $self->itemcallnumber, "" );
 177             $self->cn_sort($cn_sort);
 178         }
 179
 180
 181         if (    exists $updated_columns{location}
 182             and ( !defined($self->location) or $self->location !~ /^(CART|PROC)$/ )
 183             and not exists $updated_columns{permanent_location} )
 184         {
 185             $self->permanent_location( $self->location );
 186         }
 187
 188         # If item was lost and has now been found,
 189         # reverse any list item charges if necessary.
 190         if (    exists $updated_columns{itemlost}
 191             and $updated_columns{itemlost} <= 0
 192             and $pre_mod_item->itemlost > 0 )
 193         {
 194             $self->_set_found_trigger($pre_mod_item);
 195         }
 196
 197     }
 198
 199     my $result = $self->SUPER::store;
 200     if ( $log_action && C4::Context->preference("CataloguingLog") ) {
 201         $action eq 'create'
 202           ? logaction( "CATALOGUING", "ADD", $self->itemnumber, "item" )
 203           : logaction( "CATALOGUING", "MODIFY", $self->itemnumber, $self );
 204     }
 205     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 206     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 207         unless $params->{skip_record_index};
 208     $self->get_from_storage->_after_item_action_hooks({ action => $action });
 209
 210     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 211         {
 212             biblio_ids => [ $self->biblionumber ]
 213         }
 214     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 215
 216     return $result;
 217 }
 218
 219 =head3 delete
 220
 221 =cut
 222
 223 sub delete {
 224     my $self = shift;
 225     my $params = @_ ? shift : {};
 226
 227     # FIXME check the item has no current issues
 228     # i.e. raise the appropriate exception
 229
 230     # Get the item group so we can delete it later if it has no items left
 231     my $item_group = C4::Context->preference('EnableItemGroups') ? $self->item_group : undef;
 232
 233     my $result = $self->SUPER::delete;
 234
 235     # Delete the item gorup if it has no items left
 236     $item_group->delete if ( $item_group && $item_group->items->count == 0 );
 237
 238     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 239     $indexer->index_records( $self->biblionumber, "specialUpdate", "biblioserver" )
 240         unless $params->{skip_record_index};
 241
 242     $self->_after_item_action_hooks({ action => 'delete' });
 243
 244     logaction( "CATALOGUING", "DELETE", $self->itemnumber, "item" )
 245       if C4::Context->preference("CataloguingLog");
 246
 247     Koha::BackgroundJob::BatchUpdateBiblioHoldsQueue->new->enqueue(
 248         {
 249             biblio_ids => [ $self->biblionumber ]
 250         }
 251     ) unless $params->{skip_holds_queue} or !C4::Context->preference('RealTimeHoldsQueue');
 252
 253     return $result;
 254 }
 255
 256 =head3 safe_delete
 257
 258 =cut
 259
 260 sub safe_delete {
 261     my $self = shift;
 262     my $params = @_ ? shift : {};
 263
 264     my $safe_to_delete = $self->safe_to_delete;
 265     return $safe_to_delete unless $safe_to_delete;
 266
 267     $self->move_to_deleted;
 268
 269     return $self->delete($params);
 270 }
 271
 272 =head3 safe_to_delete
 273
 274 returns 1 if the item is safe to delete,
 275
 276 "book_on_loan" if the item is checked out,
 277
 278 "not_same_branch" if the item is blocked by independent branches,
 279
 280 "book_reserved" if the there are holds aganst the item, or
 281
 282 "linked_analytics" if the item has linked analytic records.
 283
 284 "last_item_for_hold" if the item is the last one on a record on which a biblio-level hold is placed
 285
 286 =cut
 287
 288 sub safe_to_delete {
 289     my ($self) = @_;
 290
 291     my $error;
 292
 293     $error = "book_on_loan" if $self->checkout;
 294
 295     $error //= "not_same_branch"
 296       if defined C4::Context->userenv
 297       and defined C4::Context->userenv->{number}
 298       and !Koha::Patrons->find( C4::Context->userenv->{number} )->can_edit_items_from( $self->homebranch );
 299
 300     # check it doesn't have a waiting reserve
 301     $error //= "book_reserved"
 302       if $self->holds->filter_by_found->count;
 303
 304     $error //= "linked_analytics"
 305       if C4::Items::GetAnalyticsCount( $self->itemnumber ) > 0;
 306
 307     $error //= "last_item_for_hold"
 308       if $self->biblio->items->count == 1
 309       && $self->biblio->holds->search(
 310           {
 311               itemnumber => undef,
 312           }
 313         )->count;
 314
 315     if ( $error ) {
 316         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
 317     }
 318
 319     return Koha::Result::Boolean->new(1);
 320 }
 321
 322 =head3 move_to_deleted
 323
 324 my $is_moved = $item->move_to_deleted;
 325
 326 Move an item to the deleteditems table.
 327 This can be done before deleting an item, to make sure the data are not completely deleted.
 328
 329 =cut
 330
 331 sub move_to_deleted {
 332     my ($self) = @_;
 333     my $item_infos = $self->unblessed;
 334     delete $item_infos->{timestamp}; #This ensures the timestamp date in deleteditems will be set to the current timestamp
 335     $item_infos->{deleted_on} = dt_from_string;
 336     return Koha::Database->new->schema->resultset('Deleteditem')->create($item_infos);
 337 }
 338
 339
 340 =head3 effective_itemtype
 341
 342 Returns the itemtype for the item based on whether item level itemtypes are set or not.
 343
 344 =cut
 345
 346 sub effective_itemtype {
 347     my ( $self ) = @_;
 348
 349     return $self->_result()->effective_itemtype();
 350 }
 351
 352 =head3 home_branch
 353
 354 =cut
 355
 356 sub home_branch {
 357     my ($self) = @_;
 358
 359     my $hb_rs = $self->_result->homebranch;
 360
 361     return Koha::Library->_new_from_dbic( $hb_rs );
 362 }
 363
 364 =head3 holding_branch
 365
 366 =cut
 367
 368 sub holding_branch {
 369     my ($self) = @_;
 370
 371     my $hb_rs = $self->_result->holdingbranch;
 372
 373     return Koha::Library->_new_from_dbic( $hb_rs );
 374 }
 375
 376 =head3 biblio
 377
 378 my $biblio = $item->biblio;
 379
 380 Return the bibliographic record of this item
 381
 382 =cut
 383
 384 sub biblio {
 385     my ( $self ) = @_;
 386     my $biblio_rs = $self->_result->biblio;
 387     return Koha::Biblio->_new_from_dbic( $biblio_rs );
 388 }
 389
 390 =head3 biblioitem
 391
 392 my $biblioitem = $item->biblioitem;
 393
 394 Return the biblioitem record of this item
 395
 396 =cut
 397
 398 sub biblioitem {
 399     my ( $self ) = @_;
 400     my $biblioitem_rs = $self->_result->biblioitem;
 401     return Koha::Biblioitem->_new_from_dbic( $biblioitem_rs );
 402 }
 403
 404 =head3 checkout
 405
 406 my $checkout = $item->checkout;
 407
 408 Return the checkout for this item
 409
 410 =cut
 411
 412 sub checkout {
 413     my ( $self ) = @_;
 414     my $checkout_rs = $self->_result->issue;
 415     return unless $checkout_rs;
 416     return Koha::Checkout->_new_from_dbic( $checkout_rs );
 417 }
 418
 419 =head3 item_group
 420
 421 my $item_group = $item->item_group;
 422
 423 Return the item group for this item
 424
 425 =cut
 426
 427 sub item_group {
 428     my ( $self ) = @_;
 429
 430     my $item_group_item = $self->_result->item_group_item;
 431     return unless $item_group_item;
 432
 433     my $item_group_rs = $item_group_item->item_group;
 434     return unless $item_group_rs;
 435
 436     my $item_group = Koha::Biblio::ItemGroup->_new_from_dbic( $item_group_rs );
 437     return $item_group;
 438 }
 439
 440 =head3 return_claims
 441
 442   my $return_claims = $item->return_claims;
 443
 444 Return any return_claims associated with this item
 445
 446 =cut
 447
 448 sub return_claims {
 449     my ( $self, $params, $attrs ) = @_;
 450     my $claims_rs = $self->_result->return_claims->search($params, $attrs);
 451     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $claims_rs );
 452 }
 453
 454 =head3 return_claim
 455
 456   my $return_claim = $item->return_claim;
 457
 458 Returns the most recent unresolved return_claims associated with this item
 459
 460 =cut
 461
 462 sub return_claim {
 463     my ($self) = @_;
 464     my $claims_rs =
 465       $self->_result->return_claims->search( { resolution => undef },
 466         { order_by => { '-desc' => 'created_on' }, rows => 1 } )->single;
 467     return unless $claims_rs;
 468     return Koha::Checkouts::ReturnClaim->_new_from_dbic($claims_rs);
 469 }
 470
 471 =head3 holds
 472
 473 my $holds = $item->holds();
 474 my $holds = $item->holds($params);
 475 my $holds = $item->holds({ found => 'W'});
 476
 477 Return holds attached to an item, optionally accept a hashref of params to pass to search
 478
 479 =cut
 480
 481 sub holds {
 482     my ( $self,$params ) = @_;
 483     my $holds_rs = $self->_result->reserves->search($params);
 484     return Koha::Holds->_new_from_dbic( $holds_rs );
 485 }
 486
 487 =head3 request_transfer
 488
 489   my $transfer = $item->request_transfer(
 490     {
 491         to     => $to_library,
 492         reason => $reason,
 493         [ ignore_limits => 0, enqueue => 1, replace => 1 ]
 494     }
 495   );
 496
 497 Add a transfer request for this item to the given branch for the given reason.
 498
 499 An exception will be thrown if the BranchTransferLimits would prevent the requested
 500 transfer, unless 'ignore_limits' is passed to override the limits.
 501
 502 An exception will be thrown if an active transfer (i.e pending arrival date) is found;
 503 The caller should catch such cases and retry the transfer request as appropriate passing
 504 an appropriate override.
 505
 506 Overrides
 507 * enqueue - Used to queue up the transfer when the existing transfer is found to be in transit.
 508 * replace - Used to replace the existing transfer request with your own.
 509
 510 =cut
 511
 512 sub request_transfer {
 513     my ( $self, $params ) = @_;
 514
 515     # check for mandatory params
 516     my @mandatory = ( 'to', 'reason' );
 517     for my $param (@mandatory) {
 518         unless ( defined( $params->{$param} ) ) {
 519             Koha::Exceptions::MissingParameter->throw(
 520                 error => "The $param parameter is mandatory" );
 521         }
 522     }
 523
 524     Koha::Exceptions::Item::Transfer::Limit->throw()
 525       unless ( $params->{ignore_limits}
 526         || $self->can_be_transferred( { to => $params->{to} } ) );
 527
 528     my $request = $self->get_transfer;
 529     Koha::Exceptions::Item::Transfer::InQueue->throw( transfer => $request )
 530       if ( $request && !$params->{enqueue} && !$params->{replace} );
 531
 532     $request->cancel( { reason => $params->{reason}, force => 1 } )
 533       if ( defined($request) && $params->{replace} );
 534
 535     my $transfer = Koha::Item::Transfer->new(
 536         {
 537             itemnumber    => $self->itemnumber,
 538             daterequested => dt_from_string,
 539             frombranch    => $self->holdingbranch,
 540             tobranch      => $params->{to}->branchcode,
 541             reason        => $params->{reason},
 542             comments      => $params->{comment}
 543         }
 544     )->store();
 545
 546     return $transfer;
 547 }
 548
 549 =head3 get_transfer
 550
 551   my $transfer = $item->get_transfer;
 552
 553 Return the active transfer request or undef
 554
 555 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 556 whereby the most recently sent, but not received, transfer will be returned
 557 if it exists, otherwise the oldest unsatisfied transfer will be returned.
 558
 559 This allows for transfers to queue, which is the case for stock rotation and
 560 rotating collections where a manual transfer may need to take precedence but
 561 we still expect the item to end up at a final location eventually.
 562
 563 =cut
 564
 565 sub get_transfer {
 566     my ($self) = @_;
 567
 568     my $transfer = $self->_result->current_branchtransfers->next;
 569     return  Koha::Item::Transfer->_new_from_dbic($transfer) if $transfer;
 570 }
 571
 572 =head3 get_transfers
 573
 574   my $transfer = $item->get_transfers;
 575
 576 Return the list of outstanding transfers (i.e requested but not yet cancelled
 577 or received).
 578
 579 Note: Transfers are retrieved in a Modified FIFO (First In First Out) order
 580 whereby the most recently sent, but not received, transfer will be returned
 581 first if it exists, otherwise requests are in oldest to newest request order.
 582
 583 This allows for transfers to queue, which is the case for stock rotation and
 584 rotating collections where a manual transfer may need to take precedence but
 585 we still expect the item to end up at a final location eventually.
 586
 587 =cut
 588
 589 sub get_transfers {
 590     my ($self) = @_;
 591
 592     my $transfer_rs = $self->_result->current_branchtransfers;
 593
 594     return Koha::Item::Transfers->_new_from_dbic($transfer_rs);
 595 }
 596
 597 =head3 last_returned_by
 598
 599 Gets and sets the last borrower to return an item.
 600
 601 Accepts and returns Koha::Patron objects
 602
 603 $item->last_returned_by( $borrowernumber );
 604
 605 $last_returned_by = $item->last_returned_by();
 606
 607 =cut
 608
 609 sub last_returned_by {
 610     my ( $self, $borrower ) = @_;
 611
 612     my $items_last_returned_by_rs = Koha::Database->new()->schema()->resultset('ItemsLastBorrower');
 613
 614     if ($borrower) {
 615         return $items_last_returned_by_rs->update_or_create(
 616             { borrowernumber => $borrower->borrowernumber, itemnumber => $self->id } );
 617     }
 618     else {
 619         unless ( $self->{_last_returned_by} ) {
 620             my $result = $items_last_returned_by_rs->single( { itemnumber => $self->id } );
 621             if ($result) {
 622                 $self->{_last_returned_by} = Koha::Patrons->find( $result->get_column('borrowernumber') );
 623             }
 624         }
 625
 626         return $self->{_last_returned_by};
 627     }
 628 }
 629
 630 =head3 can_article_request
 631
 632 my $bool = $item->can_article_request( $borrower )
 633
 634 Returns true if item can be specifically requested
 635
 636 $borrower must be a Koha::Patron object
 637
 638 =cut
 639
 640 sub can_article_request {
 641     my ( $self, $borrower ) = @_;
 642
 643     my $rule = $self->article_request_type($borrower);
 644
 645     return 1 if $rule && $rule ne 'no' && $rule ne 'bib_only';
 646     return q{};
 647 }
 648
 649 =head3 hidden_in_opac
 650
 651 my $bool = $item->hidden_in_opac({ [ rules => $rules ] })
 652
 653 Returns true if item fields match the hidding criteria defined in $rules.
 654 Returns false otherwise.
 655
 656 Takes HASHref that can have the following parameters:
 657     OPTIONAL PARAMETERS:
 658     $rules : { <field> => [ value_1, ... ], ... }
 659
 660 Note: $rules inherits its structure from the parsed YAML from reading
 661 the I<OpacHiddenItems> system preference.
 662
 663 =cut
 664
 665 sub hidden_in_opac {
 666     my ( $self, $params ) = @_;
 667
 668     my $rules = $params->{rules} // {};
 669
 670     return 1
 671         if C4::Context->preference('hidelostitems') and
 672            $self->itemlost > 0;
 673
 674     my $hidden_in_opac = 0;
 675
 676     foreach my $field ( keys %{$rules} ) {
 677
 678         if ( any { $self->$field eq $_ } @{ $rules->{$field} } ) {
 679             $hidden_in_opac = 1;
 680             last;
 681         }
 682     }
 683
 684     return $hidden_in_opac;
 685 }
 686
 687 =head3 can_be_transferred
 688
 689 $item->can_be_transferred({ to => $to_library, from => $from_library })
 690 Checks if an item can be transferred to given library.
 691
 692 This feature is controlled by two system preferences:
 693 UseBranchTransferLimits to enable / disable the feature
 694 BranchTransferLimitsType to use either an itemnumber or ccode as an identifier
 695                          for setting the limitations
 696
 697 Takes HASHref that can have the following parameters:
 698     MANDATORY PARAMETERS:
 699     $to   : Koha::Library
 700     OPTIONAL PARAMETERS:
 701     $from : Koha::Library  # if not given, item holdingbranch
 702                            # will be used instead
 703
 704 Returns 1 if item can be transferred to $to_library, otherwise 0.
 705
 706 To find out whether at least one item of a Koha::Biblio can be transferred, please
 707 see Koha::Biblio->can_be_transferred() instead of using this method for
 708 multiple items of the same biblio.
 709
 710 =cut
 711
 712 sub can_be_transferred {
 713     my ($self, $params) = @_;
 714
 715     my $to   = $params->{to};
 716     my $from = $params->{from};
 717
 718     $to   = $to->branchcode;
 719     $from = defined $from ? $from->branchcode : $self->holdingbranch;
 720
 721     return 1 if $from eq $to; # Transfer to current branch is allowed
 722     return 1 unless C4::Context->preference('UseBranchTransferLimits');
 723
 724     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 725     return Koha::Item::Transfer::Limits->search({
 726         toBranch => $to,
 727         fromBranch => $from,
 728         $limittype => $limittype eq 'itemtype'
 729                         ? $self->effective_itemtype : $self->ccode
 730     })->count ? 0 : 1;
 731
 732 }
 733
 734 =head3 pickup_locations
 735
 736     my $pickup_locations = $item->pickup_locations({ patron => $patron })
 737
 738 Returns possible pickup locations for this item, according to patron's home library
 739 and if item can be transferred to each pickup location.
 740
 741 Throws a I<Koha::Exceptions::MissingParameter> exception if the B<mandatory> parameter I<patron>
 742 is not passed.
 743
 744 =cut
 745
 746 sub pickup_locations {
 747     my ($self, $params) = @_;
 748
 749     Koha::Exceptions::MissingParameter->throw( parameter => 'patron' )
 750       unless exists $params->{patron};
 751
 752     my $patron = $params->{patron};
 753
 754     my $circ_control_branch =
 755       C4::Reserves::GetReservesControlBranch( $self->unblessed(), $patron->unblessed );
 756     my $branchitemrule =
 757       C4::Circulation::GetBranchItemRule( $circ_control_branch, $self->itype );
 758
 759     return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_local_hold_group' && !$self->home_branch->validate_hold_sibling( {branchcode => $patron->branchcode} );
 760     return Koha::Libraries->new()->empty if $branchitemrule->{holdallowed} eq 'from_home_library' && $self->home_branch->branchcode ne $patron->branchcode;
 761
 762     my $pickup_libraries = Koha::Libraries->search();
 763     if ($branchitemrule->{hold_fulfillment_policy} eq 'holdgroup') {
 764         $pickup_libraries = $self->home_branch->get_hold_libraries;
 765     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'patrongroup') {
 766         my $plib = Koha::Libraries->find({ branchcode => $patron->branchcode});
 767         $pickup_libraries = $plib->get_hold_libraries;
 768     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'homebranch') {
 769         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->homebranch });
 770     } elsif ($branchitemrule->{hold_fulfillment_policy} eq 'holdingbranch') {
 771         $pickup_libraries = Koha::Libraries->search({ branchcode => $self->holdingbranch });
 772     };
 773
 774     return $pickup_libraries->search(
 775         {
 776             pickup_location => 1
 777         },
 778         {
 779             order_by => ['branchname']
 780         }
 781     ) unless C4::Context->preference('UseBranchTransferLimits');
 782
 783     my $limittype = C4::Context->preference('BranchTransferLimitsType');
 784     my ($ccode, $itype) = (undef, undef);
 785     if( $limittype eq 'ccode' ){
 786         $ccode = $self->ccode;
 787     } else {
 788         $itype = $self->itype;
 789     }
 790     my $limits = Koha::Item::Transfer::Limits->search(
 791         {
 792             fromBranch => $self->holdingbranch,
 793             ccode      => $ccode,
 794             itemtype   => $itype,
 795         },
 796         { columns => ['toBranch'] }
 797     );
 798
 799     return $pickup_libraries->search(
 800         {
 801             pickup_location => 1,
 802             branchcode      => {
 803                 '-not_in' => $limits->_resultset->as_query
 804             }
 805         },
 806         {
 807             order_by => ['branchname']
 808         }
 809     );
 810 }
 811
 812 =head3 article_request_type
 813
 814 my $type = $item->article_request_type( $borrower )
 815
 816 returns 'yes', 'no', 'bib_only', or 'item_only'
 817
 818 $borrower must be a Koha::Patron object
 819
 820 =cut
 821
 822 sub article_request_type {
 823     my ( $self, $borrower ) = @_;
 824
 825     my $branch_control = C4::Context->preference('HomeOrHoldingBranch');
 826     my $branchcode =
 827         $branch_control eq 'homebranch'    ? $self->homebranch
 828       : $branch_control eq 'holdingbranch' ? $self->holdingbranch
 829       :                                      undef;
 830     my $borrowertype = $borrower->categorycode;
 831     my $itemtype = $self->effective_itemtype();
 832     my $rule = Koha::CirculationRules->get_effective_rule(
 833         {
 834             rule_name    => 'article_requests',
 835             categorycode => $borrowertype,
 836             itemtype     => $itemtype,
 837             branchcode   => $branchcode
 838         }
 839     );
 840
 841     return q{} unless $rule;
 842     return $rule->rule_value || q{}
 843 }
 844
 845 =head3 current_holds
 846
 847 =cut
 848
 849 sub current_holds {
 850     my ( $self ) = @_;
 851     my $attributes = { order_by => 'priority' };
 852     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 853     my $params = {
 854         itemnumber => $self->itemnumber,
 855         suspend => 0,
 856         -or => [
 857             reservedate => { '<=' => $dtf->format_date(dt_from_string) },
 858             waitingdate => { '!=' => undef },
 859         ],
 860     };
 861     my $hold_rs = $self->_result->reserves->search( $params, $attributes );
 862     return Koha::Holds->_new_from_dbic($hold_rs);
 863 }
 864
 865 =head3 stockrotationitem
 866
 867   my $sritem = Koha::Item->stockrotationitem;
 868
 869 Returns the stock rotation item associated with the current item.
 870
 871 =cut
 872
 873 sub stockrotationitem {
 874     my ( $self ) = @_;
 875     my $rs = $self->_result->stockrotationitem;
 876     return 0 if !$rs;
 877     return Koha::StockRotationItem->_new_from_dbic( $rs );
 878 }
 879
 880 =head3 add_to_rota
 881
 882   my $item = $item->add_to_rota($rota_id);
 883
 884 Add this item to the rota identified by $ROTA_ID, which means associating it
 885 with the first stage of that rota.  Should this item already be associated
 886 with a rota, then we will move it to the new rota.
 887
 888 =cut
 889
 890 sub add_to_rota {
 891     my ( $self, $rota_id ) = @_;
 892     Koha::StockRotationRotas->find($rota_id)->add_item($self->itemnumber);
 893     return $self;
 894 }
 895
 896 =head3 has_pending_hold
 897
 898   my $is_pending_hold = $item->has_pending_hold();
 899
 900 This method checks the tmp_holdsqueue to see if this item has been selected for a hold, but not filled yet and returns true or false
 901
 902 =cut
 903
 904 sub has_pending_hold {
 905     my ( $self ) = @_;
 906     my $pending_hold = $self->_result->tmp_holdsqueues;
 907     return $pending_hold->count ? 1: 0;
 908 }
 909
 910 =head3 has_pending_recall {
 911
 912   my $has_pending_recall
 913
 914 Return if whether has pending recall of not.
 915
 916 =cut
 917
 918 sub has_pending_recall {
 919     my ( $self ) = @_;
 920
 921     # FIXME Must be moved to $self->recalls
 922     return Koha::Recalls->search(
 923         {
 924             item_id   => $self->itemnumber,
 925             status    => 'waiting',
 926         }
 927     )->count;
 928 }
 929
 930 =head3 as_marc_field
 931
 932     my $field = $item->as_marc_field;
 933
 934 This method returns a MARC::Field object representing the Koha::Item object
 935 with the current mappings configuration.
 936
 937 =cut
 938
 939 sub as_marc_field {
 940     my ( $self ) = @_;
 941
 942     my ( $itemtag, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 943
 944     my $tagslib = C4::Biblio::GetMarcStructure( 1, $self->biblio->frameworkcode, { unsafe => 1 });
 945
 946     my @subfields;
 947
 948     my $item_field = $tagslib->{$itemtag};
 949
 950     my $more_subfields = $self->additional_attributes->to_hashref;
 951     foreach my $subfield (
 952         sort {
 953                $a->{display_order} <=> $b->{display_order}
 954             || $a->{subfield} cmp $b->{subfield}
 955         } grep { ref($_) && %$_ } values %$item_field
 956     ){
 957
 958         my $kohafield = $subfield->{kohafield};
 959         my $tagsubfield = $subfield->{tagsubfield};
 960         my $value;
 961         if ( defined $kohafield && $kohafield ne '' ) {
 962             next if $kohafield !~ m{^items\.}; # That would be weird!
 963             ( my $attribute = $kohafield ) =~ s|^items\.||;
 964             $value = $self->$attribute # This call may fail if a kohafield is not a DB column but we don't want to add extra work for that there
 965                 if defined $self->$attribute and $self->$attribute ne '';
 966         } else {
 967             $value = $more_subfields->{$tagsubfield}
 968         }
 969
 970         next unless defined $value
 971             and $value ne q{};
 972
 973         if ( $subfield->{repeatable} ) {
 974             my @values = split '\|', $value;
 975             push @subfields, ( $tagsubfield => $_ ) for @values;
 976         }
 977         else {
 978             push @subfields, ( $tagsubfield => $value );
 979         }
 980
 981     }
 982
 983     return unless @subfields;
 984
 985     return MARC::Field->new(
 986         "$itemtag", ' ', ' ', @subfields
 987     );
 988 }
 989
 990 =head3 renewal_branchcode
 991
 992 Returns the branchcode to be recorded in statistics renewal of the item
 993
 994 =cut
 995
 996 sub renewal_branchcode {
 997
 998     my ($self, $params ) = @_;
 999
1000     my $interface = C4::Context->interface;
1001     my $branchcode;
1002     if ( $interface eq 'opac' ){
1003         my $renewal_branchcode = C4::Context->preference('OpacRenewalBranch');
1004         if( !defined $renewal_branchcode || $renewal_branchcode eq 'opacrenew' ){
1005             $branchcode = 'OPACRenew';
1006         }
1007         elsif ( $renewal_branchcode eq 'itemhomebranch' ) {
1008             $branchcode = $self->homebranch;
1009         }
1010         elsif ( $renewal_branchcode eq 'patronhomebranch' ) {
1011             $branchcode = $self->checkout->patron->branchcode;
1012         }
1013         elsif ( $renewal_branchcode eq 'checkoutbranch' ) {
1014             $branchcode = $self->checkout->branchcode;
1015         }
1016         else {
1017             $branchcode = "";
1018         }
1019     } else {
1020         $branchcode = ( C4::Context->userenv && defined C4::Context->userenv->{branch} )
1021             ? C4::Context->userenv->{branch} : $params->{branch};
1022     }
1023     return $branchcode;
1024 }
1025
1026 =head3 cover_images
1027
1028 Return the cover images associated with this item.
1029
1030 =cut
1031
1032 sub cover_images {
1033     my ( $self ) = @_;
1034
1035     my $cover_image_rs = $self->_result->cover_images;
1036     return unless $cover_image_rs;
1037     return Koha::CoverImages->_new_from_dbic($cover_image_rs);
1038 }
1039
1040 =head3 columns_to_str
1041
1042     my $values = $items->columns_to_str;
1043
1044 Return a hashref with the string representation of the different attribute of the item.
1045
1046 This is meant to be used for display purpose only.
1047
1048 =cut
1049
1050 sub columns_to_str {
1051     my ( $self ) = @_;
1052
1053     my $frameworkcode = $self->biblio->frameworkcode;
1054     my $tagslib = C4::Biblio::GetMarcStructure(1, $frameworkcode);
1055     my ( $itemtagfield, $itemtagsubfield) = C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
1056
1057     my $columns_info = $self->_result->result_source->columns_info;
1058
1059     my $mss = C4::Biblio::GetMarcSubfieldStructure( $frameworkcode, { unsafe => 1 } );
1060     my $values = {};
1061     for my $column ( keys %$columns_info ) {
1062
1063         next if $column eq 'more_subfields_xml';
1064
1065         my $value = $self->$column;
1066         # Maybe we need to deal with datetime columns here, but so far we have damaged_on, itemlost_on and withdrawn_on, and they are not linked with kohafield
1067
1068         if ( not defined $value or $value eq "" ) {
1069             $values->{$column} = $value;
1070             next;
1071         }
1072
1073         my $subfield =
1074           exists $mss->{"items.$column"}
1075           ? @{ $mss->{"items.$column"} }[0] # Should we deal with several subfields??
1076           : undef;
1077
1078         $values->{$column} =
1079             $subfield
1080           ? $subfield->{authorised_value}
1081               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1082                   $subfield->{tagsubfield}, $value, '', $tagslib )
1083               : $value
1084           : $value;
1085     }
1086
1087     my $marc_more=
1088       $self->more_subfields_xml
1089       ? MARC::Record->new_from_xml( $self->more_subfields_xml, 'UTF-8' )
1090       : undef;
1091
1092     my $more_values;
1093     if ( $marc_more ) {
1094         my ( $field ) = $marc_more->fields;
1095         for my $sf ( $field->subfields ) {
1096             my $subfield_code = $sf->[0];
1097             my $value = $sf->[1];
1098             my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
1099             next unless $subfield; # We have the value but it's not mapped, data lose! No regression however.
1100             $value =
1101               $subfield->{authorised_value}
1102               ? C4::Biblio::GetAuthorisedValueDesc( $itemtagfield,
1103                 $subfield->{tagsubfield}, $value, '', $tagslib )
1104               : $value;
1105
1106             push @{$more_values->{$subfield_code}}, $value;
1107         }
1108
1109         while ( my ( $k, $v ) = each %$more_values ) {
1110             $values->{$k} = join ' | ', @$v;
1111         }
1112     }
1113
1114     return $values;
1115 }
1116
1117 =head3 additional_attributes
1118
1119     my $attributes = $item->additional_attributes;
1120     $attributes->{k} = 'new k';
1121     $item->update({ more_subfields => $attributes->to_marcxml });
1122
1123 Returns a Koha::Item::Attributes object that represents the non-mapped
1124 attributes for this item.
1125
1126 =cut
1127
1128 sub additional_attributes {
1129     my ($self) = @_;
1130
1131     return Koha::Item::Attributes->new_from_marcxml(
1132         $self->more_subfields_xml,
1133     );
1134 }
1135
1136 =head3 _set_found_trigger
1137
1138     $self->_set_found_trigger
1139
1140 Finds the most recent lost item charge for this item and refunds the patron
1141 appropriately, taking into account any payments or writeoffs already applied
1142 against the charge.
1143
1144 Internal function, not exported, called only by Koha::Item->store.
1145
1146 =cut
1147
1148 sub _set_found_trigger {
1149     my ( $self, $pre_mod_item ) = @_;
1150
1151     # Reverse any lost item charges if necessary.
1152     my $no_refund_after_days =
1153       C4::Context->preference('NoRefundOnLostReturnedItemsAge');
1154     if ($no_refund_after_days) {
1155         my $today = dt_from_string();
1156         my $lost_age_in_days =
1157           dt_from_string( $pre_mod_item->itemlost_on )->delta_days($today)
1158           ->in_units('days');
1159
1160         return $self unless $lost_age_in_days < $no_refund_after_days;
1161     }
1162
1163     my $lost_proc_return_policy = Koha::CirculationRules->get_lostreturn_policy(
1164         {
1165             item          => $self,
1166             return_branch => C4::Context->userenv
1167             ? C4::Context->userenv->{'branch'}
1168             : undef,
1169         }
1170       );
1171     my $lostreturn_policy = $lost_proc_return_policy->{lostreturn};
1172
1173     if ( $lostreturn_policy ) {
1174
1175         # refund charge made for lost book
1176         my $lost_charge = Koha::Account::Lines->search(
1177             {
1178                 itemnumber      => $self->itemnumber,
1179                 debit_type_code => 'LOST',
1180                 status          => [ undef, { '<>' => 'FOUND' } ]
1181             },
1182             {
1183                 order_by => { -desc => [ 'date', 'accountlines_id' ] },
1184                 rows     => 1
1185             }
1186         )->single;
1187
1188         if ( $lost_charge ) {
1189
1190             my $patron = $lost_charge->patron;
1191             if ( $patron ) {
1192
1193                 my $account = $patron->account;
1194
1195                 # Credit outstanding amount
1196                 my $credit_total = $lost_charge->amountoutstanding;
1197
1198                 # Use cases
1199                 if (
1200                     $lost_charge->amount > $lost_charge->amountoutstanding &&
1201                     $lostreturn_policy ne "refund_unpaid"
1202                 ) {
1203                     # some amount has been cancelled. collect the offsets that are not writeoffs
1204                     # this works because the only way to subtract from this kind of a debt is
1205                     # using the UI buttons 'Pay' and 'Write off'
1206
1207                     # We don't credit any payments if return policy is
1208                     # "refund_unpaid"
1209                     #
1210                     # In that case only unpaid/outstanding amount
1211                     # will be credited which settles the debt without
1212                     # creating extra credits
1213
1214                     my $credit_offsets = $lost_charge->debit_offsets(
1215                         {
1216                             'credit_id'               => { '!=' => undef },
1217                             'credit.credit_type_code' => { '!=' => 'Writeoff' }
1218                         },
1219                         { join => 'credit' }
1220                     );
1221
1222                     my $total_to_refund = ( $credit_offsets->count > 0 ) ?
1223                         # credits are negative on the DB
1224                         $credit_offsets->total * -1 :
1225                         0;
1226                     # Credit the outstanding amount, then add what has been
1227                     # paid to create a net credit for this amount
1228                     $credit_total += $total_to_refund;
1229                 }
1230
1231                 my $credit;
1232                 if ( $credit_total > 0 ) {
1233                     my $branchcode =
1234                       C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1235                     $credit = $account->add_credit(
1236                         {
1237                             amount      => $credit_total,
1238                             description => 'Item found ' . $self->itemnumber,
1239                             type        => 'LOST_FOUND',
1240                             interface   => C4::Context->interface,
1241                             library_id  => $branchcode,
1242                             item_id     => $self->itemnumber,
1243                             issue_id    => $lost_charge->issue_id
1244                         }
1245                     );
1246
1247                     $credit->apply( { debits => [$lost_charge] } );
1248                     $self->add_message(
1249                         {
1250                             type    => 'info',
1251                             message => 'lost_refunded',
1252                             payload => { credit_id => $credit->id }
1253                         }
1254                     );
1255                 }
1256
1257                 # Update the account status
1258                 $lost_charge->status('FOUND');
1259                 $lost_charge->store();
1260
1261                 # Reconcile balances if required
1262                 if ( C4::Context->preference('AccountAutoReconcile') ) {
1263                     $account->reconcile_balance;
1264                 }
1265             }
1266         }
1267
1268         # possibly restore fine for lost book
1269         my $lost_overdue = Koha::Account::Lines->search(
1270             {
1271                 itemnumber      => $self->itemnumber,
1272                 debit_type_code => 'OVERDUE',
1273                 status          => 'LOST'
1274             },
1275             {
1276                 order_by => { '-desc' => 'date' },
1277                 rows     => 1
1278             }
1279         )->single;
1280         if ( $lostreturn_policy eq 'restore' && $lost_overdue ) {
1281
1282             my $patron = $lost_overdue->patron;
1283             if ($patron) {
1284                 my $account = $patron->account;
1285
1286                 # Update status of fine
1287                 $lost_overdue->status('FOUND')->store();
1288
1289                 # Find related forgive credit
1290                 my $refund = $lost_overdue->credits(
1291                     {
1292                         credit_type_code => 'FORGIVEN',
1293                         itemnumber       => $self->itemnumber,
1294                         status           => [ { '!=' => 'VOID' }, undef ]
1295                     },
1296                     { order_by => { '-desc' => 'date' }, rows => 1 }
1297                 )->single;
1298
1299                 if ( $refund ) {
1300                     # Revert the forgive credit
1301                     $refund->void({ interface => 'trigger' });
1302                     $self->add_message(
1303                         {
1304                             type    => 'info',
1305                             message => 'lost_restored',
1306                             payload => { refund_id => $refund->id }
1307                         }
1308                     );
1309                 }
1310
1311                 # Reconcile balances if required
1312                 if ( C4::Context->preference('AccountAutoReconcile') ) {
1313                     $account->reconcile_balance;
1314                 }
1315             }
1316
1317         } elsif ( $lostreturn_policy eq 'charge' && ( $lost_overdue || $lost_charge ) ) {
1318             $self->add_message(
1319                 {
1320                     type    => 'info',
1321                     message => 'lost_charge',
1322                 }
1323             );
1324         }
1325     }
1326
1327     my $processingreturn_policy = $lost_proc_return_policy->{processingreturn};
1328
1329     if ( $processingreturn_policy ) {
1330
1331         # refund processing charge made for lost book
1332         my $processing_charge = Koha::Account::Lines->search(
1333             {
1334                 itemnumber      => $self->itemnumber,
1335                 debit_type_code => 'PROCESSING',
1336                 status          => [ undef, { '<>' => 'FOUND' } ]
1337             },
1338             {
1339                 order_by => { -desc => [ 'date', 'accountlines_id' ] },
1340                 rows     => 1
1341             }
1342         )->single;
1343
1344         if ( $processing_charge ) {
1345
1346             my $patron = $processing_charge->patron;
1347             if ( $patron ) {
1348
1349                 my $account = $patron->account;
1350
1351                 # Credit outstanding amount
1352                 my $credit_total = $processing_charge->amountoutstanding;
1353
1354                 # Use cases
1355                 if (
1356                     $processing_charge->amount > $processing_charge->amountoutstanding &&
1357                     $processingreturn_policy ne "refund_unpaid"
1358                 ) {
1359                     # some amount has been cancelled. collect the offsets that are not writeoffs
1360                     # this works because the only way to subtract from this kind of a debt is
1361                     # using the UI buttons 'Pay' and 'Write off'
1362
1363                     # We don't credit any payments if return policy is
1364                     # "refund_unpaid"
1365                     #
1366                     # In that case only unpaid/outstanding amount
1367                     # will be credited which settles the debt without
1368                     # creating extra credits
1369
1370                     my $credit_offsets = $processing_charge->debit_offsets(
1371                         {
1372                             'credit_id'               => { '!=' => undef },
1373                             'credit.credit_type_code' => { '!=' => 'Writeoff' }
1374                         },
1375                         { join => 'credit' }
1376                     );
1377
1378                     my $total_to_refund = ( $credit_offsets->count > 0 ) ?
1379                         # credits are negative on the DB
1380                         $credit_offsets->total * -1 :
1381                         0;
1382                     # Credit the outstanding amount, then add what has been
1383                     # paid to create a net credit for this amount
1384                     $credit_total += $total_to_refund;
1385                 }
1386
1387                 my $credit;
1388                 if ( $credit_total > 0 ) {
1389                     my $branchcode =
1390                       C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1391                     $credit = $account->add_credit(
1392                         {
1393                             amount      => $credit_total,
1394                             description => 'Item found ' . $self->itemnumber,
1395                             type        => 'PROCESSING_FOUND',
1396                             interface   => C4::Context->interface,
1397                             library_id  => $branchcode,
1398                             item_id     => $self->itemnumber,
1399                             issue_id    => $processing_charge->issue_id
1400                         }
1401                     );
1402
1403                     $credit->apply( { debits => [$processing_charge] } );
1404                     $self->add_message(
1405                         {
1406                             type    => 'info',
1407                             message => 'processing_refunded',
1408                             payload => { credit_id => $credit->id }
1409                         }
1410                     );
1411                 }
1412
1413                 # Update the account status
1414                 $processing_charge->status('FOUND');
1415                 $processing_charge->store();
1416
1417                 # Reconcile balances if required
1418                 if ( C4::Context->preference('AccountAutoReconcile') ) {
1419                     $account->reconcile_balance;
1420                 }
1421             }
1422         }
1423     }
1424
1425     return $self;
1426 }
1427
1428 =head3 public_read_list
1429
1430 This method returns the list of publicly readable database fields for both API and UI output purposes
1431
1432 =cut
1433
1434 sub public_read_list {
1435     return [
1436         'itemnumber',     'biblionumber',    'homebranch',
1437         'holdingbranch',  'location',        'collectioncode',
1438         'itemcallnumber', 'copynumber',      'enumchron',
1439         'barcode',        'dateaccessioned', 'itemnotes',
1440         'onloan',         'uri',             'itype',
1441         'notforloan',     'damaged',         'itemlost',
1442         'withdrawn',      'restricted'
1443     ];
1444 }
1445
1446 =head3 to_api
1447
1448 Overloaded to_api method to ensure item-level itypes is adhered to.
1449
1450 =cut
1451
1452 sub to_api {
1453     my ($self, $params) = @_;
1454
1455     my $response = $self->SUPER::to_api($params);
1456     my $overrides = {};
1457
1458     $overrides->{effective_item_type_id} = $self->effective_itemtype;
1459     $overrides->{effective_not_for_loan_status} = $self->notforloan ? $self->notforloan : $self->itemtype->notforloan;
1460
1461     return { %$response, %$overrides };
1462 }
1463
1464 =head3 to_api_mapping
1465
1466 This method returns the mapping for representing a Koha::Item object
1467 on the API.
1468
1469 =cut
1470
1471 sub to_api_mapping {
1472     return {
1473         itemnumber               => 'item_id',
1474         biblionumber             => 'biblio_id',
1475         biblioitemnumber         => undef,
1476         barcode                  => 'external_id',
1477         dateaccessioned          => 'acquisition_date',
1478         booksellerid             => 'acquisition_source',
1479         homebranch               => 'home_library_id',
1480         price                    => 'purchase_price',
1481         replacementprice         => 'replacement_price',
1482         replacementpricedate     => 'replacement_price_date',
1483         datelastborrowed         => 'last_checkout_date',
1484         datelastseen             => 'last_seen_date',
1485         stack                    => undef,
1486         notforloan               => 'not_for_loan_status',
1487         damaged                  => 'damaged_status',
1488         damaged_on               => 'damaged_date',
1489         itemlost                 => 'lost_status',
1490         itemlost_on              => 'lost_date',
1491         withdrawn                => 'withdrawn',
1492         withdrawn_on             => 'withdrawn_date',
1493         itemcallnumber           => 'callnumber',
1494         coded_location_qualifier => 'coded_location_qualifier',
1495         issues                   => 'checkouts_count',
1496         renewals                 => 'renewals_count',
1497         reserves                 => 'holds_count',
1498         restricted               => 'restricted_status',
1499         itemnotes                => 'public_notes',
1500         itemnotes_nonpublic      => 'internal_notes',
1501         holdingbranch            => 'holding_library_id',
1502         timestamp                => 'timestamp',
1503         location                 => 'location',
1504         permanent_location       => 'permanent_location',
1505         onloan                   => 'checked_out_date',
1506         cn_source                => 'call_number_source',
1507         cn_sort                  => 'call_number_sort',
1508         ccode                    => 'collection_code',
1509         materials                => 'materials_notes',
1510         uri                      => 'uri',
1511         itype                    => 'item_type_id',
1512         more_subfields_xml       => 'extended_subfields',
1513         enumchron                => 'serial_issue_number',
1514         copynumber               => 'copy_number',
1515         stocknumber              => 'inventory_number',
1516         new_status               => 'new_status',
1517         deleted_on               => undef,
1518     };
1519 }
1520
1521 =head3 itemtype
1522
1523     my $itemtype = $item->itemtype;
1524
1525     Returns Koha object for effective itemtype
1526
1527 =cut
1528
1529 sub itemtype {
1530     my ( $self ) = @_;
1531
1532     return Koha::ItemTypes->find( $self->effective_itemtype );
1533 }
1534
1535 =head3 orders
1536
1537   my $orders = $item->orders();
1538
1539 Returns a Koha::Acquisition::Orders object
1540
1541 =cut
1542
1543 sub orders {
1544     my ( $self ) = @_;
1545
1546     my $orders = $self->_result->item_orders;
1547     return Koha::Acquisition::Orders->_new_from_dbic($orders);
1548 }
1549
1550 =head3 tracked_links
1551
1552   my $tracked_links = $item->tracked_links();
1553
1554 Returns a Koha::TrackedLinks object
1555
1556 =cut
1557
1558 sub tracked_links {
1559     my ( $self ) = @_;
1560
1561     my $tracked_links = $self->_result->linktrackers;
1562     return Koha::TrackedLinks->_new_from_dbic($tracked_links);
1563 }
1564
1565 =head3 move_to_biblio
1566
1567   $item->move_to_biblio($to_biblio[, $params]);
1568
1569 Move the item to another biblio and update any references in other tables.
1570
1571 The final optional parameter, C<$params>, is expected to contain the
1572 'skip_record_index' key, which is relayed down to Koha::Item->store.
1573 There it prevents calling index_records, which takes most of the
1574 time in batch adds/deletes. The caller must take care of calling
1575 index_records separately.
1576
1577 $params:
1578     skip_record_index => 1|0
1579
1580 Returns undef if the move failed or the biblionumber of the destination record otherwise
1581
1582 =cut
1583
1584 sub move_to_biblio {
1585     my ( $self, $to_biblio, $params ) = @_;
1586
1587     $params //= {};
1588
1589     return if $self->biblionumber == $to_biblio->biblionumber;
1590
1591     my $from_biblionumber = $self->biblionumber;
1592     my $to_biblionumber = $to_biblio->biblionumber;
1593
1594     # Own biblionumber and biblioitemnumber
1595     $self->set({
1596         biblionumber => $to_biblionumber,
1597         biblioitemnumber => $to_biblio->biblioitem->biblioitemnumber
1598     })->store({ skip_record_index => $params->{skip_record_index} });
1599
1600     unless ($params->{skip_record_index}) {
1601         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
1602         $indexer->index_records( $from_biblionumber, "specialUpdate", "biblioserver" );
1603     }
1604
1605     # Acquisition orders
1606     $self->orders->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1607
1608     # Holds
1609     $self->holds->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1610
1611     # hold_fill_target (there's no Koha object available yet)
1612     my $hold_fill_target = $self->_result->hold_fill_target;
1613     if ($hold_fill_target) {
1614         $hold_fill_target->update({ biblionumber => $to_biblionumber });
1615     }
1616
1617     # tmp_holdsqueues - Can't update with DBIx since the table is missing a primary key
1618     # and can't even fake one since the significant columns are nullable.
1619     my $storage = $self->_result->result_source->storage;
1620     $storage->dbh_do(
1621         sub {
1622             my ($storage, $dbh, @cols) = @_;
1623
1624             $dbh->do("UPDATE tmp_holdsqueue SET biblionumber=? WHERE itemnumber=?", undef, $to_biblionumber, $self->itemnumber);
1625         }
1626     );
1627
1628     # tracked_links
1629     $self->tracked_links->update({ biblionumber => $to_biblionumber }, { no_triggers => 1 });
1630
1631     return $to_biblionumber;
1632 }
1633
1634 =head3 bundle_items
1635
1636   my $bundle_items = $item->bundle_items;
1637
1638 Returns the items associated with this bundle
1639
1640 =cut
1641
1642 sub bundle_items {
1643     my ($self) = @_;
1644
1645     if ( !$self->{_bundle_items_cached} ) {
1646         my $bundle_items = Koha::Items->search(
1647             { 'item_bundles_item.host' => $self->itemnumber },
1648             { join                     => 'item_bundles_item' } );
1649         $self->{_bundle_items}        = $bundle_items;
1650         $self->{_bundle_items_cached} = 1;
1651     }
1652
1653     return $self->{_bundle_items};
1654 }
1655
1656 =head3 is_bundle
1657
1658   my $is_bundle = $item->is_bundle;
1659
1660 Returns whether the item is a bundle or not
1661
1662 =cut
1663
1664 sub is_bundle {
1665     my ($self) = @_;
1666     return $self->bundle_items->count ? 1 : 0;
1667 }
1668
1669 =head3 bundle_host
1670
1671   my $bundle = $item->bundle_host;
1672
1673 Returns the bundle item this item is attached to
1674
1675 =cut
1676
1677 sub bundle_host {
1678     my ($self) = @_;
1679
1680     my $bundle_items_rs = $self->_result->item_bundles_item;
1681     return unless $bundle_items_rs;
1682     return Koha::Item->_new_from_dbic($bundle_items_rs->host);
1683 }
1684
1685 =head3 in_bundle
1686
1687   my $in_bundle = $item->in_bundle;
1688
1689 Returns whether this item is currently in a bundle
1690
1691 =cut
1692
1693 sub in_bundle {
1694     my ($self) = @_;
1695     return $self->bundle_host ? 1 : 0;
1696 }
1697
1698 =head3 add_to_bundle
1699
1700   my $link = $item->add_to_bundle($bundle_item);
1701
1702 Adds the bundle_item passed to this item
1703
1704 =cut
1705
1706 sub add_to_bundle {
1707     my ( $self, $bundle_item, $options ) = @_;
1708
1709     $options //= {};
1710
1711     Koha::Exceptions::Item::Bundle::IsBundle->throw()
1712       if ( $self->itemnumber eq $bundle_item->itemnumber
1713         || $bundle_item->is_bundle
1714         || $self->in_bundle );
1715
1716     my $schema = Koha::Database->new->schema;
1717
1718     my $BundleNotLoanValue = C4::Context->preference('BundleNotLoanValue');
1719
1720     try {
1721         $schema->txn_do(
1722             sub {
1723                 my $checkout = $bundle_item->checkout;
1724                 if ($checkout) {
1725                     unless ($options->{force_checkin}) {
1726                         Koha::Exceptions::Item::Bundle::ItemIsCheckedOut->throw();
1727                     }
1728
1729                     my $branchcode = C4::Context->userenv->{'branch'};
1730                     my ($success) = C4::Circulation::AddReturn($bundle_item->barcode, $branchcode);
1731                     unless ($success) {
1732                         Koha::Exceptions::Checkin::FailedCheckin->throw();
1733                     }
1734                 }
1735
1736                 my $holds = $bundle_item->current_holds;
1737                 if ($holds->count) {
1738                     unless ($options->{ignore_holds}) {
1739                         Koha::Exceptions::Item::Bundle::ItemHasHolds->throw();
1740                     }
1741                 }
1742
1743                 $self->_result->add_to_item_bundles_hosts(
1744                     { item => $bundle_item->itemnumber } );
1745
1746                 $bundle_item->notforloan($BundleNotLoanValue)->store();
1747             }
1748         );
1749     }
1750     catch {
1751
1752         # FIXME: See if we can move the below copy/paste from Koha::Object::store into it's own class and catch at a lower level in the Schema instantiation, take inspiration from DBIx::Error
1753         if ( ref($_) eq 'DBIx::Class::Exception' ) {
1754             if ( $_->{msg} =~ /Cannot add or update a child row: a foreign key constraint fails/ ) {
1755                 # FK constraints
1756                 # FIXME: MySQL error, if we support more DB engines we should implement this for each
1757                 if ( $_->{msg} =~ /FOREIGN KEY \(`(?<column>.*?)`\)/ ) {
1758                     Koha::Exceptions::Object::FKConstraint->throw(
1759                         error     => 'Broken FK constraint',
1760                         broken_fk => $+{column}
1761                     );
1762                 }
1763             }
1764             elsif (
1765                 $_->{msg} =~ /Duplicate entry '(.*?)' for key '(?<key>.*?)'/ )
1766             {
1767                 Koha::Exceptions::Object::DuplicateID->throw(
1768                     error        => 'Duplicate ID',
1769                     duplicate_id => $+{key}
1770                 );
1771             }
1772             elsif ( $_->{msg} =~
1773 /Incorrect (?<type>\w+) value: '(?<value>.*)' for column \W?(?<property>\S+)/
1774               )
1775             {    # The optional \W in the regex might be a quote or backtick
1776                 my $type     = $+{type};
1777                 my $value    = $+{value};
1778                 my $property = $+{property};
1779                 $property =~ s/['`]//g;
1780                 Koha::Exceptions::Object::BadValue->throw(
1781                     type     => $type,
1782                     value    => $value,
1783                     property => $property =~ /(\w+\.\w+)$/
1784                     ? $1
1785                     : $property
1786                     ,    # results in table.column without quotes or backtics
1787                 );
1788             }
1789
1790             # Catch-all for foreign key breakages. It will help find other use cases
1791             $_->rethrow();
1792         }
1793         else {
1794             $_->rethrow();
1795         }
1796     };
1797 }
1798
1799 =head3 remove_from_bundle
1800
1801 Remove this item from any bundle it may have been attached to.
1802
1803 =cut
1804
1805 sub remove_from_bundle {
1806     my ($self) = @_;
1807
1808     my $bundle_item_rs = $self->_result->item_bundles_item;
1809     if ( $bundle_item_rs ) {
1810         $bundle_item_rs->delete;
1811         $self->notforloan(0)->store();
1812         return 1;
1813     }
1814     return 0;
1815 }
1816
1817 =head2 Internal methods
1818
1819 =head3 _after_item_action_hooks
1820
1821 Helper method that takes care of calling all plugin hooks
1822
1823 =cut
1824
1825 sub _after_item_action_hooks {
1826     my ( $self, $params ) = @_;
1827
1828     my $action = $params->{action};
1829
1830     Koha::Plugins->call(
1831         'after_item_action',
1832         {
1833             action  => $action,
1834             item    => $self,
1835             item_id => $self->itemnumber,
1836         }
1837     );
1838 }
1839
1840 =head3 recall
1841
1842     my $recall = $item->recall;
1843
1844 Return the relevant recall for this item
1845
1846 =cut
1847
1848 sub recall {
1849     my ( $self ) = @_;
1850     my @recalls = Koha::Recalls->search(
1851         {
1852             biblio_id => $self->biblionumber,
1853             completed => 0,
1854         },
1855         { order_by => { -asc => 'created_date' } }
1856     )->as_list;
1857     foreach my $recall (@recalls) {
1858         if ( $recall->item_level and $recall->item_id == $self->itemnumber ){
1859             return $recall;
1860         }
1861     }
1862     # no item-level recall to return, so return earliest biblio-level
1863     # FIXME: eventually this will be based on priority
1864     return $recalls[0];
1865 }
1866
1867 =head3 can_be_recalled
1868
1869     if ( $item->can_be_recalled({ patron => $patron_object }) ) # do recall
1870
1871 Does item-level checks and returns if items can be recalled by this borrower
1872
1873 =cut
1874
1875 sub can_be_recalled {
1876     my ( $self, $params ) = @_;
1877
1878     return 0 if !( C4::Context->preference('UseRecalls') );
1879
1880     # check if this item is not for loan, withdrawn or lost
1881     return 0 if ( $self->notforloan != 0 );
1882     return 0 if ( $self->itemlost != 0 );
1883     return 0 if ( $self->withdrawn != 0 );
1884
1885     # check if this item is not checked out - if not checked out, can't be recalled
1886     return 0 if ( !defined( $self->checkout ) );
1887
1888     my $patron = $params->{patron};
1889
1890     my $branchcode = C4::Context->userenv->{'branch'};
1891     if ( $patron ) {
1892         $branchcode = C4::Circulation::_GetCircControlBranch( $self->unblessed, $patron->unblessed );
1893     }
1894
1895     # Check the circulation rule for each relevant itemtype for this item
1896     my $rule = Koha::CirculationRules->get_effective_rules({
1897         branchcode => $branchcode,
1898         categorycode => $patron ? $patron->categorycode : undef,
1899         itemtype => $self->effective_itemtype,
1900         rules => [
1901             'recalls_allowed',
1902             'recalls_per_record',
1903             'on_shelf_recalls',
1904         ],
1905     });
1906
1907     # check recalls allowed has been set and is not zero
1908     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1909
1910     if ( $patron ) {
1911         # check borrower has not reached open recalls allowed limit
1912         return 0 if ( $patron->recalls->filter_by_current->count >= $rule->{recalls_allowed} );
1913
1914         # check borrower has not reach open recalls allowed per record limit
1915         return 0 if ( $patron->recalls->filter_by_current->search({ biblio_id => $self->biblionumber })->count >= $rule->{recalls_per_record} );
1916
1917         # check if this patron has already recalled this item
1918         return 0 if ( Koha::Recalls->search({ item_id => $self->itemnumber, patron_id => $patron->borrowernumber })->filter_by_current->count > 0 );
1919
1920         # check if this patron has already checked out this item
1921         return 0 if ( Koha::Checkouts->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1922
1923         # check if this patron has already reserved this item
1924         return 0 if ( Koha::Holds->search({ itemnumber => $self->itemnumber, borrowernumber => $patron->borrowernumber })->count > 0 );
1925     }
1926
1927     # check item availability
1928     # items are unavailable for recall if they are lost, withdrawn or notforloan
1929     my @items = Koha::Items->search({ biblionumber => $self->biblionumber, itemlost => 0, withdrawn => 0, notforloan => 0 })->as_list;
1930
1931     # if there are no available items at all, no recall can be placed
1932     return 0 if ( scalar @items == 0 );
1933
1934     my $checked_out_count = 0;
1935     foreach (@items) {
1936         if ( Koha::Checkouts->search({ itemnumber => $_->itemnumber })->count > 0 ){ $checked_out_count++; }
1937     }
1938
1939     # can't recall if on shelf recalls only allowed when all unavailable, but items are still available for checkout
1940     return 0 if ( $rule->{on_shelf_recalls} eq 'all' && $checked_out_count < scalar @items );
1941
1942     # can't recall if no items have been checked out
1943     return 0 if ( $checked_out_count == 0 );
1944
1945     # can recall
1946     return 1;
1947 }
1948
1949 =head3 can_be_waiting_recall
1950
1951     if ( $item->can_be_waiting_recall ) { # allocate item as waiting for recall
1952
1953 Checks item type and branch of circ rules to return whether this item can be used to fill a recall.
1954 At this point the item has already been recalled. We are now at the checkin and set waiting stage.
1955
1956 =cut
1957
1958 sub can_be_waiting_recall {
1959     my ( $self ) = @_;
1960
1961     return 0 if !( C4::Context->preference('UseRecalls') );
1962
1963     # check if this item is not for loan, withdrawn or lost
1964     return 0 if ( $self->notforloan != 0 );
1965     return 0 if ( $self->itemlost != 0 );
1966     return 0 if ( $self->withdrawn != 0 );
1967
1968     my $branchcode = $self->holdingbranch;
1969     if ( C4::Context->preference('CircControl') eq 'PickupLibrary' and C4::Context->userenv and C4::Context->userenv->{'branch'} ) {
1970         $branchcode = C4::Context->userenv->{'branch'};
1971     } else {
1972         $branchcode = ( C4::Context->preference('HomeOrHoldingBranch') eq 'homebranch' ) ? $self->homebranch : $self->holdingbranch;
1973     }
1974
1975     # Check the circulation rule for each relevant itemtype for this item
1976     my $most_relevant_recall = $self->check_recalls;
1977     my $rule = Koha::CirculationRules->get_effective_rules(
1978         {
1979             branchcode   => $branchcode,
1980             categorycode => $most_relevant_recall ? $most_relevant_recall->patron->categorycode : undef,
1981             itemtype     => $self->effective_itemtype,
1982             rules        => [ 'recalls_allowed', ],
1983         }
1984     );
1985
1986     # check recalls allowed has been set and is not zero
1987     return 0 if ( !defined($rule->{recalls_allowed}) || $rule->{recalls_allowed} == 0 );
1988
1989     # can recall
1990     return 1;
1991 }
1992
1993 =head3 check_recalls
1994
1995     my $recall = $item->check_recalls;
1996
1997 Get the most relevant recall for this item.
1998
1999 =cut
2000
2001 sub check_recalls {
2002     my ( $self ) = @_;
2003
2004     my @recalls = Koha::Recalls->search(
2005         {   biblio_id => $self->biblionumber,
2006             item_id   => [ $self->itemnumber, undef ]
2007         },
2008         { order_by => { -asc => 'created_date' } }
2009     )->filter_by_current->as_list;
2010
2011     my $recall;
2012     # iterate through relevant recalls to find the best one.
2013     # if we come across a waiting recall, use this one.
2014     # if we have iterated through all recalls and not found a waiting recall, use the first recall in the array, which should be the oldest recall.
2015     foreach my $r ( @recalls ) {
2016         if ( $r->waiting ) {
2017             $recall = $r;
2018             last;
2019         }
2020     }
2021     unless ( defined $recall ) {
2022         $recall = $recalls[0];
2023     }
2024
2025     return $recall;
2026 }
2027
2028 =head3 is_notforloan
2029
2030     my $is_notforloan = $item->is_notforloan;
2031
2032 Determine whether or not this item is "notforloan" based on
2033 the item's notforloan status or its item type
2034
2035 =cut
2036
2037 sub is_notforloan {
2038     my ( $self ) = @_;
2039     my $is_notforloan = 0;
2040
2041     if ( $self->notforloan ){
2042         $is_notforloan = 1;
2043     }
2044     else {
2045         my $itemtype = $self->itemtype;
2046         if ($itemtype){
2047             if ( $itemtype->notforloan ){
2048                 $is_notforloan = 1;
2049             }
2050         }
2051     }
2052
2053     return $is_notforloan;
2054 }
2055
2056 =head3 is_denied_renewal
2057
2058     my $is_denied_renewal = $item->is_denied_renewal;
2059
2060 Determine whether or not this item can be renewed based on the
2061 rules set in the ItemsDeniedRenewal system preference.
2062
2063 =cut
2064
2065 sub is_denied_renewal {
2066     my ( $self ) = @_;
2067
2068     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
2069     return 0 unless $denyingrules;
2070     foreach my $field (keys %$denyingrules) {
2071         my $val = $self->$field;
2072         if( !defined $val) {
2073             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
2074                 return 1;
2075             }
2076         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
2077            # If the results matches the values in the syspref
2078            # We return true if match found
2079             return 1;
2080         }
2081     }
2082     return 0;
2083 }
2084
2085 =head3 strings_map
2086
2087 Returns a map of column name to string representations including the string,
2088 the mapping type and the mapping category where appropriate.
2089
2090 Currently handles authorised value mappings, library, callnumber and itemtype
2091 expansions.
2092
2093 Accepts a param hashref where the 'public' key denotes whether we want the public
2094 or staff client strings.
2095
2096 =cut
2097
2098 sub strings_map {
2099     my ( $self, $params ) = @_;
2100
2101     my $columns_info  = $self->_result->result_source->columns_info;
2102     my $frameworkcode = $self->biblio->frameworkcode;
2103     my $tagslib       = C4::Biblio::GetMarcStructure( 1, $frameworkcode );
2104     my $mss           = C4::Biblio::GetMarcSubfieldStructure( $frameworkcode, { unsafe => 1 } );
2105
2106     my ( $itemtagfield, $itemtagsubfield ) = C4::Biblio::GetMarcFromKohaField("items.itemnumber");
2107
2108     # Hardcoded known 'authorised_value' values mapped to API codes
2109     my $code_to_type = {
2110         branches  => 'library',
2111         cn_source => 'call_number_source',
2112         itemtypes => 'item_type',
2113     };
2114
2115     # Handle not null and default values for integers and dates
2116     my $strings = {};
2117
2118     foreach my $col ( keys %{$columns_info} ) {
2119
2120         # By now, we are done with known columns, now check the framework for mappings
2121         my $field = $self->_result->result_source->name . '.' . $col;
2122
2123         # Check there's an entry in the MARC subfield structure for the field
2124         if (   exists $mss->{$field}
2125             && scalar @{ $mss->{$field} } > 0
2126             && $mss->{$field}[0]->{authorised_value} )
2127         {
2128             my $subfield = $mss->{$field}[0];
2129             my $code     = $subfield->{authorised_value};
2130
2131             my $str  = C4::Biblio::GetAuthorisedValueDesc( $itemtagfield, $subfield->{tagsubfield}, $self->$col, '', $tagslib, undef, $params->{public} );
2132             my $type = exists $code_to_type->{$code} ? $code_to_type->{$code} : 'av';
2133             $strings->{$col} = {
2134                 str  => $str,
2135                 type => $type,
2136                 ( $type eq 'av' ? ( category => $code ) : () ),
2137             };
2138         }
2139     }
2140
2141     return $strings;
2142 }
2143
2144 =head3 _type
2145
2146 =cut
2147
2148 sub _type {
2149     return 'Item';
2150 }
2151
2152 =head1 AUTHOR
2153
2154 Kyle M Hall <kyle@bywatersolutions.com>
2155
2156 =cut
2157
2158 1;