Koha/Libraries.pm

   1 package Koha::Libraries;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Biblios;
  27 use Koha::Database;
  28 use Koha::Item::Transfer::Limits;
  29 use Koha::Items;
  30 use Koha::Library;
  31
  32 use base qw(Koha::Objects);
  33
  34 =head1 NAME
  35
  36 Koha::Libraries - Koha Library Object set class
  37
  38 =head1 API
  39
  40 =head2 Class Methods
  41
  42 =cut
  43
  44 =head3 pickup_locations
  45
  46 Returns available pickup locations for
  47     A. a specific item
  48     B. a biblio
  49     C. none of the above, simply all libraries with pickup_location => 1
  50
  51 This method determines the pickup location by two factors:
  52     1. is the library configured as pickup location
  53     2. can a specific item / at least one of the items of a biblio be transferred
  54        into the library
  55
  56 OPTIONAL PARAMETERS:
  57     item   # Koha::Item object / itemnumber, find pickup locations for item
  58     biblio # Koha::Biblio object / biblionumber, find pickup locations for biblio
  59
  60 If no parameters are given, all libraries with pickup_location => 1 are returned.
  61
  62 =cut
  63
  64 sub pickup_locations {
  65     my ($self, $params) = @_;
  66
  67     my $item = $params->{'item'};
  68     my $biblio = $params->{'biblio'};
  69     if ($biblio && $item) {
  70         Koha::Exceptions::BadParameter->throw(
  71             error => "Koha::Libraries->pickup_locations takes either 'biblio' or "
  72             ." 'item' as parameter, but not both."
  73         );
  74     }
  75
  76     # Select libraries that are configured as pickup locations
  77     my $libraries = $self->search({
  78         pickup_location => 1
  79     }, {
  80         order_by => ['branchname']
  81     });
  82
  83     return $libraries->unblessed unless $item or $biblio;
  84     return $libraries->unblessed
  85         unless C4::Context->preference('UseBranchTransferLimits');
  86     my $limittype = C4::Context->preference('BranchTransferLimitsType');
  87
  88     my $items;
  89     if ($item) {
  90         unless (ref($item) eq 'Koha::Item') {
  91             $item = Koha::Items->find($item);
  92             return $libraries->unblessed unless $item;
  93         }
  94     } else {
  95         unless (ref($biblio) eq 'Koha::Biblio') {
  96             $biblio = Koha::Biblios->find($biblio);
  97             return $libraries->unblessed unless $biblio;
  98         }
  99     }
 100
 101     my @pickup_locations;
 102     foreach my $library ($libraries->as_list) {
 103         if ($item && $item->can_be_transferred({ to => $library })) {
 104             push @pickup_locations, $library->unblessed;
 105         } elsif ($biblio && $biblio->can_be_transferred({ to => $library })) {
 106             push @pickup_locations, $library->unblessed;
 107         }
 108     }
 109
 110     return wantarray ? @pickup_locations : \@pickup_locations;
 111 }
 112
 113 =head3 search_filtered
 114
 115 =cut
 116
 117 sub search_filtered {
 118     my ( $self, $params, $attributes ) = @_;
 119
 120     my @branchcodes;
 121     my $userenv = C4::Context->userenv;
 122     if ( $userenv and $userenv->{number} ) {
 123         my $only_from_group = $params->{only_from_group};
 124         if ( $only_from_group ) {
 125             my $logged_in_user = Koha::Patrons->find( $userenv->{number} );
 126             my @branchcodes = $logged_in_user->libraries_where_can_see_patrons;
 127             $params->{branchcode} = { -in => \@branchcodes } if @branchcodes;
 128         } else {
 129             if ( C4::Context::only_my_library ) {
 130                 $params->{branchcode} = C4::Context->userenv->{branch};
 131             }
 132         }
 133     }
 134     delete $params->{only_from_group};
 135     return $self->SUPER::search( $params, $attributes );
 136 }
 137
 138 =head3 type
 139
 140 =cut
 141
 142 sub _type {
 143     return 'Branch';
 144 }
 145
 146 sub object_class {
 147     return 'Koha::Library';
 148 }
 149
 150 1;