Koha/Plugins/Base.pm

   1 package Koha::Plugins::Base;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Module::Pluggable require => 1;
  23 use Cwd qw(abs_path);
  24 use List::Util qw(max);
  25
  26 use base qw{Module::Bundled::Files};
  27
  28 use C4::Context;
  29 use C4::Output qw(output_with_http_headers output_html_with_http_headers);
  30
  31 =head1 NAME
  32
  33 Koha::Plugins::Base - Base Module for plugins
  34
  35 =cut
  36
  37 sub new {
  38     my ( $class, $args ) = @_;
  39
  40     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  41
  42     $args->{'class'} = $class;
  43     $args->{'template'} = Template->new( { ABSOLUTE => 1, ENCODING => 'UTF-8' } );
  44
  45     my $self = bless( $args, $class );
  46
  47     my $plugin_version = $self->get_metadata->{version};
  48     my $database_version = $self->retrieve_data('__INSTALLED_VERSION__');
  49
  50     ## Run the installation method if it exists and hasn't been run before
  51     if ( $self->can('install') && !$self->retrieve_data('__INSTALLED__') ) {
  52         if ( $self->install() ) {
  53             $self->store_data( { '__INSTALLED__' => 1 } );
  54             if ( my $version = $plugin_version ) {
  55                 $self->store_data({ '__INSTALLED_VERSION__' => $version });
  56             }
  57         } else {
  58             warn "Plugin $class failed during installation!";
  59         }
  60     } elsif ( $self->can('upgrade') && $plugin_version && $database_version ) {
  61         if ( _version_compare( $plugin_version, $database_version ) == 1 ) {
  62             if ( $self->upgrade() ) {
  63                 $self->store_data({ '__INSTALLED_VERSION__' => $plugin_version });
  64                 warn "Plugin $class failed during upgrade!";
  65             }
  66         }
  67     }
  68
  69     return $self;
  70 }
  71
  72 =head2 store_data
  73
  74 store_data allows a plugin to store key value pairs in the database for future use.
  75
  76 usage: $self->store_data({ param1 => 'param1val', param2 => 'param2value' })
  77
  78 =cut
  79
  80 sub store_data {
  81     my ( $self, $data ) = @_;
  82
  83     my $dbh = C4::Context->dbh;
  84     my $sql = "REPLACE INTO plugin_data SET plugin_class = ?, plugin_key = ?, plugin_value = ?";
  85     my $sth = $dbh->prepare($sql);
  86
  87     foreach my $key ( keys %$data ) {
  88         $sth->execute( $self->{'class'}, $key, $data->{$key} );
  89     }
  90 }
  91
  92 =head2 retrieve_data
  93
  94 retrieve_data allows a plugin to read the values that were previously saved with store_data
  95
  96 usage: my $value = $self->retrieve_data( $key );
  97
  98 =cut
  99
 100 sub retrieve_data {
 101     my ( $self, $key ) = @_;
 102
 103     my $dbh = C4::Context->dbh;
 104     my $sql = "SELECT plugin_value FROM plugin_data WHERE plugin_class = ? AND plugin_key = ?";
 105     my $sth = $dbh->prepare($sql);
 106     $sth->execute( $self->{'class'}, $key );
 107     my $row = $sth->fetchrow_hashref();
 108
 109     return $row->{'plugin_value'};
 110 }
 111
 112 =head2 get_template
 113
 114 get_template returns a Template object. Eventually this will probably be calling
 115 C4:Template, but at the moment, it does not.
 116
 117 =cut
 118
 119 sub get_template {
 120     my ( $self, $args ) = @_;
 121
 122     require C4::Auth;
 123
 124     my $template_name = $args->{'file'} // '';
 125     # if not absolute, call mbf_path, which dies if file does not exist
 126     $template_name = $self->mbf_path( $template_name )
 127         if $template_name !~ m/^\//;
 128     my ( $template, $loggedinuser, $cookie ) = C4::Auth::get_template_and_user(
 129         {   template_name   => $template_name,
 130             query           => $self->{'cgi'},
 131             type            => "intranet",
 132             authnotrequired => 1,
 133         }
 134     );
 135
 136     $template->param(
 137         CLASS       => $self->{'class'},
 138         METHOD      => scalar $self->{'cgi'}->param('method'),
 139         PLUGIN_PATH => $self->get_plugin_http_path(),
 140     );
 141
 142     return $template;
 143 }
 144
 145 sub get_metadata {
 146     my ( $self, $args ) = @_;
 147
 148     return $self->{'metadata'};
 149 }
 150
 151 =head2 get_qualified_table_name
 152
 153 To avoid naming conflict, each plugins tables should use a fully qualified namespace.
 154 To avoid hardcoding and make plugins more flexible, this method will return the proper
 155 fully qualified table name.
 156
 157 usage: my $table = $self->get_qualified_table_name( 'myTable' );
 158
 159 =cut
 160
 161 sub get_qualified_table_name {
 162     my ( $self, $table_name ) = @_;
 163
 164     return lc( join( '_', split( '::', $self->{'class'} ), $table_name ) );
 165 }
 166
 167 =head2 get_plugin_http_path
 168
 169 To access a plugin's own resources ( images, js files, css files, etc... )
 170 a plugin will need to know what path to use in the template files. This
 171 method returns that path.
 172
 173 usage: my $path = $self->get_plugin_http_path();
 174
 175 =cut
 176
 177 sub get_plugin_http_path {
 178     my ($self) = @_;
 179
 180     return "/plugin/" . join( '/', split( '::', $self->{'class'} ) );
 181 }
 182
 183 =head2 go_home
 184
 185    go_home is a quick redirect to the Koha plugins home page
 186
 187 =cut
 188
 189 sub go_home {
 190     my ( $self, $params ) = @_;
 191
 192     print $self->{'cgi'}->redirect("/cgi-bin/koha/plugins/plugins-home.pl");
 193 }
 194
 195 =head2 output_html
 196
 197     $self->output_html( $data, $status, $extra_options );
 198
 199 Outputs $data setting the right headers for HTML content.
 200
 201 Note: this is a wrapper function for C4::Output::output_with_http_headers
 202
 203 =cut
 204
 205 sub output_html {
 206     my ( $self, $data, $status, $extra_options ) = @_;
 207     output_with_http_headers( $self->{cgi}, undef, $data, 'html', $status, $extra_options );
 208 }
 209
 210 =head2 output
 211
 212    $self->output( $data, $content_type[, $status[, $extra_options]]);
 213
 214 Outputs $data with the appropriate HTTP headers,
 215 the authentication cookie and a Content-Type specified in
 216 $content_type.
 217
 218 $content_type is one of the following: 'html', 'js', 'json', 'xml', 'rss', or 'atom'.
 219
 220 $status is an HTTP status message, like '403 Authentication Required'. It defaults to '200 OK'.
 221
 222 $extra_options is hashref.  If the key 'force_no_caching' is present and has
 223 a true value, the HTTP headers include directives to force there to be no
 224 caching whatsoever.
 225
 226 Note: this is a wrapper function for C4::Output::output_with_http_headers
 227
 228 =cut
 229
 230 sub output {
 231     my ( $self, $data, $content_type, $status, $extra_options ) = @_;
 232     output_with_http_headers( $self->{cgi}, undef, $data, $content_type, $status, $extra_options );
 233 }
 234
 235 =head2 _version_compare
 236
 237 Utility method to compare two version numbers.
 238 Returns 1 if the first argument is the higher version
 239 Returns -1 if the first argument is the lower version
 240 Returns 0 if both versions are equal
 241
 242 if ( _version_compare( '2.6.26', '2.6.0' ) == 1 ) {
 243     print "2.6.26 is greater than 2.6.0\n";
 244 }
 245
 246 =cut
 247
 248 sub _version_compare {
 249     my $ver1 = shift || 0;
 250     my $ver2 = shift || 0;
 251
 252     my @v1 = split /[.+:~-]/, $ver1;
 253     my @v2 = split /[.+:~-]/, $ver2;
 254
 255     for ( my $i = 0 ; $i < max( scalar(@v1), scalar(@v2) ) ; $i++ ) {
 256
 257         # Add missing version parts if one string is shorter than the other
 258         # i.e. 0 should be lt 0.2.1 and not equal, so we append .0
 259         # 0.0.0 <=> 0.2.1 = -1
 260         push( @v1, 0 ) unless defined( $v1[$i] );
 261         push( @v2, 0 ) unless defined( $v2[$i] );
 262         if ( int( $v1[$i] ) > int( $v2[$i] ) ) {
 263             return 1;
 264         }
 265         elsif ( int( $v1[$i] ) < int( $v2[$i] ) ) {
 266             return -1;
 267         }
 268     }
 269     return 0;
 270 }
 271
 272 1;
 273 __END__
 274
 275 =head1 AUTHOR
 276
 277 Kyle M Hall <kyle.m.hall@gmail.com>
 278
 279 =cut