Koha/Template/Plugin/KohaDates.pm

   1 package Koha::Template::Plugin::KohaDates;
   2
   3 # Copyright Catalyst IT 2011
   4
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Template::Plugin::Filter;
  23 use base qw( Template::Plugin::Filter );
  24
  25 use Koha::DateUtils qw( dt_from_string output_pref );
  26 use C4::Context;
  27 our $DYNAMIC = 1;
  28
  29 sub filter {
  30     my ( $self, $text, $args, $config ) = @_;
  31     return "" unless $text;
  32     $config->{with_hours} //= 0;
  33
  34     my $dt = dt_from_string( $text, 'iso' );
  35     $dt->add( %$_ ) for _parse_config_for_durations($config); # Allow date add/subtract; see _parse_config_for_durations
  36
  37     return $config->{as_due_date} ?
  38         output_pref({ dt => $dt, as_due_date => 1, dateformat => $config->{dateformat} }) :
  39         output_pref({ dt => $dt, dateonly => !$config->{with_hours}, dateformat => $config->{dateformat} });
  40 }
  41
  42 sub _parse_config_for_durations {
  43 # Supports passing things like add_years => 1 or subtract_years => 1
  44 # Same for months, weeks, days, hours, minutes or seconds
  45 # Returns a list of hashrefs like { years => 1 }, { days => -1 } that can be passed to dt->add
  46     my $config = shift;
  47     my @results;
  48     foreach my $entry ( keys %$config ) {
  49         if( $entry =~ /^(add|subtract)_(years|months|weeks|days|hours|minutes|seconds)$/ ) {
  50             push @results, { $2 => ( $1 eq 'add' ? 1 : -1 ) * $config->{$entry} };
  51         }
  52     }
  53     return @results;
  54 }
  55
  56 sub output_preference {
  57     my ( $self, @params ) = @_;
  58     return output_pref( @params );
  59 }
  60
  61 sub tz {
  62     return C4::Context->tz->name;
  63 }
  64
  65 1;