misc/cronjobs/advance_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 advance_notices.pl - cron script to put item due reminders into message queue
  23
  24 =head1 SYNOPSIS
  25
  26 ./advance_notices.pl -c
  27
  28 or, in crontab:
  29 0 1 * * * advance_notices.pl -c
  30
  31 =head1 DESCRIPTION
  32
  33 This script prepares pre-due and item due reminders to be sent to
  34 patrons. It queues them in the message queue, which is processed by
  35 the process_message_queue.pl cronjob. The type and timing of the
  36 messages can be configured by the patrons in their "My Alerts" tab in
  37 the OPAC.
  38
  39 =cut
  40
  41 use strict;
  42 use warnings;
  43 use Getopt::Long;
  44 use Pod::Usage;
  45 use Data::Dumper;
  46 BEGIN {
  47     # find Koha's Perl modules
  48     # test carefully before changing this
  49     use FindBin;
  50     eval { require "$FindBin::Bin/../kohalib.pl" };
  51 }
  52 use C4::Biblio;
  53 use C4::Context;
  54 use C4::Letters;
  55 use C4::Members;
  56 use C4::Members::Messaging;
  57 use C4::Overdues;
  58 use Koha::DateUtils;
  59 use C4::Log;
  60 use Koha::Items;
  61 use Koha::Libraries;
  62 use Koha::Patrons;
  63
  64 =head1 NAME
  65
  66 advance_notices.pl - prepare messages to be sent to patrons for nearly due, or due, items
  67
  68 =head1 SYNOPSIS
  69
  70 advance_notices.pl
  71   [ -n ][ -m <number of days> ][ --itemscontent <comma separated field list> ][ -c ]
  72
  73 =head1 OPTIONS
  74
  75 =over 8
  76
  77 =item B<--help>
  78
  79 Print a brief help message and exits.
  80
  81 =item B<--man>
  82
  83 Prints the manual page and exits.
  84
  85 =item B<-v>
  86
  87 Verbose. Without this flag set, only fatal errors are reported.
  88
  89 =item B<-n>
  90
  91 Do not send any email. Advanced or due notices that would have been sent to
  92 the patrons are printed to standard out.
  93
  94 =item B<-m>
  95
  96 Defines the maximum number of days in advance to send advance notices.
  97
  98 =item B<-c>
  99
 100 Confirm flag: Add this option. The script will only print a usage
 101 statement otherwise.
 102
 103 =item B<--itemscontent>
 104
 105 comma separated list of fields that get substituted into templates in
 106 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 107 defaults to date_due,title,author,barcode
 108
 109 Other possible values come from fields in the biblios, items and
 110 issues tables.
 111
 112 =back
 113
 114 =head1 DESCRIPTION
 115
 116 This script is designed to alert patrons when items are due, or coming due
 117
 118 =head2 Configuration
 119
 120 This script pays attention to the advanced notice configuration
 121 performed by borrowers in the OPAC, or by staff in the patron detail page of the intranet. The content of the messages is configured in Tools -> Notices and slips. Advanced notices use the PREDUE template, due notices use DUE. More information about the use of this
 122 section of Koha is available in the Koha manual.
 123
 124 =head2 Outgoing emails
 125
 126 Typically, messages are prepared for each patron with due
 127 items, and who have selected (or the library has elected for them) Advance or Due notices.
 128
 129 These emails are staged in the outgoing message queue, as are messages
 130 produced by other features of Koha. This message queue must be
 131 processed regularly by the
 132 F<misc/cronjobs/process_message_queue.pl> program.
 133
 134 In the event that the C<-n> flag is passed to this program, no emails
 135 are sent. Instead, messages are sent on standard output from this
 136 program. They may be redirected to a file if desired.
 137
 138 =head2 Templates
 139
 140 Templates can contain variables enclosed in double angle brackets like
 141 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 142 specific to the overdue items or relevant patron. Available variables
 143 are:
 144
 145 =over
 146
 147 =item E<lt>E<lt>items.contentE<gt>E<gt>
 148
 149 one line for each item, each line containing a tab separated list of
 150 date due, title, author, barcode
 151
 152 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 153
 154 any field from the borrowers table
 155
 156 =item E<lt>E<lt>branches.*E<gt>E<gt>
 157
 158 any field from the branches table
 159
 160 =back
 161
 162 =head1 SEE ALSO
 163
 164 The F<misc/cronjobs/overdue_notices.pl> program allows you to send
 165 messages to patrons when their messages are overdue.
 166
 167 =cut
 168
 169 binmode( STDOUT, ':encoding(UTF-8)' );
 170
 171 # These are defaults for command line options.
 172 my $confirm;                                                        # -c: Confirm that the user has read and configured this script.
 173 my $nomail;                                                         # -n: No mail. Will not send any emails.
 174 my $mindays     = 0;                                                # -m: Maximum number of days in advance to send notices
 175 my $maxdays     = 30;                                               # -e: the End of the time period
 176 my $verbose     = 0;                                                # -v: verbose
 177 my $itemscontent = join(',',qw( date_due title author barcode ));
 178
 179 my $help    = 0;
 180 my $man     = 0;
 181
 182 GetOptions(
 183             'help|?'         => \$help,
 184             'man'            => \$man,
 185             'c'              => \$confirm,
 186             'n'              => \$nomail,
 187             'm:i'            => \$maxdays,
 188             'v'              => \$verbose,
 189             'itemscontent=s' => \$itemscontent,
 190        )or pod2usage(2);
 191 pod2usage(1) if $help;
 192 pod2usage( -verbose => 2 ) if $man;
 193
 194 # Since advance notice options are not visible in the web-interface
 195 # unless EnhancedMessagingPreferences is on, let the user know that
 196 # this script probably isn't going to do much
 197 if ( ! C4::Context->preference('EnhancedMessagingPreferences') ) {
 198     warn <<'END_WARN';
 199
 200 The "EnhancedMessagingPreferences" syspref is off.
 201 Therefore, it is unlikely that this script will actually produce any messages to be sent.
 202 To change this, edit the "EnhancedMessagingPreferences" syspref.
 203
 204 END_WARN
 205 }
 206 unless ($confirm) {
 207      pod2usage(1);
 208 }
 209
 210 cronlogaction();
 211
 212 # The fields that will be substituted into <<items.content>>
 213 my @item_content_fields = split(/,/,$itemscontent);
 214
 215 warn 'getting upcoming due issues' if $verbose;
 216 my $upcoming_dues = C4::Circulation::GetUpcomingDueIssues( { days_in_advance => $maxdays } );
 217 warn 'found ' . scalar( @$upcoming_dues ) . ' issues' if $verbose;
 218
 219 # hash of borrowernumber to number of items upcoming
 220 # for patrons wishing digests only.
 221 my $upcoming_digest;
 222 my $due_digest;
 223
 224 my $dbh = C4::Context->dbh();
 225 my $sth = $dbh->prepare(<<'END_SQL');
 226 SELECT biblio.*, items.*, issues.*
 227   FROM issues,items,biblio
 228   WHERE items.itemnumber=issues.itemnumber
 229     AND biblio.biblionumber=items.biblionumber
 230     AND issues.borrowernumber = ?
 231     AND issues.itemnumber = ?
 232     AND (TO_DAYS(date_due)-TO_DAYS(NOW()) = ?)
 233 END_SQL
 234
 235 my $admin_adress = C4::Context->preference('KohaAdminEmailAddress');
 236
 237 my @letters;
 238 UPCOMINGITEM: foreach my $upcoming ( @$upcoming_dues ) {
 239     @letters = ();
 240     warn 'examining ' . $upcoming->{'itemnumber'} . ' upcoming due items' if $verbose;
 241
 242     my $from_address = $upcoming->{branchemail} || $admin_adress;
 243
 244     my $borrower_preferences;
 245     if ( 0 == $upcoming->{'days_until_due'} ) {
 246         # This item is due today. Send an 'item due' message.
 247         $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $upcoming->{'borrowernumber'},
 248                                                                                    message_name   => 'item_due' } );
 249         next unless $borrower_preferences;
 250
 251         if ( $borrower_preferences->{'wants_digest'} ) {
 252             # cache this one to process after we've run through all of the items.
 253             $due_digest->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 254             $due_digest->{ $upcoming->{borrowernumber} }->{count}++;
 255         } else {
 256             my $item = Koha::Items->find( $upcoming->{itemnumber} );
 257             my $letter_type = 'DUE';
 258             $sth->execute($upcoming->{'borrowernumber'},$upcoming->{'itemnumber'},'0');
 259             my $titles = "";
 260             while ( my $item_info = $sth->fetchrow_hashref()) {
 261               my @item_info = map { $_ =~ /^date|date$/ ? format_date($item_info->{$_}) : $item_info->{$_} || '' } @item_content_fields;
 262               $titles .= join("\t",@item_info) . "\n";
 263             }
 264
 265             ## Get branch info for borrowers home library.
 266             foreach my $transport ( keys %{$borrower_preferences->{'transports'}} ) {
 267                 my $letter = parse_letter( { letter_code    => $letter_type,
 268                                       borrowernumber => $upcoming->{'borrowernumber'},
 269                                       branchcode     => $upcoming->{'branchcode'},
 270                                       biblionumber   => $item->biblionumber,
 271                                       itemnumber     => $upcoming->{'itemnumber'},
 272                                       substitute     => { 'items.content' => $titles },
 273                                       message_transport_type => $transport,
 274                                     } )
 275                     or warn "no letter of type '$letter_type' found for borrowernumber ".$upcoming->{'borrowernumber'}.". Please see sample_notices.sql";
 276                 push @letters, $letter if $letter;
 277             }
 278         }
 279     } else {
 280         $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $upcoming->{'borrowernumber'},
 281                                                                                    message_name   => 'advance_notice' } );
 282         next UPCOMINGITEM unless $borrower_preferences && exists $borrower_preferences->{'days_in_advance'};
 283         next UPCOMINGITEM unless $borrower_preferences->{'days_in_advance'} == $upcoming->{'days_until_due'};
 284
 285         if ( $borrower_preferences->{'wants_digest'} ) {
 286             # cache this one to process after we've run through all of the items.
 287             $upcoming_digest->{ $upcoming->{borrowernumber} }->{email} = $from_address;
 288             $upcoming_digest->{ $upcoming->{borrowernumber} }->{count}++;
 289         } else {
 290             my $item = Koha::Items->find( $upcoming->{itemnumber} );
 291             my $letter_type = 'PREDUE';
 292             $sth->execute($upcoming->{'borrowernumber'},$upcoming->{'itemnumber'},$borrower_preferences->{'days_in_advance'});
 293             my $titles = "";
 294             while ( my $item_info = $sth->fetchrow_hashref()) {
 295               my @item_info = map { $_ =~ /^date|date$/ ? format_date($item_info->{$_}) : $item_info->{$_} || '' } @item_content_fields;
 296               $titles .= join("\t",@item_info) . "\n";
 297             }
 298
 299             ## Get branch info for borrowers home library.
 300             foreach my $transport ( keys %{$borrower_preferences->{'transports'}} ) {
 301                 my $letter = parse_letter( { letter_code    => $letter_type,
 302                                       borrowernumber => $upcoming->{'borrowernumber'},
 303                                       branchcode     => $upcoming->{'branchcode'},
 304                                       biblionumber   => $item->biblionumber,
 305                                       itemnumber     => $upcoming->{'itemnumber'},
 306                                       substitute     => { 'items.content' => $titles },
 307                                       message_transport_type => $transport,
 308                                     } )
 309                     or warn "no letter of type '$letter_type' found for borrowernumber ".$upcoming->{'borrowernumber'}.". Please see sample_notices.sql";
 310                 push @letters, $letter if $letter;
 311             }
 312         }
 313     }
 314
 315     # If we have prepared a letter, send it.
 316     if ( @letters ) {
 317       if ($nomail) {
 318         for my $letter ( @letters ) {
 319             local $, = "\f";
 320             print $letter->{'content'};
 321         }
 322       }
 323       else {
 324         for my $letter ( @letters ) {
 325             C4::Letters::EnqueueLetter( { letter                 => $letter,
 326                                           borrowernumber         => $upcoming->{'borrowernumber'},
 327                                           from_address           => $from_address,
 328                                           message_transport_type => $letter->{message_transport_type} } );
 329         }
 330       }
 331     }
 332 }
 333
 334
 335
 336 # Now, run through all the people that want digests and send them
 337
 338 $sth = $dbh->prepare(<<'END_SQL');
 339 SELECT biblio.*, items.*, issues.*
 340   FROM issues,items,biblio
 341   WHERE items.itemnumber=issues.itemnumber
 342     AND biblio.biblionumber=items.biblionumber
 343     AND issues.borrowernumber = ?
 344     AND (TO_DAYS(date_due)-TO_DAYS(NOW()) = ?)
 345 END_SQL
 346 PATRON: while ( my ( $borrowernumber, $digest ) = each %$upcoming_digest ) {
 347     @letters = ();
 348     my $count = $digest->{count};
 349     my $from_address = $digest->{email};
 350
 351     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $borrowernumber,
 352                                                                                   message_name   => 'advance_notice' } );
 353     next PATRON unless $borrower_preferences; # how could this happen?
 354
 355
 356     my $letter_type = 'PREDUEDGST';
 357
 358     $sth->execute($borrowernumber,$borrower_preferences->{'days_in_advance'});
 359     my $titles = "";
 360     while ( my $item_info = $sth->fetchrow_hashref()) {
 361       my @item_info = map { $_ =~ /^date|date$/ ? format_date($item_info->{$_}) : $item_info->{$_} || '' } @item_content_fields;
 362       $titles .= join("\t",@item_info) . "\n";
 363     }
 364
 365     ## Get branch info for borrowers home library.
 366     my %branch_info = get_branch_info( $borrowernumber );
 367
 368     foreach my $transport ( keys %{ $borrower_preferences->{'transports'} } ) {
 369         my $letter = parse_letter(
 370             {
 371                 letter_code    => $letter_type,
 372                 borrowernumber => $borrowernumber,
 373                 substitute     => {
 374                     count           => $count,
 375                     'items.content' => $titles,
 376                     %branch_info,
 377                 },
 378                 branchcode             => $branch_info{"branches.branchcode"},
 379                 message_transport_type => $transport,
 380             }
 381           )
 382           or warn "no letter of type '$letter_type' found for borrowernumber $borrowernumber. Please see sample_notices.sql";
 383         push @letters, $letter if $letter;
 384     }
 385
 386     if ( @letters ) {
 387       if ($nomail) {
 388         for my $letter ( @letters ) {
 389             local $, = "\f";
 390             print $letter->{'content'};
 391         }
 392       }
 393       else {
 394         for my $letter ( @letters ) {
 395             C4::Letters::EnqueueLetter( { letter                 => $letter,
 396                                           borrowernumber         => $borrowernumber,
 397                                           from_address           => $from_address,
 398                                           message_transport_type => $letter->{message_transport_type} } );
 399         }
 400       }
 401     }
 402 }
 403
 404 # Now, run through all the people that want digests and send them
 405 PATRON: while ( my ( $borrowernumber, $digest ) = each %$due_digest ) {
 406     @letters = ();
 407     my $count = $digest->{count};
 408     my $from_address = $digest->{email};
 409
 410     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $borrowernumber,
 411                                                                                   message_name   => 'item_due' } );
 412     next PATRON unless $borrower_preferences; # how could this happen?
 413
 414     my $letter_type = 'DUEDGST';
 415     $sth->execute($borrowernumber,'0');
 416     my $titles = "";
 417     while ( my $item_info = $sth->fetchrow_hashref()) {
 418       my @item_info = map { $_ =~ /^date|date$/ ? format_date($item_info->{$_}) : $item_info->{$_} || '' } @item_content_fields;
 419       $titles .= join("\t",@item_info) . "\n";
 420     }
 421
 422     ## Get branch info for borrowers home library.
 423     my %branch_info = get_branch_info( $borrowernumber );
 424
 425     for my $transport ( keys %{ $borrower_preferences->{'transports'} } ) {
 426         my $letter = parse_letter(
 427             {
 428                 letter_code    => $letter_type,
 429                 borrowernumber => $borrowernumber,
 430                 substitute     => {
 431                     count           => $count,
 432                     'items.content' => $titles,
 433                     %branch_info,
 434                 },
 435                 branchcode             => $branch_info{"branches.branchcode"},
 436                 message_transport_type => $transport,
 437             }
 438           )
 439           or warn "no letter of type '$letter_type' found for borrowernumber $borrowernumber. Please see sample_notices.sql";
 440         push @letters, $letter if $letter;
 441     }
 442
 443     if ( @letters ) {
 444       if ($nomail) {
 445         for my $letter ( @letters ) {
 446             local $, = "\f";
 447             print $letter->{'content'};
 448         }
 449       }
 450       else {
 451         for my $letter ( @letters ) {
 452             C4::Letters::EnqueueLetter( { letter                 => $letter,
 453                                           borrowernumber         => $borrowernumber,
 454                                           from_address           => $from_address,
 455                                           message_transport_type => $letter->{message_transport_type} } );
 456         }
 457       }
 458     }
 459
 460 }
 461
 462 =head1 METHODS
 463
 464 =head2 parse_letter
 465
 466 =cut
 467
 468 sub parse_letter {
 469     my $params = shift;
 470     foreach my $required ( qw( letter_code borrowernumber ) ) {
 471         return unless exists $params->{$required};
 472     }
 473     my $patron = Koha::Patrons->find( $params->{borrowernumber} );
 474
 475     my %table_params = ( 'borrowers' => $params->{'borrowernumber'} );
 476
 477     if ( my $p = $params->{'branchcode'} ) {
 478         $table_params{'branches'} = $p;
 479     }
 480     if ( my $p = $params->{'itemnumber'} ) {
 481         $table_params{'issues'} = $p;
 482         $table_params{'items'} = $p;
 483     }
 484     if ( my $p = $params->{'biblionumber'} ) {
 485         $table_params{'biblio'} = $p;
 486         $table_params{'biblioitems'} = $p;
 487     }
 488
 489     return C4::Letters::GetPreparedLetter (
 490         module => 'circulation',
 491         letter_code => $params->{'letter_code'},
 492         branchcode => $table_params{'branches'},
 493         lang => $patron->lang,
 494         substitute => $params->{'substitute'},
 495         tables     => \%table_params,
 496         message_transport_type => $params->{message_transport_type},
 497     );
 498 }
 499
 500 sub format_date {
 501     my $date_string = shift;
 502     my $dt=dt_from_string($date_string);
 503     return output_pref($dt);
 504 }
 505
 506 =head2 get_branch_info
 507
 508 =cut
 509
 510 sub get_branch_info {
 511     my ( $borrowernumber ) = @_;
 512
 513     ## Get branch info for borrowers home library.
 514     my $borrower_details = C4::Members::GetMember( borrowernumber => $borrowernumber );
 515     my $borrower_branchcode = $borrower_details->{'branchcode'};
 516     my $branch = Koha::Libraries->find( $borrower_branchcode )->unblessed;
 517     my %branch_info;
 518     foreach my $key( keys %$branch ) {
 519         $branch_info{"branches.$key"} = $branch->{$key};
 520     }
 521
 522     return %branch_info;
 523 }
 524
 525 1;
 526
 527 __END__