circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use strict;
  26 use warnings;
  27 use CGI qw ( -utf8 );
  28 use DateTime;
  29 use DateTime::Duration;
  30 use C4::Output;
  31 use C4::Print;
  32 use C4::Auth qw/:DEFAULT get_session haspermission/;
  33 use C4::Branch; # GetBranches
  34 use C4::Koha;   # GetPrinter
  35 use C4::Circulation;
  36 use C4::Utils::DataTables::Members;
  37 use C4::Members;
  38 use C4::Biblio;
  39 use C4::Search;
  40 use MARC::Record;
  41 use C4::Reserves;
  42 use Koha::Holds;
  43 use C4::Context;
  44 use CGI::Session;
  45 use C4::Members::Attributes qw(GetBorrowerAttributes);
  46 use Koha::Borrower::Debarments qw(GetDebarments IsDebarred);
  47 use Koha::DateUtils;
  48 use Koha::Database;
  49
  50 use Date::Calc qw(
  51   Today
  52   Add_Delta_YM
  53   Add_Delta_Days
  54   Date_to_Days
  55 );
  56 use List::MoreUtils qw/uniq/;
  57
  58 #
  59 # PARAMETERS READING
  60 #
  61 my $query = new CGI;
  62
  63 my $sessionID = $query->cookie("CGISESSID") ;
  64 my $session = get_session($sessionID);
  65
  66 # branch and printer are now defined by the userenv
  67 # but first we have to check if someone has tried to change them
  68
  69 my $branch = $query->param('branch');
  70 if ($branch){
  71     # update our session so the userenv is updated
  72     $session->param('branch', $branch);
  73     $session->param('branchname', GetBranchName($branch));
  74 }
  75
  76 my $printer = $query->param('printer');
  77 if ($printer){
  78     # update our session so the userenv is updated
  79     $session->param('branchprinter', $printer);
  80 }
  81
  82 if (!C4::Context->userenv && !$branch){
  83     if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  84         # no branch set we can't issue
  85         print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  86         exit;
  87     }
  88 }
  89
  90 my $barcodes = [];
  91 my $barcode =  $query->param('barcode');
  92 # Barcode given by user could be '0'
  93 if ( $barcode || $barcode eq '0' ) {
  94     $barcodes = [ $barcode ];
  95 } else {
  96     my $filefh = $query->upload('uploadfile');
  97     if ( $filefh ) {
  98         while ( my $content = <$filefh> ) {
  99             $content =~ s/[\r\n]*$//g;
 100             push @$barcodes, $content if $content;
 101         }
 102     } elsif ( my $list = $query->param('barcodelist') ) {
 103         push @$barcodes, split( /\s\n/, $list );
 104         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 105     } else {
 106         @$barcodes = $query->param('barcodes');
 107     }
 108 }
 109
 110 $barcodes = [ uniq @$barcodes ];
 111
 112 my $template_name = q|circ/circulation.tt|;
 113 my $borrowernumber = $query->param('borrowernumber');
 114 my $borrower = $borrowernumber ? GetMember( borrowernumber => $borrowernumber ) : undef;
 115 my $batch = $query->param('batch');
 116 my $batch_allowed = 0;
 117 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 118     $template_name = q|circ/circulation_batch_checkouts.tt|;
 119     my @batch_category_codes = split '\|', C4::Context->preference('BatchCheckoutsValidCategories');
 120     if ( grep {/^$borrower->{categorycode}$/} @batch_category_codes ) {
 121         $batch_allowed = 1;
 122     } else {
 123         $barcodes = [];
 124     }
 125 }
 126
 127 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 128     {
 129         template_name   => $template_name,
 130         query           => $query,
 131         type            => "intranet",
 132         authnotrequired => 0,
 133         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 134     }
 135 );
 136
 137 my $branches = GetBranches();
 138
 139 my $force_allow_issue = $query->param('forceallow') || 0;
 140 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 141     $force_allow_issue = 0;
 142 }
 143
 144 my $onsite_checkout = $query->param('onsite_checkout');
 145
 146 my @failedrenews = $query->param('failedrenew');    # expected to be itemnumbers
 147 our %renew_failed = ();
 148 for (@failedrenews) { $renew_failed{$_} = 1; }
 149
 150 my @failedreturns = $query->param('failedreturn');
 151 our %return_failed = ();
 152 for (@failedreturns) { $return_failed{$_} = 1; }
 153
 154 my $findborrower = $query->param('findborrower') || q{};
 155 $findborrower =~ s|,| |g;
 156
 157 $branch  = C4::Context->userenv->{'branch'};
 158 $printer = C4::Context->userenv->{'branchprinter'};
 159
 160 # If AutoLocation is not activated, we show the Circulation Parameters to chage settings of librarian
 161 if (C4::Context->preference("AutoLocation") != 1) {
 162     $template->param(ManualLocation => 1);
 163 }
 164
 165 if (C4::Context->preference("DisplayClearScreenButton")) {
 166     $template->param(DisplayClearScreenButton => 1);
 167 }
 168
 169 for my $barcode ( @$barcodes ) {
 170     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 171     $barcode = barcodedecode($barcode)
 172         if( $barcode && C4::Context->preference('itemBarcodeInputFilter'));
 173 }
 174
 175 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 176 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 177 $duedatespec = eval { output_pref( { dt => dt_from_string( $duedatespec ), dateformat => 'iso' }); }
 178     if ( $duedatespec );
 179 my $restoreduedatespec  = $query->param('restoreduedatespec') || $session->param('stickyduedate') || $duedatespec;
 180 if ($restoreduedatespec eq "highholds_empty") {
 181     undef $restoreduedatespec;
 182 }
 183 my $issueconfirmed = $query->param('issueconfirmed');
 184 my $cancelreserve  = $query->param('cancelreserve');
 185 my $print          = $query->param('print') || q{};
 186 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 187 my $charges        = $query->param('charges') || q{};
 188
 189 # Check if stickyduedate is turned off
 190 if ( @$barcodes ) {
 191     # was stickyduedate loaded from session?
 192     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 193         $session->clear( 'stickyduedate' );
 194         $stickyduedate  = $query->param('stickyduedate');
 195         $duedatespec    = $query->param('duedatespec');
 196     }
 197     $session->param('auto_renew', $query->param('auto_renew'));
 198 }
 199 else {
 200     $session->clear('auto_renew');
 201 }
 202
 203 my ($datedue,$invalidduedate);
 204
 205 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 206 if( $onsite_checkout && !$duedatespec_allow ) {
 207     $datedue = output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 208     $datedue .= ' 23:59:00';
 209 } elsif( $duedatespec_allow ) {
 210     if ( $duedatespec ) {
 211         $datedue = eval { dt_from_string( $duedatespec ) };
 212         if (! $datedue ) {
 213             $invalidduedate = 1;
 214             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 215         }
 216     }
 217 }
 218
 219 # check and see if we should print
 220 if ( @$barcodes == 0 && $print eq 'maybe' ) {
 221     $print = 'yes';
 222 }
 223
 224 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 225 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 226     $template->param(
 227         PAYCHARGES     => 'yes',
 228         borrowernumber => $borrowernumber
 229     );
 230 }
 231
 232 if ( $print eq 'yes' && $borrowernumber ne '' ) {
 233     if ( C4::Context->boolean_preference('printcirculationslips') ) {
 234         my $letter = IssueSlip($branch, $borrowernumber, "QUICK");
 235         NetworkPrint($letter->{content});
 236     }
 237     $query->param( 'borrowernumber', '' );
 238     $borrowernumber = '';
 239 }
 240
 241 #
 242 # STEP 2 : FIND BORROWER
 243 # if there is a list of find borrowers....
 244 #
 245 my $message;
 246 if ($findborrower) {
 247     my $borrower = C4::Members::GetMember( cardnumber => $findborrower );
 248     if ( $borrower ) {
 249         $borrowernumber = $borrower->{borrowernumber};
 250     } else {
 251         my $dt_params = { iDisplayLength => -1 };
 252         my $results = C4::Utils::DataTables::Members::search(
 253             {
 254                 searchmember => $findborrower,
 255                 searchtype => 'contain',
 256                 dt_params => $dt_params,
 257             }
 258         );
 259         my $borrowers = $results->{patrons};
 260         if ( scalar @$borrowers == 1 ) {
 261             $borrowernumber = $borrowers->[0]->{borrowernumber};
 262             $query->param( 'borrowernumber', $borrowernumber );
 263             $query->param( 'barcode',           '' );
 264         } elsif ( @$borrowers ) {
 265             $template->param( borrowers => $borrowers );
 266         } else {
 267             $query->param( 'findborrower', '' );
 268             $message = "'$findborrower'";
 269         }
 270     }
 271 }
 272
 273 # get the borrower information.....
 274 if ($borrowernumber) {
 275     $borrower = GetMemberDetails( $borrowernumber, 0 );
 276     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrowernumber );
 277
 278     # Warningdate is the date that the warning starts appearing
 279     my (  $today_year,   $today_month,   $today_day) = Today();
 280     my ($warning_year, $warning_month, $warning_day) = split /-/, $borrower->{'dateexpiry'};
 281     my (  $enrol_year,   $enrol_month,   $enrol_day) = split /-/, $borrower->{'dateenrolled'};
 282     # Renew day is calculated by adding the enrolment period to today
 283     my (  $renew_year,   $renew_month,   $renew_day);
 284     if ($enrol_year*$enrol_month*$enrol_day>0) {
 285         (  $renew_year,   $renew_month,   $renew_day) =
 286         Add_Delta_YM( $enrol_year, $enrol_month, $enrol_day,
 287             0 , $borrower->{'enrolmentperiod'});
 288     }
 289     # if the expiry date is before today ie they have expired
 290     if ( !$borrower->{'dateexpiry'} || $warning_year*$warning_month*$warning_day==0
 291         || Date_to_Days($today_year,     $today_month, $today_day  )
 292          > Date_to_Days($warning_year, $warning_month, $warning_day) )
 293     {
 294         #borrowercard expired, no issues
 295         $template->param(
 296             flagged  => "1",
 297             noissues => ($force_allow_issue) ? 0 : "1",
 298             forceallow => $force_allow_issue,
 299             expired => "1",
 300             renewaldate => "$renew_year-$renew_month-$renew_day",
 301         );
 302     }
 303     # check for NotifyBorrowerDeparture
 304     elsif ( C4::Context->preference('NotifyBorrowerDeparture') &&
 305             Date_to_Days(Add_Delta_Days($warning_year,$warning_month,$warning_day,- C4::Context->preference('NotifyBorrowerDeparture'))) <
 306             Date_to_Days( $today_year, $today_month, $today_day ) )
 307     {
 308         # borrower card soon to expire warn librarian
 309         $template->param( "warndeparture" => $borrower->{dateexpiry} ,
 310                           flagged         => "1"
 311                         );
 312         if (C4::Context->preference('ReturnBeforeExpiry')){
 313             $template->param("returnbeforeexpiry" => 1);
 314         }
 315     }
 316     $template->param(
 317         overduecount => $od,
 318         issuecount   => $issue,
 319         finetotal    => $fines
 320     );
 321
 322     if ( IsDebarred($borrowernumber) ) {
 323         $template->param(
 324             'userdebarred'    => $borrower->{debarred},
 325             'debarredcomment' => $borrower->{debarredcomment},
 326         );
 327
 328         if ( $borrower->{debarred} ne "9999-12-31" ) {
 329             $template->param( 'userdebarreddate' => $borrower->{debarred} );
 330         }
 331     }
 332
 333 }
 334
 335 #
 336 # STEP 3 : ISSUING
 337 #
 338 #
 339 if (@$barcodes) {
 340   my $checkout_infos;
 341   for my $barcode ( @$barcodes ) {
 342     my $template_params = { barcode => $barcode };
 343     # always check for blockers on issuing
 344     my ( $error, $question, $alerts ) =
 345     CanBookBeIssued( $borrower, $barcode, $datedue , $inprocess, undef, { onsite_checkout => $onsite_checkout } );
 346     my $blocker = $invalidduedate ? 1 : 0;
 347
 348     $template_params->{alert} = $alerts;
 349
 350     #  Get the item title for more information
 351     my $getmessageiteminfo = GetBiblioFromItemNumber(undef,$barcode);
 352     $template_params->{authvalcode_notforloan} =
 353         C4::Koha::GetAuthValCode('items.notforloan', $getmessageiteminfo->{'frameworkcode'});
 354
 355     # Fix for bug 7494: optional checkout-time fallback search for a book
 356
 357     if ( $error->{'UNKNOWN_BARCODE'}
 358         && C4::Context->preference("itemBarcodeFallbackSearch")
 359         && not $batch
 360     )
 361     {
 362      $template_params->{FALLBACK} = 1;
 363
 364         my $query = "kw=" . $barcode;
 365         my ( $searcherror, $results, $total_hits ) = SimpleSearch($query);
 366
 367         # if multiple hits, offer options to librarian
 368         if ( $total_hits > 0 ) {
 369             my @options = ();
 370             foreach my $hit ( @{$results} ) {
 371                 my $chosen =
 372                   TransformMarcToKoha( C4::Context->dbh,
 373                     C4::Search::new_record_from_zebra('biblioserver',$hit) );
 374
 375                 # offer all barcodes individually
 376                 if ( $chosen->{barcode} ) {
 377                     foreach my $barcode ( sort split(/\s*\|\s*/, $chosen->{barcode}) ) {
 378                         my %chosen_single = %{$chosen};
 379                         $chosen_single{barcode} = $barcode;
 380                         push( @options, \%chosen_single );
 381                     }
 382                 }
 383             }
 384             $template_params->{options} = \@options;
 385         }
 386     }
 387
 388     unless( $onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce") ) {
 389         delete $question->{'DEBT'} if ($debt_confirmed);
 390         foreach my $impossible ( keys %$error ) {
 391             $template_params->{$impossible} = $$error{$impossible};
 392             $template_params->{IMPOSSIBLE} = 1;
 393             $blocker = 1;
 394         }
 395     }
 396     my $iteminfo = GetBiblioFromItemNumber(undef, $barcode);
 397     if( !$blocker || $force_allow_issue ){
 398         my $confirm_required = 0;
 399         unless($issueconfirmed){
 400             #  Get the item title for more information
 401             $template_params->{additional_materials} = $iteminfo->{'materials'};
 402             $template_params->{itemhomebranch} = $iteminfo->{'homebranch'};
 403
 404             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 405             foreach my $needsconfirmation ( keys %$question ) {
 406                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 407                 $template_params->{getTitleMessageIteminfo} = $iteminfo->{'title'};
 408                 $template_params->{getBarcodeMessageIteminfo} = $iteminfo->{'barcode'};
 409                 $template_params->{NEEDSCONFIRMATION} = 1;
 410                 $template_params->{onsite_checkout} = $onsite_checkout;
 411                 $confirm_required = 1;
 412             }
 413         }
 414         unless($confirm_required) {
 415             my $issue = AddIssue( $borrower, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew') } );
 416             $template->param( issue => $issue );
 417             $session->clear('auto_renew');
 418             $inprocess = 1;
 419         }
 420     }
 421
 422     # FIXME If the issue is confirmed, we launch another time GetMemberIssuesAndFines, now display the issue count after issue
 423     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines($borrowernumber);
 424
 425     if ($question->{RESERVE_WAITING} or $question->{RESERVED}){
 426         $template->param(
 427             reserveborrowernumber => $question->{'resborrowernumber'},
 428             itembiblionumber => $getmessageiteminfo->{'biblionumber'}
 429         );
 430     }
 431
 432     $template_params->{issuecount} = $issue;
 433
 434     if ( $iteminfo ) {
 435         $iteminfo->{subtitle} = GetRecordValue('subtitle', GetMarcBiblio($iteminfo->{biblionumber}), GetFrameworkCode($iteminfo->{biblionumber}));
 436         $template_params->{item} = $iteminfo;
 437     }
 438     push @$checkout_infos, $template_params;
 439   }
 440   unless ( $batch ) {
 441     $template->param( %{$checkout_infos->[0]} );
 442     $template->param( barcode => $barcodes->[0] );
 443   } else {
 444     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 445     $template->param(
 446         checkout_infos => $checkout_infos,
 447         confirmation_needed => $confirmation_needed,
 448     );
 449   }
 450 }
 451
 452 # reload the borrower info for the sake of reseting the flags.....
 453 if ($borrowernumber) {
 454     $borrower = GetMemberDetails( $borrowernumber, 0 );
 455 }
 456
 457 ##################################################################################
 458 # BUILD HTML
 459 # show all reserves of this borrower, and the position of the reservation ....
 460 if ($borrowernumber) {
 461     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 462     my $waiting_holds = $holds->waiting;
 463     $template->param(
 464         holds_count  => $holds->count(),
 465         WaitingHolds => $waiting_holds,
 466     );
 467
 468     $template->param( adultborrower => 1 ) if ( $borrower->{category_type} eq 'A' || $borrower->{category_type} eq 'I' );
 469 }
 470
 471 #title
 472 my $flags = $borrower->{'flags'};
 473 foreach my $flag ( sort keys %$flags ) {
 474     $template->param( flagged=> 1);
 475     $flags->{$flag}->{'message'} =~ s#\n#<br />#g;
 476     if ( $flags->{$flag}->{'noissues'} ) {
 477         $template->param(
 478             noissues => ($force_allow_issue) ? 0 : 'true',
 479             forceallow => $force_allow_issue,
 480         );
 481         if ( $flag eq 'GNA' ) {
 482             $template->param( gna => 'true' );
 483         }
 484         elsif ( $flag eq 'LOST' ) {
 485             $template->param( lost => 'true' );
 486         }
 487         elsif ( $flag eq 'DBARRED' ) {
 488             $template->param( dbarred => 'true' );
 489         }
 490         elsif ( $flag eq 'CHARGES' ) {
 491             $template->param(
 492                 charges    => 'true',
 493                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 494                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 495                 charges_is_blocker => 1
 496             );
 497         }
 498         elsif ( $flag eq 'CREDITS' ) {
 499             $template->param(
 500                 credits    => 'true',
 501                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 502                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 503             );
 504         }
 505     }
 506     else {
 507         if ( $flag eq 'CHARGES' ) {
 508             $template->param(
 509                 charges    => 'true',
 510                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 511                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 512             );
 513         }
 514         elsif ( $flag eq 'CREDITS' ) {
 515             $template->param(
 516                 credits    => 'true',
 517                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 518                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 519             );
 520         }
 521         elsif ( $flag eq 'ODUES' ) {
 522             $template->param(
 523                 odues    => 'true',
 524                 oduesmsg => $flags->{'ODUES'}->{'message'}
 525             );
 526
 527             my $items = $flags->{$flag}->{'itemlist'};
 528             if ( ! $query->param('module') || $query->param('module') ne 'returns' ) {
 529                 $template->param( nonreturns => 'true' );
 530             }
 531         }
 532         elsif ( $flag eq 'NOTES' ) {
 533             $template->param(
 534                 notes    => 'true',
 535                 notesmsg => $flags->{'NOTES'}->{'message'}
 536             );
 537         }
 538     }
 539 }
 540
 541 my $amountold = $borrower->{flags}->{'CHARGES'}->{'message'} || 0;
 542 $amountold =~ s/^.*\$//;    # remove upto the $, if any
 543
 544 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 545
 546 if ( $borrowernumber && $borrower->{'category_type'} eq 'C') {
 547     my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 548     my $cnt = scalar(@$catcodes);
 549     $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 550     $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 551 }
 552
 553 my $lib_messages_loop = GetMessages( $borrowernumber, 'L', $branch );
 554 if($lib_messages_loop){ $template->param(flagged => 1 ); }
 555
 556 my $bor_messages_loop = GetMessages( $borrowernumber, 'B', $branch );
 557 if($bor_messages_loop){ $template->param(flagged => 1 ); }
 558
 559 my $fast_cataloging = 0;
 560 if (defined getframeworkinfo('FA')) {
 561     $fast_cataloging = 1
 562 }
 563
 564 if (C4::Context->preference('ExtendedPatronAttributes')) {
 565     my $attributes = GetBorrowerAttributes($borrowernumber);
 566     $template->param(
 567         ExtendedPatronAttributes => 1,
 568         extendedattributes => $attributes
 569     );
 570 }
 571 my $view = $batch
 572     ?'batch_checkout_view'
 573     : 'circview';
 574
 575 my @relatives = GetMemberRelatives( $borrower->{'borrowernumber'} );
 576 my $relatives_issues_count =
 577   Koha::Database->new()->schema()->resultset('Issue')
 578   ->count( { borrowernumber => \@relatives } );
 579
 580 my $roadtype = C4::Koha::GetAuthorisedValueByCode( 'ROADTYPE', $borrower->{streettype} );
 581
 582 $template->param(%$borrower);
 583
 584 # Restore date if changed by holds and/or save stickyduedate to session
 585 if ($restoreduedatespec || $stickyduedate) {
 586     $duedatespec = $restoreduedatespec || $duedatespec;
 587
 588     if ($stickyduedate) {
 589         $session->param( 'stickyduedate', $duedatespec );
 590     }
 591 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 592     undef $duedatespec;
 593 }
 594
 595 $template->param(
 596     lib_messages_loop => $lib_messages_loop,
 597     bor_messages_loop => $bor_messages_loop,
 598     all_messages_del  => C4::Context->preference('AllowAllMessageDeletion'),
 599     findborrower      => $findborrower,
 600     borrower          => $borrower,
 601     borrowernumber    => $borrowernumber,
 602     categoryname      => $borrower->{'description'},
 603     branch            => $branch,
 604     branchname        => GetBranchName($borrower->{'branchcode'}),
 605     printer           => $printer,
 606     printername       => $printer,
 607     was_renewed       => $query->param('was_renewed') ? 1 : 0,
 608     expiry            => $borrower->{'dateexpiry'},
 609     roadtype          => $roadtype,
 610     amountold         => $amountold,
 611     barcodes          => $barcodes,
 612     stickyduedate     => $stickyduedate,
 613     duedatespec       => $duedatespec,
 614     restoreduedatespec => $restoreduedatespec,
 615     message           => $message,
 616     totaldue          => sprintf('%.2f', $total),
 617     inprocess         => $inprocess,
 618     is_child          => ($borrowernumber && $borrower->{'category_type'} eq 'C'),
 619     $view             => 1,
 620     batch_allowed     => $batch_allowed,
 621     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 622     fast_cataloging   => $fast_cataloging,
 623     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 624     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 625     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 626     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 627     RoutingSerials => C4::Context->preference('RoutingSerials'),
 628     relatives_issues_count => $relatives_issues_count,
 629     relatives_borrowernumbers => \@relatives,
 630 );
 631
 632 my ($picture, $dberror) = GetPatronImage($borrower->{'borrowernumber'});
 633 $template->param( picture => 1 ) if $picture;
 634
 635 # get authorised values with type of BOR_NOTES
 636
 637 my $canned_notes = GetAuthorisedValues("BOR_NOTES");
 638
 639 $template->param(
 640     debt_confirmed            => $debt_confirmed,
 641     SpecifyDueDate            => $duedatespec_allow,
 642     CircAutocompl             => C4::Context->preference("CircAutocompl"),
 643     AllowRenewalLimitOverride => C4::Context->preference("AllowRenewalLimitOverride"),
 644     canned_bor_notes_loop     => $canned_notes,
 645     debarments                => GetDebarments({ borrowernumber => $borrowernumber }),
 646     todaysdate                => output_pref( { dt => dt_from_string()->set(hour => 23)->set(minute => 59), dateformat => 'sql' } ),
 647 );
 648
 649 output_html_with_http_headers $query, $cookie, $template->output;