opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use String::Random qw( random_string );
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use C4::Members;
  27 use C4::Form::MessagingPreferences;
  28 use Koha::Borrower::Modifications;
  29 use C4::Branch qw(GetBranchesLoop);
  30 use C4::Scrubber;
  31 use Email::Valid;
  32
  33 my $cgi = new CGI;
  34 my $dbh = C4::Context->dbh;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "opac-memberentry.tt",
  39         type            => "opac",
  40         query           => $cgi,
  41         authnotrequired => 1,
  42     }
  43 );
  44
  45 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  46 {
  47     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  48     exit;
  49 }
  50
  51 my $action = $cgi->param('action') || q{};
  52 if ( $action eq q{} ) {
  53     if ($borrowernumber) {
  54         $action = 'edit';
  55     }
  56     else {
  57         $action = 'new';
  58     }
  59 }
  60
  61 my $mandatory = GetMandatoryFields($action);
  62 my $hidden = GetHiddenFields($mandatory);
  63
  64 $template->param(
  65     action            => $action,
  66     hidden            => $hidden,
  67     mandatory         => $mandatory,
  68     member_titles     => GetTitles() || undef,
  69     branches          => GetBranchesLoop(),
  70     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  71 );
  72
  73 if ( $action eq 'create' ) {
  74
  75     my %borrower = ParseCgiForBorrower($cgi);
  76
  77     %borrower = DelEmptyFields(%borrower);
  78
  79     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
  80     my $invalidformfields = CheckForInvalidFields(\%borrower);
  81
  82     if (@empty_mandatory_fields || @$invalidformfields) {
  83         $template->param(
  84             empty_mandatory_fields => \@empty_mandatory_fields,
  85             invalid_form_fields    => $invalidformfields,
  86             borrower               => \%borrower
  87         );
  88     }
  89     elsif (
  90         md5_base64( $cgi->param('captcha') ) ne $cgi->param('captcha_digest') )
  91     {
  92         $template->param(
  93             failed_captcha => 1,
  94             borrower       => \%borrower
  95         );
  96     }
  97     else {
  98         if (
  99             C4::Context->boolean_preference(
 100                 'PatronSelfRegistrationVerifyByEmail')
 101           )
 102         {
 103             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 104                 {
 105                     template_name   => "opac-registration-email-sent.tt",
 106                     type            => "opac",
 107                     query           => $cgi,
 108                     authnotrequired => 1,
 109                 }
 110             );
 111             $template->param( 'email' => $borrower{'email'} );
 112
 113             my $verification_token = md5_hex( \%borrower );
 114             $borrower{'password'} = random_string("..........");
 115
 116             Koha::Borrower::Modifications->new(
 117                 verification_token => $verification_token )
 118               ->AddModifications(\%borrower);
 119
 120             #Send verification email
 121             my $letter = C4::Letters::GetPreparedLetter(
 122                 module      => 'members',
 123                 letter_code => 'OPAC_REG_VERIFY',
 124                 tables      => {
 125                     borrower_modifications => $verification_token,
 126                 },
 127             );
 128
 129             C4::Letters::EnqueueLetter(
 130                 {
 131                     letter                 => $letter,
 132                     message_transport_type => 'email',
 133                     to_address             => $borrower{'email'},
 134                     from_address =>
 135                       C4::Context->preference('KohaAdminEmailAddress'),
 136                 }
 137             );
 138         }
 139         else {
 140             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 141                 {
 142                     template_name   => "opac-registration-confirmation.tt",
 143                     type            => "opac",
 144                     query           => $cgi,
 145                     authnotrequired => 1,
 146                 }
 147             );
 148
 149             $template->param( OpacPasswordChange =>
 150                   C4::Context->preference('OpacPasswordChange') );
 151
 152             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 153             C4::Form::MessagingPreferences::handle_form_action($cgi, { borrowernumber => $borrowernumber }, $template, 1, C4::Context->preference('PatronSelfRegistrationDefaultCategory') ) if $borrowernumber && C4::Context->preference('EnhancedMessagingPreferences');
 154
 155             $template->param( password_cleartext => $password );
 156             $template->param(
 157                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 158             $template->param(
 159                 PatronSelfRegistrationAdditionalInstructions =>
 160                   C4::Context->preference(
 161                     'PatronSelfRegistrationAdditionalInstructions')
 162             );
 163         }
 164     }
 165 }
 166 elsif ( $action eq 'update' ) {
 167
 168     my %borrower = ParseCgiForBorrower($cgi);
 169
 170     my %borrower_changes = DelEmptyFields(%borrower);
 171     my @empty_mandatory_fields =
 172       CheckMandatoryFields( \%borrower_changes, $action );
 173     my $invalidformfields = CheckForInvalidFields(\%borrower);
 174
 175     if (@empty_mandatory_fields || @$invalidformfields) {
 176         $template->param(
 177             empty_mandatory_fields => \@empty_mandatory_fields,
 178             invalid_form_fields    => $invalidformfields,
 179             borrower               => \%borrower
 180         );
 181
 182         $template->param( action => 'edit' );
 183     }
 184     else {
 185         ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 186             {
 187                 template_name   => "opac-memberentry-update-submitted.tt",
 188                 type            => "opac",
 189                 query           => $cgi,
 190                 authnotrequired => 1,
 191             }
 192         );
 193
 194         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 195
 196         my $m =
 197           Koha::Borrower::Modifications->new(
 198             borrowernumber => $borrowernumber );
 199
 200         $m->DelModifications;
 201         $m->AddModifications(\%borrower_changes);
 202         $template->param(
 203             borrower => GetMember( borrowernumber => $borrowernumber ),
 204         );
 205     }
 206 }
 207 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 208     my $borrower = GetMember( borrowernumber => $borrowernumber );
 209
 210     if (C4::Context->preference('ExtendedPatronAttributes')) {
 211         my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber, 'opac');
 212         if (scalar(@$attributes) > 0) {
 213             $borrower->{ExtendedPatronAttributes} = 1;
 214             $borrower->{patron_attributes} = $attributes;
 215         }
 216     }
 217
 218     $template->param(
 219         borrower => $borrower, );
 220
 221     if (C4::Context->preference('OPACpatronimages')) {
 222         my ($image, $dberror) = GetPatronImage($borrower->{borrowernumber});
 223         if ($image) {
 224             $template->param(
 225                 display_patron_image => 1
 226             );
 227         }
 228     }
 229
 230 }
 231
 232 my $captcha = random_string("CCCCC");
 233
 234 $template->param(
 235     captcha        => $captcha,
 236     captcha_digest => md5_base64($captcha)
 237 );
 238
 239 output_html_with_http_headers $cgi, $cookie, $template->output;
 240
 241 sub GetHiddenFields {
 242     my ($mandatory) = @_;
 243     my %hidden_fields;
 244
 245     my $BorrowerUnwantedField =
 246       C4::Context->preference("PatronSelfRegistrationBorrowerUnwantedField");
 247
 248     my @fields = split( /\|/, $BorrowerUnwantedField );
 249     foreach (@fields) {
 250         next unless m/\w/o;
 251         #Don't hide mandatory fields
 252         next if $mandatory->{$_};
 253         $hidden_fields{$_} = 1;
 254     }
 255
 256     return \%hidden_fields;
 257 }
 258
 259 sub GetMandatoryFields {
 260     my ($action) = @_;
 261
 262     my %mandatory_fields;
 263
 264     my $BorrowerMandatoryField =
 265       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 266
 267     my @fields = split( /\|/, $BorrowerMandatoryField );
 268
 269     foreach (@fields) {
 270         $mandatory_fields{$_} = 1;
 271     }
 272
 273     if ( $action eq 'create' || $action eq 'new' ) {
 274         $mandatory_fields{'email'} = 1
 275           if C4::Context->boolean_preference(
 276             'PatronSelfRegistrationVerifyByEmail');
 277     }
 278
 279     return \%mandatory_fields;
 280 }
 281
 282 sub CheckMandatoryFields {
 283     my ( $borrower, $action ) = @_;
 284
 285     my @empty_mandatory_fields;
 286
 287     my $mandatory_fields = GetMandatoryFields($action);
 288     delete $mandatory_fields->{'cardnumber'};
 289
 290     foreach my $key ( keys %$mandatory_fields ) {
 291         push( @empty_mandatory_fields, $key )
 292           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 293     }
 294
 295     return @empty_mandatory_fields;
 296 }
 297
 298 sub CheckForInvalidFields {
 299     my $borrower = shift;
 300     my @invalidFields;
 301     if ($borrower->{'email'}) {
 302         push(@invalidFields, "email") if (!Email::Valid->address($borrower->{'email'}));
 303     }
 304     if ($borrower->{'emailpro'}) {
 305         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 306     }
 307     if ($borrower->{'B_email'}) {
 308         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 309     }
 310     return \@invalidFields;
 311 }
 312
 313 sub ParseCgiForBorrower {
 314     my ($cgi) = @_;
 315
 316     my $scrubber = C4::Scrubber->new();
 317     my %borrower;
 318
 319     foreach ( $cgi->param ) {
 320         if ( $_ =~ '^borrower_' ) {
 321             my ($key) = substr( $_, 9 );
 322             $borrower{$key} = $scrubber->scrub( $cgi->param($_) );
 323         }
 324     }
 325
 326     $borrower{'dateofbirth'} =
 327       C4::Dates->new( $borrower{'dateofbirth'} )->output("iso")
 328       if ( defined( $borrower{'dateofbirth'} ) );
 329
 330     return %borrower;
 331 }
 332
 333 sub DelUnchangedFields {
 334     my ( $borrowernumber, %new_data ) = @_;
 335
 336     my $current_data = GetMember( borrowernumber => $borrowernumber );
 337
 338     foreach my $key ( keys %new_data ) {
 339         if ( $current_data->{$key} eq $new_data{$key} ) {
 340             delete $new_data{$key};
 341         }
 342     }
 343
 344     return %new_data;
 345 }
 346
 347 sub DelEmptyFields {
 348     my (%borrower) = @_;
 349
 350     foreach my $key ( keys %borrower ) {
 351         delete $borrower{$key} unless $borrower{$key};
 352     }
 353
 354     return %borrower;
 355 }