catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = new CGI;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 198         $template->param(
 199             holdfor => $cgi->cookie("holdfor"),
 200             holdfor_surname => $holdfor_patron->surname,
 201             holdfor_firstname => $holdfor_patron->firstname,
 202             holdfor_cardnumber => $holdfor_patron->cardnumber,
 203         );
 204     }
 205 }
 206
 207 if($cgi->cookie("holdforclub")){
 208     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 209     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 210         $template->param(
 211             holdforclub => $cgi->cookie("holdforclub"),
 212             holdforclub_name => $holdfor_club->name,
 213         );
 214     }
 215 }
 216
 217 if($cgi->cookie("searchToOrder")){
 218     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 219     $template->param(
 220         searchtoorder_basketno => $basketno,
 221         searchtoorder_vendorid => $vendorid
 222     );
 223 }
 224
 225 # get biblionumbers stored in the cart
 226 my @cart_list;
 227
 228 if($cgi->cookie("intranet_bib_list")){
 229     my $cart_list = $cgi->cookie("intranet_bib_list");
 230     @cart_list = split(/\//, $cart_list);
 231 }
 232
 233 my @search_groups =
 234   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 235 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 236
 237 $template->param(
 238     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 239     search_groups    => \@search_groups,
 240 );
 241
 242 # load the Type stuff
 243 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 244 my $advancedsearchesloop = prepare_adv_search_types($types);
 245 $template->param(advancedsearchesloop => $advancedsearchesloop);
 246
 247 # The following should only be loaded if we're bringing up the advanced search template
 248 if ( $template_type eq 'advsearch' ) {
 249
 250     # load the servers (used for searching -- to do federated searching, etc.)
 251     my $primary_servers_loop;# = displayPrimaryServers();
 252     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 253
 254     my $secondary_servers_loop;
 255     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 256
 257     # set the default sorting
 258     if (   C4::Context->preference('defaultSortField')
 259         && C4::Context->preference('defaultSortOrder') ) {
 260         my $default_sort_by =
 261             C4::Context->preference('defaultSortField') . '_'
 262           . C4::Context->preference('defaultSortOrder');
 263         $template->param( sort_by => $default_sort_by  );
 264     }
 265
 266     # determine what to display next to the search boxes (ie, boolean option
 267     # shouldn't appear on the first one, scan indexes should, adding a new
 268     # box should only appear on the last, etc.
 269     my @search_boxes_array;
 270     my $search_boxes_count = 3; # begin with 3 boxes
 271     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 272     for (my $i=1;$i<=$search_boxes_count;$i++) {
 273         # if it's the first one, don't display boolean option, but show scan indexes
 274         if ($i==1) {
 275             push @search_boxes_array, {scan_index => 1};
 276         }
 277         # if it's the last one, show the 'add field' box
 278         elsif ($i==$search_boxes_count) {
 279             push @search_boxes_array,
 280                 {
 281                 boolean => 1,
 282                 add_field => 1,
 283                 };
 284         }
 285         else {
 286             push @search_boxes_array,
 287                 {
 288                 boolean => 1,
 289                 };
 290         }
 291
 292     }
 293     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 294                       search_boxes_loop => \@search_boxes_array);
 295
 296     # load the language limits (for search)
 297     my $languages_limit_loop = getLanguages($lang, 1);
 298     $template->param(search_languages_loop => $languages_limit_loop,);
 299
 300     # Expanded search options in advanced search:
 301     # use the global setting by default, but let the user override it
 302     {
 303         my $expanded = $cgi->param('expanded_options');
 304         $expanded = C4::Context->preference("expandedSearchOption") || 0
 305             if !defined($expanded) || $expanded !~ /^0|1$/;
 306         $template->param( expanded_options => $expanded );
 307     }
 308
 309     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 310
 311     output_html_with_http_headers $cgi, $cookie, $template->output;
 312     exit;
 313 }
 314
 315 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 316
 317 # Fetch the paramater list as a hash in scalar context:
 318 #  * returns paramater list as tied hash ref
 319 #  * we can edit the values by changing the key
 320 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 321 my $params = $cgi->Vars;
 322 # Params that can have more than one value
 323 # sort by is used to sort the query
 324 # in theory can have more than one but generally there's just one
 325 my @sort_by;
 326 my $default_sort_by;
 327 if (   C4::Context->preference('defaultSortField')
 328     && C4::Context->preference('defaultSortOrder') ) {
 329     $default_sort_by =
 330         C4::Context->preference('defaultSortField') . '_'
 331       . C4::Context->preference('defaultSortOrder');
 332 }
 333
 334 @sort_by = $cgi->multi_param('sort_by');
 335 $sort_by[0] = $default_sort_by unless $sort_by[0];
 336 foreach my $sort (@sort_by) {
 337     $template->param($sort => 1) if $sort;
 338 }
 339 $template->param('sort_by' => $sort_by[0]);
 340
 341 # Use the servers defined, or just search our local catalog(default)
 342 my @servers = $cgi->multi_param('server');
 343 unless (@servers) {
 344     #FIXME: this should be handled using Context.pm
 345     @servers = ("biblioserver");
 346     # @servers = C4::Context->config("biblioserver");
 347 }
 348 # operators include boolean and proximity operators and are used
 349 # to evaluate multiple operands
 350 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 351
 352 # indexes are query qualifiers, like 'title', 'author', etc. They
 353 # can be single or multiple parameters separated by comma: kw,right-Truncation
 354 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 355
 356 # if a simple index (only one)  display the index used in the top search box
 357 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 358     my $idx = "ms_".$indexes[0];
 359     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 360     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 361     $template->param($idx => 1);
 362 }
 363
 364 # an operand can be a single term, a phrase, or a complete ccl query
 365 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 366
 367 # if a simple search, display the value in the search box
 368 if ($operands[0] && !$operands[1]) {
 369     my $ms_query = $operands[0];
 370     $ms_query =~ s/ #\S+//;
 371     $template->param(ms_value => $ms_query);
 372 }
 373
 374 # limits are use to limit to results to a pre-defined category such as branch or language
 375 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 376 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 377 my %is_nolimit = map { $_ => 1 } @nolimits;
 378 @limits = grep { not $is_nolimit{$_} } @limits;
 379
 380 if($params->{'multibranchlimit'}) {
 381     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 382     my @libraries = $search_group->all_libraries;
 383     my $multibranch = '('.join( " OR ", map { '(homebranch: ' . $_->branchcode .')' } @libraries ) .')';
 384     push @limits, $multibranch if ($multibranch ne  '()');
 385 }
 386
 387 my $available;
 388 foreach my $limit(@limits) {
 389     if ($limit =~/available/) {
 390         $available = 1;
 391     }
 392 }
 393 $template->param(available => $available);
 394
 395 # append year limits if they exist
 396 my $limit_yr;
 397 my $limit_yr_value;
 398 if ($params->{'limit-yr'}) {
 399     if ($params->{'limit-yr'} =~ /\d{4}/) {
 400         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 401         $limit_yr_value = $params->{'limit-yr'};
 402     }
 403     push @limits,$limit_yr;
 404     #FIXME: Should return a error to the user, incorect date format specified
 405 }
 406
 407 # convert indexes and operands to corresponding parameter names for the z3950 search
 408 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 409 my $z3950par;
 410 my $indexes2z3950 = {
 411     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 412     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 413     ti=>'title', 'ti,phr'=>'title', se=>'title'
 414 };
 415 for (my $ii = 0; $ii < @operands; ++$ii)
 416 {
 417     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 418     if (defined $name && defined $operands[$ii])
 419     {
 420         $z3950par ||= {};
 421         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 422     }
 423 }
 424
 425
 426 # Params that can only have one value
 427 my $scan = $params->{'scan'};
 428 my $count = C4::Context->preference('numSearchResults') || 20;
 429 my $results_per_page = $params->{'count'} || $count;
 430 my $offset = $params->{'offset'} || 0;
 431 my $whole_record = $params->{'whole_record'} || 0;
 432 $offset = 0 if $offset < 0;
 433 my $page = $cgi->param('page') || 1;
 434 #my $offset = ($page-1)*$results_per_page;
 435
 436 # Define some global variables
 437 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 438
 439 my $builder = Koha::SearchEngine::QueryBuilder->new(
 440     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 441 my $searcher = Koha::SearchEngine::Search->new(
 442     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 443
 444 ## I. BUILD THE QUERY
 445 (
 446     $error,             $query, $simple_query, $query_cgi,
 447     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 448     $query_type
 449   )
 450   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 451     \@sort_by, $scan, $lang, { weighted_fields => !$cgi->param('advsearch'), whole_record => $whole_record });
 452
 453 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 454
 455 ## parse the query_cgi string and put it into a form suitable for <input>s
 456 my @query_inputs;
 457 my $scan_index_to_use;
 458 my $scan_search_term_to_use;
 459
 460 if ($query_cgi) {
 461     for my $this_cgi ( split('&', $query_cgi) ) {
 462         next unless $this_cgi;
 463         $this_cgi =~ m/(.*?)=(.*)/;
 464         my $input_name = $1;
 465         my $input_value = $2;
 466         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 467         if ($input_name eq 'idx') {
 468             # The form contains multiple fields, so take the first value as the scan index
 469             $scan_index_to_use = $input_value unless $scan_index_to_use;
 470         }
 471         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 472             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 473         }
 474     }
 475 }
 476
 477 $template->param ( QUERY_INPUTS => \@query_inputs,
 478                    scan_index_to_use => $scan_index_to_use,
 479                    scan_search_term_to_use => $scan_search_term_to_use );
 480
 481 ## parse the limit_cgi string and put it into a form suitable for <input>s
 482 my @limit_inputs;
 483 if ($limit_cgi) {
 484     for my $this_cgi ( split('&', $limit_cgi) ) {
 485         next unless $this_cgi;
 486         # handle special case limit-yr
 487         if ($this_cgi =~ /yr,st-numeric/) {
 488             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 489             next;
 490         }
 491         $this_cgi =~ m/(.*=)(.*)/;
 492         my $input_name = $1;
 493         my $input_value = $2;
 494         $input_name =~ s/=$//;
 495         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 496     }
 497 }
 498 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 499
 500 ## II. DO THE SEARCH AND GET THE RESULTS
 501 my $total = 0; # the total results for the whole set
 502 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 503 my $results_hashref;
 504
 505 eval {
 506     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 507     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 508         $query,            $simple_query, \@sort_by,       \@servers,
 509         $results_per_page, $offset,       undef,           $itemtypes,
 510         $query_type,       $scan
 511     );
 512 };
 513
 514 if ($@ || $error) {
 515     $template->param(query_error => $error.$@);
 516     output_html_with_http_headers $cgi, $cookie, $template->output;
 517     exit;
 518 }
 519
 520 # At this point, each server has given us a result set
 521 # now we build that set for template display
 522 my @sup_results_array;
 523 for (my $i=0;$i<@servers;$i++) {
 524     my $server = $servers[$i];
 525     if ($server =~/biblioserver/) { # this is the local bibliographic server
 526         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 527         my $page = $cgi->param('page') || 0;
 528         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 529                                        $results_hashref->{$server}->{"RECORDS"});
 530         $total = $total + $hits;
 531
 532         # Search history
 533         if (C4::Context->preference('EnableSearchHistory')) {
 534             unless ( $offset ) {
 535                 my $path_info = $cgi->url(-path_info=>1);
 536                 my $query_cgi_history = $cgi->url(-query=>1);
 537                 $query_cgi_history =~ s/^$path_info\?//;
 538                 $query_cgi_history =~ s/;/&/g;
 539                 my $query_desc_history = $query_desc;
 540                 $query_desc_history .= ", $limit_desc"
 541                     if $limit_desc;
 542
 543                 C4::Search::History::add({
 544                     userid => $borrowernumber,
 545                     sessionid => $cgi->cookie("CGISESSID"),
 546                     query_desc => $query_desc_history,
 547                     query_cgi => $query_cgi_history,
 548                     total => $total,
 549                     type => "biblio",
 550                 });
 551             }
 552             $template->param( EnableSearchHistory => 1 );
 553         }
 554
 555         ## If there's just one result, redirect to the detail page unless doing an index scan
 556         if ($total == 1 && !$scan) {
 557             my $biblionumber = $newresults[0]->{biblionumber};
 558             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 559             my $views = { C4::Search::enabled_staff_search_views };
 560             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 561                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 562             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 563                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 564             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 565                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 566             } else {
 567                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 568             }
 569             exit;
 570         }
 571
 572         # set up parameters if user wishes to re-run the search
 573         # as a Z39.50 search
 574         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 575
 576         if ($hits) {
 577             $template->param(total => $hits);
 578             if ($limit_cgi) {
 579                 my $limit_cgi_not_availablity = $limit_cgi;
 580                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 581                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 582             }
 583             $template->param(limit_cgi => $limit_cgi);
 584             $template->param(query_cgi => $query_cgi);
 585             $template->param(query_desc => $query_desc);
 586             $template->param(limit_desc => $limit_desc);
 587             $template->param(offset     => $offset);
 588             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 589             if ($query_desc || $limit_desc) {
 590                 $template->param(searchdesc => 1);
 591             }
 592             $template->param(results_per_page =>  $results_per_page);
 593             # must define a value for size if not present in DB
 594             # in order to avoid problems generated by the default size value in TT
 595             foreach my $line (@newresults) {
 596                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 597                 # while we're checking each line, see if item is in the cart
 598                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 599                     $line->{'incart'} = 1;
 600                 }
 601             }
 602             $template->param(SEARCH_RESULTS => \@newresults);
 603             ## FIXME: add a global function for this, it's better than the current global one
 604             ## Build the page numbers on the bottom of the page
 605             my @page_numbers;
 606             my $max_result_window = $searcher->max_result_window;
 607             my $hits_to_paginate = ($max_result_window && $max_result_window < $hits) ? $max_result_window : $hits;
 608             $template->param( hits_to_paginate => $hits_to_paginate );
 609             # total number of pages there will be
 610             my $pages = ceil($hits_to_paginate / $results_per_page);
 611             my $last_page_offset = ( $pages -1 ) * $results_per_page;
 612             # default page number
 613             my $current_page_number = 1;
 614             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 615             my $previous_page_offset;
 616             if ( $offset >= $results_per_page ) {
 617                 $previous_page_offset = $offset - $results_per_page;
 618             }
 619             my $next_page_offset = $offset + $results_per_page;
 620             # If we're within the first 10 pages, keep it simple
 621             #warn "current page:".$current_page_number;
 622             if ($current_page_number < 10) {
 623                 # just show the first 10 pages
 624                 # Loop through the pages
 625                 my $pages_to_show = 10;
 626                 $pages_to_show = $pages if $pages<10;
 627                 for (my $i=1; $i<=$pages_to_show;$i++) {
 628                     # the offset for this page
 629                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 630                     # the page number for this page
 631                     my $this_page_number = $i;
 632                     # put it in the array
 633                     push @page_numbers,
 634                       { offset    => $this_offset,
 635                         pg        => $this_page_number,
 636                         # it should only be highlighted if it's the current page
 637                         highlight => $this_page_number == $current_page_number,
 638                         sort_by   => join ' ', @sort_by
 639                       };
 640
 641                 }
 642
 643             }
 644
 645             # now, show twenty pages, with the current one smack in the middle
 646             else {
 647                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 648                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 649                     my $this_page_number = $i-9;
 650                     if ( $this_page_number <= $pages ) {
 651                         push @page_numbers,
 652                           { offset    => $this_offset,
 653                             pg        => $this_page_number,
 654                             highlight => $this_page_number == $current_page_number,
 655                             sort_by   => join ' ', @sort_by
 656                           };
 657                     }
 658                 }
 659             }
 660             # FIXME: no previous_page_offset when pages < 2
 661             $template->param(   PAGE_NUMBERS => \@page_numbers,
 662                                 last_page_offset => $last_page_offset,
 663                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 664             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 665         }
 666
 667
 668         # no hits
 669         else {
 670             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 671         }
 672
 673     } # end of the if local
 674
 675     # asynchronously search the authority server
 676     elsif ($server =~/authorityserver/) { # this is the local authority server
 677         my @inner_sup_results_array;
 678         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 679             my $marc_record_object = C4::Search::new_record_from_zebra(
 680                 'authorityserver',
 681                 $sup_record
 682             );
 683             # warn "Authority Found: ".$marc_record_object->as_formatted();
 684             push @inner_sup_results_array, {
 685                 'title' => $marc_record_object->field(100)->subfield('a'),
 686                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 687             };
 688         }
 689         push @sup_results_array, {  servername => $server,
 690                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 691     }
 692     # FIXME: can add support for other targets as needed here
 693     $template->param(           outer_sup_results_loop => \@sup_results_array);
 694 } #/end of the for loop
 695 #$template->param(FEDERATED_RESULTS => \@results_array);
 696
 697 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 698
 699 my $gotonumber = $cgi->param('gotoNumber');
 700 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 701     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 702 }
 703 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 704 my $gotopage = $cgi->param('gotoPage');
 705 $template->{'VARS'}->{'gotoPage'} = $gotopage
 706   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 707
 708 for my $facet ( @$facets ) {
 709     for my $entry ( @{ $facet->{facets} } ) {
 710         my $index = $entry->{type_link_value};
 711         my $value = $entry->{facet_link_value};
 712         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 713     }
 714 }
 715
 716 $template->param(
 717             #classlist => $classlist,
 718             total => $total,
 719             opacfacets => 1,
 720             facets_loop => $facets,
 721             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 722             scan => $scan,
 723             search_error => $error,
 724 );
 725
 726 if ($query_desc || $limit_desc) {
 727     $template->param(searchdesc => 1);
 728 }
 729
 730 # VI. BUILD THE TEMPLATE
 731
 732 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 733     {
 734         borrowernumber => $borrowernumber,
 735         add_allowed    => 1,
 736         category       => 1,
 737     }
 738 );
 739 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 740     {
 741         borrowernumber => $borrowernumber,
 742         add_allowed    => 1,
 743         category       => 2,
 744     }
 745 );
 746
 747
 748 $template->param(
 749     add_to_some_private_shelves => $some_private_shelves,
 750     add_to_some_public_shelves  => $some_public_shelves,
 751 );
 752
 753 output_html_with_http_headers $cgi, $cookie, $template->output;
 754
 755
 756 =head2 prepare_adv_search_types
 757
 758     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 759     my @advanced_search_types = prepare_adv_search_types($type);
 760
 761 Different types can be searched for in the advanced search. This takes the
 762 system preference that defines these types and parses it into an arrayref for
 763 the template.
 764
 765 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 766 It also accounts for the "item-level_itypes" system preference.
 767
 768 =cut
 769
 770 sub prepare_adv_search_types {
 771     my ($types) = @_;
 772
 773     my @advanced_search_types = split( /\|/, $types );
 774
 775     # the index parameter is different for item-level itemtypes
 776     my $itype_or_itemtype =
 777       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 778     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 779
 780     my ( $cnt, @result );
 781     foreach my $advanced_srch_type (@advanced_search_types) {
 782         $advanced_srch_type =~ s/^\s*//;
 783         $advanced_srch_type =~ s/\s*$//;
 784         if ( $advanced_srch_type eq 'itemtypes' ) {
 785
 786        # itemtype is a special case, since it's not defined in authorized values
 787             my @itypesloop;
 788             foreach my $thisitemtype (
 789                 sort {
 790                     $itemtypes->{$a}->{'translated_description'}
 791                       cmp $itemtypes->{$b}->{'translated_description'}
 792                 } keys %$itemtypes
 793               )
 794             {
 795                 my %row = (
 796                     number      => $cnt++,
 797                     ccl         => "$itype_or_itemtype,phr",
 798                     code        => $thisitemtype,
 799                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 800                     imageurl    => getitemtypeimagelocation(
 801                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 802                     ),
 803                 );
 804                 push @itypesloop, \%row;
 805             }
 806             my %search_code = (
 807                 advanced_search_type => $advanced_srch_type,
 808                 code_loop            => \@itypesloop
 809             );
 810             push @result, \%search_code;
 811         }
 812         else {
 813             # covers all the other cases: non-itemtype authorized values
 814             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 815             my @authvalueloop;
 816             for my $thisitemtype (@$advsearchtypes) {
 817                 my %row = (
 818                     number      => $cnt++,
 819                     ccl         => $advanced_srch_type,
 820                     code        => $thisitemtype->{authorised_value},
 821                     description => $thisitemtype->{'lib'},
 822                     imageurl    => getitemtypeimagelocation(
 823                         'intranet', $thisitemtype->{'imageurl'}
 824                     ),
 825                 );
 826                 push @authvalueloop, \%row;
 827             }
 828             my %search_code = (
 829                 advanced_search_type => $advanced_srch_type,
 830                 code_loop            => \@authvalueloop
 831             );
 832             push @result, \%search_code;
 833         }
 834     }
 835     return \@result;
 836 }