Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 use Koha::Item;
  27 use Koha::CirculationRules;
  28
  29 use base qw(Koha::Objects);
  30
  31 =head1 NAME
  32
  33 Koha::Items - Koha Item object set class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =cut
  40
  41 =head3 filter_by_for_hold
  42
  43     my $filtered_items = $items->filter_by_for_hold;
  44
  45 Return the items of the set that are *potentially* holdable
  46
  47 Caller has the responsability to call C4::Reserves::CanItemBeReserved before
  48 placing a hold on one of those items.
  49
  50 =cut
  51
  52 sub filter_by_for_hold {
  53     my ($self) = @_;
  54
  55     my @hold_not_allowed_itypes = Koha::CirculationRules->search(
  56         {
  57             rule_name    => 'holdallowed',
  58             branchcode   => undef,
  59             categorycode => undef,
  60             rule_value   => 'not_allowed',
  61         }
  62     )->get_column('itemtype');
  63
  64     return $self->search(
  65         {
  66             itemlost   => 0,
  67             withdrawn  => 0,
  68             notforloan => { '<=' => 0 }
  69             ,    # items with negative or zero notforloan value are holdable
  70             ( ! C4::Context->preference('AllowHoldsOnDamagedItems' ) ? ( damaged => 0 ) : () ),
  71             itype        => { -not_in => \@hold_not_allowed_itypes },
  72         }
  73     );
  74 }
  75
  76 =head3 filter_by_visible_in_opac
  77
  78     my $filered_items = $items->filter_by_visible_in_opac(
  79         {
  80             [ patron => $patron ]
  81         }
  82     );
  83
  84 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
  85 for the passed I<Koha::Patron> object that is passed.
  86
  87 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
  88 are honoured.
  89
  90 =cut
  91
  92 sub filter_by_visible_in_opac {
  93     my ($self, $params) = @_;
  94
  95     my $patron = $params->{patron};
  96
  97     my $result = $self;
  98
  99     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
 100     unless ( $patron and $patron->category->override_hidden_items ) {
 101         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
 102
 103         my $rules_params;
 104         foreach my $field ( keys %$rules ) {
 105             $rules_params->{$field} =
 106               [ { '-not_in' => $rules->{$field} }, undef ];
 107         }
 108
 109         $result = $result->search( $rules_params );
 110     }
 111
 112     if (C4::Context->preference('hidelostitems')) {
 113         $result = $result->filter_out_lost;
 114     }
 115
 116     return $result;
 117 }
 118
 119 =head3 filter_out_lost
 120
 121     my $filered_items = $items->filter_out_lost;
 122
 123 Returns a new resultset, containing those items that are not marked as lost.
 124
 125 =cut
 126
 127 sub filter_out_lost {
 128     my ($self) = @_;
 129
 130     my $params = { itemlost => 0 };
 131
 132     return $self->search( $params );
 133 }
 134
 135 =head2 Internal methods
 136
 137 =head3 _type
 138
 139 =cut
 140
 141 sub _type {
 142     return 'Item';
 143 }
 144
 145 =head3 object_class
 146
 147 =cut
 148
 149 sub object_class {
 150     return 'Koha::Item';
 151 }
 152
 153 =head1 AUTHOR
 154
 155 Kyle M Hall <kyle@bywatersolutions.com>
 156 Tomas Cohen Arazi <tomascohen@theke.io>
 157 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 158
 159 =cut
 160
 161 1;