C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Digest::MD5 qw(md5_base64);
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use List::MoreUtils qw( any );
  30 use Net::LDAP;
  31 use Net::LDAP::Filter;
  32
  33 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  34
  35 BEGIN {
  36         require Exporter;
  37     $VERSION = 3.07.00.049;     # set the version for version checking
  38         @ISA    = qw(Exporter);
  39         @EXPORT = qw( checkpw_ldap );
  40 }
  41
  42 # Redefine checkpw_ldap:
  43 # connect to LDAP (named or anonymous)
  44 # ~ retrieves $userid from KOHA_CONF mapping
  45 # ~ then compares $password with userPassword
  46 # ~ then gets the LDAP entry
  47 # ~ and calls the memberadd if necessary
  48
  49 sub ldapserver_error {
  50         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  51 }
  52
  53 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  54 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  55 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  56 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  57 my $base      = $ldap->{base}           or die ldapserver_error('base');
  58 $ldapname     = $ldap->{user}           ;
  59 $ldappassword = $ldap->{pass}           ;
  60 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  61 my @mapkeys = keys %mapping;
  62 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  63 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  65
  66 my %config = (
  67         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  68     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  69        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  70 );
  71
  72 sub description {
  73         my $result = shift or return;
  74         return "LDAP error #" . $result->code
  75                         . ": " . $result->error_name . "\n"
  76                         . "# " . $result->error_text . "\n";
  77 }
  78
  79 sub search_method {
  80     my $db     = shift or return;
  81     my $userid = shift or return;
  82         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  83         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  84         my $search = $db->search(
  85                   base => $base,
  86                 filter => $filter,
  87                 # attrs => ['*'],
  88         ) or die "LDAP search failed to return object.";
  89         my $count = $search->count;
  90         if ($search->code > 0) {
  91                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  92                 return 0;
  93         }
  94         if ($count != 1) {
  95                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
  96                 return 0;
  97         }
  98     return $search;
  99 }
 100
 101 sub checkpw_ldap {
 102     my ($dbh, $userid, $password) = @_;
 103     my @hosts = split(',', $prefhost);
 104     my $db = Net::LDAP->new(\@hosts);
 105     unless ( $db ) {
 106         warn "LDAP connexion failed";
 107         return 0;
 108     }
 109
 110         #$debug and $db->debug(5);
 111     my $userldapentry;
 112
 113   if ( $ldap->{auth_by_bind} ) {
 114     # Perform an anonymous bind
 115     my $res = $db->bind;
 116     if ( $res->code ) {
 117       $debug and warn "Anonymous LDAP bind failed: ". description($res);
 118       return 0;
 119     }
 120
 121     # Perform a LDAP search for the given username
 122     my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 123     $userldapentry = $search->shift_entry;
 124
 125     # Perform a LDAP bind for the given username using the matched DN
 126     $res = $db->bind( $userldapentry->dn, password => $password );
 127     if ( $res->code ) {
 128       $debug and warn "LDAP bind failed as kohauser $userid: ". description($res);
 129       return 0;
 130     }
 131
 132   } else {
 133                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 134                 if ($res->code) {               # connection refused
 135                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 136                         return 0;
 137                 }
 138         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 139         $userldapentry = $search->shift_entry;
 140                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 141                 if ($cmpmesg->code != 6) {
 142                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 143                         return 0;
 144                 }
 145         }
 146
 147     # To get here, LDAP has accepted our user's login attempt.
 148     # But we still have work to do.  See perldoc below for detailed breakdown.
 149
 150     my (%borrower);
 151         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 152
 153     if (( $borrowernumber and $config{update}   ) or
 154         (!$borrowernumber and $config{replicate})   ) {
 155         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 156         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 157     }
 158
 159     if ($borrowernumber) {
 160         if ($config{update}) { # A1, B1
 161             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 162             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 163         } else { # C1, D1
 164             # maybe update just the password?
 165                 return(1, $cardnumber, $local_userid);
 166         }
 167     } elsif ($config{replicate}) { # A2, C2
 168         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 169    } else {
 170         return 0;   # B2, D2
 171     }
 172     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 173         my @extended_patron_attributes;
 174         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 175             my $code = $attribute_type->{code};
 176             if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
 177                 push @extended_patron_attributes, { code => $code, value => $borrower{$code} };
 178             }
 179         }
 180         #Check before add
 181         my @unique_attr;
 182         foreach my $attr ( @extended_patron_attributes ) {
 183             if (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 184                 push @unique_attr, $attr;
 185             } else {
 186                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 187             }
 188         }
 189         C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, \@unique_attr);
 190     }
 191 return(1, $cardnumber, $userid);
 192 }
 193
 194 # Pass LDAP entry object and local cardnumber (userid).
 195 # Returns borrower hash.
 196 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 197 # Ensure that mandatory fields are correctly filled!
 198 #
 199 sub ldap_entry_2_hash {
 200         my $userldapentry = shift;
 201         my %borrower = ( cardnumber => shift );
 202         my %memberhash;
 203         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 204         if ($debug) {
 205                 foreach (keys %$userldapentry) {
 206                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 207                 }
 208         }
 209         my $x = $userldapentry->{attrs} or return;
 210         foreach (keys %$x) {
 211                 $memberhash{$_} = join ' ', @{$x->{$_}};
 212                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 213         }
 214         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 215                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 216         foreach my $key (keys %mapping) {
 217                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 218                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 219                 unless (defined $data) {
 220                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 221                 }
 222                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 223         }
 224         $borrower{initials} = $memberhash{initials} ||
 225                 ( substr($borrower{'firstname'},0,1)
 226                 . substr($borrower{ 'surname' },0,1)
 227                 . " ");
 228
 229         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 230         my $dbh = C4::Context->dbh;
 231         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 232         $sth->execute( uc($borrower{'categorycode'}) );
 233         unless ( my $row = $sth->fetchrow_hashref ) {
 234                 my $default = $mapping{'categorycode'}->{content};
 235                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 236                 $borrower{'categorycode'} = $default
 237         }
 238
 239         return %borrower;
 240 }
 241
 242 sub exists_local {
 243         my $arg = shift;
 244         my $dbh = C4::Context->dbh;
 245         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 246
 247         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 248         $sth->execute($arg);
 249         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 250         ($sth->rows == 1) and return $sth->fetchrow;
 251
 252         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 253         $sth->execute($arg);
 254         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 255         ($sth->rows == 1) and return $sth->fetchrow;
 256         return 0;
 257 }
 258
 259 sub _do_changepassword {
 260     my ($userid, $borrowerid, $digest) = @_;
 261     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 262     changepassword($userid, $borrowerid, $digest);
 263
 264         # Confirm changes
 265         my $sth = C4::Context->dbh->prepare("SELECT password,cardnumber FROM borrowers WHERE borrowernumber=? ");
 266         $sth->execute($borrowerid);
 267         if ($sth->rows) {
 268                 my ($md5password, $cardnum) = $sth->fetchrow;
 269         ($digest eq $md5password) and return $cardnum;
 270                 warn "Password mismatch after update to cardnumber=$cardnum (borrowernumber=$borrowerid)";
 271                 return;
 272         }
 273         die "Unexpected error after password update to userid/borrowernumber: $userid / $borrowerid.";
 274 }
 275
 276 sub update_local {
 277         my   $userid   = shift             or return;
 278         my   $digest   = md5_base64(shift) or return;
 279         my $borrowerid = shift             or return;
 280         my $borrower   = shift             or return;
 281         my @keys = keys %$borrower;
 282         my $dbh = C4::Context->dbh;
 283         my $query = "UPDATE  borrowers\nSET     " .
 284                 join(',', map {"$_=?"} @keys) .
 285                 "\nWHERE   borrowernumber=? ";
 286         my $sth = $dbh->prepare($query);
 287         if ($debug) {
 288                 print STDERR $query, "\n",
 289                         join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 290                 print STDERR "\nuserid = $userid\n";
 291         }
 292         $sth->execute(
 293                 ((map {$borrower->{$_}} @keys), $borrowerid)
 294         );
 295
 296         # MODIFY PASSWORD/LOGIN
 297         _do_changepassword($userid, $borrowerid, $digest);
 298 }
 299
 300 1;
 301 __END__
 302
 303 =head1 NAME
 304
 305 C4::Auth - Authenticates Koha users
 306
 307 =head1 SYNOPSIS
 308
 309   use C4::Auth_with_ldap;
 310
 311 =head1 LDAP Configuration
 312
 313     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 314         working LDAP servers.
 315         To use it :
 316            * Modify ldapserver element in KOHA_CONF
 317            * Establish field mapping in <mapping> element.
 318
 319         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 320         the username would match the "uid" field, and the password should match the "userpassword" field.
 321
 322         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 323         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 324
 325         mysql> show COLUMNS from borrowers;
 326                 +---------------------+--------------+------+-----+---------+----------------+
 327                 | Field               | Type         | Null | Key | Default | Extra          |
 328                 +---------------------+--------------+------+-----+---------+----------------+
 329                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 330                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 331                 | surname             | mediumtext   | NO   |     | NULL    |                |
 332                 | firstname           | text         | YES  |     | NULL    |                |
 333                 | title               | mediumtext   | YES  |     | NULL    |                |
 334                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 335                 | initials            | text         | YES  |     | NULL    |                |
 336                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 337                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 338                 | address             | mediumtext   | NO   |     | NULL    |                |
 339                 | address2            | text         | YES  |     | NULL    |                |
 340                 | city                | mediumtext   | NO   |     | NULL    |                |
 341                 | state               | mediumtext   | YES  |     | NULL    |                |
 342                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 343                 | country             | text         | YES  |     | NULL    |                |
 344                 | email               | mediumtext   | YES  |     | NULL    |                |
 345                 | phone               | text         | YES  |     | NULL    |                |
 346                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 347                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 348                 | emailpro            | text         | YES  |     | NULL    |                |
 349                 | phonepro            | text         | YES  |     | NULL    |                |
 350                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 351                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 352                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 353                 | B_address2          | text         | YES  |     | NULL    |                |
 354                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 355                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 356                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 357                 | B_country           | text         | YES  |     | NULL    |                |
 358                 | B_email             | text         | YES  |     | NULL    |                |
 359                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 360                 | dateofbirth         | date         | YES  |     | NULL    |                |
 361                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 362                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 363                 | dateenrolled        | date         | YES  |     | NULL    |                |
 364                 | dateexpiry          | date         | YES  |     | NULL    |                |
 365                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 366                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 367                 | debarred            | date         | YES  |     | NULL    |                |
 368                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 369                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 370                 | contactfirstname    | text         | YES  |     | NULL    |                |
 371                 | contacttitle        | text         | YES  |     | NULL    |                |
 372                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 373                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 374                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 375                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 376                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 377                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 378                 | password            | varchar(30)  | YES  |     | NULL    |                |
 379                 | flags               | int(11)      | YES  |     | NULL    |                |
 380                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 381                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 382                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 383                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 384                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 385                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 386                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 387                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 388                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 389                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 390                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 391                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 392                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 393                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 394                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 395                 | privacy             | int(11)      | NO   |     | 1       |                |
 396                 +---------------------+--------------+------+-----+---------+----------------+
 397                 66 rows in set (0.00 sec)
 398                 Where Null="NO", the field is required.
 399
 400 =head1 KOHA_CONF and field mapping
 401
 402 Example XML stanza for LDAP configuration in KOHA_CONF.
 403
 404  <config>
 405   ...
 406   <useldapserver>1</useldapserver>
 407   <!-- LDAP SERVER (optional) -->
 408   <ldapserver id="ldapserver">
 409     <hostname>localhost</hostname>
 410     <base>dc=metavore,dc=com</base>
 411     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 412     <pass>metavore</pass>          <!-- password, if not anonymous -->
 413     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 414     <update>1</update>             <!-- update existing users in Koha database -->
 415     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 416                                         password comparison, e.g., to use Active Directory -->
 417     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 418       <firstname    is="givenname"      ></firstname>
 419       <surname      is="sn"             ></surname>
 420       <address      is="postaladdress"  ></address>
 421       <city         is="l"              >Athens, OH</city>
 422       <zipcode      is="postalcode"     ></zipcode>
 423       <branchcode   is="branch"         >MAIN</branchcode>
 424       <userid       is="uid"            ></userid>
 425       <password     is="userpassword"   ></password>
 426       <email        is="mail"           ></email>
 427       <categorycode is="employeetype"   >PT</categorycode>
 428       <phone        is="telephonenumber"></phone>
 429     </mapping>
 430   </ldapserver>
 431  </config>
 432
 433 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 434 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 435 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 436 patron).
 437
 438 =head1 CONFIGURATION
 439
 440 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 441 your configuration and the presence of a matching Koha user in your local DB:
 442
 443                          LOCAL_USER
 444  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 445    A1      1       1        1      OK : We're updating them anyway.
 446    A2      1       1        0      OK : We're adding them anyway.
 447    B1      1       0        1      OK : We update them.
 448    B2      1       0        0     FAIL: We cannot add new user.
 449    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 450    C2      0       1        0      OK : We add the new user.
 451    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 452    D2      0       0        0     FAIL: We cannot add new user.
 453
 454 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 455 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 456 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 457
 458 If you choose NOT to update local users, the borrowers table will not be affected at all.
 459 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 460 the local table never contained the LDAP values.
 461
 462 =head2 auth_by_bind
 463
 464 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 465
 466 =head2 principal_name
 467
 468 Provides an optional sprintf-style format for manipulating the userid before the bind.
 469 Even though the userPrincipalName is one intended target, any uniquely identifying
 470 attribute that the server allows to be used for binding could be used.
 471
 472 Currently, principal_name only operates when auth_by_bind is enabled.
 473
 474 =head2 Active Directory
 475
 476 The auth_by_bind and principal_name settings are recommended for Active Directory.
 477
 478 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 479 we would typically under openldap.  Instead of:
 480
 481     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 482
 483 We might get:
 484
 485     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 486
 487 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 488 in Koha userids.  But the userPrincipalName should be consistent, something like:
 489
 490     userPrincipalName: barnes.7@my_company.com
 491
 492 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 493 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 494 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 495 like this:
 496     <principal_name>%s@core.my_company.com</principal_name>
 497
 498 The user of the previous example, barnes.7, would then attempt to bind as:
 499     barnes.7@core.my_company.com
 500
 501 =head1 SEE ALSO
 502
 503 CGI(3)
 504
 505 Net::LDAP()
 506
 507 XML::Simple()
 508
 509 Digest::MD5(3)
 510
 511 sprintf()
 512
 513 =cut
 514
 515 # For reference, here's an important difference in the data structure we rely on.
 516 # ========================================
 517 # Using attrs instead of {asn}->attributes
 518 # ========================================
 519 #
 520 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 521 #       LDAP key: ->{             cn}->{           sss} = sss
 522 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 523 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 524 #
 525 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 526 #       LDAP key: ->{      givenname}->{Steve} = Steve
 527 #