misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl -w
   2
   3 # Copyright 2008 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21 use warnings;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use C4::Context;
  32 use C4::Dates qw/format_date/;
  33 use C4::Debug;
  34 use C4::Letters;
  35
  36 use Getopt::Long;
  37 use Pod::Usage;
  38 use Text::CSV_XS;
  39
  40 =head1 NAME
  41
  42 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  43
  44 =head1 SYNOPSIS
  45
  46 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  47
  48  Options:
  49    -help                          brief help message
  50    -man                           full documentation
  51    -n                             No email will be sent
  52    -max          <days>           maximum days overdue to deal with
  53    -library      <branchname>     only deal with overdues from this library
  54    -csv          <filename>       populate CSV file
  55    -itemscontent <list of fields> item information in templates
  56
  57 =head1 OPTIONS
  58
  59 =over 8
  60
  61 =item B<-help>
  62
  63 Print a brief help message and exits.
  64
  65 =item B<-man>
  66
  67 Prints the manual page and exits.
  68
  69 =item B<-v>
  70
  71 Verbose. Without this flag set, only fatal errors are reported.
  72
  73 =item B<-n>
  74
  75 Do not send any email. Overdue notices that would have been sent to
  76 the patrons or to the admin are printed to standard out. CSV data (if
  77 the -csv flag is set) is written to standard out or to any csv
  78 filename given.
  79
  80 =item B<-max>
  81
  82 Items older than max days are assumed to be handled somewhere else,
  83 probably the F<longoverdues.pl> script. They are therefore ignored by
  84 this program. No notices are sent for them, and they are not added to
  85 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  86
  87 =item B<-library>
  88
  89 select overdues for one specific library. Use the value in the
  90 branches.branchcode table.
  91
  92 =item B<-csv>
  93
  94 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
  95 sent to standard out or to a filename if provided. Otherwise, only
  96 overdues that could not be emailed are sent in CSV format to the admin.
  97
  98 =item B<-itemscontent>
  99
 100 comma separated list of fields that get substituted into templates in
 101 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 102 defaults to issuedate,title,barcode,author
 103
 104 Other possible values come from fields in the biblios, items, and
 105 issues tables.
 106
 107 =item B<-t> | B<--triggered>
 108
 109 This option causes a notice to be generated if and only if
 110 an item is overdue by the number of days defined in a notice trigger.
 111
 112 By default, a notice is sent each time the script runs, which is suitable for
 113 less frequent run cron script, but requires syncing notice triggers with
 114 the  cron schedule to ensure proper behavior.
 115 Add the --triggered option for daily cron, at the risk of no notice
 116 being generated if the cron fails to run on time.
 117
 118 =item B<-list-all>
 119
 120 Default items.content lists only those items that fall in the
 121 range of the currently processing notice.
 122 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 123
 124 =back
 125
 126 =head1 DESCRIPTION
 127
 128 This script is designed to alert patrons and administrators of overdue
 129 items.
 130
 131 =head2 Configuration
 132
 133 This script pays attention to the overdue notice configuration
 134 performed in the "Overdue notice/status triggers" section of the
 135 "Tools" area of the staff interface to Koha. There, you can choose
 136 which letter templates are sent out after a configurable number of
 137 days to patrons of each library. More information about the use of this
 138 section of Koha is available in the Koha manual.
 139
 140 The templates used to craft the emails are defined in the "Tools:
 141 Notices" section of the staff interface to Koha.
 142
 143 =head2 Outgoing emails
 144
 145 Typically, messages are prepared for each patron with overdue
 146 items. Messages for whom there is no email address on file are
 147 collected and sent as attachments in a single email to each library
 148 administrator, or if that is not set, then to the email address in the
 149 C<KohaAdminEmailAddress> system preference.
 150
 151 These emails are staged in the outgoing message queue, as are messages
 152 produced by other features of Koha. This message queue must be
 153 processed regularly by the
 154 F<misc/cronjobs/process_message_queue.pl> program.
 155
 156 In the event that the C<-n> flag is passed to this program, no emails
 157 are sent. Instead, messages are sent on standard output from this
 158 program. They may be redirected to a file if desired.
 159
 160 =head2 Templates
 161
 162 Templates can contain variables enclosed in double angle brackets like
 163 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 164 specific to the overdue items or relevant patron. Available variables
 165 are:
 166
 167 =over
 168
 169 =item E<lt>E<lt>bibE<gt>E<gt>
 170
 171 the name of the library
 172
 173 =item E<lt>E<lt>items.contentE<gt>E<gt>
 174
 175 one line for each item, each line containing a tab separated list of
 176 title, author, barcode, issuedate
 177
 178 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 179
 180 any field from the borrowers table
 181
 182 =item E<lt>E<lt>branches.*E<gt>E<gt>
 183
 184 any field from the branches table
 185
 186 =back
 187
 188 =head2 CSV output
 189
 190 The C<-csv> command line option lets you specify a file to which
 191 overdues data should be output in CSV format.
 192
 193 With the C<-n> flag set, data about all overdues is written to the
 194 file. Without that flag, only information about overdues that were
 195 unable to be sent directly to the patrons will be written. In other
 196 words, this CSV file replaces the data that is typically sent to the
 197 administrator email address.
 198
 199 =head1 USAGE EXAMPLES
 200
 201 C<overdue_notices.pl> - In this most basic usage, with no command line
 202 arguments, all libraries are procesed individually, and notices are
 203 prepared for all patrons with overdue items for whom we have email
 204 addresses. Messages for those patrons for whom we have no email
 205 address are sent in a single attachment to the library administrator's
 206 email address, or to the address in the KohaAdminEmailAddress system
 207 preference.
 208
 209 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 210 populates F</tmp/overdues.csv> with information about all overdue
 211 items.
 212
 213 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 214 overdues in the last 2 weeks for the MAIN library.
 215
 216 =head1 SEE ALSO
 217
 218 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 219 messages to patrons in advance of thier items becoming due, or to
 220 alert them of items that have just become due.
 221
 222 =cut
 223
 224 # These variables are set by command line options.
 225 # They are initially set to default values.
 226 my $help    = 0;
 227 my $man     = 0;
 228 my $verbose = 0;
 229 my $nomail  = 0;
 230 my $MAX     = 90;
 231 my $mybranch;
 232 my $csvfilename;
 233 my $triggered = 0;
 234 my $listall = 0;
 235 my $itemscontent = join( ',', qw( issuedate title barcode author ) );
 236
 237 GetOptions(
 238     'help|?'         => \$help,
 239     'man'            => \$man,
 240     'v'              => \$verbose,
 241     'n'              => \$nomail,
 242     'max=s'          => \$MAX,
 243     'library=s'      => \$mybranch,
 244     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 245     'itemscontent=s' => \$itemscontent,
 246     'list-all'      => \$listall,
 247     't|triggered'             => \$triggered,
 248 ) or pod2usage(2);
 249 pod2usage(1) if $help;
 250 pod2usage( -verbose => 2 ) if $man;
 251
 252 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 253     warn qq(using "$csvfilename" as filename, that seems odd);
 254 }
 255
 256 my @branches    = C4::Overdues::GetBranchcodesWithOverdueRules();
 257 my $branchcount = scalar(@branches);
 258 if ($branchcount) {
 259     my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 260     $verbose and warn "Found $branchcount $branch_word with first message enabled: " . join( ', ', map { "'$_'" } @branches ), "\n";
 261 } else {
 262     die 'No branches with active overduerules';
 263 }
 264
 265 if ($mybranch) {
 266     $verbose and warn "Branch $mybranch selected\n";
 267     if ( scalar grep { $mybranch eq $_ } @branches ) {
 268         @branches = ($mybranch);
 269     } else {
 270         $verbose and warn "No active overduerules for branch '$mybranch'\n";
 271         ( scalar grep { '' eq $_ } @branches )
 272           or die "No active overduerules for DEFAULT either!";
 273         $verbose and warn "Falling back on default rules for $mybranch\n";
 274         @branches = ('');
 275     }
 276 }
 277
 278 # these are the fields that will be substituted into <<item.content>>
 279 my @item_content_fields = split( /,/, $itemscontent );
 280
 281 my $dbh = C4::Context->dbh();
 282 binmode( STDOUT, ":utf8" );
 283
 284 our $csv;       # the Text::CSV_XS object
 285 our $csv_fh;    # the filehandle to the CSV file.
 286 if ( defined $csvfilename ) {
 287     my $sep_char = C4::Context->preference('delimiter') || ',';
 288     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 289     if ( $csvfilename eq '' ) {
 290         $csv_fh = *STDOUT;
 291     } else {
 292         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 293     }
 294     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 295         print $csv_fh $csv->string, "\n";
 296     } else {
 297         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 298     }
 299 }
 300
 301 foreach my $branchcode (@branches) {
 302
 303     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 304     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 305     my @output_chunks;    # may be sent to mail or stdout or csv file.
 306
 307     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 308
 309     my $sth2 = $dbh->prepare( <<'END_SQL' );
 310 SELECT biblio.*, items.*, issues.*, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 311   FROM issues,items,biblio
 312   WHERE items.itemnumber=issues.itemnumber
 313     AND biblio.biblionumber   = items.biblionumber
 314     AND issues.borrowernumber = ?
 315     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 316 END_SQL
 317
 318     my $rqoverduerules = $dbh->prepare("SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ");
 319     $rqoverduerules->execute($branchcode);
 320     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 321     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 322       PERIOD: foreach my $i ( 1 .. 3 ) {
 323
 324             $verbose and warn "branch '$branchcode', pass $i\n";
 325             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 326             my $maxdays = (
 327                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 328                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 329                 : ($MAX)
 330             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 331
 332             if ( !$overdue_rules->{"letter$i"} ) {
 333                 $verbose and warn "No letter$i code for branch '$branchcode'";
 334                 next PERIOD;
 335             }
 336
 337             # $letter->{'content'} is the text of the mail that is sent.
 338             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 339             # The following fields are available :
 340             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 341             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 342
 343             my $borrower_sql = <<'END_SQL';
 344 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, MIN(date_due) as longest_issue
 345 FROM   issues,borrowers,categories
 346 WHERE  issues.borrowernumber=borrowers.borrowernumber
 347 AND    borrowers.categorycode=categories.categorycode
 348 END_SQL
 349             my @borrower_parameters;
 350             if ($branchcode) {
 351                 $borrower_sql .= ' AND issues.branchcode=? ';
 352                 push @borrower_parameters, $branchcode;
 353             }
 354             if ( $overdue_rules->{categorycode} ) {
 355                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 356                 push @borrower_parameters, $overdue_rules->{categorycode};
 357             }
 358             $borrower_sql .= '  AND categories.overduenoticerequired=1
 359                                 GROUP BY issues.borrowernumber ';
 360             if($triggered) {
 361                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 362                 push @borrower_parameters, $mindays;
 363             } else {
 364                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 365                 push @borrower_parameters, $mindays, $maxdays;
 366             }
 367
 368             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 369                 my $sth = $dbh->prepare($borrower_sql);
 370             $sth->execute(@borrower_parameters);
 371             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 372
 373             while( my ( $itemcount, $borrowernumber, $firstname, $lastname, $address1, $address2, $city, $postcode, $email ) = $sth->fetchrow ) {
 374                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 375
 376                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 377                 unless ($letter) {
 378                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 379
 380                     # might as well skip while PERIOD, no other borrowers are going to work.
 381                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 382                     next PERIOD;
 383                 }
 384
 385                 if ( $overdue_rules->{"debarred$i"} ) {
 386
 387                     #action taken is debarring
 388                     C4::Members::DebarMember($borrowernumber);
 389                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 390                 }
 391                 $sth2->execute( ($listall) ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ) );
 392                 my $itemcount = 0;
 393                 my $titles = "";
 394                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 395                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 396                     $titles .= join("\t", @item_info) . "\n";
 397                     $itemcount++;
 398                 }
 399                 $sth2->finish;
 400
 401                 $letter = parse_letter(
 402                     {   letter         => $letter,
 403                         borrowernumber => $borrowernumber,
 404                         branchcode     => $branchcode,
 405                         substitute     => {
 406                             bib             => $branch_details->{'branchname'},
 407                             'items.content' => $titles
 408                         }
 409                     }
 410                 );
 411
 412                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 413                 if (@misses) {
 414                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 415                 }
 416                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 417                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 418
 419                 if ($nomail) {
 420
 421                     push @output_chunks,
 422                       prepare_letter_for_printing(
 423                         {   letter         => $letter,
 424                             borrowernumber => $borrowernumber,
 425                             firstname      => $firstname,
 426                             lastname       => $lastname,
 427                             address1       => $address1,
 428                             address2       => $address2,
 429                             city           => $city,
 430                             postcode       => $postcode,
 431                             email          => $email,
 432                             itemcount      => $itemcount,
 433                             titles         => $titles,
 434                             outputformat   => defined $csvfilename ? 'csv' : '',
 435                         }
 436                       );
 437                 } else {
 438                     if ($email) {
 439                         C4::Letters::EnqueueLetter(
 440                             {   letter                 => $letter,
 441                                 borrowernumber         => $borrowernumber,
 442                                 message_transport_type => 'email',
 443                                 from_address           => $admin_email_address,
 444                             }
 445                         );
 446                     } else {
 447
 448                         # If we don't have an email address for this patron, send it to the admin to deal with.
 449                         push @output_chunks,
 450                           prepare_letter_for_printing(
 451                             {   letter         => $letter,
 452                                 borrowernumber => $borrowernumber,
 453                                 firstname      => $firstname,
 454                                 lastname       => $lastname,
 455                                 address1       => $address1,
 456                                 address2       => $address2,
 457                                 city           => $city,
 458                                 postcode       => $postcode,
 459                                 email          => $email,
 460                                 itemcount      => $itemcount,
 461                                 titles         => $titles,
 462                                 outputformat   => defined $csvfilename ? 'csv' : '',
 463                             }
 464                           );
 465                     }
 466                 }
 467             }
 468             $sth->finish;
 469         }
 470     }
 471
 472     if (@output_chunks) {
 473         if ($nomail) {
 474             if ( defined $csvfilename ) {
 475                 print $csv_fh @output_chunks;
 476             } else {
 477                 local $, = "\f";    # pagebreak
 478                 print @output_chunks;
 479             }
 480         } else {
 481             my $attachment = {
 482                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 483                 type => 'text/plain',
 484                 content => join( "\n", @output_chunks )
 485             };
 486
 487             my $letter = {
 488                 title   => 'Overdue Notices',
 489                 content => 'These messages were not sent directly to the patrons.',
 490             };
 491             C4::Letters::EnqueueLetter(
 492                 {   letter                 => $letter,
 493                     borrowernumber         => undef,
 494                     message_transport_type => 'email',
 495                     attachments            => [$attachment],
 496                     to_address             => $admin_email_address,
 497                 }
 498             );
 499         }
 500     }
 501
 502 }
 503 if ($csvfilename) {
 504
 505     # note that we're not testing on $csv_fh to prevent closing
 506     # STDOUT.
 507     close $csv_fh;
 508 }
 509
 510 =head1 INTERNAL METHODS
 511
 512 These methods are internal to the operation of overdue_notices.pl.
 513
 514 =head2 parse_letter
 515
 516 parses the letter template, replacing the placeholders with data
 517 specific to this patron, biblio, or item
 518
 519 named parameters:
 520   letter - required hashref
 521   borrowernumber - required integer
 522   substitute - optional hashref of other key/value pairs that should
 523     be substituted in the letter content
 524
 525 returns the C<letter> hashref, with the content updated to reflect the
 526 substituted keys and values.
 527
 528
 529 =cut
 530
 531 sub parse_letter {
 532     my $params = shift;
 533     foreach my $required (qw( letter borrowernumber )) {
 534         return unless exists $params->{$required};
 535     }
 536
 537     if ( $params->{'substitute'} ) {
 538         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 539             my $replacefield = "<<$key>>";
 540
 541             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 542             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 543         }
 544     }
 545
 546     C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 547
 548     if ( $params->{'branchcode'} ) {
 549         C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 550     }
 551
 552     if ( $params->{'biblionumber'} ) {
 553         C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $params->{'biblionumber'} );
 554         C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $params->{'biblionumber'} );
 555     }
 556
 557     return $params->{'letter'};
 558 }
 559
 560 =head2 prepare_letter_for_printing
 561
 562 returns a string of text appropriate for printing in the event that an
 563 overdue notice will not be sent to the patron's email
 564 address. Depending on the desired output format, this may be a CSV
 565 string, or a human-readable representation of the notice.
 566
 567 required parameters:
 568   letter
 569   borrowernumber
 570
 571 optional parameters:
 572   outputformat
 573
 574 =cut
 575
 576 sub prepare_letter_for_printing {
 577     my $params = shift;
 578
 579     return unless ref $params eq 'HASH';
 580
 581     foreach my $required_parameter (qw( letter borrowernumber )) {
 582         return unless defined $params->{$required_parameter};
 583     }
 584
 585     my $return;
 586     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 587         if ($csv->combine(
 588                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 589                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 590             )
 591           ) {
 592             return $csv->string, "\n";
 593         } else {
 594             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 595         }
 596     } else {
 597         $return .= "$params->{'letter'}->{'content'}\n";
 598
 599         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 600     }
 601     return $return;
 602 }
 603