opac/opac-showmarc.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2007 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 # standard or CPAN modules used
  23 use CGI qw ( -utf8 );
  24 use Encode;
  25
  26 # Koha modules used
  27 use C4::Context;
  28 use C4::Output;
  29 use C4::Auth;
  30 use C4::Biblio;
  31 use C4::ImportBatch;
  32 use C4::XSLT ();
  33 use C4::Templates;
  34 use Koha::RecordProcessor;
  35
  36 my $input       = new CGI;
  37 my $biblionumber = $input->param('id');
  38 $biblionumber   = int($biblionumber);
  39 my $importid= $input->param('importid');
  40 my $view= $input->param('viewas') || 'marc';
  41
  42 my $record_unfiltered;
  43 if ($importid) {
  44     my ($marc) = GetImportRecordMarc($importid);
  45     $record_unfiltered = MARC::Record->new_from_usmarc($marc);
  46 }
  47 else {
  48     $record_unfiltered = GetMarcBiblio($biblionumber);
  49 }
  50 if(!ref $record_unfiltered) {
  51     print $input->redirect("/cgi-bin/koha/errors/404.pl");
  52     exit;
  53 }
  54
  55 my $record_processor = Koha::RecordProcessor->new({ filters => 'ViewPolicy' });
  56 my $record_filtered  = $record_unfiltered->clone();
  57 my $record           = $record_processor->process($record_filtered);
  58
  59 if ($view eq 'card' || $view eq 'html') {
  60     # FIXME: GetXmlBiblio needs filtering later.
  61     my $xml = $importid ? $record->as_xml(): GetXmlBiblio($biblionumber);
  62     if (!$importid && $view eq 'html') {
  63         my $unfiltered_record = MARC::Record->new_from_xml($xml);
  64         my $frameworkcode = GetFrameworkCode($biblionumber);
  65         $record_processor->options({ frameworkcode => $frameworkcode});
  66         my $filtered_record = $record_processor->process($unfiltered_record);
  67         $xml = $filtered_record->as_xml();
  68     }
  69     my $xsl =  $view eq 'card' ? 'compact.xsl' : 'plainMARC.xsl';
  70     my $htdocs = C4::Context->config('opachtdocs');
  71     my ($theme, $lang) = C4::Templates::themelanguage($htdocs, $xsl, 'opac', $input);
  72     $xsl = "$htdocs/$theme/$lang/xslt/$xsl";
  73     print $input->header(-charset => 'UTF-8'),
  74           Encode::encode_utf8(C4::XSLT::engine->transform($xml, $xsl));
  75 }
  76 else { #view eq marc
  77     my ( $template, $loggedinuser, $cookie ) = get_template_and_user({
  78         template_name   => "opac-showmarc.tt",
  79         query           => $input,
  80         type            => "opac",
  81         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  82         debug           => 1,
  83     });
  84     $template->param( MARC_FORMATTED => $record->as_formatted );
  85     output_html_with_http_headers $input, $cookie, $template->output;
  86 }