opac/opac-search.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Garry Collum and the Koha Development team
   4 # Copyright 2010 BibLibre
   5 # Copyright 2011 KohaAloha, NZ
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # Script to perform searching
  23 # Mostly copied from search.pl, see POD there
  24 use Modern::Perl;
  25
  26 ## STEP 1. Load things that are used in both search page and
  27 # results page and decide which template to load, operations
  28 # to perform, etc.
  29 ## load Koha modules
  30 use C4::Context;
  31 use List::MoreUtils q/any/;
  32
  33 use Data::Dumper; # TODO remove
  34
  35 use Koha::SearchEngine::Search;
  36 use Koha::SearchEngine::QueryBuilder;
  37
  38 my $searchengine = C4::Context->preference("SearchEngine");
  39 my ($builder, $searcher);
  40 #$searchengine = 'Zebra'; # XXX
  41 $builder  = Koha::SearchEngine::QueryBuilder->new({index => 'biblios'});
  42 $searcher = Koha::SearchEngine::Search->new({index => 'biblios'});
  43
  44 use C4::Output;
  45 use C4::Auth qw(:DEFAULT get_session);
  46 use C4::Languages qw(getLanguages);
  47 use C4::Search;
  48 use C4::Search::History;
  49 use C4::Biblio; # Unused here?
  50 use C4::Koha;
  51 use C4::Tags qw(get_tags);
  52 use C4::SocialData;
  53 use C4::External::OverDrive;
  54 use C4::External::BakerTaylor qw( image_url link_url );
  55
  56 use Koha::Libraries;
  57 use Koha::ItemTypes;
  58 use Koha::Ratings;
  59 use Koha::Virtualshelves;
  60 use Koha::Library::Groups;
  61 use Koha::Patrons;
  62 use Koha::SearchFields;
  63
  64 use POSIX qw(ceil floor strftime);
  65 use URI::Escape;
  66 use JSON qw/decode_json encode_json/;
  67 use Business::ISBN;
  68
  69 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
  70 # create a new CGI object
  71 # FIXME: no_undef_params needs to be tested
  72 use CGI qw('-no_undef_params' -utf8);
  73 my $cgi = new CGI;
  74
  75 my $branch_group_limit = $cgi->param("branch_group_limit");
  76 if ( $branch_group_limit ) {
  77     if ( $branch_group_limit =~ /^multibranchlimit-/ ) {
  78         # For search groups we are going to convert this branch_group_limit CGI
  79         # parameter into a multibranchlimit CGI parameter for the purposes of
  80         # actually performing the query
  81         $cgi->param(
  82             -name => 'multibranchlimit',
  83             -values => substr($branch_group_limit, 17)
  84         );
  85     } else {
  86         $cgi->append(
  87             -name => 'limit',
  88             -values => [ $branch_group_limit ]
  89         );
  90     }
  91 }
  92
  93 my ($template,$borrowernumber,$cookie);
  94 # decide which template to use
  95 my $template_name;
  96 my $template_type = 'basic';
  97 my @params = $cgi->multi_param("limit");
  98 my @searchCategories = $cgi->multi_param('searchcat');
  99
 100 my $format = $cgi->param("format") || '';
 101 my $build_grouped_results = C4::Context->preference('OPACGroupResults');
 102 if ($format =~ /(rss|atom|opensearchdescription)/) {
 103     $template_name = 'opac-opensearch.tt';
 104 }
 105 elsif (@params && $build_grouped_results) {
 106     $template_name = 'opac-results-grouped.tt';
 107 }
 108 elsif ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) || @searchCategories ) {
 109     $template_name = 'opac-results.tt';
 110 }
 111 else {
 112     $template_name = 'opac-advsearch.tt';
 113     $template_type = 'advsearch';
 114 }
 115
 116 $format = 'rss' if $format =~ /^rss2?$/;
 117
 118 # load the template
 119 ($template, $borrowernumber, $cookie) = get_template_and_user({
 120     template_name => $template_name,
 121     query => $cgi,
 122     type => "opac",
 123     authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
 124     }
 125 );
 126 my $patron = Koha::Patrons->find( $borrowernumber );
 127
 128 my $lang = C4::Languages::getlanguage($cgi);
 129
 130 if ($template_name eq 'opac-results.tt') {
 131    $template->param('COinSinOPACResults' => C4::Context->preference('COinSinOPACResults'));
 132 }
 133
 134 # get biblionumbers stored in the cart
 135 my @cart_list;
 136
 137 if($cgi->cookie("bib_list")){
 138     my $cart_list = $cgi->cookie("bib_list");
 139     @cart_list = split(/\//, $cart_list);
 140 }
 141
 142 if ($format eq 'rss' or $format eq 'opensearchdescription' or $format eq 'atom') {
 143     $template->param($format => 1);
 144     $template->param(timestamp => strftime("%Y-%m-%dT%H:%M:%S-00:00", gmtime)) if ($format eq 'atom');
 145     # FIXME - the timestamp is a hack - the biblio update timestamp should be used for each
 146     # entry, but not sure if that's worth an extra database query for each bib
 147 }
 148 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 149     $template->param('UNIMARC' => 1);
 150 }
 151 elsif (C4::Context->preference("marcflavour") eq "MARC21" ) {
 152     $template->param('usmarc' => 1);
 153 }
 154
 155 $template->param( 'OPACNoResultsFound' => C4::Context->preference('OPACNoResultsFound') );
 156
 157 $template->param(
 158     OpacStarRatings => C4::Context->preference("OpacStarRatings") );
 159
 160 if (C4::Context->preference('BakerTaylorEnabled')) {
 161     $template->param(
 162         BakerTaylorEnabled  => 1,
 163         BakerTaylorImageURL => &image_url(),
 164         BakerTaylorLinkURL  => &link_url(),
 165         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 166     );
 167 }
 168
 169 if (C4::Context->preference('TagsEnabled')) {
 170     $template->param(TagsEnabled => 1);
 171     foreach (qw(TagsShowOnList TagsInputOnList)) {
 172         C4::Context->preference($_) and $template->param($_ => 1);
 173     }
 174 }
 175
 176 ## URI Re-Writing
 177 # Deprecated, but preserved because it's interesting :-)
 178 # The same thing can be accomplished with mod_rewrite in
 179 # a more elegant way
 180 #
 181 #my $rewrite_flag;
 182 #my $uri = $cgi->url(-base => 1);
 183 #my $relative_url = $cgi->url(-relative=>1);
 184 #$uri.="/".$relative_url."?";
 185 #warn "URI:$uri";
 186 #my @cgi_params_list = $cgi->param();
 187 #my $url_params = $cgi->Vars;
 188 #
 189 #for my $each_param_set (@cgi_params_list) {
 190 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 191 #}
 192 #warn "New URI:$uri";
 193 # Only re-write a URI if there are params or if it already hasn't been re-written
 194 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 195 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 196 #                            -cookie => $cookie);
 197 #    exit;
 198 #}
 199
 200 # load the branches
 201
 202 if ($cgi->param("returntosearch")) {
 203     $template->param('ReturnToSearch' => 1);
 204 }
 205 if ($cgi->cookie("search_path_code")) {
 206     my $pathcode = $cgi->cookie("search_path_code");
 207     if ($pathcode eq '"ads"') {
 208         $template->param('ReturnPath' => '/cgi-bin/koha/opac-search.pl?returntosearch=1');
 209     }
 210     elsif ($pathcode eq '"exs"') {
 211          $template->param('ReturnPath' => '/cgi-bin/koha/opac-search.pl?expanded_options=1&returntosearch=1');
 212     }
 213     else {
 214         warn "ReturnPath switch error";
 215     }
 216 }
 217
 218 my @search_groups = Koha::Library::Groups->get_search_groups();
 219 $template->param( search_groups => \@search_groups );
 220
 221 # load the language limits (for search)
 222 my $languages_limit_loop = getLanguages($lang, 1);
 223 $template->param(search_languages_loop => $languages_limit_loop,);
 224
 225 # load the Type stuff
 226 my $itemtypes = GetItemTypesCategorized;
 227 # add translated_description to itemtypes
 228 foreach my $itemtype ( keys %{$itemtypes} ) {
 229     # Itemtypes search categories don't have (yet) translated descriptions, they are auth values (and could still have no descriptions too BZ 18400)
 230     # If 'iscat' (see ITEMTYPECAT) then there is no itemtype and the description is not translated
 231     my $translated_description = $itemtypes->{$itemtype}->{iscat}
 232       ? $itemtypes->{$itemtype}->{description}
 233       : Koha::ItemTypes->find($itemtype)->translated_description;
 234     $itemtypes->{$itemtype}->{translated_description} = $translated_description || $itemtypes->{$itemtype}->{description} || q{};
 235 }
 236
 237 # the index parameter is different for item-level itemtypes
 238 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 239 my @advancedsearchesloop;
 240 my $cnt;
 241 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 242 my @advanced_search_types = split(/\|/, $advanced_search_types);
 243
 244 my $hidingrules = {};
 245 my $yaml = C4::Context->preference('OpacHiddenItems');
 246 if ( $yaml =~ /\S/ ) {
 247     $yaml = "$yaml\n\n"; # YAML expects trailing newline. Surplus does not hurt.
 248     eval {
 249         $hidingrules = YAML::Load($yaml);
 250     };
 251     if ($@) {
 252         warn "Unable to parse OpacHiddenItems syspref : $@";
 253     }
 254 }
 255
 256 my @sorted_itemtypes = sort { $itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes;
 257 foreach my $advanced_srch_type (@advanced_search_types) {
 258     $advanced_srch_type =~ s/^\s*//;
 259     $advanced_srch_type =~ s/\s*$//;
 260    if ($advanced_srch_type eq 'itemtypes') {
 261    # itemtype is a special case, since it's not defined in authorized values
 262         my @itypesloop;
 263         foreach my $thisitemtype ( @sorted_itemtypes ) {
 264             next if $hidingrules->{itype} && any { $_ eq $thisitemtype } @{$hidingrules->{itype}};
 265             next if $hidingrules->{itemtype} && any { $_ eq $thisitemtype } @{$hidingrules->{itemtype}};
 266             my %row =(  number=>$cnt++,
 267                 ccl => "$itype_or_itemtype,phr",
 268                 code => $thisitemtype,
 269                 description => $itemtypes->{$thisitemtype}->{translated_description},
 270                 imageurl=> getitemtypeimagelocation( 'opac', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 271                 cat => $itemtypes->{$thisitemtype}->{'iscat'},
 272                 hideinopac => $itemtypes->{$thisitemtype}->{'hideinopac'},
 273                 searchcategory => $itemtypes->{$thisitemtype}->{'searchcategory'},
 274             );
 275             if ( !$itemtypes->{$thisitemtype}->{'hideinopac'} ) {
 276                 push @itypesloop, \%row;
 277             }
 278         }
 279         my %search_code = (  advanced_search_type => $advanced_srch_type,
 280                              code_loop => \@itypesloop );
 281         push @advancedsearchesloop, \%search_code;
 282     } else {
 283     # covers all the other cases: non-itemtype authorized values
 284        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type, 'opac');
 285         my @authvalueloop;
 286         for my $thisitemtype (@$advsearchtypes) {
 287             my $hiding_key = lc $thisitemtype->{category};
 288             $hiding_key = "location" if $hiding_key eq 'loc';
 289             next if $hidingrules->{$hiding_key} && any { $_ eq $thisitemtype->{authorised_value} } @{$hidingrules->{$hiding_key}};
 290                 my %row =(
 291                                 number=>$cnt++,
 292                                 ccl => $advanced_srch_type,
 293                 code => $thisitemtype->{authorised_value},
 294                 description => $thisitemtype->{'lib_opac'} || $thisitemtype->{'lib'},
 295                 searchcategory => $itemtypes->{$thisitemtype}->{'searchcategory'},
 296                 imageurl => getitemtypeimagelocation( 'opac', $thisitemtype->{'imageurl'} ),
 297                 );
 298                 push @authvalueloop, \%row;
 299         }
 300         my %search_code = (  advanced_search_type => $advanced_srch_type,
 301                              code_loop => \@authvalueloop );
 302         push @advancedsearchesloop, \%search_code;
 303     }
 304 }
 305 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 306
 307 # The following should only be loaded if we're bringing up the advanced search template
 308 if ( $template_type && $template_type eq 'advsearch' ) {
 309     # load the servers (used for searching -- to do federated searching, etc.)
 310     my $primary_servers_loop;# = displayPrimaryServers();
 311     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 312
 313     my $secondary_servers_loop;
 314     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 315
 316     # set the default sorting
 317     if (   C4::Context->preference('OPACdefaultSortField')
 318         && C4::Context->preference('OPACdefaultSortOrder') ) {
 319         my $default_sort_by =
 320             C4::Context->preference('OPACdefaultSortField') . '_'
 321           . C4::Context->preference('OPACdefaultSortOrder');
 322         $template->param( sort_by => $default_sort_by );
 323     }
 324
 325     # determine what to display next to the search boxes (ie, boolean option
 326     # shouldn't appear on the first one, scan indexes should, adding a new
 327     # box should only appear on the last, etc.
 328     my @search_boxes_array;
 329     my $search_boxes_count = 3; # begin with 3 boxes
 330     $template->param( search_boxes_count => $search_boxes_count );
 331
 332     if ($cgi->cookie("num_paragraph")){
 333         $search_boxes_count = $cgi->cookie("num_paragraph");
 334     }
 335
 336     for (my $i=1;$i<=$search_boxes_count;$i++) {
 337         # if it's the first one, don't display boolean option, but show scan indexes
 338         if ($i==1) {
 339             push @search_boxes_array,
 340                 {
 341                 scan_index => 1,
 342                 };
 343
 344         }
 345         # if it's the last one, show the 'add field' box
 346         elsif ($i==$search_boxes_count) {
 347             push @search_boxes_array,
 348                 {
 349                 boolean => 1,
 350                 add_field => 1,
 351                 };
 352         }
 353         else {
 354             push @search_boxes_array,
 355                 {
 356                 boolean => 1,
 357                 };
 358         }
 359
 360     }
 361
 362     my @advsearch_limits = split /,/, C4::Context->preference('OpacAdvSearchOptions');
 363     my @advsearch_more_limits = split /,/,
 364       C4::Context->preference('OpacAdvSearchMoreOptions');
 365     $template->param(
 366         uc( C4::Context->preference("marcflavour") ) => 1,    # we already did this for UNIMARC
 367         advsearch         => 1,
 368         search_boxes_loop => \@search_boxes_array,
 369         OpacAdvSearchOptions     => \@advsearch_limits,
 370         OpacAdvSearchMoreOptions => \@advsearch_more_limits,
 371     );
 372
 373     # use the global setting by default
 374     if ( C4::Context->preference("expandedSearchOption") == 1 ) {
 375         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 376     }
 377     # but let the user override it
 378     if (defined $cgi->param('expanded_options')) {
 379         if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 380             $template->param( expanded_options => scalar $cgi->param('expanded_options'));
 381         }
 382     }
 383
 384
 385     output_html_with_http_headers $cgi, $cookie, $template->output;
 386     exit;
 387 }
 388
 389 ### OK, if we're this far, we're performing an actual search
 390
 391 # Fetch the paramater list as a hash in scalar context:
 392 #  * returns paramater list as tied hash ref
 393 #  * we can edit the values by changing the key
 394 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 395 my $params = $cgi->Vars;
 396 my $tag;
 397 if ( $params->{tag} ) {
 398     $tag = $params->{tag};
 399     $template->param( tag => $tag );
 400 }
 401
 402 # String with params with the search criteria for the paging in opac-detail
 403 # param value is URI encoded and params separator is HTML encode (&amp;)
 404 my $pasarParams = '';
 405 my $j = 0;
 406 for (keys %$params) {
 407     my @pasarParam = $cgi->multi_param($_);
 408     for my $paramValue(@pasarParam) {
 409         $pasarParams .= '&amp;' if ($j > 0);
 410         $pasarParams .= $_ . '=' . uri_escape_utf8($paramValue);
 411         $j++;
 412     }
 413 }
 414
 415 # Params that can have more than one value
 416 # sort by is used to sort the query
 417 # in theory can have more than one but generally there's just one
 418 my @sort_by;
 419 my $default_sort_by;
 420 if (   C4::Context->preference('OPACdefaultSortField')
 421     && C4::Context->preference('OPACdefaultSortOrder') ) {
 422     $default_sort_by =
 423         C4::Context->preference('OPACdefaultSortField') . '_'
 424       . C4::Context->preference('OPACdefaultSortOrder');
 425 }
 426
 427 my @allowed_sortby = qw /acqdate_asc acqdate_dsc author_az author_za call_number_asc call_number_dsc popularity_asc popularity_dsc pubdate_asc pubdate_dsc relevance title_az title_za/;
 428 @sort_by = $cgi->multi_param('sort_by');
 429 $sort_by[0] = $default_sort_by if !$sort_by[0] && defined($default_sort_by);
 430 foreach my $sort (@sort_by) {
 431     if ( grep { /^$sort$/ } @allowed_sortby ) {
 432         $template->param($sort => 1);
 433     }
 434 }
 435 $template->param('sort_by' => $sort_by[0]);
 436
 437 # Use the servers defined, or just search our local catalog(default)
 438 my @servers = $cgi->multi_param('server');
 439 unless (@servers) {
 440     #FIXME: this should be handled using Context.pm
 441     @servers = ("biblioserver");
 442     # @servers = C4::Context->config("biblioserver");
 443 }
 444
 445 # operators include boolean and proximity operators and are used
 446 # to evaluate multiple operands
 447 my @operators = $cgi->multi_param('op');
 448 @operators = map { uri_unescape($_) } @operators;
 449
 450 # indexes are query qualifiers, like 'title', 'author', etc. They
 451 # can be single or multiple parameters separated by comma: kw,right-Truncation
 452 my @indexes = $cgi->multi_param('idx');
 453 @indexes = map { uri_unescape($_) } @indexes;
 454
 455 # if a simple index (only one)  display the index used in the top search box
 456 if ($indexes[0] && !$indexes[1]) {
 457     my $idx = "ms_".$indexes[0];
 458     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 459     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 460     $template->param($idx => 1);
 461 }
 462 # an operand can be a single term, a phrase, or a complete ccl query
 463 my @operands = $cgi->multi_param('q');
 464 @operands = map { uri_unescape($_) } @operands;
 465
 466 $template->{VARS}->{querystring} = join(' ', @operands);
 467
 468 # if a simple search, display the value in the search box
 469 if ($operands[0] && !$operands[1]) {
 470     my $ms_query = $operands[0];
 471     $ms_query =~ s/ #\S+//;
 472     $template->param(ms_value => $ms_query);
 473 }
 474
 475 # limits are use to limit to results to a pre-defined category such as branch or language
 476 my @limits = $cgi->multi_param('limit');
 477 @limits = map { uri_unescape($_) } @limits;
 478 my @nolimits = $cgi->multi_param('nolimit');
 479 @nolimits = map { uri_unescape($_) } @nolimits;
 480 my %is_nolimit = map { $_ => 1 } @nolimits;
 481 @limits = grep { not $is_nolimit{$_} } @limits;
 482
 483 if (@searchCategories > 0) {
 484     my @tabcat;
 485     foreach my $typecategory (@searchCategories) {
 486         my @itemtypes = Koha::ItemTypes->search({ searchcategory => $typecategory });
 487         push @tabcat, $_->itemtype for @itemtypes;
 488     }
 489
 490     foreach my $itemtypeInCategory (@tabcat) {
 491         push (@limits, "mc-$itype_or_itemtype,phr:".$itemtypeInCategory);
 492     }
 493 }
 494
 495 @limits = map { uri_unescape($_) } @limits;
 496
 497 if($params->{'multibranchlimit'}) {
 498     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 499     my @libraries = $search_group->all_libraries;
 500     my $multibranch = '('.join( " OR ", map { 'homebranch: ' . $_->branchcode } @libraries ) .')';
 501     push @limits, $multibranch if ($multibranch ne  '()');
 502 }
 503
 504 my $available;
 505 foreach my $limit(@limits) {
 506     if ($limit =~/available/) {
 507         $available = 1;
 508     }
 509 }
 510 $template->param(available => $available);
 511
 512 # append year limits if they exist
 513 if ($params->{'limit-yr'}) {
 514     if ($params->{'limit-yr'} =~ /\d{4}/) {
 515         push @limits, "yr,st-numeric=$params->{'limit-yr'}";
 516     }
 517     else {
 518         #FIXME: Should return a error to the user, incorect date format specified
 519     }
 520 }
 521
 522 # Params that can only have one value
 523 my $scan = $params->{'scan'};
 524 my $count = C4::Context->preference('OPACnumSearchResults') || 20;
 525 my $countRSS         = C4::Context->preference('numSearchRSSResults') || 50;
 526 my $results_per_page = $params->{'count'} || $count;
 527 my $offset = $params->{'offset'} || 0;
 528 $offset = 0 if $offset < 0;
 529 my $page = $cgi->param('page') || 1;
 530 $offset = ($page-1)*$results_per_page if $page>1;
 531 my $hits;
 532
 533 # Define some global variables
 534 my ($error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 535
 536 my @results;
 537
 538 my $suppress = 0;
 539 if (C4::Context->preference('OpacSuppression')) {
 540     # OPAC suppression by IP address
 541     if (C4::Context->preference('OpacSuppressionByIPRange')) {
 542         my $IPAddress = $ENV{'REMOTE_ADDR'};
 543         my $IPRange = C4::Context->preference('OpacSuppressionByIPRange');
 544         $suppress = ($IPAddress !~ /^$IPRange/);
 545     }
 546     else {
 547         $suppress = 1;
 548     }
 549 }
 550
 551 ## I. BUILD THE QUERY
 552 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type)
 553   = $builder->build_query_compat(
 554     \@operators,
 555     \@operands,
 556     \@indexes,
 557     \@limits,
 558     \@sort_by,
 559     0,
 560     $lang,
 561     {
 562         suppress => $suppress,
 563         is_opac => 1,
 564         weighted_fields => !$cgi->param('advsearch')
 565     }
 566 );
 567
 568 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 569
 570 sub _input_cgi_parse {
 571     my @elements;
 572     my $query_cgi = shift or return @elements;
 573     for my $this_cgi ( split('&',$query_cgi) ) {
 574         next unless $this_cgi;
 575         $this_cgi =~ /(.*?)=(.*)/;
 576         push @elements, { input_name => $1, input_value => Encode::decode_utf8( uri_unescape($2) ) };
 577     }
 578     return @elements;
 579 }
 580
 581 ## parse the query_cgi string and put it into a form suitable for <input>s
 582 my @query_inputs = _input_cgi_parse($query_cgi);
 583 $template->param ( QUERY_INPUTS => \@query_inputs );
 584
 585 ## parse the limit_cgi string and put it into a form suitable for <input>s
 586 my @limit_inputs = $limit_cgi ? _input_cgi_parse($limit_cgi) : ();
 587
 588 # OpenURL
 589 my @OpenURL_itypes;
 590 if (C4::Context->preference('OPACShowOpenURL')) {
 591     @OpenURL_itypes = split( /\s/, C4::Context->preference('OPACOpenURLItemTypes') );
 592     $template->param(
 593         OPACShowOpenURL => 1,
 594         OpenURLResolverURL => C4::Context->preference('OpenURLResolverURL'),
 595         OpenURLText => C4::Context->preference('OpenURLText'),
 596         OpenURLImageLocation => C4::Context->preference('OpenURLImageLocation')
 597     );
 598 }
 599
 600 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 601 $template->param ( OPACResultsSidebar => C4::Context->preference('OPACResultsSidebar'));
 602
 603 ## II. DO THE SEARCH AND GET THE RESULTS
 604 my $total = 0; # the total results for the whole set
 605 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 606 my @results_array;
 607 my $results_hashref;
 608 my @coins;
 609
 610 if ($tag) {
 611     $query_cgi = "tag=" .  uri_escape_utf8( $tag ) . "&" . $query_cgi;
 612     my $taglist = get_tags({term=>$tag, approved=>1});
 613     $results_hashref->{biblioserver}->{hits} = scalar (@$taglist);
 614     my @marclist = map { C4::Biblio::GetXmlBiblio( $_->{biblionumber} ) } @$taglist;
 615     $DEBUG and printf STDERR "taglist (%s biblionumber)\nmarclist (%s records)\n", scalar(@$taglist), scalar(@marclist);
 616     $results_hashref->{biblioserver}->{RECORDS} = \@marclist;
 617     # FIXME: tag search and standard search should work together, not exclusively
 618     # FIXME: Because search and standard search don't work together OpacHiddenItems
 619     #        displays search results which should be hidden.
 620     # FIXME: No facets for tags search.
 621 } elsif ($build_grouped_results) {
 622     eval {
 623         ($error, $results_hashref, $facets) = C4::Search::pazGetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,undef,$query_type,$scan);
 624     };
 625 } else {
 626     $pasarParams .= '&amp;query=' . uri_escape_utf8($query);
 627     $pasarParams .= '&amp;count=' . uri_escape_utf8($results_per_page);
 628     $pasarParams .= '&amp;simple_query=' . uri_escape_utf8($simple_query);
 629     $pasarParams .= '&amp;query_type=' . uri_escape_utf8($query_type) if ($query_type);
 630     my $itemtypes_nocategory = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 631     eval {
 632         ($error, $results_hashref, $facets) = $searcher->search_compat($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,undef,$itemtypes_nocategory,$query_type,$scan,1);
 633 };
 634 }
 635
 636 # use Data::Dumper; print STDERR "-" x 25, "\n", Dumper($results_hashref);
 637 if (not $tag and ( $@ || $error)) {
 638     $template->param(query_error => $error.$@);
 639     output_html_with_http_headers $cgi, $cookie, $template->output;
 640     exit;
 641 }
 642
 643 # At this point, each server has given us a result set
 644 # now we build that set for template display
 645 my @sup_results_array;
 646 my $search_context = {};
 647 $search_context->{'interface'} = 'opac';
 648 if (C4::Context->preference('OpacHiddenItemsExceptions')){
 649     $search_context->{'category'} = $patron ? $patron->categorycode : q{};
 650 }
 651
 652 my $variables = { anonymous_session => ($borrowernumber) ? 0 : 1 };
 653
 654 for (my $i=0;$i<@servers;$i++) {
 655     my $server = $servers[$i];
 656     if ($server && $server =~/biblioserver/) { # this is the local bibliographic server
 657         $hits = $results_hashref->{$server}->{"hits"};
 658         my $page = $cgi->param('page') || 0;
 659         my @newresults;
 660         if ($build_grouped_results) {
 661             foreach my $group (@{ $results_hashref->{$server}->{"GROUPS"} }) {
 662                 # because pazGetRecords handles retieving only the records
 663                 # we want as specified by $offset and $results_per_page,
 664                 # we need to set the offset parameter of searchResults to 0
 665                 my @group_results = searchResults( $search_context, $query_desc, $group->{'group_count'},$results_per_page, 0, $scan,
 666                                                    $group->{"RECORDS"}, $variables);
 667                 push @newresults, { group_label => $group->{'group_label'}, GROUP_RESULTS => \@group_results };
 668             }
 669         } else {
 670             @newresults = searchResults( $search_context, $query_desc, $hits, $results_per_page, $offset, $scan,
 671                                         $results_hashref->{$server}->{"RECORDS"}, $variables);
 672         }
 673         $hits = 0 unless @newresults;
 674
 675         my $art_req_itypes;
 676         if( C4::Context->preference('ArticleRequests') ) {
 677             $art_req_itypes = Koha::IssuingRules->guess_article_requestable_itemtypes({ $patron ? ( categorycode => $patron->categorycode ) : () });
 678         }
 679
 680         foreach my $res (@newresults) {
 681
 682             # must define a value for size if not present in DB
 683             # in order to avoid problems generated by the default size value in TT
 684             if ( not exists $res->{'size'} ) { $res->{'size'} = "" }
 685             # while we're checking each line, see if item is in the cart
 686             if ( grep {$_ eq $res->{'biblionumber'}} @cart_list) {
 687                 $res->{'incart'} = 1;
 688             }
 689
 690             if (C4::Context->preference('COinSinOPACResults')) {
 691                 my $biblio = Koha::Biblios->find( $res->{'biblionumber'} );
 692                 # Catch the exception as Koha::Biblio::Metadata->record can explode if the MARCXML is invalid
 693                 $res->{coins} = $biblio ? eval {$biblio->get_coins} : q{}; # FIXME This should be moved at the beginning of the @newresults loop
 694             }
 695             if ( C4::Context->preference( "Babeltheque" ) and $res->{normalized_isbn} ) {
 696                 if( my $isbn = Business::ISBN->new( $res->{normalized_isbn} ) ) {
 697                     $isbn = $isbn->as_isbn13->as_string;
 698                     $isbn =~ s/-//g;
 699                     my $social_datas = C4::SocialData::get_data( $isbn );
 700                     if ( $social_datas ) {
 701                         for my $key ( keys %$social_datas ) {
 702                             $res->{$key} = $$social_datas{$key};
 703                             if ( $key eq 'score_avg' ){
 704                                 $res->{score_int} = sprintf("%.0f", $$social_datas{score_avg} );
 705                             }
 706                         }
 707                     }
 708                 }
 709             }
 710
 711             if (C4::Context->preference('TagsEnabled') and
 712                 C4::Context->preference('TagsShowOnList')) {
 713                 if ( my $bibnum = $res->{biblionumber} ) {
 714                     $res->{itemsissued} = CountItemsIssued( $bibnum );
 715                     $res->{'TagLoop'} = get_tags({
 716                         biblionumber => $bibnum,
 717                         approved => 1,
 718                         sort => '-weight',
 719                         limit => C4::Context->preference('TagsShowOnList')
 720                     });
 721                 }
 722             }
 723
 724             $res->{shelves} = Koha::Virtualshelves->get_shelves_containing_record(
 725                 {
 726                     biblionumber   => $res->{biblionumber},
 727                     borrowernumber => $borrowernumber
 728                 }
 729             );
 730
 731             if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 732                 my $ratings = Koha::Ratings->search({ biblionumber => $res->{biblionumber} });
 733                 $res->{ratings} = $ratings;
 734                 $res->{my_rating} = $borrowernumber ? $ratings->search({ borrowernumber => $borrowernumber })->next : undef;
 735             }
 736
 737             # BZ17530: 'Intelligent' guess if result can be article requested
 738             $res->{artreqpossible} = ( $art_req_itypes->{ $res->{itemtype} // q{} } || $art_req_itypes->{ '*' } ) ? 1 : q{};
 739         }
 740
 741         if ($results_hashref->{$server}->{"hits"}){
 742             $total = $total + $hits;
 743         }
 744
 745         # Opac search history
 746         if (C4::Context->preference('EnableOpacSearchHistory')) {
 747             unless ( $offset ) {
 748                 my $path_info = $cgi->url(-path_info=>1);
 749                 my $query_cgi_history = $cgi->url(-query=>1);
 750                 $query_cgi_history =~ s/^$path_info\?//;
 751                 $query_cgi_history =~ s/;/&/g;
 752                 my $query_desc_history = join ", ", grep { defined $_ } $query_desc, $limit_desc;
 753
 754                 unless ( $borrowernumber ) {
 755                     my $new_searches = C4::Search::History::add_to_session({
 756                             cgi => $cgi,
 757                             query_desc => $query_desc_history,
 758                             query_cgi => $query_cgi_history,
 759                             total => $total,
 760                             type => "biblio",
 761                     });
 762                 } else {
 763                     # To the session (the user is logged in)
 764                     C4::Search::History::add({
 765                         userid => $borrowernumber,
 766                         sessionid => $cgi->cookie("CGISESSID"),
 767                         query_desc => $query_desc_history,
 768                         query_cgi => $query_cgi_history,
 769                         total => $total,
 770                         type => "biblio",
 771                     });
 772                 }
 773             }
 774             $template->param( EnableOpacSearchHistory => 1 );
 775         }
 776
 777         ## If there's just one result, redirect to the detail page
 778         if ($total == 1 && $format ne 'rss'
 779         && $format ne 'opensearchdescription' && $format ne 'atom') {
 780             my $biblionumber=$newresults[0]->{biblionumber};
 781             if (C4::Context->preference('BiblioDefaultView') eq 'isbd') {
 782                 print $cgi->redirect("/cgi-bin/koha/opac-ISBDdetail.pl?biblionumber=$biblionumber");
 783             } elsif  (C4::Context->preference('BiblioDefaultView') eq 'marc') {
 784                 print $cgi->redirect("/cgi-bin/koha/opac-MARCdetail.pl?biblionumber=$biblionumber");
 785             } else {
 786                 print $cgi->redirect("/cgi-bin/koha/opac-detail.pl?biblionumber=$biblionumber");
 787             }
 788             exit;
 789         }
 790         if ($hits) {
 791             if ( !$build_grouped_results ) {
 792                 # We build the encrypted list of first OPACnumSearchResults biblios to pass with the search criteria for paging on opac-detail
 793                 $pasarParams .= '&amp;listBiblios=';
 794                 my $j = 0;
 795                 foreach (@newresults) {
 796                     my $bibnum = ($_->{biblionumber})?$_->{biblionumber}:0;
 797                     $pasarParams .= uri_escape_utf8($bibnum) . ',';
 798                     $j++;
 799                     last if ($j == $results_per_page);
 800                 }
 801                 chop $pasarParams if ($pasarParams =~ /,$/);
 802                 $pasarParams .= '&amp;total=' . uri_escape_utf8( int($total) ) if ($pasarParams !~ /total=(?:[0-9]+)?/);
 803                 if ($pasarParams) {
 804                     my $session = get_session($cgi->cookie("CGISESSID"));
 805                     $session->param('busc' => $pasarParams);
 806                 }
 807                 #
 808             }
 809             $template->param(total => $hits);
 810             my $limit_cgi_not_availablity = $limit_cgi;
 811             $limit_cgi_not_availablity =~ s/&limit=available//g if defined $limit_cgi_not_availablity;
 812             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 813             $template->param(limit_cgi => $limit_cgi);
 814             $template->param(countrss  => $countRSS );
 815             $template->param(query_cgi => $query_cgi);
 816             $template->param(query_desc => $query_desc);
 817             $template->param(limit_desc => $limit_desc);
 818             $template->param(offset     => $offset);
 819             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 820             if ($query_desc || $limit_desc) {
 821                 $template->param(searchdesc => 1);
 822             }
 823             $template->param(results_per_page =>  $results_per_page);
 824             my $hide = C4::Context->preference('OpacHiddenItems');
 825             $hide = ($hide =~ m/\S/) if $hide; # Just in case it has some spaces/new lines
 826             my $branch = '';
 827             if (C4::Context->userenv){
 828                 $branch = C4::Context->userenv->{branch};
 829             }
 830             if ( C4::Context->preference('HighlightOwnItemsOnOPAC') ) {
 831                 if (
 832                     ( ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) && $branch )
 833                     ||
 834                     C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch'
 835                 ) {
 836                     my $branchcode;
 837                     if ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) {
 838                         $branchcode = $branch;
 839                     }
 840                     elsif (  C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch' ) {
 841                         $branchcode = $ENV{'BRANCHCODE'};
 842                     }
 843
 844                     foreach my $res ( @newresults ) {
 845                         my @new_loop;
 846                         my @top_loop;
 847                         my @old_loop = @{$res->{'available_items_loop'}};
 848                         foreach my $item ( @old_loop ) {
 849                             if ( $item->{'branchcode'} eq $branchcode ) {
 850                                 $item->{'this_branch'} = 1;
 851                                 push( @top_loop, $item );
 852                             } else {
 853                                 push( @new_loop, $item );
 854                             }
 855                         }
 856                         my @complete_loop = ( @top_loop, @new_loop );
 857                         $res->{'available_items_loop'} = \@complete_loop;
 858                     }
 859                 }
 860             }
 861
 862             $template->param(
 863                 SEARCH_RESULTS => \@newresults,
 864                 OPACItemsResultsDisplay => (C4::Context->preference("OPACItemsResultsDisplay")),
 865                 suppress_result_number => $hide,
 866                             );
 867             if (C4::Context->preference("OPACLocalCoverImages")){
 868                 $template->param(OPACLocalCoverImages => 1);
 869                 $template->param(OPACLocalCoverImagesPriority => C4::Context->preference("OPACLocalCoverImagesPriority"));
 870             }
 871             ## Build the page numbers on the bottom of the page
 872             my @page_numbers;
 873             my $max_result_window = $searcher->max_result_window;
 874             my $hits_to_paginate = ($max_result_window && $max_result_window < $hits) ? $max_result_window : $hits;
 875             $template->param( hits_to_paginate => $hits_to_paginate );
 876             # total number of pages there will be
 877             my $pages = ceil($hits_to_paginate / $results_per_page);
 878             my $last_page_offset = ( $pages - 1 ) * $results_per_page;
 879             # default page number
 880             my $current_page_number = 1;
 881             if ($offset) {
 882                 $current_page_number = ( $offset / $results_per_page + 1 );
 883             }
 884             my $previous_page_offset;
 885             if ( $offset >= $results_per_page ) {
 886                 $previous_page_offset = $offset - $results_per_page;
 887             }
 888             my $next_page_offset = $offset + $results_per_page;
 889             # If we're within the first 10 pages, keep it simple
 890             #warn "current page:".$current_page_number;
 891             if ($current_page_number < 10) {
 892                 # just show the first 10 pages
 893                 # Loop through the pages
 894                 my $pages_to_show = 10;
 895                 $pages_to_show = $pages if $pages<10;
 896                 for ($i=1; $i<=$pages_to_show;$i++) {
 897                     # the offset for this page
 898                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 899                     # the page number for this page
 900                     my $this_page_number = $i;
 901                     # put it in the array
 902                     push @page_numbers,
 903                       { offset    => $this_offset,
 904                         pg        => $this_page_number,
 905                         highlight => $this_page_number == $current_page_number,
 906                         sort_by   => join ' ', @sort_by
 907                       };
 908
 909                 }
 910
 911             }
 912             # now, show twenty pages, with the current one smack in the middle
 913             else {
 914                 for ($i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 915                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 916                     my $this_page_number = $i-9;
 917                     if ( $this_page_number <= $pages ) {
 918                         push @page_numbers,
 919                           { offset    => $this_offset,
 920                             pg        => $this_page_number,
 921                             highlight => $this_page_number == $current_page_number,
 922                             sort_by => join ' ', @sort_by
 923                           };
 924                     }
 925                 }
 926
 927             }
 928             $template->param(   PAGE_NUMBERS => \@page_numbers,
 929                                 last_page_offset => $last_page_offset,
 930                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 931             $template->param(next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 932         }
 933         # no hits
 934         else {
 935             my $nohits = C4::Context->preference('OPACNoResultsFound');
 936             if ($nohits and $nohits=~/{QUERY_KW}/){
 937                 # extracting keywords in case of relaunching search
 938                 (my $query_kw=$query_desc)=~s/ and|or / /g;
 939                 my @query_kw=($query_kw=~ /([-\w]+\b)(?:[^,:]|$)/g);
 940                 $query_kw=join('+',@query_kw);
 941                 $nohits=~s/{QUERY_KW}/$query_kw/g;
 942                 $template->param('OPACNoResultsFound' =>$nohits);
 943             }
 944             $template->param(
 945                 searchdesc => 1,
 946                 query_desc => $query_desc,
 947                 limit_desc => $limit_desc,
 948                 query_cgi  => $query_cgi,
 949                 limit_cgi  => $limit_cgi
 950             );
 951         }
 952     } # end of the if local
 953     # asynchronously search the authority server
 954     elsif ($server && $server =~/authorityserver/) { # this is the local authority server
 955         my @inner_sup_results_array;
 956         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 957             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 958             my $title_field = $marc_record_object->field(100);
 959             push @inner_sup_results_array, {
 960                 'title' => $title_field->subfield('a'),
 961                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 962             };
 963         }
 964         my $servername = $server;
 965         push @sup_results_array, {  servername => $servername,
 966                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 967     }
 968     # FIXME: can add support for other targets as needed here
 969     $template->param(           outer_sup_results_loop => \@sup_results_array);
 970 } #/end of the for loop
 971 #$template->param(FEDERATED_RESULTS => \@results_array);
 972
 973 for my $facet ( @$facets ) {
 974     for my $entry ( @{ $facet->{facets} } ) {
 975         my $index = $entry->{type_link_value};
 976         my $value = $entry->{facet_link_value};
 977         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 978     }
 979 }
 980
 981
 982 $template->param(
 983             #classlist => $classlist,
 984             total => $total,
 985             opacfacets => 1,
 986             facets_loop => $facets,
 987             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 988             scan => $scan,
 989             search_error => $error,
 990 );
 991
 992 if ($query_desc || $limit_desc) {
 993     $template->param(searchdesc => 1);
 994 }
 995
 996 # VI. BUILD THE TEMPLATE
 997 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 998     {
 999         borrowernumber => $borrowernumber,
1000         add_allowed    => 1,
1001         category       => 1,
1002     }
1003 );
1004 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
1005     {
1006         borrowernumber => $borrowernumber,
1007         add_allowed    => 1,
1008         category       => 2,
1009     }
1010 );
1011
1012 $template->param(
1013     add_to_some_private_shelves => $some_private_shelves,
1014     add_to_some_public_shelves  => $some_public_shelves,
1015 );
1016
1017 my $content_type = ($format eq 'rss' or $format eq 'atom') ? $format : 'html';
1018
1019 # If GoogleIndicTransliteration system preference is On Set parameter to load Google's javascript in OPAC search screens
1020 if (C4::Context->preference('GoogleIndicTransliteration')) {
1021         $template->param('GoogleIndicTransliteration' => 1);
1022 }
1023
1024 $template->{VARS}->{DidYouMean} =
1025   ( defined C4::Context->preference('OPACdidyoumean')
1026       && C4::Context->preference('OPACdidyoumean') =~ m/enable/ );
1027 $template->{VARS}->{IDreamBooksReviews} = C4::Context->preference('IDreamBooksReviews');
1028 $template->{VARS}->{IDreamBooksReadometer} = C4::Context->preference('IDreamBooksReadometer');
1029 $template->{VARS}->{IDreamBooksResults} = C4::Context->preference('IDreamBooksResults');
1030
1031 if ($offset == 0) {
1032     $template->param(firstPage => 1);
1033 }
1034
1035     $template->param( borrowernumber    => $borrowernumber);
1036 output_with_http_headers $cgi, $cookie, $template->output, $content_type;