Koha/REST/V1/Illrequests.pm

   1 package Koha::REST::V1::Illrequests;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 3 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Controller';
  21
  22 use Koha::Illrequests;
  23 use Koha::Illrequestattributes;
  24 use Koha::Libraries;
  25 use Koha::Patrons;
  26 use Koha::Libraries;
  27
  28 =head1 NAME
  29
  30 Koha::REST::V1::Illrequests
  31
  32 =head2 Operations
  33
  34 =head3 list
  35
  36 Return a list of ILL requests, after applying filters.
  37
  38 =cut
  39
  40 sub list {
  41     my $c = shift->openapi->valid_input or return;
  42
  43     my $args = $c->req->params->to_hash // {};
  44
  45     # Create a hash where all keys are embedded values
  46     # Enables easy checking
  47     my %embed;
  48     my $args_arr = (ref $args->{embed} eq 'ARRAY') ? $args->{embed} : [ $args->{embed} ];
  49     if (defined $args->{embed}) {
  50         %embed = map { $_ => 1 }  @{$args_arr};
  51         delete $args->{embed};
  52     }
  53
  54     # Get all requests
  55     my @requests = Koha::Illrequests->as_list;
  56
  57     # Identify patrons & branches that
  58     # we're going to need and get them
  59     my $to_fetch = {
  60         patrons      => {},
  61         branches     => {},
  62         capabilities => {}
  63     };
  64     foreach my $req(@requests) {
  65         $to_fetch->{patrons}->{$req->borrowernumber} = 1 if $embed{patron};
  66         $to_fetch->{branches}->{$req->branchcode} = 1 if $embed{library};
  67         $to_fetch->{capabilities}->{$req->backend} = 1 if $embed{capabilities};
  68     }
  69
  70     # Fetch the patrons we need
  71     my $patron_arr = [];
  72     if ($embed{patron}) {
  73         my @patron_ids = keys %{$to_fetch->{patrons}};
  74         if (scalar @patron_ids > 0) {
  75             my $where = {
  76                 borrowernumber => { -in => \@patron_ids }
  77             };
  78             $patron_arr = Koha::Patrons->search($where)->unblessed;
  79         }
  80     }
  81
  82     # Fetch the branches we need
  83     my $branch_arr = [];
  84     if ($embed{library}) {
  85         my @branchcodes = keys %{$to_fetch->{branches}};
  86         if (scalar @branchcodes > 0) {
  87             my $where = {
  88                 branchcode => { -in => \@branchcodes }
  89             };
  90             $branch_arr = Koha::Libraries->search($where)->unblessed;
  91         }
  92     }
  93
  94     # Fetch the capabilities we need
  95     if ($embed{capabilities}) {
  96         my @backends = keys %{$to_fetch->{capabilities}};
  97         if (scalar @backends > 0) {
  98             foreach my $bc(@backends) {
  99                 my $backend = Koha::Illrequest->new->load_backend($bc);
 100                 $to_fetch->{$bc} = $backend->capabilities;
 101             }
 102         }
 103     }
 104
 105     # Now we've got all associated users and branches,
 106     # we can augment the request objects
 107     my @output = ();
 108     foreach my $req(@requests) {
 109         my $to_push = $req->unblessed;
 110         $to_push->{id_prefix} = $req->id_prefix;
 111         foreach my $p(@{$patron_arr}) {
 112             if ($p->{borrowernumber} == $req->borrowernumber) {
 113                 $to_push->{patron} = {
 114                     firstname  => $p->{firstname},
 115                     surname    => $p->{surname},
 116                     cardnumber => $p->{cardnumber}
 117                 };
 118                 last;
 119             }
 120         }
 121         foreach my $b(@{$branch_arr}) {
 122             if ($b->{branchcode} eq $req->branchcode) {
 123                 $to_push->{library} = $b;
 124                 last;
 125             }
 126         }
 127         if ($embed{metadata}) {
 128             my $metadata = Koha::Illrequestattributes->search(
 129                 { illrequest_id => $req->illrequest_id },
 130                 { columns => [qw/type value/] }
 131             )->unblessed;
 132             my $meta_hash = {};
 133             foreach my $meta(@{$metadata}) {
 134                 $meta_hash->{$meta->{type}} = $meta->{value};
 135             }
 136             $to_push->{metadata} = $meta_hash;
 137         }
 138         if ($embed{capabilities}) {
 139             $to_push->{capabilities} = $to_fetch->{$req->backend};
 140         }
 141         if ($embed{comments}) {
 142             $to_push->{comments} = $req->illcomments->count;
 143         }
 144         push @output, $to_push;
 145     }
 146
 147     return $c->render( status => 200, openapi => \@output );
 148 }
 149
 150 1;