circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use URI::Escape qw( uri_escape_utf8 );
  30 use DateTime;
  31 use DateTime::Duration;
  32 use Scalar::Util qw( blessed looks_like_number );
  33 use Try::Tiny;
  34 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  35 use C4::Auth qw( get_session get_template_and_user );
  36 use C4::Koha;
  37 use C4::Circulation qw( barcodedecode CanBookBeIssued AddIssue AddReturn );
  38 use C4::Members;
  39 use C4::Biblio qw( TransformMarcToKoha );
  40 use C4::Search qw( new_record_from_zebra );
  41 use C4::Reserves qw( ModReserveAffect );
  42 use Koha::Holds;
  43 use C4::Context;
  44 use CGI::Session;
  45 use Koha::AuthorisedValues;
  46 use Koha::CsvProfiles;
  47 use Koha::Patrons;
  48 use Koha::DateUtils qw( dt_from_string );
  49 use Koha::Patron::Restriction::Types;
  50 use Koha::Plugins;
  51 use Koha::Database;
  52 use Koha::BiblioFrameworks;
  53 use Koha::Items;
  54 use Koha::SearchEngine;
  55 use Koha::SearchEngine::Search;
  56 use Koha::Patron::Modifications;
  57 use Koha::Token;
  58
  59 use List::MoreUtils qw( uniq );
  60
  61 #
  62 # PARAMETERS READING
  63 #
  64 my $query = CGI->new;
  65
  66 my $borrowernumber = $query->param('borrowernumber');
  67 my $barcodes       = [];
  68 my $barcode        = $query->param('barcode');
  69
  70
  71 # Barcode given by user could be '0'
  72 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
  73     $barcodes = [ $barcode ];
  74 } else {
  75     my $filefh = $query->upload('uploadfile');
  76     if ( $filefh ) {
  77         while ( my $content = <$filefh> ) {
  78             $content =~ s/[\r\n]*$//g;
  79             push @$barcodes, $content if $content;
  80         }
  81     } elsif ( my $list = $query->param('barcodelist') ) {
  82         push @$barcodes, split( /\s\n/, $list );
  83         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
  84     } else {
  85         @$barcodes = $query->multi_param('barcodes');
  86     }
  87 }
  88 $barcodes = [ uniq @$barcodes ];
  89
  90 my $template_name = q|circ/circulation.tt|;
  91 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
  92 my $batch = $query->param('batch');
  93 my $batch_allowed = 0;
  94 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
  95     $template_name = q|circ/circulation_batch_checkouts.tt|;
  96     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
  97     my $categorycode = $patron->categorycode;
  98     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
  99         $batch_allowed = 1;
 100     } else {
 101         $barcodes = [];
 102     }
 103 }
 104
 105 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 106     {
 107         template_name   => $template_name,
 108         query           => $query,
 109         type            => "intranet",
 110         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 111     }
 112 );
 113
 114 my $op                      = $query->param('op');
 115 my $override_high_holds     = $query->param('override_high_holds');
 116 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
 117
 118 my $sessionID = $query->cookie("CGISESSID");
 119 my $session   = get_session($sessionID);
 120
 121 my $userenv = C4::Context->userenv;
 122 my $branch  = $userenv->{'branch'} // '';
 123 my $desk_id = $userenv->{"desk_id"} || '';
 124
 125 my $findborrower;
 126 my $autoswitched;
 127
 128 if ( C4::Context->preference("AutoSwitchPatron") && $barcode ) {
 129     my $new_barcode = $barcode;
 130     Koha::Plugins->call( 'patron_barcode_transform', \$new_barcode );
 131     if ( Koha::Patrons->search( { cardnumber => $new_barcode } )->count() > 0 ) {
 132         $findborrower = $barcode;
 133         undef $barcode;
 134         undef $borrowernumber;
 135         $autoswitched = 1;
 136     }
 137 }
 138 $findborrower ||= $query->param('findborrower') || q{};
 139 $findborrower =~ s|,| |g;
 140
 141 if ( $op eq 'cud-confirm_hold' && $query->param('confirm_hold') ) {
 142     my $reserve_id          = $query->param('confirm_hold');
 143     my $hold_branch         = $query->param('hold_branch');
 144     my $hold_itemnumber     = $query->param('hold_itemnumber');
 145     my $hold_borrowernumber = $query->param('hold_borrowernumber');
 146     my $diffBranchSend      = ( $branch ne $hold_branch );
 147
 148     # diffBranchSend tells ModReserveAffect whether document is expected in this library or not,
 149     # i.e., whether to apply waiting status
 150     ModReserveAffect( $hold_itemnumber, $hold_borrowernumber, $diffBranchSend, $reserve_id, $desk_id );
 151 }
 152
 153
 154 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
 155
 156 my $force_allow_issue = $query->param('forceallow') || 0;
 157 if (!C4::Auth::haspermission( $userenv->{id} , { circulate => 'force_checkout' } )) {
 158     $force_allow_issue = 0;
 159 }
 160 my $onsite_checkout = $query->param('onsite_checkout');
 161
 162 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
 163     $template->param(onsite_checkout => $onsite_checkout);
 164 }
 165
 166 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 167 our %renew_failed = ();
 168 for (@failedrenews) { $renew_failed{$_} = 1; }
 169
 170 my @failedreturns = $query->multi_param('failedreturn');
 171 our %return_failed = ();
 172 for (@failedreturns) { $return_failed{$_} = 1; }
 173
 174 for my $barcode ( @$barcodes ) {
 175     $barcode = barcodedecode( $barcode ) if $barcode;
 176 }
 177
 178 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 179 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 180 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 181 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 182     undef $restoreduedatespec;
 183 }
 184 my $issueconfirmed = $query->param('issueconfirmed');
 185 my $cancelreserve  = $query->param('cancelreserve');
 186 my $cancel_recall  = $query->param('cancel_recall');
 187 my $recall_id      = $query->param('recall_id');
 188 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 189 my $charges        = $query->param('charges') || q{};
 190
 191 # Check if stickyduedate is turned off
 192 if ( @$barcodes ) {
 193     # was stickyduedate loaded from session?
 194     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 195         $session->clear( 'stickyduedate' );
 196         $stickyduedate  = $query->param('stickyduedate');
 197         $duedatespec    = $query->param('duedatespec');
 198     }
 199     $session->param('auto_renew', scalar $query->param('auto_renew'));
 200 }
 201 else {
 202     $session->clear('auto_renew');
 203 }
 204
 205 $template->param( auto_renew => $session->param('auto_renew') );
 206
 207 my ($datedue,$invalidduedate);
 208
 209 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 210 if( $onsite_checkout && !$duedatespec_allow ) {
 211     $datedue = dt_from_string()->truncate(to => 'day');
 212     $datedue->set_hour(23);
 213     $datedue->set_minute(59);
 214 } elsif( $duedatespec_allow ) {
 215     if ( $duedatespec ) {
 216         $datedue = eval { dt_from_string( $duedatespec ) };
 217         if (! $datedue ) {
 218             $invalidduedate = 1;
 219             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 220         }
 221     }
 222 }
 223 my $reduced_datedue = $query->param('reduceddue');
 224 if ( $reduced_datedue ) {
 225     $datedue = dt_from_string( $reduced_datedue );
 226 }
 227
 228 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 229 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 230     $template->param(
 231         PAYCHARGES     => 'yes',
 232         borrowernumber => $borrowernumber
 233     );
 234 }
 235
 236 #
 237 # STEP 2 : FIND BORROWER
 238 # if there is a list of find borrowers....
 239 #
 240 my $message;
 241 if ($findborrower) {
 242     Koha::Plugins->call( 'patron_barcode_transform', \$findborrower );
 243     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 244     if ( $patron ) {
 245         $borrowernumber = $patron->borrowernumber;
 246     } else {
 247         print $query->redirect( "/cgi-bin/koha/members/member.pl?quicksearch=1&circsearch=1&searchmember=" . uri_escape_utf8($findborrower) );
 248         exit;
 249     }
 250 }
 251
 252 # get the borrower information.....
 253 my $balance = 0;
 254 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 255 if ($patron) {
 256
 257     $template->param( borrowernumber => $patron->borrowernumber );
 258     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 259
 260     my $overdues = $patron->overdues;
 261     my $issues = $patron->checkouts;
 262     $balance = $patron->account->balance;
 263
 264
 265     # if the expiry date is before today ie they have expired
 266     if ( $patron->is_expired ) {
 267         #borrowercard expired, no issues
 268         $template->param(
 269             noissues => ($force_allow_issue) ? 0 : "1",
 270             forceallow => $force_allow_issue,
 271             expired => "1",
 272         );
 273     }
 274     # check for NotifyBorrowerDeparture
 275     elsif ( $patron->is_going_to_expire ) {
 276         # borrower card soon to expire warn librarian
 277         $template->param( "warndeparture" => $patron->dateexpiry ,
 278                         );
 279         if (C4::Context->preference('ReturnBeforeExpiry')){
 280             $template->param("returnbeforeexpiry" => 1);
 281         }
 282     }
 283     $template->param(
 284         overduecount => $overdues->count,
 285         issuecount   => $issues->count,
 286         finetotal    => $balance,
 287     );
 288
 289     if ( $patron and $patron->is_debarred ) {
 290         $template->param(
 291             'userdebarred'    => $patron->debarred,
 292             'debarredcomment' => $patron->debarredcomment,
 293             'debarredsince'   => $patron->restrictions->search()->single->created,
 294         );
 295
 296         if ( $patron->debarred ne "9999-12-31" ) {
 297             $template->param( 'userdebarreddate' => $patron->debarred );
 298         }
 299     }
 300
 301     # Calculate and display patron's age
 302     if ( !$patron->is_valid_age ) {
 303         $template->param( age_limitations => 1 );
 304         $template->param( age_low => $patron->category->dateofbirthrequired );
 305         $template->param( age_high => $patron->category->upperagelimit );
 306     }
 307
 308 }
 309
 310 #
 311 # STEP 3 : ISSUING
 312 #
 313 #
 314 if (@$barcodes && $op eq 'cud-checkout') {
 315     my $checkout_infos;
 316     for my $barcode ( @$barcodes ) {
 317
 318         my $template_params = {
 319             barcode         => $barcode,
 320             onsite_checkout => $onsite_checkout,
 321         };
 322
 323         # always check for blockers on issuing
 324         my ( $issuingimpossible, $needsconfirmation, $alerts, $messages );
 325         try {
 326             ( $issuingimpossible, $needsconfirmation, $alerts, $messages ) = CanBookBeIssued(
 327                 $patron,
 328                 $barcode, $datedue,
 329                 $inprocess,
 330                 undef,
 331                 {
 332                     onsite_checkout     => $onsite_checkout,
 333                     override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 334                 }
 335             );
 336         } catch {
 337             die $_ unless blessed $_ && $_->can('rethrow');
 338
 339             if ( $_->isa('Koha::Exceptions::Calendar::NoOpenDays') ) {
 340                 $issuingimpossible = { NO_OPEN_DAYS => 1 };
 341             } else {
 342                 $_->rethrow;
 343             }
 344         };
 345
 346     my $blocker = $invalidduedate ? 1 : 0;
 347
 348     $template_params->{alert} = $alerts;
 349     $template_params->{messages} = $messages;
 350
 351     my $item = Koha::Items->find({ barcode => $barcode });
 352
 353     my $biblio;
 354     if ( $item ) {
 355         $biblio = $item->biblio;
 356     }
 357
 358     if ( $issuingimpossible->{'STATS'} ) {
 359         $template->param( STATS => 1 );
 360
 361         if ( $item->onloan ) {
 362             my ( $stats_return, $stats_messages, $stats_iteminformation, $stats_borrower ) =
 363                 AddReturn( $item->barcode, C4::Context->userenv->{'branch'}, undef, undef, 1 );
 364
 365             $template->param(
 366                 CHECKEDIN => $stats_return,
 367                 MESSAGES  => $stats_messages,
 368                 ITEM      => $stats_iteminformation,
 369                 BORROWER  => $stats_borrower,
 370             );
 371         }
 372     }
 373     # Fix for bug 7494: optional checkout-time fallback search for a book
 374
 375     if ( $issuingimpossible->{'UNKNOWN_BARCODE'}
 376         && C4::Context->preference("itemBarcodeFallbackSearch")
 377         && not $batch
 378     )
 379     {
 380      $template_params->{FALLBACK} = 1;
 381
 382         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 383         my $query = "kw=" . $barcode;
 384         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 385
 386         # if multiple hits, offer options to librarian
 387         if ( $total_hits > 0 ) {
 388             my @barcodes;
 389             foreach my $hit ( @{$results} ) {
 390                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
 391                   TransformMarcToKoha({ record => C4::Search::new_record_from_zebra('biblioserver',$hit) });
 392
 393                 # offer all barcodes individually
 394                 if ( $chosen->{barcode} ) {
 395                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
 396                 }
 397             }
 398             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
 399             $template_params->{options} = $items;
 400         }
 401     }
 402
 403     # Only some errors will block when performing forced onsite checkout,
 404     # for other cases all errors will block
 405     my @blocking_error_codes =
 406         ( $onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce") )
 407         ? qw( UNKNOWN_BARCODE NO_OPEN_DAYS )
 408         : ( keys %$issuingimpossible );
 409
 410     if ( $issuingimpossible->{BOOKED_TO_ANOTHER} ) {
 411         $template_params->{BOOKED_TO_ANOTHER} = $issuingimpossible->{BOOKED_TO_ANOTHER};
 412         $template_params->{IMPOSSIBLE}        = 1;
 413         $blocker                              = 1;
 414     }
 415
 416     foreach my $code ( @blocking_error_codes ) {
 417         if ($issuingimpossible->{$code}) {
 418             $template_params->{$code} = $issuingimpossible->{$code};
 419
 420             $template_params->{IMPOSSIBLE} = 1;
 421             $blocker = 1;
 422         }
 423     }
 424
 425     delete $needsconfirmation->{'DEBT'} if ($debt_confirmed);
 426
 427     if( $item and ( !$blocker or $force_allow_issue ) ){
 428         my $confirm_required = 0;
 429         unless($issueconfirmed){
 430             #  Get the item title for more information
 431             my $materials = $item->materials;
 432             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 433             $materials = $descriptions->{lib} // $materials;
 434             $template_params->{ADDITIONAL_MATERIALS} = $materials;
 435             $template_params->{itemhomebranch} = $item->homebranch;
 436
 437             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 438             foreach my $needsconfirmation_key ( keys %$needsconfirmation ) {
 439                 $template_params->{$needsconfirmation_key} = $needsconfirmation->{$needsconfirmation_key};
 440                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 441                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 442                 $template_params->{NEEDSCONFIRMATION} = 1;
 443                 $confirm_required = 1;
 444                 if ( $needsconfirmation_key eq 'BOOKED_TO_ANOTHER' ) {
 445                     my $reduceddue =
 446                         dt_from_string( $$needsconfirmation{$needsconfirmation_key}->start_date )->subtract( days => 1 );
 447                     $template_params->{reduceddue} = $reduceddue;
 448                 }
 449             }
 450         }
 451         unless ($confirm_required) {
 452             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 453             if ( C4::Context->preference('UseRecalls') && !$recall_id ) {
 454                 my $recall = Koha::Recalls->find(
 455                     {
 456                         biblio_id => $item->biblionumber,
 457                         item_id   => [ undef,       $item->itemnumber ],
 458                         status    => [ 'requested', 'waiting' ],
 459                         completed => 0,
 460                         patron_id => $patron->borrowernumber,
 461                     }
 462                 );
 463                 $recall_id = ( $recall and $recall->id ) ? $recall->id : undef;
 464             }
 465
 466             # If booked (alerts or confirmation) update datedue to end of booking
 467             if ( my $booked = $needsconfirmation->{BOOKED_EARLY} // $alerts->{BOOKED} ) {
 468                 $datedue = $booked->end_date;
 469             }
 470             my $issue = AddIssue(
 471                 $patron, $barcode, $datedue,
 472                 $cancelreserve,
 473                 undef, undef,
 474                 {
 475                     onsite_checkout        => $onsite_checkout,        auto_renew    => $session->param('auto_renew'),
 476                     switch_onsite_checkout => $switch_onsite_checkout, cancel_recall => $cancel_recall,
 477                     recall_id              => $recall_id,
 478                 }
 479             );
 480             $template_params->{issue} = $issue;
 481             $session->clear('auto_renew');
 482             $inprocess = 1;
 483         }
 484     }
 485
 486     if ($needsconfirmation->{RESERVE_WAITING} or $needsconfirmation->{RESERVED} or $needsconfirmation->{TRANSFERRED} or $needsconfirmation->{PROCESSING}){
 487         $template->param(
 488             reserveborrowernumber => $needsconfirmation->{'resborrowernumber'},
 489             reserve_id => $needsconfirmation->{reserve_id},
 490         );
 491     }
 492
 493
 494     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 495     $patron = Koha::Patrons->find( $borrowernumber );
 496     $template_params->{issuecount} = $patron->checkouts->count;
 497
 498     if ( $item ) {
 499         $template_params->{item} = $item;
 500         $template_params->{biblio} = $biblio;
 501         $template_params->{itembiblionumber} = $biblio->biblionumber;
 502     }
 503     push @$checkout_infos, $template_params;
 504   }
 505   unless ( $batch ) {
 506     $template->param( %{$checkout_infos->[0]} );
 507     $template->param( barcode => $barcodes->[0] );
 508   } else {
 509     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 510     $template->param(
 511         checkout_infos      => $checkout_infos,
 512         onsite_checkout     => $onsite_checkout,
 513         confirmation_needed => $confirmation_needed,
 514     );
 515   }
 516 }
 517
 518 ##################################################################################
 519 # BUILD HTML
 520 # show all reserves of this borrower, and the position of the reservation ....
 521 if ($patron) {
 522     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 523     my $waiting_holds = $holds->waiting;
 524     $template->param(
 525         holds_count  => $holds->count(),
 526         WaitingHolds => $waiting_holds,
 527     );
 528
 529     if ( C4::Context->preference('UseRecalls') ) {
 530         my $waiting_recalls = $patron->recalls->search({ status => 'waiting' });
 531         $template->param(
 532             recalls => $patron->recalls->filter_by_current->search({},{ order_by => { -asc => 'created_date' } }),
 533             specific_patron => 1,
 534             waiting_recalls => $waiting_recalls,
 535         );
 536     }
 537 }
 538
 539 if ( $patron ) {
 540     my $noissues;
 541     if ( $patron->gonenoaddress ) {
 542         $template->param( gonenoaddress => 1 );
 543         $noissues = 1;
 544     }
 545     if ( $patron->lost ) {
 546         $template->param( lost=> 1 );
 547         $noissues = 1;
 548     }
 549     if ( $patron->is_debarred ) {
 550         $template->param( is_debarred=> 1 );
 551         $noissues = 1;
 552     }
 553     if ( $patron->borrowernumber eq C4::Context->preference("AnonymousPatron") ) {
 554         $template->param( is_anonymous => 1 );
 555         $noissues = 1;
 556     }
 557     my $account = $patron->account;
 558     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 559         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 560         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 561         $template->param(
 562             charges => 1,
 563             chargesamount => $owing,
 564         )
 565     } elsif ( $balance < 0 ) {
 566         $template->param(
 567             credits => 1,
 568             creditsamount => -$balance,
 569         );
 570     }
 571
 572     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 573     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 574     if ( $no_issues_charge_guarantors ) {
 575         my $guarantors_non_issues_charges = $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 576
 577         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
 578             $template->param(
 579                 charges_guarantors_guarantees => $guarantors_non_issues_charges
 580             );
 581             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 582         }
 583     }
 584
 585     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 586     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 587     if ( defined $no_issues_charge_guarantees ) {
 588         my $guarantees_non_issues_charges = 0;
 589         my $guarantees = $patron->guarantee_relationships->guarantees;
 590         while ( my $g = $guarantees->next ) {
 591             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 592         }
 593         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 594             $template->param(
 595                 charges_guarantees    => 1,
 596                 chargesamount_guarantees => $guarantees_non_issues_charges,
 597             );
 598             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 599         }
 600     }
 601
 602     if ( $patron->has_overdues ) {
 603         $template->param( odues => 1 );
 604     }
 605
 606     if ( $patron->borrowernotes ) {
 607         my $borrowernotes = $patron->borrowernotes;
 608         $borrowernotes =~ s#\n#<br />#g;
 609         $template->param(
 610             notes =>1,
 611             notesmsg => $borrowernotes,
 612         )
 613     }
 614
 615     if ( $noissues ) {
 616         $template->param(
 617             noissues => ($force_allow_issue) ? 0 : 'true',
 618             forceallow => $force_allow_issue,
 619         );
 620     }
 621
 622     my $patron_messages = $patron->messages->search(
 623         {},
 624         {
 625            join => 'manager',
 626            '+select' => ['manager.surname', 'manager.firstname' ],
 627            '+as' => ['manager_surname', 'manager_firstname'],
 628         }
 629     );
 630     $template->param( patron_messages => $patron_messages );
 631
 632     if ( C4::Context->preference("WaitingNotifyAtCheckout") ) {
 633
 634         #Check for waiting holds
 635         my $waiting_holds          = $patron->holds->search( { found => 'W', branchcode => $branch } );
 636         my @waiting_holds_barcodes = ();
 637         while ( my $hold = $waiting_holds->next ) {
 638             push( @waiting_holds_barcodes, $hold->item->barcode );
 639         }
 640
 641         $template->param( waiting_holds_barcodes => \@waiting_holds_barcodes );
 642     }
 643 }
 644
 645 my $fast_cataloging = 0;
 646 if ( Koha::BiblioFrameworks->find('FA') ) {
 647     $fast_cataloging = 1
 648 }
 649
 650 my $view = $batch
 651     ?'batch_checkout_view'
 652     : 'circview';
 653
 654 my @relatives;
 655 if ( $patron ) {
 656     if ( my @guarantors = $patron->guarantor_relationships()->guarantors->as_list ) {
 657         push( @relatives, $_->id ) for @guarantors;
 658         push( @relatives, $_->id ) for $patron->siblings->as_list;
 659     } else {
 660         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees->as_list;
 661     }
 662 }
 663 my $relatives_issues_count =
 664   Koha::Database->new()->schema()->resultset('Issue')
 665   ->count( { borrowernumber => \@relatives } );
 666
 667 if ( $patron ) {
 668     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 669     my $roadtype = $av->count ? $av->next->lib : '';
 670     $template->param(
 671         roadtype          => $roadtype,
 672         patron            => $patron,
 673         categoryname      => $patron->category->description,
 674         expiry            => $patron->dateexpiry,
 675     );
 676 }
 677
 678 # Restore date if changed by holds and/or save stickyduedate to session
 679 if ($restoreduedatespec || $stickyduedate) {
 680     $duedatespec = $restoreduedatespec || $duedatespec;
 681
 682     if ($stickyduedate) {
 683         $session->param( 'stickyduedate', $duedatespec );
 684     }
 685 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 686     undef $duedatespec;
 687 }
 688
 689 $template->param(
 690     borrowernumber    => $borrowernumber,
 691     branch            => $branch,
 692     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 693     barcodes          => $barcodes,
 694     stickyduedate     => $stickyduedate,
 695     duedatespec       => $duedatespec,
 696     restoreduedatespec => $restoreduedatespec,
 697     message           => $message,
 698     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 699     inprocess         => $inprocess,
 700     $view             => 1,
 701     batch_allowed     => $batch_allowed,
 702     batch             => $batch,
 703     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 704     fast_cataloging   => $fast_cataloging,
 705     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 706     RoutingSerials => C4::Context->preference('RoutingSerials'),
 707     relatives_issues_count => $relatives_issues_count,
 708     relatives_borrowernumbers => \@relatives,
 709 );
 710
 711
 712 if ( C4::Context->preference("ExportCircHistory") ) {
 713     $template->param(csv_profiles => Koha::CsvProfiles->search({ type => 'marc' }));
 714 }
 715
 716 my ( $has_modifications, $patron_lists_count);
 717 if ( $patron ) {
 718     $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 719     $patron_lists_count = $patron->get_lists_with_patron->count();
 720 }
 721 $template->param(
 722     debt_confirmed            => $debt_confirmed,
 723     SpecifyDueDate            => $duedatespec_allow,
 724     PatronAutoComplete        => C4::Context->preference("PatronAutoComplete"),
 725     today_due_date_and_time   => dt_from_string()->set(hour => 23)->set(minute => 59),
 726     restriction_types         => scalar Koha::Patron::Restriction::Types->search(),
 727     has_modifications         => $has_modifications,
 728     patron_lists_count        => $patron_lists_count,
 729     override_high_holds       => $override_high_holds,
 730     nopermission              => scalar $query->param('nopermission'),
 731     autoswitched              => $autoswitched,
 732     logged_in_user            => $logged_in_user,
 733 );
 734
 735 output_html_with_http_headers $query, $cookie, $template->output;