C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use Koha::Cache::Memory::Lite;
  30 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  31
  32 BEGIN {
  33     $VERSION = 3.07.00.049;
  34     require Exporter;
  35     @ISA    = qw(Exporter);
  36     @EXPORT = qw(
  37         &getFrameworkLanguages
  38         &getTranslatedLanguages
  39         &getLanguages
  40         &getAllLanguages
  41     );
  42     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage);
  43     $DEBUG = 0;
  44 }
  45
  46 =head1 NAME
  47
  48 C4::Languages - Perl Module containing language list functions for Koha
  49
  50 =head1 SYNOPSIS
  51
  52 use C4::Languages;
  53
  54 =head1 DESCRIPTION
  55
  56 =cut
  57
  58 =head1 FUNCTIONS
  59
  60 =head2 getFrameworkLanguages
  61
  62 Returns a reference to an array of hashes:
  63
  64  my $languages = getFrameworkLanguages();
  65  for my $language(@$languages) {
  66     print "$language->{language_code}\n"; # language code in iso 639-2
  67     print "$language->{language_name}\n"; # language name in native script
  68     print "$language->{language_locale_name}\n"; # language name in current locale
  69  }
  70
  71 =cut
  72
  73 sub getFrameworkLanguages {
  74     # get a hash with all language codes, names, and locale names
  75     my $all_languages = getAllLanguages();
  76     my @languages;
  77
  78     # find the available directory names
  79     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  80     opendir (MYDIR,$dir);
  81     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  82     closedir MYDIR;
  83
  84     # pull out all data for the dir names that exist
  85     for my $dirname (@listdir) {
  86         for my $language_set (@$all_languages) {
  87
  88             if ($dirname eq $language_set->{language_code}) {
  89                 push @languages, {
  90                     'language_code'=>$dirname,
  91                     'language_description'=>$language_set->{language_description},
  92                     'native_descrition'=>$language_set->{language_native_description} }
  93             }
  94         }
  95     }
  96     return \@languages;
  97 }
  98
  99 =head2 getTranslatedLanguages
 100
 101 Returns a reference to an array of hashes:
 102
 103  my $languages = getTranslatedLanguages();
 104  print "Available translated languages:\n";
 105  for my $language(@$trlanguages) {
 106     print "$language->{language_code}\n"; # language code in iso 639-2
 107     print "$language->{language_name}\n"; # language name in native script
 108     print "$language->{language_locale_name}\n"; # language name in current locale
 109  }
 110
 111 =cut
 112
 113 sub getTranslatedLanguages {
 114     my ($interface, $theme, $current_language, $which) = @_;
 115     my $htdocs;
 116     my @languages;
 117     my @enabled_languages;
 118
 119     if ($interface && $interface eq 'opac' ) {
 120         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 121         $htdocs = C4::Context->config('opachtdocs');
 122         if ( $theme and -d "$htdocs/$theme" ) {
 123             (@languages) = _get_language_dirs($htdocs,$theme);
 124         }
 125         else {
 126             for my $theme ( _get_themes('opac') ) {
 127                 push @languages, _get_language_dirs($htdocs,$theme);
 128             }
 129         }
 130     }
 131     elsif ($interface && $interface eq 'intranet' ) {
 132         @enabled_languages = split ",", C4::Context->preference('language');
 133         $htdocs = C4::Context->config('intrahtdocs');
 134         if ( $theme and -d "$htdocs/$theme" ) {
 135             @languages = _get_language_dirs($htdocs,$theme);
 136         }
 137         else {
 138             foreach my $theme ( _get_themes('intranet') ) {
 139                 push @languages, _get_language_dirs($htdocs,$theme);
 140             }
 141         }
 142     }
 143     else {
 144         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 145         my $htdocs = C4::Context->config('intrahtdocs');
 146         foreach my $theme ( _get_themes('intranet') ) {
 147             push @languages, _get_language_dirs($htdocs,$theme);
 148         }
 149         $htdocs = C4::Context->config('opachtdocs');
 150         foreach my $theme ( _get_themes('opac') ) {
 151             push @languages, _get_language_dirs($htdocs,$theme);
 152         }
 153         my %seen;
 154         $seen{$_}++ for @languages;
 155         @languages = keys %seen;
 156     }
 157     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 158 }
 159
 160 =head2 getAllLanguages
 161
 162 Returns a reference to an array of hashes:
 163
 164  my $alllanguages = getAllLanguages();
 165  print "Available translated languages:\n";
 166  for my $language(@$alllanguages) {
 167     print "$language->{language_code}\n";
 168     print "$language->{language_name}\n";
 169     print "$language->{language_locale_name}\n";
 170  }
 171
 172 This routine is a wrapper for getLanguages().
 173
 174 =cut
 175
 176 sub getAllLanguages {
 177     return getLanguages(shift);
 178 }
 179
 180 =head2 getLanguages
 181
 182     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 183
 184 Returns a reference to an array of hashes of languages.
 185
 186 - If no parameter is passed to the function, it returns english languages names
 187 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 188   If a language name is not translated in $lang in database, the function returns english language name
 189 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 190
 191 =cut
 192
 193 sub getLanguages {
 194     my $lang = shift;
 195     my $isFiltered = shift;
 196
 197     my @languages_loop;
 198     my $dbh=C4::Context->dbh;
 199     my $default_language = 'en';
 200     my $current_language = $default_language;
 201     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 202     if ($lang) {
 203         $current_language = regex_lang_subtags($lang)->{'language'};
 204     }
 205     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 206     $sth->execute();
 207     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 208         my $desc;
 209         # check if language name is stored in current language
 210         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 211         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 212         while (my $language_desc = $sth4->fetchrow_hashref) {
 213              $desc=$language_desc->{description};
 214         }
 215         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 216         if ($desc) {
 217             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 218         }
 219         else {
 220             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 221         }
 222         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 223         # add the correct description info
 224         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 225             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 226             my $native_description;
 227             while (my $description = $sth3->fetchrow_hashref) {
 228                 $native_description = $description->{description};
 229             }
 230
 231             # fill in the ISO6329 code
 232             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 233             # fill in the native description of the language, as well as the current language's translation of that if it exists
 234             if ($native_description) {
 235                 $language_subtag_registry->{language_description} = $native_description;
 236                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 237             }
 238             else {
 239                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 240             }
 241         }
 242         # Do not push unless valid iso639-2 code
 243         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 244             push @languages_loop, $language_subtag_registry;
 245         }
 246     }
 247     return \@languages_loop;
 248 }
 249
 250 =head2 _get_themes
 251
 252 Internal function, returns an array of all available themes.
 253
 254   (@themes) = &_get_themes('opac');
 255   (@themes) = &_get_themes('intranet');
 256
 257 =cut
 258
 259 sub _get_themes {
 260     my $interface = shift;
 261     my $htdocs;
 262     my @themes;
 263     if ( $interface && $interface eq 'intranet' ) {
 264         $htdocs = C4::Context->config('intrahtdocs');
 265     }
 266     else {
 267         $htdocs = C4::Context->config('opachtdocs');
 268     }
 269     opendir D, "$htdocs";
 270     my @dirlist = readdir D;
 271     foreach my $directory (@dirlist) {
 272         # if there's an en dir, it's a valid theme
 273         -d "$htdocs/$directory/en" and push @themes, $directory;
 274     }
 275     return @themes;
 276 }
 277
 278 =head2 _get_language_dirs
 279
 280 Internal function, returns an array of directory names, excluding non-language directories
 281
 282 =cut
 283
 284 sub _get_language_dirs {
 285     my ($htdocs,$theme) = @_;
 286     $htdocs //= '';
 287     $theme //= '';
 288     my @lang_strings;
 289     opendir D, "$htdocs/$theme";
 290     for my $lang_string ( readdir D ) {
 291         next if $lang_string =~/^\./;
 292         next if $lang_string eq 'all';
 293         next if $lang_string =~/png$/;
 294         next if $lang_string =~/js$/;
 295         next if $lang_string =~/css$/;
 296         next if $lang_string =~/CVS$/;
 297         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 298         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 299         push @lang_strings, $lang_string;
 300     }
 301         return (@lang_strings);
 302 }
 303
 304 =head2 _build_languages_arrayref
 305
 306 Internal function for building the ref to array of hashes
 307
 308 FIXME: this could be rewritten and simplified using map
 309
 310 =cut
 311
 312 sub _build_languages_arrayref {
 313         my ($translated_languages,$current_language,$enabled_languages) = @_;
 314         $current_language //= '';
 315         my @translated_languages = @$translated_languages;
 316         my @languages_loop; # the final reference to an array of hashrefs
 317         my @enabled_languages = @$enabled_languages;
 318         # how many languages are enabled, if one, take note, some contexts won't need to display it
 319         my %seen_languages; # the language tags we've seen
 320         my %found_languages;
 321         my $language_groups;
 322         my $track_language_groups;
 323         my $current_language_regex = regex_lang_subtags($current_language);
 324         # Loop through the translated languages
 325         for my $translated_language (@translated_languages) {
 326             # separate the language string into its subtag types
 327             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 328
 329             # is this language string 'enabled'?
 330             for my $enabled_language (@enabled_languages) {
 331                 #warn "Checking out if $translated_language eq $enabled_language";
 332                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 333             }
 334
 335             # group this language, key by langtag
 336             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 337             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 338             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 339             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 340             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 341             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 342             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 343             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 344         }
 345         # $key is a language subtag like 'en'
 346         while( my ($key, $value) = each %$language_groups) {
 347
 348             # is this language group enabled? are any of the languages within it enabled?
 349             my $enabled;
 350             for my $enabled_language (@enabled_languages) {
 351                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 352                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 353             }
 354             push @languages_loop,  {
 355                             # this is only use if there is one
 356                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 357                             native_description => language_get_description($key,$key,'language'),
 358                             language => $key,
 359                             sublanguages_loop => $value,
 360                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 361                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 362                             group_enabled => $enabled,
 363                            };
 364         }
 365         return \@languages_loop;
 366 }
 367
 368 sub language_get_description {
 369     my ($script,$lang,$type) = @_;
 370     my $dbh = C4::Context->dbh;
 371     my $desc;
 372     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 373     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 374     $sth->execute($script,$lang,$type);
 375     while (my $descriptions = $sth->fetchrow_hashref) {
 376         $desc = $descriptions->{'description'};
 377     }
 378     unless ($desc) {
 379         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 380         $sth->execute($script,'en',$type);
 381         while (my $descriptions = $sth->fetchrow_hashref) {
 382             $desc = $descriptions->{'description'};
 383         }
 384     }
 385     return $desc;
 386 }
 387 =head2 regex_lang_subtags
 388
 389 This internal sub takes a string composed according to RFC 4646 as
 390 an input and returns a reference to a hash containing keys and values
 391 for ( language, script, region, variant, extension, privateuse )
 392
 393 =cut
 394
 395 sub regex_lang_subtags {
 396     my $string = shift;
 397
 398     # Regex for recognizing RFC 4646 well-formed tags
 399     # http://www.rfc-editor.org/rfc/rfc4646.txt
 400
 401     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 402     # The structure requires no forward references, so it reverses the order.
 403     # The uppercase comments are fragments copied from RFC 4646
 404     #
 405     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 406
 407     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 408     my $digit   = qr/[0-9]/ ;   # DIGIT
 409     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 410     my $x   = qr/[xX]/ ;    # private use singleton
 411     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 412     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 413
 414     # Now do the components. The structure is slightly different to allow for capturing the right components.
 415     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 416
 417     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 418     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 419     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 420
 421     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 422
 423     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 424
 425     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 426     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 427
 428     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 429     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 430
 431     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 432
 433     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 434     # Since these are limited, this is safe even later changes to the registry --
 435     # the only oddity is that it might change the type of the tag, and thus
 436     # the results from the capturing groups.
 437     # http://www.iana.org/assignments/language-subtag-registry
 438     # Note that these have to be compared case insensitively, requiring (?i) below.
 439
 440     my $grandfathered   = qr{(?: (?i)
 441         en $s GB $s oed
 442     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 443     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 444 )}x;
 445
 446     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 447
 448     #   |   art $s lojban
 449     #   |   cel $s gaulish
 450     #   |   en $s (?: boont | GB $s oed | scouse )
 451     #   |   no $s (?: bok | nyn)
 452     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 453
 454     # Here is the final breakdown, with capturing groups for each of these components
 455     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 456
 457     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 458
 459     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 460     my %subtag = (
 461         'rfc4646_subtag' => $string,
 462         'language' => $1,
 463         'script' => $2,
 464         'region' => $3,
 465         'variant' => $4,
 466         'extension' => $5,
 467         'privateuse' => $6,
 468     );
 469     return \%subtag;
 470 }
 471
 472 # Script Direction Resources:
 473 # http://www.w3.org/International/questions/qa-scripts
 474 sub get_bidi {
 475     my ($language_script)= @_;
 476     my $dbh = C4::Context->dbh;
 477     my $bidi;
 478     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 479     $sth->execute($language_script);
 480     while (my $result = $sth->fetchrow_hashref) {
 481         $bidi = $result->{'bidi'};
 482     }
 483     return $bidi;
 484 };
 485
 486 sub accept_language {
 487     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 488     my ($clientPreferences,$supportedLanguages) = @_;
 489     my @languages = ();
 490     if ($clientPreferences) {
 491         # There should be no whitespace anways, but a cleanliness/sanity check
 492         $clientPreferences =~ s/\s//g;
 493         # Prepare the list of client-acceptable languages
 494         foreach my $tag (split(/,/, $clientPreferences)) {
 495             my ($language, $quality) = split(/\;/, $tag);
 496             $quality =~ s/^q=//i if $quality;
 497             $quality = 1 unless $quality;
 498             next if $quality <= 0;
 499             # We want to force the wildcard to be last
 500             $quality = 0 if ($language eq '*');
 501             # Pushing lowercase language here saves processing later
 502             push(@languages, { quality => $quality,
 503                language => $language,
 504                lclanguage => lc($language) });
 505         }
 506     } else {
 507         carp "accept_language(x,y) called with no clientPreferences (x).";
 508     }
 509     # Prepare the list of server-supported languages
 510     my %supportedLanguages = ();
 511     my %secondaryLanguages = ();
 512     foreach my $language (@$supportedLanguages) {
 513         # warn "Language supported: " . $language->{language};
 514         my $subtag = $language->{rfc4646_subtag};
 515         $supportedLanguages{lc($subtag)} = $subtag;
 516         if ( $subtag =~ /^([^-]+)-?/ ) {
 517             $secondaryLanguages{lc($1)} = $subtag;
 518         }
 519     }
 520
 521     # Reverse sort the list, making best quality at the front of the array
 522     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 523     my $secondaryMatch = '';
 524     foreach my $tag (@languages) {
 525         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 526             # Client en-us eq server en-us
 527             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 528             return $supportedLanguages{$tag->{lclanguage}};
 529         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 530             # Client en eq server en-us
 531             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 532             return $supportedLanguages{$tag->{lclanguage}};
 533         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 534             # Client en-gb eq server en-us
 535             $secondaryMatch = $secondaryLanguages{$1};
 536         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 537             # FIXME: We just checked the exact same conditional!
 538             # Client en-us eq server en
 539             $secondaryMatch = $supportedLanguages{$1};
 540         } elsif ($tag->{lclanguage} eq '*') {
 541         # * matches every language not already specified.
 542         # It doesn't care which we pick, so let's pick the default,
 543         # if available, then the first in the array.
 544         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 545         return $supportedLanguages->[0];
 546         }
 547     }
 548     # No primary matches. Secondary? (ie, en-us requested and en supported)
 549     return $secondaryMatch if $secondaryMatch;
 550     return undef;   # else, we got nothing.
 551 }
 552
 553 =head2 getlanguage
 554
 555     Select a language based on the URL parameter 'language', a cookie,
 556     syspref available languages & browser
 557
 558 =cut
 559
 560 sub getlanguage {
 561     my ($cgi) = @_;
 562
 563     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 564     my $cache_key = "getlanguage";
 565     unless ( $cgi and $cgi->param('language') ) {
 566         my $cached = $memory_cache->get_from_cache($cache_key);
 567         return $cached if $cached;
 568     }
 569
 570     $cgi //= new CGI;
 571     my $interface = C4::Context->interface;
 572     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 573     my $language;
 574
 575     my $preference_to_check =
 576       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 577     # Get the available/valid languages list
 578     my @languages;
 579     my $preference_value = C4::Context->preference($preference_to_check);
 580     if ($preference_value) {
 581         @languages = split /,/, $preference_value;
 582     }
 583
 584     # Chose language from the URL
 585     my $cgi_param_language = $cgi->param( 'language' );
 586     if ( defined $cgi_param_language && any { $_ eq $cgi_param_language } @languages) {
 587         $language = $cgi_param_language;
 588     }
 589
 590     # cookie
 591     if (not $language and my $cgi_cookie_language = $cgi->cookie('KohaOpacLanguage') ) {
 592         ( $language = $cgi_cookie_language ) =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 593     }
 594
 595     # HTTP_ACCEPT_LANGUAGE
 596     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 597         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 598             getTranslatedLanguages( $interface, $theme ) );
 599     }
 600
 601     # Ignore a lang not selected in sysprefs
 602     if ( $language && not any { $_ eq $language } @languages ) {
 603         $language = undef;
 604     }
 605
 606     # Pick the first selected syspref language
 607     $language = shift @languages unless $language;
 608
 609     # Fall back to English if necessary
 610     $language ||= 'en';
 611
 612     $memory_cache->set_in_cache( $cache_key, $language );
 613     return $language;
 614 }
 615
 616 1;
 617
 618 __END__
 619
 620 =head1 AUTHOR
 621
 622 Joshua Ferraro
 623
 624 =cut