Koha/Items.pm

   1 package Koha::Items;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22
  23 use Koha::Database;
  24
  25 use Koha::Item;
  26
  27 use base qw(Koha::Objects);
  28
  29 use Koha::SearchEngine::Indexer;
  30
  31 =head1 NAME
  32
  33 Koha::Items - Koha Item object set class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =cut
  40
  41 =head3 filter_by_for_hold
  42
  43     my $filtered_items = $items->filter_by_for_hold;
  44
  45 Return the items of the set that are holdable
  46
  47 =cut
  48
  49 sub filter_by_for_hold {
  50     my ($self) = @_;
  51
  52     return $self->search(
  53         {
  54             itemlost   => 0,
  55             withdrawn  => 0,
  56             notforloan => { '<=' => 0 }
  57             ,    # items with negative or zero notforloan value are holdable
  58             ( C4::Context->preference('AllowHoldsOnDamagedItems') ? ( damaged => 0 ) : () ),
  59         }
  60     );
  61 }
  62
  63 =head3 filter_by_visible_in_opac
  64
  65     my $filered_items = $items->filter_by_visible_in_opac(
  66         {
  67             [ patron => $patron ]
  68         }
  69     );
  70
  71 Returns a new resultset, containing those items that are not expected to be hidden in OPAC
  72 for the passed I<Koha::Patron> object that is passed.
  73
  74 The I<OpacHiddenItems>, I<hidelostitems> and I<OpacHiddenItemsExceptions> system preferences
  75 are honoured.
  76
  77 =cut
  78
  79 sub filter_by_visible_in_opac {
  80     my ($self, $params) = @_;
  81
  82     my $patron = $params->{patron};
  83
  84     my $result = $self;
  85
  86     # Filter out OpacHiddenItems unless disabled by OpacHiddenItemsExceptions
  87     unless ( $patron and $patron->category->override_hidden_items ) {
  88         my $rules = C4::Context->yaml_preference('OpacHiddenItems') // {};
  89
  90         my $rules_params;
  91         foreach my $field ( keys %$rules ) {
  92             $rules_params->{$field} =
  93               [ { '-not_in' => $rules->{$field} }, undef ];
  94         }
  95
  96         $result = $result->search( $rules_params );
  97     }
  98
  99     if (C4::Context->preference('hidelostitems')) {
 100         $result = $result->filter_out_lost;
 101     }
 102
 103     return $result;
 104 }
 105
 106 =head3 filter_out_lost
 107
 108     my $filered_items = $items->filter_out_lost;
 109
 110 Returns a new resultset, containing those items that are not marked as lost.
 111
 112 =cut
 113
 114 sub filter_out_lost {
 115     my ($self) = @_;
 116
 117     my $params = { itemlost => 0 };
 118
 119     return $self->search( $params );
 120 }
 121
 122 =head3 move_to_biblio
 123
 124  $items->move_to_biblio($to_biblio);
 125
 126 Move items to a given biblio.
 127
 128 =cut
 129
 130 sub move_to_biblio {
 131     my ( $self, $to_biblio ) = @_;
 132
 133     my $biblionumbers = { $to_biblio->biblionumber => 1 };
 134     while ( my $item = $self->next() ) {
 135         $biblionumbers->{ $item->biblionumber } = 1;
 136         $item->move_to_biblio( $to_biblio, { skip_record_index => 1 } );
 137     }
 138     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 139     for my $biblionumber ( keys %{$biblionumbers} ) {
 140         $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 141     }
 142 }
 143
 144
 145 =head2 Internal methods
 146
 147 =head3 _type
 148
 149 =cut
 150
 151 sub _type {
 152     return 'Item';
 153 }
 154
 155 =head3 object_class
 156
 157 =cut
 158
 159 sub object_class {
 160     return 'Koha::Item';
 161 }
 162
 163 =head1 AUTHOR
 164
 165 Kyle M Hall <kyle@bywatersolutions.com>
 166 Tomas Cohen Arazi <tomascohen@theke.io>
 167 Martin Renvoize <martin.renvoize@ptfs-europe.com>
 168
 169 =cut
 170
 171 1;