C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBIx::Connector;
 101 use Encode;
 102 use ZOOM;
 103 use XML::Simple;
 104 use C4::Boolean;
 105 use C4::Debug;
 106 use Koha;
 107 use POSIX ();
 108 use DateTime::TimeZone;
 109 use Module::Load::Conditional qw(can_load);
 110 use Carp;
 111
 112 =head1 NAME
 113
 114 C4::Context - Maintain and manipulate the context of a Koha script
 115
 116 =head1 SYNOPSIS
 117
 118   use C4::Context;
 119
 120   use C4::Context("/path/to/koha-conf.xml");
 121
 122   $config_value = C4::Context->config("config_variable");
 123
 124   $koha_preference = C4::Context->preference("preference");
 125
 126   $db_handle = C4::Context->dbh;
 127
 128   $Zconn = C4::Context->Zconn;
 129
 130   $stopwordhash = C4::Context->stopwords;
 131
 132 =head1 DESCRIPTION
 133
 134 When a Koha script runs, it makes use of a certain number of things:
 135 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 136 databases, and so forth. These things make up the I<context> in which
 137 the script runs.
 138
 139 This module takes care of setting up the context for a script:
 140 figuring out which configuration file to load, and loading it, opening
 141 a connection to the right database, and so forth.
 142
 143 Most scripts will only use one context. They can simply have
 144
 145   use C4::Context;
 146
 147 at the top.
 148
 149 Other scripts may need to use several contexts. For instance, if a
 150 library has two databases, one for a certain collection, and the other
 151 for everything else, it might be necessary for a script to use two
 152 different contexts to search both databases. Such scripts should use
 153 the C<&set_context> and C<&restore_context> functions, below.
 154
 155 By default, C4::Context reads the configuration from
 156 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 157 environment variable to the pathname of a configuration file to use.
 158
 159 =head1 METHODS
 160
 161 =cut
 162
 163 #'
 164 # In addition to what is said in the POD above, a Context object is a
 165 # reference-to-hash with the following fields:
 166 #
 167 # config
 168 #    A reference-to-hash whose keys and values are the
 169 #    configuration variables and values specified in the config
 170 #    file (/etc/koha/koha-conf.xml).
 171 # dbh
 172 #    A handle to the appropriate database for this context.
 173 # dbh_stack
 174 #    Used by &set_dbh and &restore_dbh to hold other database
 175 #    handles for this context.
 176 # Zconn
 177 #     A connection object for the Zebra server
 178
 179 # Koha's main configuration file koha-conf.xml
 180 # is searched for according to this priority list:
 181 #
 182 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 183 # 2. Path supplied in KOHA_CONF environment variable.
 184 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 185 #    as value has changed from its default of
 186 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 187 #    when Koha is installed in 'standard' or 'single'
 188 #    mode.
 189 # 4. Path supplied in CONFIG_FNAME.
 190 #
 191 # The first entry that refers to a readable file is used.
 192
 193 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 194                 # Default config file, if none is specified
 195
 196 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 197                 # path to config file set by installer
 198                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 199                 # when Koha is installed in 'standard' or 'single'
 200                 # mode.  If Koha was installed in 'dev' mode,
 201                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 202                 # developers should set the KOHA_CONF environment variable
 203
 204 $context = undef;        # Initially, no context is set
 205 @context_stack = ();        # Initially, no saved contexts
 206
 207
 208 =head2 read_config_file
 209
 210 Reads the specified Koha config file.
 211
 212 Returns an object containing the configuration variables. The object's
 213 structure is a bit complex to the uninitiated ... take a look at the
 214 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 215 here are a few examples that may give you what you need:
 216
 217 The simple elements nested within the <config> element:
 218
 219     my $pass = $koha->{'config'}->{'pass'};
 220
 221 The <listen> elements:
 222
 223     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 224
 225 The elements nested within the <server> element:
 226
 227     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 228
 229 Returns undef in case of error.
 230
 231 =cut
 232
 233 sub read_config_file {          # Pass argument naming config file to read
 234     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 235
 236     if ($ismemcached) {
 237       $memcached->set('kohaconf',$koha);
 238     }
 239
 240     return $koha;                       # Return value: ref-to-hash holding the configuration
 241 }
 242
 243 =head2 ismemcached
 244
 245 Returns the value of the $ismemcached variable (0/1)
 246
 247 =cut
 248
 249 sub ismemcached {
 250     return $ismemcached;
 251 }
 252
 253 =head2 memcached
 254
 255 If $ismemcached is true, returns the $memcache variable.
 256 Returns undef otherwise
 257
 258 =cut
 259
 260 sub memcached {
 261     if ($ismemcached) {
 262       return $memcached;
 263     } else {
 264       return;
 265     }
 266 }
 267
 268 =head2 db_scheme2dbi
 269
 270     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 271
 272 This routines translates a database type to part of the name
 273 of the appropriate DBD driver to use when establishing a new
 274 database connection.  It recognizes 'mysql' and 'Pg'; if any
 275 other scheme is supplied it defaults to 'mysql'.
 276
 277 =cut
 278
 279 sub db_scheme2dbi {
 280     my $scheme = shift // '';
 281     return $scheme eq 'Pg' ? $scheme : 'mysql';
 282 }
 283
 284 sub import {
 285     # Create the default context ($C4::Context::Context)
 286     # the first time the module is called
 287     # (a config file can be optionaly passed)
 288
 289     # default context allready exists?
 290     return if $context;
 291
 292     # no ? so load it!
 293     my ($pkg,$config_file) = @_ ;
 294     my $new_ctx = __PACKAGE__->new($config_file);
 295     return unless $new_ctx;
 296
 297     # if successfully loaded, use it by default
 298     $new_ctx->set_context;
 299     1;
 300 }
 301
 302 =head2 new
 303
 304   $context = new C4::Context;
 305   $context = new C4::Context("/path/to/koha-conf.xml");
 306
 307 Allocates a new context. Initializes the context from the specified
 308 file, which defaults to either the file given by the C<$KOHA_CONF>
 309 environment variable, or F</etc/koha/koha-conf.xml>.
 310
 311 It saves the koha-conf.xml values in the declared memcached server(s)
 312 if currently available and uses those values until them expire and
 313 re-reads them.
 314
 315 C<&new> does not set this context as the new default context; for
 316 that, use C<&set_context>.
 317
 318 =cut
 319
 320 #'
 321 # Revision History:
 322 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 323 sub new {
 324     my $class = shift;
 325     my $conf_fname = shift;        # Config file to load
 326     my $self = {};
 327
 328     # check that the specified config file exists and is not empty
 329     undef $conf_fname unless
 330         (defined $conf_fname && -s $conf_fname);
 331     # Figure out a good config file to load if none was specified.
 332     if (!defined($conf_fname))
 333     {
 334         # If the $KOHA_CONF environment variable is set, use
 335         # that. Otherwise, use the built-in default.
 336         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 337             $conf_fname = $ENV{"KOHA_CONF"};
 338         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 339             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 340             # regex to anything else -- don't want installer to rewrite it
 341             $conf_fname = $INSTALLED_CONFIG_FNAME;
 342         } elsif (-s CONFIG_FNAME) {
 343             $conf_fname = CONFIG_FNAME;
 344         } else {
 345             warn "unable to locate Koha configuration file koha-conf.xml";
 346             return;
 347         }
 348     }
 349
 350     if ($ismemcached) {
 351         # retreive from memcached
 352         $self = $memcached->get('kohaconf');
 353         if (not defined $self) {
 354             # not in memcached yet
 355             $self = read_config_file($conf_fname);
 356         }
 357     } else {
 358         # non-memcached env, read from file
 359         $self = read_config_file($conf_fname);
 360     }
 361
 362     $self->{"config_file"} = $conf_fname;
 363     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 364     return if !defined($self->{"config"});
 365
 366     $self->{"dbh"} = undef;        # Database handle
 367     $self->{"Zconn"} = undef;    # Zebra Connections
 368     $self->{"stopwords"} = undef; # stopwords list
 369     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 370     $self->{"userenv"} = undef;        # User env
 371     $self->{"activeuser"} = undef;        # current active user
 372     $self->{"shelves"} = undef;
 373     $self->{tz} = undef; # local timezone object
 374
 375     bless $self, $class;
 376     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 377     return $self;
 378 }
 379
 380 =head2 set_context
 381
 382   $context = new C4::Context;
 383   $context->set_context();
 384 or
 385   set_context C4::Context $context;
 386
 387   ...
 388   restore_context C4::Context;
 389
 390 In some cases, it might be necessary for a script to use multiple
 391 contexts. C<&set_context> saves the current context on a stack, then
 392 sets the context to C<$context>, which will be used in future
 393 operations. To restore the previous context, use C<&restore_context>.
 394
 395 =cut
 396
 397 #'
 398 sub set_context
 399 {
 400     my $self = shift;
 401     my $new_context;    # The context to set
 402
 403     # Figure out whether this is a class or instance method call.
 404     #
 405     # We're going to make the assumption that control got here
 406     # through valid means, i.e., that the caller used an instance
 407     # or class method call, and that control got here through the
 408     # usual inheritance mechanisms. The caller can, of course,
 409     # break this assumption by playing silly buggers, but that's
 410     # harder to do than doing it properly, and harder to check
 411     # for.
 412     if (ref($self) eq "")
 413     {
 414         # Class method. The new context is the next argument.
 415         $new_context = shift;
 416     } else {
 417         # Instance method. The new context is $self.
 418         $new_context = $self;
 419     }
 420
 421     # Save the old context, if any, on the stack
 422     push @context_stack, $context if defined($context);
 423
 424     # Set the new context
 425     $context = $new_context;
 426 }
 427
 428 =head2 restore_context
 429
 430   &restore_context;
 431
 432 Restores the context set by C<&set_context>.
 433
 434 =cut
 435
 436 #'
 437 sub restore_context
 438 {
 439     my $self = shift;
 440
 441     if ($#context_stack < 0)
 442     {
 443         # Stack underflow.
 444         die "Context stack underflow";
 445     }
 446
 447     # Pop the old context and set it.
 448     $context = pop @context_stack;
 449
 450     # FIXME - Should this return something, like maybe the context
 451     # that was current when this was called?
 452 }
 453
 454 =head2 config
 455
 456   $value = C4::Context->config("config_variable");
 457
 458   $value = C4::Context->config_variable;
 459
 460 Returns the value of a variable specified in the configuration file
 461 from which the current context was created.
 462
 463 The second form is more compact, but of course may conflict with
 464 method names. If there is a configuration variable called "new", then
 465 C<C4::Config-E<gt>new> will not return it.
 466
 467 =cut
 468
 469 sub _common_config {
 470         my $var = shift;
 471         my $term = shift;
 472     return if !defined($context->{$term});
 473        # Presumably $self->{$term} might be
 474        # undefined if the config file given to &new
 475        # didn't exist, and the caller didn't bother
 476        # to check the return value.
 477
 478     # Return the value of the requested config variable
 479     return $context->{$term}->{$var};
 480 }
 481
 482 sub config {
 483         return _common_config($_[1],'config');
 484 }
 485 sub zebraconfig {
 486         return _common_config($_[1],'server');
 487 }
 488 sub ModZebrations {
 489         return _common_config($_[1],'serverinfo');
 490 }
 491
 492 =head2 preference
 493
 494   $sys_preference = C4::Context->preference('some_variable');
 495
 496 Looks up the value of the given system preference in the
 497 systempreferences table of the Koha database, and returns it. If the
 498 variable is not set or does not exist, undef is returned.
 499
 500 In case of an error, this may return 0.
 501
 502 Note: It is impossible to tell the difference between system
 503 preferences which do not exist, and those whose values are set to NULL
 504 with this method.
 505
 506 =cut
 507
 508 # FIXME: running this under mod_perl will require a means of
 509 # flushing the caching mechanism.
 510
 511 my %sysprefs;
 512 my $use_syspref_cache = 1;
 513
 514 sub preference {
 515     my $self = shift;
 516     my $var  = shift;    # The system preference to return
 517
 518     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 519         return $sysprefs{lc $var};
 520     }
 521
 522     my $dbh  = C4::Context->dbh or return 0;
 523
 524     my $value;
 525     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 526         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 527     } else {
 528         # Look up systempreferences.variable==$var
 529         my $sql = q{
 530             SELECT  value
 531             FROM    systempreferences
 532             WHERE   variable = ?
 533             LIMIT   1
 534         };
 535         $value = $dbh->selectrow_array( $sql, {}, lc $var );
 536     }
 537
 538     $sysprefs{lc $var} = $value;
 539     return $value;
 540 }
 541
 542 sub boolean_preference {
 543     my $self = shift;
 544     my $var = shift;        # The system preference to return
 545     my $it = preference($self, $var);
 546     return defined($it)? C4::Boolean::true_p($it): undef;
 547 }
 548
 549 =head2 enable_syspref_cache
 550
 551   C4::Context->enable_syspref_cache();
 552
 553 Enable the in-memory syspref cache used by C4::Context. This is the
 554 default behavior.
 555
 556 =cut
 557
 558 sub enable_syspref_cache {
 559     my ($self) = @_;
 560     $use_syspref_cache = 1;
 561 }
 562
 563 =head2 disable_syspref_cache
 564
 565   C4::Context->disable_syspref_cache();
 566
 567 Disable the in-memory syspref cache used by C4::Context. This should be
 568 used with Plack and other persistent environments.
 569
 570 =cut
 571
 572 sub disable_syspref_cache {
 573     my ($self) = @_;
 574     $use_syspref_cache = 0;
 575     $self->clear_syspref_cache();
 576 }
 577
 578 =head2 clear_syspref_cache
 579
 580   C4::Context->clear_syspref_cache();
 581
 582 cleans the internal cache of sysprefs. Please call this method if
 583 you update the systempreferences table. Otherwise, your new changes
 584 will not be seen by this process.
 585
 586 =cut
 587
 588 sub clear_syspref_cache {
 589     %sysprefs = ();
 590 }
 591
 592 =head2 set_preference
 593
 594   C4::Context->set_preference( $variable, $value );
 595
 596 This updates a preference's value both in the systempreferences table and in
 597 the sysprefs cache.
 598
 599 =cut
 600
 601 sub set_preference {
 602     my $self = shift;
 603     my $var = lc(shift);
 604     my $value = shift;
 605
 606     my $dbh = C4::Context->dbh or return 0;
 607
 608     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 609
 610     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 611
 612     # force explicit protocol on OPACBaseURL
 613     if ($var eq 'opacbaseurl' && substr($value,0,4) !~ /http/) {
 614         $value = 'http://' . $value;
 615     }
 616
 617     my $sth = $dbh->prepare( "
 618       INSERT INTO systempreferences
 619         ( variable, value )
 620         VALUES( ?, ? )
 621         ON DUPLICATE KEY UPDATE value = VALUES(value)
 622     " );
 623
 624     if($sth->execute( $var, $value )) {
 625         $sysprefs{$var} = $value;
 626     }
 627     $sth->finish;
 628 }
 629
 630 # AUTOLOAD
 631 # This implements C4::Config->foo, and simply returns
 632 # C4::Context->config("foo"), as described in the documentation for
 633 # &config, above.
 634
 635 # FIXME - Perhaps this should be extended to check &config first, and
 636 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 637 # code, so it'd probably be best to delete it altogether so as not to
 638 # encourage people to use it.
 639 sub AUTOLOAD
 640 {
 641     my $self = shift;
 642
 643     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 644                     # leaving only the function name.
 645     return $self->config($AUTOLOAD);
 646 }
 647
 648 =head2 Zconn
 649
 650   $Zconn = C4::Context->Zconn
 651
 652 Returns a connection to the Zebra database
 653
 654 C<$self>
 655
 656 C<$server> one of the servers defined in the koha-conf.xml file
 657
 658 C<$async> whether this is a asynchronous connection
 659
 660 =cut
 661
 662 sub Zconn {
 663     my ($self, $server, $async ) = @_;
 664     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 665     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 666         # if we are running the script from the commandline, lets try to use the caching
 667         return $context->{"Zconn"}->{$cache_key};
 668     }
 669     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 670     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 671     return $context->{"Zconn"}->{$cache_key};
 672 }
 673
 674 =head2 _new_Zconn
 675
 676 $context->{"Zconn"} = &_new_Zconn($server,$async);
 677
 678 Internal function. Creates a new database connection from the data given in the current context and returns it.
 679
 680 C<$server> one of the servers defined in the koha-conf.xml file
 681
 682 C<$async> whether this is a asynchronous connection
 683
 684 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 685
 686 =cut
 687
 688 sub _new_Zconn {
 689     my ( $server, $async ) = @_;
 690
 691     my $tried=0; # first attempt
 692     my $Zconn; # connection object
 693     my $elementSetName;
 694     my $index_mode;
 695     my $syntax;
 696
 697     $server //= "biblioserver";
 698
 699     if ( $server eq 'biblioserver' ) {
 700         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 701     } elsif ( $server eq 'authorityserver' ) {
 702         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 703     }
 704
 705     if ( $index_mode eq 'grs1' ) {
 706         $elementSetName = 'F';
 707         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 708                 ? 'unimarc'
 709                 : 'usmarc';
 710
 711     } else { # $index_mode eq 'dom'
 712         $syntax = 'xml';
 713         $elementSetName = 'marcxml';
 714     }
 715
 716     my $host = $context->{'listen'}->{$server}->{'content'};
 717     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 718     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 719     eval {
 720         # set options
 721         my $o = new ZOOM::Options();
 722         $o->option(user => $user) if $user && $password;
 723         $o->option(password => $password) if $user && $password;
 724         $o->option(async => 1) if $async;
 725         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 726         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 727         $o->option(preferredRecordSyntax => $syntax);
 728         $o->option(elementSetName => $elementSetName) if $elementSetName;
 729         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 730
 731         # create a new connection object
 732         $Zconn= create ZOOM::Connection($o);
 733
 734         # forge to server
 735         $Zconn->connect($host, 0);
 736
 737         # check for errors and warn
 738         if ($Zconn->errcode() !=0) {
 739             warn "something wrong with the connection: ". $Zconn->errmsg();
 740         }
 741     };
 742     return $Zconn;
 743 }
 744
 745 # _new_dbh
 746 # Internal helper function (not a method!). This creates a new
 747 # database connection from the data given in the current context, and
 748 # returns it.
 749 sub _new_dbh
 750 {
 751
 752     ## $context
 753     ## correct name for db_scheme
 754     my $db_driver = $context->{db_driver};
 755
 756     my $db_name   = $context->config("database");
 757     my $db_host   = $context->config("hostname");
 758     my $db_port   = $context->config("port") || '';
 759     my $db_user   = $context->config("user");
 760     my $db_passwd = $context->config("pass");
 761     # MJR added or die here, as we can't work without dbh
 762     my $dbh = DBIx::Connector->connect(
 763         "dbi:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 764         $db_user, $db_passwd,
 765         {
 766             'RaiseError' => $ENV{DEBUG} ? 1 : 0
 767         }
 768     );
 769
 770     # Check for the existence of a systempreference table; if we don't have this, we don't
 771     # have a valid database and should not set RaiseError in order to allow the installer
 772     # to run; installer will not run otherwise since we raise all db errors
 773
 774     eval {
 775                 local $dbh->{PrintError} = 0;
 776                 local $dbh->{RaiseError} = 1;
 777                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 778     };
 779
 780     if ($@) {
 781         $dbh->{RaiseError} = 0;
 782     }
 783
 784     if ( $db_driver eq 'mysql' ) {
 785         $dbh->{mysql_auto_reconnect} = 1;
 786     }
 787
 788         my $tz = $ENV{TZ};
 789     if ( $db_driver eq 'mysql' ) {
 790         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 791         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 792         $dbh->{'mysql_enable_utf8'}=1; #enable
 793         $dbh->do("set NAMES 'utf8'");
 794         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 795     }
 796     elsif ( $db_driver eq 'Pg' ) {
 797             $dbh->do( "set client_encoding = 'UTF8';" );
 798         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 799     }
 800     return $dbh;
 801 }
 802
 803 =head2 dbh
 804
 805   $dbh = C4::Context->dbh;
 806
 807 Returns a database handle connected to the Koha database for the
 808 current context. If no connection has yet been made, this method
 809 creates one, and connects to the database.
 810
 811 This database handle is cached for future use: if you call
 812 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 813 times. If you need a second database handle, use C<&new_dbh> and
 814 possibly C<&set_dbh>.
 815
 816 =cut
 817
 818 #'
 819 sub dbh
 820 {
 821     my $self = shift;
 822     my $params = shift;
 823     my $sth;
 824
 825     unless ( $params->{new} ) {
 826         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 827             return $context->{"dbh"};
 828         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 829             return $context->{"dbh"};
 830         }
 831     }
 832
 833     # No database handle or it died . Create one.
 834     $context->{"dbh"} = &_new_dbh();
 835
 836     return $context->{"dbh"};
 837 }
 838
 839 =head2 new_dbh
 840
 841   $dbh = C4::Context->new_dbh;
 842
 843 Creates a new connection to the Koha database for the current context,
 844 and returns the database handle (a C<DBI::db> object).
 845
 846 The handle is not saved anywhere: this method is strictly a
 847 convenience function; the point is that it knows which database to
 848 connect to so that the caller doesn't have to know.
 849
 850 =cut
 851
 852 #'
 853 sub new_dbh
 854 {
 855     my $self = shift;
 856
 857     return &_new_dbh();
 858 }
 859
 860 =head2 set_dbh
 861
 862   $my_dbh = C4::Connect->new_dbh;
 863   C4::Connect->set_dbh($my_dbh);
 864   ...
 865   C4::Connect->restore_dbh;
 866
 867 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 868 C<&set_context> and C<&restore_context>.
 869
 870 C<&set_dbh> saves the current database handle on a stack, then sets
 871 the current database handle to C<$my_dbh>.
 872
 873 C<$my_dbh> is assumed to be a good database handle.
 874
 875 =cut
 876
 877 #'
 878 sub set_dbh
 879 {
 880     my $self = shift;
 881     my $new_dbh = shift;
 882
 883     # Save the current database handle on the handle stack.
 884     # We assume that $new_dbh is all good: if the caller wants to
 885     # screw himself by passing an invalid handle, that's fine by
 886     # us.
 887     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 888     $context->{"dbh"} = $new_dbh;
 889 }
 890
 891 =head2 restore_dbh
 892
 893   C4::Context->restore_dbh;
 894
 895 Restores the database handle saved by an earlier call to
 896 C<C4::Context-E<gt>set_dbh>.
 897
 898 =cut
 899
 900 #'
 901 sub restore_dbh
 902 {
 903     my $self = shift;
 904
 905     if ($#{$context->{"dbh_stack"}} < 0)
 906     {
 907         # Stack underflow
 908         die "DBH stack underflow";
 909     }
 910
 911     # Pop the old database handle and set it.
 912     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 913
 914     # FIXME - If it is determined that restore_context should
 915     # return something, then this function should, too.
 916 }
 917
 918 =head2 queryparser
 919
 920   $queryparser = C4::Context->queryparser
 921
 922 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 923
 924 =cut
 925
 926 sub queryparser {
 927     my $self = shift;
 928     unless (defined $context->{"queryparser"}) {
 929         $context->{"queryparser"} = &_new_queryparser();
 930     }
 931
 932     return
 933       defined( $context->{"queryparser"} )
 934       ? $context->{"queryparser"}->new
 935       : undef;
 936 }
 937
 938 =head2 _new_queryparser
 939
 940 Internal helper function to create a new QueryParser object. QueryParser
 941 is loaded dynamically so as to keep the lack of the QueryParser library from
 942 getting in anyone's way.
 943
 944 =cut
 945
 946 sub _new_queryparser {
 947     my $qpmodules = {
 948         'OpenILS::QueryParser'           => undef,
 949         'Koha::QueryParser::Driver::PQF' => undef
 950     };
 951     if ( can_load( 'modules' => $qpmodules ) ) {
 952         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 953         my $config_file = $context->config('queryparser_config');
 954         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 955         if ( $QParser->load_config($config_file) ) {
 956             # Set 'keyword' as the default search class
 957             $QParser->default_search_class('keyword');
 958             # TODO: allow indexes to be configured in the database
 959             return $QParser;
 960         }
 961     }
 962     return;
 963 }
 964
 965 =head2 marcfromkohafield
 966
 967   $dbh = C4::Context->marcfromkohafield;
 968
 969 Returns a hash with marcfromkohafield.
 970
 971 This hash is cached for future use: if you call
 972 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 973
 974 =cut
 975
 976 #'
 977 sub marcfromkohafield
 978 {
 979     my $retval = {};
 980
 981     # If the hash already exists, return it.
 982     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 983
 984     # No hash. Create one.
 985     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 986
 987     return $context->{"marcfromkohafield"};
 988 }
 989
 990 # _new_marcfromkohafield
 991 # Internal helper function (not a method!). This creates a new
 992 # hash with stopwords
 993 sub _new_marcfromkohafield
 994 {
 995     my $dbh = C4::Context->dbh;
 996     my $marcfromkohafield;
 997     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 998     $sth->execute;
 999     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1000         my $retval = {};
1001         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1002     }
1003     return $marcfromkohafield;
1004 }
1005
1006 =head2 stopwords
1007
1008   $dbh = C4::Context->stopwords;
1009
1010 Returns a hash with stopwords.
1011
1012 This hash is cached for future use: if you call
1013 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1014
1015 =cut
1016
1017 #'
1018 sub stopwords
1019 {
1020     my $retval = {};
1021
1022     # If the hash already exists, return it.
1023     return $context->{"stopwords"} if defined($context->{"stopwords"});
1024
1025     # No hash. Create one.
1026     $context->{"stopwords"} = &_new_stopwords();
1027
1028     return $context->{"stopwords"};
1029 }
1030
1031 # _new_stopwords
1032 # Internal helper function (not a method!). This creates a new
1033 # hash with stopwords
1034 sub _new_stopwords
1035 {
1036     my $dbh = C4::Context->dbh;
1037     my $stopwordlist;
1038     my $sth = $dbh->prepare("select word from stopwords");
1039     $sth->execute;
1040     while (my $stopword = $sth->fetchrow_array) {
1041         $stopwordlist->{$stopword} = uc($stopword);
1042     }
1043     $stopwordlist->{A} = "A" unless $stopwordlist;
1044     return $stopwordlist;
1045 }
1046
1047 =head2 userenv
1048
1049   C4::Context->userenv;
1050
1051 Retrieves a hash for user environment variables.
1052
1053 This hash shall be cached for future use: if you call
1054 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1055
1056 =cut
1057
1058 #'
1059 sub userenv {
1060     my $var = $context->{"activeuser"};
1061     if (defined $var and defined $context->{"userenv"}->{$var}) {
1062         return $context->{"userenv"}->{$var};
1063     } else {
1064         return;
1065     }
1066 }
1067
1068 =head2 set_userenv
1069
1070   C4::Context->set_userenv($usernum, $userid, $usercnum,
1071                            $userfirstname, $usersurname,
1072                            $userbranch, $branchname, $userflags,
1073                            $emailaddress, $branchprinter, $persona);
1074
1075 Establish a hash of user environment variables.
1076
1077 set_userenv is called in Auth.pm
1078
1079 =cut
1080
1081 #'
1082 sub set_userenv {
1083     shift @_;
1084     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
1085     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
1086     @_;
1087     my $var=$context->{"activeuser"} || '';
1088     my $cell = {
1089         "number"     => $usernum,
1090         "id"         => $userid,
1091         "cardnumber" => $usercnum,
1092         "firstname"  => $userfirstname,
1093         "surname"    => $usersurname,
1094         #possibly a law problem
1095         "branch"     => $userbranch,
1096         "branchname" => $branchname,
1097         "flags"      => $userflags,
1098         "emailaddress"     => $emailaddress,
1099         "branchprinter"    => $branchprinter,
1100         "persona"    => $persona,
1101         "shibboleth" => $shibboleth,
1102     };
1103     $context->{userenv}->{$var} = $cell;
1104     return $cell;
1105 }
1106
1107 sub set_shelves_userenv {
1108         my ($type, $shelves) = @_ or return;
1109         my $activeuser = $context->{activeuser} or return;
1110         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1111         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1112         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1113 }
1114
1115 sub get_shelves_userenv {
1116         my $active;
1117         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1118                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1119                 return;
1120         }
1121         my $totshelves = $active->{totshelves} or undef;
1122         my $pubshelves = $active->{pubshelves} or undef;
1123         my $barshelves = $active->{barshelves} or undef;
1124         return ($totshelves, $pubshelves, $barshelves);
1125 }
1126
1127 =head2 _new_userenv
1128
1129   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1130
1131 Builds a hash for user environment variables.
1132
1133 This hash shall be cached for future use: if you call
1134 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1135
1136 _new_userenv is called in Auth.pm
1137
1138 =cut
1139
1140 #'
1141 sub _new_userenv
1142 {
1143     shift;  # Useless except it compensates for bad calling style
1144     my ($sessionID)= @_;
1145      $context->{"activeuser"}=$sessionID;
1146 }
1147
1148 =head2 _unset_userenv
1149
1150   C4::Context->_unset_userenv;
1151
1152 Destroys the hash for activeuser user environment variables.
1153
1154 =cut
1155
1156 #'
1157
1158 sub _unset_userenv
1159 {
1160     my ($sessionID)= @_;
1161     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1162 }
1163
1164
1165 =head2 get_versions
1166
1167   C4::Context->get_versions
1168
1169 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1170
1171 =cut
1172
1173 #'
1174
1175 # A little example sub to show more debugging info for CGI::Carp
1176 sub get_versions {
1177     my %versions;
1178     $versions{kohaVersion}  = Koha::version();
1179     $versions{kohaDbVersion} = C4::Context->preference('version');
1180     $versions{osVersion} = join(" ", POSIX::uname());
1181     $versions{perlVersion} = $];
1182     {
1183         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1184         $versions{mysqlVersion}  = `mysql -V`;
1185         $versions{apacheVersion} = `httpd -v`;
1186         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1187         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1188         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1189     }
1190     return %versions;
1191 }
1192
1193
1194 =head2 tz
1195
1196   C4::Context->tz
1197
1198   Returns a DateTime::TimeZone object for the system timezone
1199
1200 =cut
1201
1202 sub tz {
1203     my $self = shift;
1204     if (!defined $context->{tz}) {
1205         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1206     }
1207     return $context->{tz};
1208 }
1209
1210
1211 =head2 IsSuperLibrarian
1212
1213     C4::Context->IsSuperlibrarian();
1214
1215 =cut
1216
1217 sub IsSuperLibrarian {
1218     my $userenv = C4::Context->userenv;
1219
1220     unless ( $userenv and exists $userenv->{flags} ) {
1221         # If we reach this without a user environment,
1222         # assume that we're running from a command-line script,
1223         # and act as a superlibrarian.
1224         carp("C4::Context->userenv not defined!");
1225         return 1;
1226     }
1227
1228     return ($userenv->{flags}//0) % 2;
1229 }
1230
1231 =head2 interface
1232
1233 Sets the current interface for later retrieval in any Perl module
1234
1235     C4::Context->interface('opac');
1236     C4::Context->interface('intranet');
1237     my $interface = C4::Context->interface;
1238
1239 =cut
1240
1241 sub interface {
1242     my ($class, $interface) = @_;
1243
1244     if (defined $interface) {
1245         $interface = lc $interface;
1246         if ($interface eq 'opac' || $interface eq 'intranet') {
1247             $context->{interface} = $interface;
1248         } else {
1249             warn "invalid interface : '$interface'";
1250         }
1251     }
1252
1253     return $context->{interface} // 'opac';
1254 }
1255
1256 1;
1257 __END__
1258
1259 =head1 ENVIRONMENT
1260
1261 =head2 C<KOHA_CONF>
1262
1263 Specifies the configuration file to read.
1264
1265 =head1 SEE ALSO
1266
1267 XML::Simple
1268
1269 =head1 AUTHORS
1270
1271 Andrew Arensburger <arensb at ooblick dot com>
1272
1273 Joshua Ferraro <jmf at liblime dot com>
1274