Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 # See http://www.koha.org/wiki/?page=KohaInstaller
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27
  28 my $DEBUG = 0;
  29 die "perl 5.6.1 or later required" unless ($] >= 5.006001);
  30
  31 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  32
  33 my $dirtree = hashdir('.');
  34 my %result = ();
  35
  36 =head1 NAME
  37
  38 Makefile.PL - Koha packager and installer
  39
  40 =head1 SYNOPSIS
  41
  42 =head2 BASIC INSTALLATION
  43
  44         perl Makefile.PL
  45         make
  46         sudo make install
  47
  48 =head2 PACKAGING RELEASE TARBALLS
  49
  50         make manifest tardist
  51         make manifest zipdist
  52
  53 =head2 CLEANING UP
  54
  55         make clean
  56
  57 =head1 DESCRIPTION
  58
  59 This is a packager and installer that uses
  60 ExtUtils::MakeMaker, which is fairly common
  61 on perl systems.
  62 As well as building tar or zip files
  63 and installing with the above commands,
  64 it allows us to check pre-requisites
  65 and generate configuration files.
  66
  67 =head1 VARIABLES
  68
  69 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  70
  71 Basic metadata about this software.
  72
  73 =head2 NO_META
  74
  75 Suppress generation of META.yml file.
  76
  77 =head2 PREREQ_PM
  78
  79 Hash of perl modules and versions required.
  80
  81 =head2 PM
  82
  83 Hash of file mappings
  84
  85 =head2 PL_FILES
  86
  87 This is a hash of PL scripts to run after installation and
  88 the files to ask them to generate.
  89 Maybe use the values from CONFIGURE
  90 to generate initial configuration files in future.
  91
  92 =cut
  93
  94 =head2 target_map
  95
  96 This is a hash mapping directories and files in the
  97 source tree to installation target directories.  The rules
  98 for this mapping are:
  99
 100 =over 4
 101
 102 =item If a directory or file is specified, it and its
 103 contents will be copied to the installation target directory.
 104
 105 =item If a subdirectory of a mapped directory is specified,
 106 its target overrides the parent's target for that subdirectory.
 107
 108 =item The value of each map entry may either be a scalar containing
 109 one target or a reference to a hash containing 'target' and 'trimdir'
 110 keys.
 111
 112 =item Any files at the top level of the source tree that are
 113 not included in the map will not be installed.
 114
 115 =item Any directories at the top level of the source tree
 116 that are not included in the map will be installed in
 117 INTRANET_CGI_DIR.  This is a sensible default given the
 118 current organization of the source tree, but (FIXME) it
 119 would be better to reorganize the source tree to better
 120 match the installation system, to allow adding new directories
 121 without having to adjust Makefile.PL each time.  The idea
 122 is to make the C<$target_map> hash as minimal as possible.
 123
 124 =back
 125
 126 The permitted installation targets are:
 127
 128 =over 4
 129
 130 =item INTRANET_CGI_DIR
 131
 132 CGI scripts for intranet (staff) interface.
 133
 134 =item INTRANET_TMPL_DIR
 135
 136 HTML templates for the intranet interface.
 137
 138 =item INTRANET_WWW_DIR
 139
 140 HTML files, images, etc. for DocumentRoot for the intranet interface.
 141
 142 =item OPAC_CGI_DIR
 143
 144 CGI scripts for OPAC (public) interface.
 145
 146 =item OPAC_TMPL_DIR
 147
 148 HTML templates for the OPAC interface.
 149
 150 =item OPAC_WWW_DIR
 151
 152 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 153
 154 =item PERL_MODULE_DIR
 155
 156 Perl modules (at present just the C4 modules) that are intimately
 157 tied to Koha.  Depending on the installation options, these
 158 may or may not be installed one of the standard directories
 159 in Perl's default @LIB.
 160
 161 =item KOHA_CONF_DIR
 162
 163 Directory for Koha configuration files.
 164
 165 =item ZEBRA_CONF_DIR
 166
 167 Directory for Zebra configuration files.
 168
 169 =item ZEBRA_LOCK_DIR
 170
 171 Directory for Zebra's lock files.
 172
 173 =item ZEBRA_DATA_DIR
 174
 175 Directory for Zebra's data files.
 176
 177 =item ZEBRA_RUN_DIR
 178
 179 Directory for Zebra's UNIX-domain sockets.
 180
 181 =item EXAMPLE_DIR
 182
 183 Directory for example configuration files.  This directory
 184 exists primarily to make it easier to change the
 185 MARC format or language of the active Zebra
 186 indexes.
 187
 188 =item SCRIPT_DIR
 189
 190 Directory for command-line scripts and daemons.
 191
 192 =item MAN_DIR
 193
 194 Directory for man pages created from POD -- will mostly
 195 contain information of interest to Koha developers.
 196
 197 =item DOC_DIR
 198
 199 Directory for Koha documentation accessed from the
 200 command-line, e.g., READMEs.
 201
 202 =item LOG_DIR
 203
 204 Directory for Apache and Zebra logs produced by Koha.
 205
 206 =item NONE
 207
 208 This is a dummy target used to explicitly state
 209 that a given file or directory is not to be installed.
 210 This is used either for parts of the installer itself
 211 or for development tools that are not applicable to a
 212 production installation.
 213
 214 =back
 215
 216 =cut
 217
 218 my $target_map = {
 219   './about.pl'                  => 'INTRANET_CGI_DIR',
 220   './acqui'                     => 'INTRANET_CGI_DIR',
 221   './admin'                     => 'INTRANET_CGI_DIR',
 222   './authorities'               => 'INTRANET_CGI_DIR',
 223   './C4'                        => 'PERL_MODULE_DIR',
 224   './C4/SIP/t'                  => 'NONE',
 225   './C4/SIP/koha_test'          => 'NONE',
 226   './C4/tests'                  => 'NONE',
 227   './catalogue'                 => 'INTRANET_CGI_DIR',
 228   './cataloguing'               => 'INTRANET_CGI_DIR',
 229   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 230   './check_sysprefs.pl'         => 'NONE',
 231   './circ'                      => 'INTRANET_CGI_DIR',
 232   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 233   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 234   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 235   './help.pl'                   => 'NONE', # FIXME
 236   './installer-CPAN.pl'         => 'NONE',
 237   './installer'                 => 'INTRANET_CGI_DIR',
 238   './koha-tmpl/errors'          => {target => 'INTRANET_CGI_DIR', trimdir => 2},
 239   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 240   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 241   './kohaversion.pl'            => 'INTRANET_CGI_DIR', # FIXME this may need to be in OPAC_CGI_DIR as well, with an update to C4::Context
 242   './labels'                    => 'INTRANET_CGI_DIR',
 243   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 244   './Makefile.PL'               => 'NONE',
 245   './MANIFEST.SKIP'             => 'NONE',
 246   './members'                   => 'INTRANET_CGI_DIR',
 247   './misc'                      => { target => 'SCRIPT_DIR', trimdir => -1 },
 248   './misc/info'                 => { target => 'DOC_DIR', trimdir => 2 },
 249   './misc/release notes'        => { target => 'DOC_DIR', trimdir => 2 },
 250   './misc/translator'           => { target => 'EXAMPLE_DIR', trimdir => 2 },
 251   './misc/installer_devel_notes' => 'NONE',
 252   './opac'                      => 'OPAC_CGI_DIR',
 253   './README.txt'                => 'NONE',
 254   './reports'                   => 'INTRANET_CGI_DIR',
 255   './reserve'                   => 'INTRANET_CGI_DIR',
 256   './reviews'                   => 'INTRANET_CGI_DIR',
 257   './rewrite-config.PL'         => 'NONE',
 258   './reviews'                   => 'INTRANET_CGI_DIR',
 259   './rss'                       => 'NONE', # FIXME deal with a little later
 260   './serials'                   => 'INTRANET_CGI_DIR',
 261   './skel'                      => 'NONE',
 262   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 263   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 264   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 265   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 266   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 267   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 268   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 269   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 270   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 271   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 272   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 273   './sms'                       => 'INTRANET_CGI_DIR',
 274   './suggestion'                => 'INTRANET_CGI_DIR',
 275   './svc'                       => 'INTRANET_CGI_DIR',
 276   './t'                         => 'NONE',
 277   './tmp'                       => 'NONE', # FIXME deal with later
 278   './tools'                     => 'INTRANET_CGI_DIR',
 279   './virtualshelves'            => 'INTRANET_CGI_DIR',
 280   # ignore files and directories created by the install itself
 281   './pm_to_blib'                => 'NONE',
 282   './blib'                      => 'NONE',
 283 };
 284
 285 =head1 CONFIGURATION OPTIONS
 286
 287 The following configuration options are used by the installer.
 288
 289 =over 4
 290
 291 =item INSTALL_MODE
 292
 293 Specifies whether installation will be FHS-compliant (default,
 294 assumes user has root), put everything under
 295 a single directory (for users installing on a web host
 296 that allows CGI scripts and a MySQL database but not root
 297 access), or development (for a developer who wants to run
 298 Koha from a git clone with no fuss).
 299
 300 =item INSTALL_BASE
 301
 302 Directory under which most components will go.  Default
 303 value will vary depending on INSTALL_MODE.
 304
 305 =item INSTALL_ZEBRA
 306
 307 Whether to install Zebra configuration files and data
 308 directories.
 309
 310 =item ZEBRA_MARC_FORMAT
 311
 312 Specifies format of MARC records to be indexed by Zebra.
 313
 314 =item ZEBRA_LANGUAGE
 315
 316 Specifies primary language of records that will be
 317 indexed by Zebra.
 318
 319 =back
 320
 321 =cut
 322
 323 # default configuration options
 324 my %config_defaults = (
 325   'INSTALL_MODE'      => 'standard',
 326   'INSTALL_BASE'      => '/usr/share/koha',
 327   'DB_TYPE'           => 'mysql',
 328   'DB_HOST'           => 'localhost',
 329   'DB_NAME'           => 'koha',
 330   'DB_USER'           => 'kohaadmin',
 331   'DB_PASS'           => 'katikoan',
 332   'INSTALL_ZEBRA'     => 'yes',
 333   'ZEBRA_MARC_FORMAT' => 'marc21',
 334   'ZEBRA_LANGUAGE'    => 'en',
 335   'ZEBRA_USER'        => 'kohauser',
 336   'ZEBRA_PASS'        => 'zebrastripes',
 337   'KOHA_USER'         => 'koha',
 338   'KOHA_GROUP'        => 'koha',
 339 );
 340
 341 # valid values for certain configuration options
 342 my %valid_config_values = (
 343   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 344   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 345   'INSTALL_ZEBRA' => { 'yes' => 1, 'no' => 1 },
 346   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 347   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'fr' => 1 }, # FIXME should generate from contents of distribution
 348 );
 349
 350 my %config = get_configuration(\%config_defaults, \%valid_config_values);
 351 my %target_directories = get_target_directories(\%config);
 352 display_configuration(\%config, \%target_directories);
 353 my $file_map = {};
 354 get_file_map($target_map, $dirtree, $file_map, $config{'INSTALL_ZEBRA'} eq "yes" ? 1: 0);
 355
 356 my $pl_files = {
 357       'rewrite-config.PL' => [
 358          'blib/KOHA_CONF_DIR/koha-conf.xml',
 359          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 360          ]
 361 };
 362
 363 if ($config{'INSTALL_ZEBRA'} eq "yes") {
 364     push @{ $pl_files->{'rewrite-config.PL'} }, (
 365          'blib/ZEBRA_CONF_DIR/etc/passwd',
 366          'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 367          'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg'
 368     );
 369 }
 370
 371 WriteMakefile(
 372     NAME => 'koha',
 373     #VERSION => strftime('2.9.%Y%m%d%H',gmtime),
 374     VERSION_FROM => 'C4/Context.pm',
 375     ABSTRACT => 'Award-winning integrated library system (ILS) and Web OPAC',
 376     AUTHOR => 'Koha Developers <koha-devel@nongnu.org>',
 377     NO_META => 1,
 378     PREREQ_PM => {
 379 'CGI' => 3.15,
 380 'CGI::Carp' => 1.29,
 381 'CGI::Session' => '4.10',
 382 'Class::Factory::Util' => 1.7,
 383 'Class::Accessor' => 0.30,
 384 'DBD::mysql' => 3.0008,
 385 'DBI' => 1.53,
 386 'Data::Dumper' => 2.121_08,
 387 'Date::Calc' => 5.4,
 388 'Date::Manip' => 5.44,
 389 'Digest::MD5' => 2.36,
 390 'File::Temp' => 0.16,
 391 'GD::Barcode::UPCE' => 1.1,
 392 'Getopt::Long' => 2.35,
 393 'Getopt::Std' => 1.05,
 394 'HTML::Template::Pro' => 0.65,
 395 'HTTP::Cookies' => 1.39,
 396 'HTTP::Request::Common' => 1.26,
 397 'LWP::Simple' => 1.41,
 398 'LWP::UserAgent' => 2.033,
 399 'Lingua::Stem' => 0.82,
 400 'List::Util' => 1.18,
 401 'Locale::Language' => 2.07,
 402 'MARC::Charset' => 0.98,
 403 'MARC::Crosswalk::DublinCore' => 0.03,
 404 'MARC::File::XML' => 0.88,
 405 'MARC::Record' => 2.00,
 406 'MIME::Base64' => 3.07,
 407 'MIME::QuotedPrint' => 3.07,
 408 'Mail::Sendmail' => 0.79,
 409 'PDF::API2' => 2.000,
 410 'PDF::API2::Page' => 2.000,
 411 'PDF::API2::Util' => 2.000,
 412 'PDF::Reuse' => 0.33,
 413 'PDF::Reuse::Barcode' => 0.05,
 414 'POSIX' => 1.09,
 415 'Schedule::At' => 1.06,
 416 'Term::ANSIColor' => 1.10,
 417 'Test' => 1.25,
 418 'Test::Harness' => 2.56,
 419 'Test::More' => 0.62,
 420 'Text::CSV' => 0.01,
 421 'Text::CSV_XS' => 0.32,
 422 'Text::Wrap' => 2005.082401,
 423 'Time::HiRes' => 1.86,
 424 'Time::localtime' => 1.02,
 425 'Unicode::Normalize' => 0.32,
 426 'XML::Dumper' => 0.81,
 427 'XML::LibXML' => 1.59,
 428 'XML::SAX::ParserFactory' => 1.01,
 429 'XML::Simple' => 2.14,
 430 'XML::RSS' => 1.31,
 431 'ZOOM' => 1.16,
 432         },
 433
 434         # File tree mapping
 435         PM => $file_map,
 436
 437     # Man pages generated from POD
 438     INSTALLMAN1DIR => File::Spec->catdir($target_directories{'MAN_DIR'}, 'man1'),
 439     INSTALLMAN3DIR => File::Spec->catdir($target_directories{'MAN_DIR'}, 'man3'),
 440
 441 #   CONFIGURE => sub {
 442 #     # Ask for options with prompt($question,$default) calls here?
 443 #     return { macro => { 'export TEST' => '755' } }
 444 #     },
 445
 446    PL_FILES => $pl_files,
 447
 448 #     'opac/getfromintranet.PL' => ['$(INST_LIBDIR)/opac/cgi-bin/detail.pl','$(INST_LIBDIR)/opac/cgi-bin/moredetail.pl','$(INST_LIBDIR)/opac/cgi-bin/search.pl','$(INST_LIBDIR)/opac/cgi-bin/subjectsearch.pl','$(INST_LIBDIR)/opac/cgi-bin/logout.pl'],
 449 #     'misc/koha.conf.PL' => '$(INST_LIBDIR)/../etc/koha.conf',
 450 #     'misc/apache-koha.conf.PL' => '$(INST_LIBDIR)/../etc/apache-koha.conf',
 451 #     'misc/koha.sql.PL' => '$(INST_LIBDIR)/intranet/scripts/koha.sql',
 452 #     'z3950/z3950-daemon-options.PL' => '$(INST_LIBDIR)/intranet/scripts/z3950daemon/z3950-daemon-options',
 453 #     # fake target to check permissions
 454 #     'misc/chmod.PL' => '$(INST_LIBDIR)/fake-target'
 455 #     }
 456    # need to set ownerships
 457    # need to load koha.sql
 458    # need to link koha-httpd.conf
 459    # need to start z3950-daemon
 460 );
 461
 462 =head1 FUNCTIONS
 463
 464 =head2 hashdir
 465
 466 This function recurses through the directory structure and builds
 467 a hash of hashes containing the structure with arrays holding filenames.
 468 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 469
 470 =cut
 471
 472 sub hashdir{
 473     my $dir = shift;
 474     opendir my $dh, $dir or die $!;
 475     my $tree = {}->{$dir} = {};
 476     while( my $file = readdir($dh) ) {
 477         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 478         my $path = $dir .'/' . $file;
 479         $tree->{$file} = hashdir($path), next if -d $path;
 480         push @{$tree->{'.'}}, $file;
 481     }
 482     return $tree;
 483 }
 484
 485 =head2 get_file_map
 486
 487 This function combines the target_map and file hash to
 488 map each source file to its destination relative to
 489 the set of installation targets.
 490
 491 Output will be a hash mapping from each source file
 492 to its destination value, like this:
 493
 494 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 495
 496 =cut
 497
 498 sub get_file_map {
 499     my $target_map = shift;
 500     my $dirtree = shift;
 501     my $file_map = shift;
 502     my $install_zebra = shift;
 503     my $curr_path = @_ ? shift : ['.'];
 504
 505     # Traverse the directory tree.
 506     # For each file or directory, identify the
 507     # most specific match in the target_map
 508     foreach my $dir (sort keys %{ $dirtree }) {
 509         if ($dir eq '.') {
 510             # deal with files in directory
 511             foreach my $file (sort @{ $dirtree->{$dir} }) {
 512                 my $targetdir = undef;
 513                 my $matchlevel = undef;
 514                 # first, see if there is a match on this specific
 515                 # file in the target map
 516                 my $filepath = join("/", @$curr_path, $file);
 517                 if (exists $target_map->{$filepath}) {
 518                     $targetdir = $target_map->{$filepath};
 519                     $matchlevel = scalar(@$curr_path) + 1;
 520                 } else {
 521                     # no match on the specific file; look for
 522                     # a directory match
 523                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 524                         my $dirpath = join("/", @$curr_path[0..$i]);
 525                         if (exists $target_map->{$dirpath}) {
 526                             $targetdir = $target_map->{$dirpath};
 527                             $matchlevel = $i + 1;
 528                             last;
 529                         }
 530                     }
 531                 }
 532                 if (defined $targetdir) {
 533                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel, $install_zebra);
 534                 } else {
 535                     my $path = join("/", @$curr_path);
 536                     print "failed to map: $path/$file\n" if $DEBUG;
 537                 }
 538             }
 539         } else {
 540             # dealing with subdirectory
 541             push @$curr_path, $dir;
 542             get_file_map($target_map, $dirtree->{$dir}, $file_map, $install_zebra, $curr_path);
 543             pop @$curr_path;
 544         }
 545     }
 546 }
 547
 548 sub _add_to_file_map {
 549     my $file_map = shift;
 550     my $targetdir = shift;
 551     my $curr_path = shift;
 552     my $file = shift;
 553     my $matchlevel = shift;
 554     my $install_zebra = shift;
 555     my $dest_path = @_ ? shift : $curr_path;
 556
 557     # The target can be one of the following:
 558     # 1. scalar representing target symbol
 559     # 2. hash ref containing target and trimdir keys
 560     #
 561     # Consequently, this routine traverses this structure,
 562     # calling itself recursively, until it deals with
 563     # all of the scalar target symbols.
 564     if (ref $targetdir eq 'HASH') {
 565         my $subtarget = $targetdir->{target};
 566         if (exists $targetdir->{trimdir}) {
 567             # if we get here, we've specified that
 568             # rather than installing the file to
 569             # $(TARGET)/matching/dirs/subdirs/file,
 570             # we want to install it to
 571             # $(TARGET)/subdirs/file
 572             #
 573             # Note that this the only place where
 574             # $matchlevel is used.
 575             my @new_dest_path = @$dest_path;
 576             if ($targetdir->{trimdir} == -1)  {
 577                 splice @new_dest_path, 0, $matchlevel;
 578             } else {
 579                 splice @new_dest_path, 0, $targetdir->{trimdir};
 580             }
 581             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra, \@new_dest_path);
 582         } else {
 583             # actually getting here means that the
 584             # target was unnecessarily listed
 585             # as a hash, but we'll forgive that
 586             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra);
 587         }
 588     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 589         my $source = File::Spec->catfile(@$curr_path, $file);
 590         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 591         #print "$source => $destination\n"; # DEBUG
 592         # quote spaces in file names
 593         # FIXME: this is of questionable portability and
 594         # probably depends on user's make recognizing this
 595         # quoting syntax -- probably better to remove
 596         # spaces and shell metacharacters from all file names
 597         $source =~ s/ /\\ /g;
 598         $destination =~ s/ /\\ /g;
 599
 600         $file_map->{$source} = $destination unless (!$install_zebra and $targetdir =~ /ZEBRA/);
 601     }
 602 }
 603
 604 =head2 get_configuration_options
 605
 606 This prompts the user for various configuration options.
 607
 608 =cut
 609
 610 sub get_configuration {
 611   my $defaults = shift;
 612   my $valid_values = shift;
 613   my %config = ();
 614
 615   my $msg = q(
 616 By default, Koha can be installed in one of three ways:
 617
 618 standard: Install files in conformance with the Filesystem
 619           Hierarchy Standard (FHS).  This is the default mode
 620           and should be used when installing a production
 621           Koha system.  On Unix systems, root access is
 622           needed to complete a standard installation.
 623
 624 single:   Install files under a single directory.  This option
 625           is useful for installing Koha without root access, e.g.,
 626           on a web host that allows CGI scripts and MySQL databases
 627           but requires the user to keep all files under the user's
 628           HOME directory.
 629
 630 dev:      Create a set of symbolic links and configuration files to
 631           allow Koha to run directly from the source distribution.
 632           This mode is useful for developers who want to run
 633           Koha from a git clone.
 634
 635 Installation mode);
 636     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 637     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values);
 638
 639     # set message and default value for INSTALL_BASE
 640     # depending on value of INSTALL_MODE
 641     my $install_base_default = $defaults->{'INSTALL_BASE'};
 642     if ($config{'INSTALL_MODE'} eq 'dev') {
 643         $msg = q(
 644 Please specify the directory in which to install Koha's
 645 active configuration files and (if applicable) the
 646 Zebra database.  Koha's CGI scripts and templates will
 647 be run from the current directory.
 648
 649 Configuration directory:);
 650         # FIXME - home directory portability consideration apply
 651         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha-dev" : "/usr/share/koha-dev";
 652     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 653         $msg = "\nPlease specify the directory in which to install Koha";
 654         # FIXME -- we're assuming under a 'single' mode install
 655         # that user will likely want to install under the home
 656         # directory.  This is OK in and of itself, but we should
 657         # use File::HomeDir to locate the home directory portably.
 658         # This is deferred for now because File::HomeDir is not yet
 659         # core.
 660         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : "/usr/share/koha";
 661     } else {
 662         # must be standard
 663         $msg = q(
 664 Please specify the directory under which most Koha files
 665 will be installed.
 666
 667 Note that if you are planning in installing more than
 668 one instance of Koha, you may want to modify the last
 669 component of the directory path, which will be used
 670 as the package name in the FHS layout.
 671
 672 Base installation directory);
 673     }
 674     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values);
 675     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 676
 677     if ($config{'INSTALL_MODE'} eq "standard") {
 678         $msg = q(
 679 Since you are using the 'standard' install
 680 mode, you should run 'make install' as root.
 681 However, it is recommended that a non-root
 682 user (on Unix and Linux platforms) have
 683 ownership of Koha's files, including the
 684 Zebra indexes if applicable.
 685
 686 Please specify a user account.  This
 687 user account does not need to exist
 688 right now, but it needs to exist
 689 before you run 'make install'.  Please
 690 note that for security reasons, this
 691 user should not be the same as the user
 692 account Apache runs under.
 693
 694 User account);
 695         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values);
 696
 697         $msg = q(
 698 Please specify the group that should own
 699 Koha's files.  As above, this group need
 700 not exist right now, but should be created
 701 before you run 'make install'.
 702
 703 Group);
 704         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values);
 705     }
 706
 707     $msg = q(
 708 Please specify which database engine you will use
 709 to store data in Koha.  The choices are MySQL and
 710 PostgreSQL; please note that at the moment
 711 PostgreSQL support is highly experimental.
 712
 713 DBMS to use);
 714     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 715     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values);
 716
 717     $msg = q(
 718 Please specify the name or address of your
 719 database server.  Note that the database
 720 does not have to exist at this point, it
 721 can be created after running 'make install'
 722 and before you try using Koha for the first time.
 723
 724 Database server);
 725     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values);
 726
 727     $msg = q(
 728 Please specify the port used to connect to the
 729 DMBS);
 730     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 731     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values);
 732
 733     $msg = q(
 734 Please specify the name of the database to be
 735 used by Koha);
 736     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values);
 737
 738     $msg = q(
 739 Please specify the user that owns the database to be
 740 used by Koha);
 741     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values);
 742
 743     $msg = q(
 744 Please specify the password of the user that owns the
 745 database to be used by Koha);
 746     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values);
 747
 748     $msg = q(
 749 Koha can use the Zebra search engine for high-performance
 750 searching of bibliographic and authority records.  If you
 751 have installed the Zebra software and would like to use it,
 752 please answer 'yes' to the following question.  Otherwise,
 753 Koha will default to using its internal search engine.
 754
 755 Please note that if you choose *NOT* to install Zebra,
 756 koha-conf.xml will still contain some references to Zebra
 757 settings.  Those references will be ignored by Koha.
 758
 759 Install the Zebra configuration files?);
 760     $msg .= _add_valid_values_disp('INSTALL_ZEBRA', $valid_values);
 761     $config{'INSTALL_ZEBRA'} = _get_value('INSTALL_ZEBRA', $msg, $defaults->{'INSTALL_ZEBRA'}, $valid_values);
 762
 763     if ($config{'INSTALL_ZEBRA'} eq 'yes') {
 764         $msg = q(
 765 Since you've chosen to use Zebra with Koha,
 766 you must specify the primary MARC format of the
 767 records to be indexed by Zebra.
 768
 769 Koha provides Zebra configuration files for MARC 21
 770 and UNIMARC.
 771
 772 MARC format for Zebra indexing);
 773         $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 774         $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values);
 775         $msg = q(
 776 Koha supplies Zebra configuration files tuned for
 777 searching either English (en) or French (fr) MARC
 778 records.
 779
 780 Primary language for Zebra indexing);
 781         $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 782         $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values);
 783
 784         $msg = q(
 785 Please specify Zebra database user);
 786         $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values);
 787
 788         $msg = q(
 789 Please specify the Zebra database password);
 790         $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values);
 791
 792     }
 793     return %config;
 794 }
 795
 796 sub _add_valid_values_disp {
 797     my $key = shift;
 798     my $valid_values = shift;
 799
 800     my $disp = "";
 801     if (exists $valid_values->{$key}) {
 802         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
 803     }
 804     return $disp;
 805 }
 806
 807 sub _get_value {
 808     my $key = shift;
 809     my $msg = shift;
 810     my $default = shift;
 811     my $valid_values = shift;
 812
 813     my $val = prompt($msg, $default);
 814     while (exists $valid_values->{$key} and not exists $valid_values->{$key}->{$val}) {
 815         my $retry_msg = "Value '$val' is not a valid option.\n";
 816         $retry_msg .= "Please enter a value";
 817         $retry_msg .= _add_valid_values_disp($key, $valid_values);
 818         $val = prompt($retry_msg, $default);
 819     }
 820     return $val;
 821 }
 822
 823 =head2 get_target_directories
 824
 825 Creates a hash mapping from symbols for installation target
 826 directories to actual directory paths.
 827
 828 =cut
 829
 830 sub get_target_directories {
 831     my $config = shift;
 832
 833     my $base = $config->{'INSTALL_BASE'};
 834     my $mode = $config->{'INSTALL_MODE'};
 835
 836     # get last component of install base directory
 837     # to treat as package name
 838     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
 839     my @basedir = File::Spec->splitdir($directories);
 840     my $package = pop @basedir;
 841
 842     my %dirmap = ();
 843     if ($mode eq 'single') {
 844         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 845         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 846         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 847         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 848         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 849         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 850         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 851         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 852         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 853         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 854         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 855         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 856         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 857         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 858         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 859         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 860         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 861     } elsif ($mode eq 'dev') {
 862         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
 863         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
 864         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 865         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 866         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir, 'opac');
 867         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 868         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 869         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
 870         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 871         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 872         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 873         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 874         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 875         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 876         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 877         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 878         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 879         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 880     } else {
 881         # mode is standard, i.e., 'fhs'
 882         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 883         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 884         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 885         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 886         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 887         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 888         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 889         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
 890         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
 891         $dirmap{'EXAMPLE_DIR'} = File::Spec->catdir(@basedir, $package, 'example');
 892         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 893         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 894         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 895         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
 896         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
 897         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
 898         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
 899     }
 900
 901     _get_argv_overrides(\%dirmap);
 902
 903     return %dirmap;
 904 }
 905
 906 sub _get_argv_overrides {
 907     my $dirmap = shift;
 908
 909     my @new_argv = ();
 910     for (my $i = 0; $i <= $#ARGV; $i++) {
 911         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
 912             $dirmap->{$1} = $2;
 913         } else {
 914             push @new_argv, $ARGV[$i];
 915         }
 916     }
 917     @ARGV = @new_argv;
 918 }
 919
 920 sub display_configuration {
 921     my $config = shift;
 922     my $dirmap = shift;
 923     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
 924     foreach my $key (sort keys %$config) {
 925         print sprintf("%-25.25s%s\n", $key, $config->{$key});
 926     }
 927
 928     print "\nand in the following directories:\n\n";
 929     foreach my $key (sort keys %$dirmap) {
 930         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
 931     }
 932     print "\n\nTo change any configuration setting, please run\n";
 933     print "perl Makefile.PL again.  To override one of the target\n";
 934     print "directories, you can do so on the command line like this:\n";
 935     print "\nperl Makefile.PL PERL_MODULE_DIR=/usr/share/perl/5.8\n\n";
 936 }
 937
 938 package MY;
 939
 940 sub test {
 941     my $self = shift;
 942     my $test = $self->SUPER::test(@_);
 943     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
 944     return $test;
 945 }
 946
 947 sub install {
 948     my $self = shift;
 949     my $install = "";
 950     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
 951     # This means that we're completely overriding EU::MM's default
 952     # installation and uninstallation targets.
 953     foreach my $key (sort keys %target_directories) {
 954         $install .= qq(
 955 KOHA_INST_$key = blib/$key
 956 KOHA_DEST_$key = $target_directories{$key}
 957 ) unless $config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/;
 958     }
 959
 960     $install .= qq(
 961 install :: all install_koha set_koha_ownership
 962 \t\$(NOECHO) \$(NOOP)
 963 );
 964     $install .= "install_koha ::\n";
 965     $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
 966     foreach my $key (sort keys %target_directories) {
 967         $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n" unless $config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/;
 968     }
 969     $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
 970     $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
 971
 972     $install .= "\n";
 973     $install .= "set_koha_ownership ::\n";
 974     if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
 975         foreach my $key (sort keys %target_directories) {
 976             $install .= "\t\$(NOECHO); chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key) \\\n";
 977         }
 978         $install .= "\t\$(NOECHO) \$(NOOP)\n\n";
 979     } else {
 980         $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
 981     }
 982
 983     return $install;
 984 }
 985
 986 sub postamble {
 987     # put directory mappings into Makefile
 988     # so that Make will export as environment
 989     # variables -- this is for the use of
 990     # rewrite-confg.PL
 991     my $env = join("\n", map { "export __${_}__ = $target_directories{$_}" } keys %target_directories);
 992     $env .= "\n\n";
 993     $env .= join("\n", map { "export __${_}__ = $config{$_}" } keys %config);
 994     return "$env\n";
 995 }
 996
 997 __END__
 998
 999
1000 =head1 SEE ALSO
1001
1002 ExtUtils::MakeMaker(3)
1003
1004 =head1 AUTHORS
1005
1006 MJ Ray mjr at phonecoop.coop
1007
1008 =cut
1009 FIXME: deal with .htaccess