Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28
  29 use base qw(Koha::Object);
  30
  31 =head1 NAME
  32
  33 Koha::Library - Koha Library Object class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =head3 stockrotationstages
  40
  41   my $stages = Koha::Library->stockrotationstages;
  42
  43 Returns the stockrotation stages associated with this Library.
  44
  45 =cut
  46
  47 sub stockrotationstages {
  48     my ( $self ) = @_;
  49     my $rs = $self->_result->stockrotationstages;
  50     return Koha::StockRotationStages->_new_from_dbic( $rs );
  51 }
  52
  53 =head3 get_effective_marcorgcode
  54
  55     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  56
  57 Returns the effective MARC organization code of the library. It falls back to the value
  58 from the I<MARCOrgCode> syspref if undefined for the library.
  59
  60 =cut
  61
  62 sub get_effective_marcorgcode {
  63     my ( $self )  = @_;
  64
  65     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  66 }
  67
  68 =head3 get_effective_email
  69
  70   my $to_email = Koha::Library->get_effective_email;
  71
  72 Returns an effective email address which should be accessible to librarians at the branch.
  73
  74 =cut
  75
  76 sub get_effective_email {
  77     my ($self) = @_;
  78
  79     return
  80          $self->branchreplyto
  81       || $self->branchemail
  82       || C4::Context->preference('ReplytoDefault')
  83       || C4::Context->preference('KohaAdminEmailAddress');
  84 }
  85
  86 =head3 library_groups
  87
  88 Return the Library groups of this library
  89
  90 =cut
  91
  92 sub library_groups {
  93     my ( $self ) = @_;
  94     my $rs = $self->_result->library_groups;
  95     return Koha::Library::Groups->_new_from_dbic( $rs );
  96 }
  97
  98 =head3 cash_registers
  99
 100 Return Cash::Registers associated with this Library
 101
 102 =cut
 103
 104 sub cash_registers {
 105     my ( $self ) = @_;
 106     my $rs = $self->_result->cash_registers;
 107     return Koha::Cash::Registers->_new_from_dbic( $rs );
 108 }
 109
 110 =head3 to_api_mapping
 111
 112 This method returns the mapping for representing a Koha::Library object
 113 on the API.
 114
 115 =cut
 116
 117 sub to_api_mapping {
 118     return {
 119         branchcode       => 'library_id',
 120         branchname       => 'name',
 121         branchaddress1   => 'address1',
 122         branchaddress2   => 'address2',
 123         branchaddress3   => 'address3',
 124         branchzip        => 'postal_code',
 125         branchcity       => 'city',
 126         branchstate      => 'state',
 127         branchcountry    => 'country',
 128         branchphone      => 'phone',
 129         branchfax        => 'fax',
 130         branchemail      => 'email',
 131         branchreplyto    => 'reply_to_email',
 132         branchreturnpath => 'return_path_email',
 133         branchurl        => 'url',
 134         issuing          => undef,
 135         branchip         => 'ip',
 136         branchnotes      => 'notes',
 137         marcorgcode      => 'marc_org_code',
 138     };
 139 }
 140
 141 =head3 get_hold_libraries
 142
 143 Return all libraries (including self) that belong to the same hold groups
 144
 145 =cut
 146
 147 sub get_hold_libraries {
 148     my ( $self ) = @_;
 149     my $library_groups = $self->library_groups;
 150     my @hold_libraries;
 151     while ( my $library_group = $library_groups->next ) {
 152         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 153         if($root->ft_local_hold_group) {
 154             push @hold_libraries, $root->all_libraries;
 155         }
 156     }
 157
 158     my %seen;
 159     @hold_libraries =
 160       grep { !$seen{ $_->id }++ } @hold_libraries;
 161
 162     return @hold_libraries;
 163 }
 164
 165 =head3 validate_hold_sibling
 166
 167 Return if given library is a valid hold group member
 168
 169 =cut
 170
 171 sub validate_hold_sibling {
 172     my ( $self, $params ) = @_;
 173     my @hold_libraries = $self->get_hold_libraries;
 174
 175     foreach (@hold_libraries) {
 176         my $hold_library = $_;
 177         my $is_valid = 1;
 178         foreach my $key (keys %$params) {
 179             unless($hold_library->$key eq $params->{$key}) {
 180                 $is_valid=0;
 181                 last;
 182             }
 183         }
 184         if($is_valid) {
 185             #Found one library that meets all search parameters
 186             return 1;
 187         }
 188     }
 189     return 0;
 190 }
 191
 192 =head2 Internal methods
 193
 194 =head3 _type
 195
 196 =cut
 197
 198 sub _type {
 199     return 'Branch';
 200 }
 201
 202 1;