t/lib/Selenium.pm

   1 package t::lib::Selenium;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18
  19 use Modern::Perl;
  20 use Carp qw( croak );
  21
  22 use C4::Context;
  23
  24 use base qw(Class::Accessor);
  25 __PACKAGE__->mk_accessors(qw(login password base_url selenium_addr selenium_port driver));
  26
  27 sub new {
  28     my ( $class, $params ) = @_;
  29     my $self   = {};
  30     my $config = $class->config;
  31     $self->{login}    = $params->{login}    || $config->{login};
  32     $self->{password} = $params->{password} || $config->{password};
  33     $self->{base_url} = $params->{base_url} || $config->{base_url};
  34     $self->{selenium_addr} = $params->{selenium_addr} || $config->{selenium_addr};
  35     $self->{selenium_port} = $params->{selenium_port} || $config->{selenium_port};
  36     $self->{driver} = Selenium::Remote::Driver->new(
  37         port               => $self->{selenium_port},
  38         remote_server_addr => $self->{selenium_addr},
  39         error_handler => sub {
  40             my $selenium_error = $_[1];
  41             print STDERR "\nSTRACE:";
  42             my $i = 1;
  43             while ( (my @call_details = (caller($i++))) ){
  44                 print STDERR "\t" . $call_details[1]. ":" . $call_details[2] . " in " . $call_details[3]."\n";
  45             }
  46             print STDERR "\n";
  47             croak $selenium_error; }
  48     );
  49     return bless $self, $class;
  50 }
  51
  52 sub config {
  53     return {
  54         login    => $ENV{KOHA_USER} || 'koha',
  55         password => $ENV{KOHA_PASS} || 'koha',
  56         base_url => ( $ENV{KOHA_INTRANET_URL} || C4::Context->preference("staffClientBaseURL") ) . "/cgi-bin/koha/",
  57         selenium_addr => $ENV{SELENIUM_ADDR} || 'localhost',
  58         selenium_port => $ENV{SELENIUM_PORT} || 4444,
  59     };
  60 }
  61
  62 sub auth {
  63     my ( $self, $login, $password ) = @_;
  64
  65     $login ||= $self->login;
  66     $password ||= $self->password;
  67     my $mainpage = $self->base_url . 'mainpage.pl';
  68
  69     $self->driver->get($mainpage);
  70     $self->fill_form( { userid => $login, password => $password } );
  71     my $login_button = $self->driver->find_element('//input[@id="submit"]');
  72     $login_button->submit();
  73 }
  74
  75 sub fill_form {
  76     my ( $self, $values ) = @_;
  77     while ( my ( $id, $value ) = each %$values ) {
  78         my $element = $self->driver->find_element('//*[@id="'.$id.'"]');
  79         my $tag = $element->get_tag_name();
  80         if ( $tag eq 'input' ) {
  81             $self->driver->find_element('//input[@id="'.$id.'"]')->send_keys($value);
  82         } elsif ( $tag eq 'select' ) {
  83             $self->driver->find_element('//select[@id="'.$id.'"]/option[@value="'.$value.'"]')->click;
  84         }
  85     }
  86 }
  87
  88 =head1 NAME
  89
  90 t::lib::Selenium - Selenium helper module
  91
  92 =head1 SYNOPSIS
  93
  94     my $s = t::lib::Selenium->new;
  95     my $driver = $s->driver;
  96     my $base_url = $s->base_url;
  97     $s->auth;
  98     $driver->get($s->base_url . 'mainpage.pl');
  99     $s->fill_form({ input_id => 'value' });
 100
 101 =head1 DESCRIPTION
 102
 103 The goal of this module is to group the different actions we need
 104 when we use automation test using Selenium
 105 =head1 METHODS
 106
 107 =head2 new
 108
 109     my $s = t::lib::Selenium->new;
 110
 111     Constructor - Returns the object Selenium
 112     You can pass login, password, base_url, selenium_addr, selenium_port
 113     If not passed, the environment variables will be used
 114     KOHA_USER, KOHA_PASS, KOHA_INTRANET_URL, SELENIUM_ADDR SELENIUM_PORT
 115     Or koha, koha, syspref staffClientBaseURL, localhost, 4444
 116
 117 =head2 auth
 118
 119     $s->auth;
 120
 121     Will login into Koha.
 122
 123 =head2 fill_form
 124
 125     $driver->get($url)
 126     $s->fill_form({
 127         input_id => 'value',
 128         element_id => 'other_value',
 129     });
 130
 131     Will fill the different elements of a form.
 132     The keys must be element ids (input and select are supported so far)
 133     The values must a string.
 134
 135 =head1 AUTHOR
 136
 137 Jonathan Druart <jonathan.druart@bugs.koha-community.org>
 138
 139 Koha Development Team
 140
 141 =head1 COPYRIGHT
 142
 143 Copyright 2017 - Koha Development Team
 144
 145 =head1 LICENSE
 146
 147 This file is part of Koha.
 148
 149 Koha is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by
 150 the Free Software Foundation; either version 3 of the License, or (at your option) any later version.
 151
 152 Koha is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
 153
 154 You should have received a copy of the GNU General Public License along with Koha; if not, see <http://www.gnu.org/licenses>.
 155
 156 =cut
 157
 158 1;