Koha/UploadedFile.pm

   1 package Koha::UploadedFile;
   2
   3 # Copyright Rijksmuseum 2016
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21 use File::Spec;
  22
  23 use parent qw(Koha::Object);
  24
  25 =head1 NAME
  26
  27 Koha::UploadedFile - Koha::Object class for single uploaded file
  28
  29 =head1 SYNOPSIS
  30
  31     use Koha::UploadedFile;
  32
  33     # store record in uploaded_files
  34     my $upload = Koha::UploadedFile->new({ [columns and values] });
  35
  36     # get a file handle on an uploaded_file
  37     my $fh = $upload->file_handle;
  38
  39     # get full path
  40     my $path = $upload->full_path;
  41
  42     # delete uploaded file
  43     $upload->delete;
  44
  45 =head1 DESCRIPTION
  46
  47 Allows regular CRUD operations on uploaded_files via Koha::Object / DBIx.
  48
  49 The delete method also takes care of deleting files. The full_path method
  50 returns a fully qualified path for an upload.
  51
  52 Additional methods include: file_handle, httpheaders.
  53
  54 =head1 METHODS
  55
  56 =head2 INSTANCE METHODS
  57
  58 =head3 delete
  59
  60 Delete uploaded file.
  61 It deletes not only the record, but also the actual file (unless you pass
  62 the keep_file parameter).
  63
  64 Returns filename on successful delete or undef.
  65
  66 =cut
  67
  68 sub delete {
  69     my ( $self, $params ) = @_;
  70
  71     my $name = $self->filename;
  72     my $file = $self->full_path;
  73
  74     my $retval = $self->SUPER::delete;
  75     return $retval if $params->{keep_file};
  76
  77     if( ! -e $file ) {
  78         warn "Removing record for $name within category ".
  79             $self->uploadcategorycode. ", but file was missing.";
  80     } elsif( ! unlink($file) ) {
  81         $retval = 0;
  82         warn "Problem while deleting: $file";
  83     }
  84     return $retval;
  85 }
  86
  87 =head3 full_path
  88
  89 Returns the fully qualified path name for an uploaded file.
  90
  91 =cut
  92
  93 sub full_path {
  94     my ( $self ) = @_;
  95     my $path = File::Spec->catfile(
  96         $self->permanent?
  97             $self->permanent_directory: $self->temporary_directory,
  98         $self->dir,
  99         $self->hashvalue. '_'. $self->filename,
 100     );
 101     return $path;
 102 }
 103
 104 =head3 file_handle
 105
 106 Returns a file handle for an uploaded file.
 107
 108 =cut
 109
 110 sub file_handle {
 111     my ( $self ) = @_;
 112     $self->{_file_handle} = IO::File->new( $self->full_path, "r" );
 113     return if !$self->{_file_handle};
 114     $self->{_file_handle}->binmode;
 115     return $self->{_file_handle};
 116 }
 117
 118 =head3 httpheaders
 119
 120 httpheaders returns http headers for a retrievable upload.
 121
 122 Will be extended by report 14282
 123
 124 =cut
 125
 126 sub httpheaders {
 127     my ( $self ) = @_;
 128     return (
 129         '-type'       => 'application/octet-stream',
 130         '-attachment' => $self->filename,
 131     );
 132 }
 133
 134 =head2 CLASS METHODS
 135
 136 =head3 permanent_directory
 137
 138 Returns root directory for permanent storage
 139
 140 =cut
 141
 142 sub permanent_directory {
 143     my ( $class ) = @_;
 144     return C4::Context->config('upload_path');
 145 }
 146
 147 =head3 tmp_directory
 148
 149 Returns root directory for temporary storage
 150
 151 =cut
 152
 153 sub temporary_directory {
 154     my ( $class ) = @_;
 155     return File::Spec->tmpdir;
 156 }
 157
 158 =head3 _type
 159
 160 Returns name of corresponding DBIC resultset
 161
 162 =cut
 163
 164 sub _type {
 165     return 'UploadedFile';
 166 }
 167
 168 =head1 AUTHOR
 169
 170 Marcel de Rooy (Rijksmuseum)
 171
 172 Koha Development Team
 173
 174 =cut
 175
 176 1;