circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 # Copyright 2012 software.coop and MJ Ray
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 # FIXME There are too many calls to Koha::Patrons->find in this script
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use URI::Escape qw( uri_escape_utf8 );
  30 use DateTime;
  31 use DateTime::Duration;
  32 use Scalar::Util qw( looks_like_number );
  33 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  34 use C4::Auth qw( get_session get_template_and_user );
  35 use C4::Koha;
  36 use C4::Circulation qw( barcodedecode CanBookBeIssued AddIssue );
  37 use C4::Utils::DataTables::Members;
  38 use C4::Members;
  39 use C4::Biblio qw( TransformMarcToKoha );
  40 use C4::Search qw( new_record_from_zebra );
  41 use C4::Reserves;
  42 use Koha::Holds;
  43 use C4::Context;
  44 use CGI::Session;
  45 use Koha::AuthorisedValues;
  46 use Koha::CsvProfiles;
  47 use Koha::Patrons;
  48 use Koha::Patron::Debarments qw( GetDebarments );
  49 use Koha::DateUtils qw( dt_from_string output_pref );
  50 use Koha::Plugins;
  51 use Koha::Database;
  52 use Koha::BiblioFrameworks;
  53 use Koha::Items;
  54 use Koha::SearchEngine;
  55 use Koha::SearchEngine::Search;
  56 use Koha::Patron::Modifications;
  57
  58 use List::MoreUtils qw( uniq );
  59
  60 #
  61 # PARAMETERS READING
  62 #
  63 my $query = CGI->new;
  64
  65 my $override_high_holds     = $query->param('override_high_holds');
  66 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
  67
  68 my $sessionID = $query->cookie("CGISESSID") ;
  69 my $session = get_session($sessionID);
  70
  71 my $barcodes = [];
  72 my $barcode =  $query->param('barcode');
  73 my $findborrower;
  74 my $autoswitched;
  75 my $borrowernumber = $query->param('borrowernumber');
  76
  77 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
  78     my $new_barcode = $barcode;
  79     Koha::Plugins->call( 'patron_barcode_transform', \$new_barcode );
  80     if (Koha::Patrons->search( { cardnumber => $new_barcode} )->count() > 0) {
  81         $findborrower = $barcode;
  82         undef $barcode;
  83         undef $borrowernumber;
  84         $autoswitched = 1;
  85     }
  86 }
  87 $findborrower ||= $query->param('findborrower') || q{};
  88 $findborrower =~ s|,| |g;
  89
  90 # Barcode given by user could be '0'
  91 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
  92     $barcodes = [ $barcode ];
  93 } else {
  94     my $filefh = $query->upload('uploadfile');
  95     if ( $filefh ) {
  96         while ( my $content = <$filefh> ) {
  97             $content =~ s/[\r\n]*$//g;
  98             push @$barcodes, $content if $content;
  99         }
 100     } elsif ( my $list = $query->param('barcodelist') ) {
 101         push @$barcodes, split( /\s\n/, $list );
 102         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
 103     } else {
 104         @$barcodes = $query->multi_param('barcodes');
 105     }
 106 }
 107
 108 $barcodes = [ uniq @$barcodes ];
 109
 110 my $template_name = q|circ/circulation.tt|;
 111 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
 112 my $batch = $query->param('batch');
 113 my $batch_allowed = 0;
 114 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
 115     $template_name = q|circ/circulation_batch_checkouts.tt|;
 116     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
 117     my $categorycode = $patron->categorycode;
 118     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
 119         $batch_allowed = 1;
 120     } else {
 121         $barcodes = [];
 122     }
 123 }
 124
 125 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
 126     {
 127         template_name   => $template_name,
 128         query           => $query,
 129         type            => "intranet",
 130         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
 131     }
 132 );
 133 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
 134
 135 my $force_allow_issue = $query->param('forceallow') || 0;
 136 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
 137     $force_allow_issue = 0;
 138 }
 139 my $onsite_checkout = $query->param('onsite_checkout');
 140
 141 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
 142     $template->param(onsite_checkout => $onsite_checkout);
 143 }
 144
 145 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
 146 our %renew_failed = ();
 147 for (@failedrenews) { $renew_failed{$_} = 1; }
 148
 149 my @failedreturns = $query->multi_param('failedreturn');
 150 our %return_failed = ();
 151 for (@failedreturns) { $return_failed{$_} = 1; }
 152
 153 my $searchtype = $query->param('searchtype') || q{contain};
 154
 155 my $branch = C4::Context->userenv->{'branch'};
 156
 157 if (C4::Context->preference("DisplayClearScreenButton")) {
 158     $template->param(DisplayClearScreenButton => 1);
 159 }
 160
 161 for my $barcode ( @$barcodes ) {
 162     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 163     $barcode = barcodedecode( $barcode ) if $barcode;
 164 }
 165
 166 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 167 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 168 $duedatespec = eval { output_pref( { dt => dt_from_string( $duedatespec ), dateformat => 'iso' }); }
 169     if ( $duedatespec );
 170 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
 171 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
 172     undef $restoreduedatespec;
 173 }
 174 my $issueconfirmed = $query->param('issueconfirmed');
 175 my $cancelreserve  = $query->param('cancelreserve');
 176 my $cancel_recall  = $query->param('cancel_recall');
 177 my $recall_id      = $query->param('recall_id');
 178 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 179 my $charges        = $query->param('charges') || q{};
 180
 181 # Check if stickyduedate is turned off
 182 if ( @$barcodes ) {
 183     # was stickyduedate loaded from session?
 184     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 185         $session->clear( 'stickyduedate' );
 186         $stickyduedate  = $query->param('stickyduedate');
 187         $duedatespec    = $query->param('duedatespec');
 188     }
 189     $session->param('auto_renew', scalar $query->param('auto_renew'));
 190 }
 191 else {
 192     $session->clear('auto_renew');
 193 }
 194
 195 $template->param( auto_renew => $session->param('auto_renew') );
 196
 197 my ($datedue,$invalidduedate);
 198
 199 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 200 if( $onsite_checkout && !$duedatespec_allow ) {
 201     $datedue = output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 202     $datedue .= ' 23:59:00';
 203 } elsif( $duedatespec_allow ) {
 204     if ( $duedatespec ) {
 205         $datedue = eval { dt_from_string( $duedatespec ) };
 206         if (! $datedue ) {
 207             $invalidduedate = 1;
 208             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
 209         }
 210     }
 211 }
 212
 213 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
 214 if ( @$barcodes == 0 && $charges eq 'yes' ) {
 215     $template->param(
 216         PAYCHARGES     => 'yes',
 217         borrowernumber => $borrowernumber
 218     );
 219 }
 220
 221 #
 222 # STEP 2 : FIND BORROWER
 223 # if there is a list of find borrowers....
 224 #
 225 my $message;
 226 if ($findborrower) {
 227     Koha::Plugins->call( 'patron_barcode_transform', \$findborrower );
 228     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 229     if ( $patron ) {
 230         $borrowernumber = $patron->borrowernumber;
 231     } else {
 232         print $query->redirect( "/cgi-bin/koha/members/member.pl?quicksearch=1&circsearch=1&searchmember=" . uri_escape_utf8($findborrower) );
 233         exit;
 234     }
 235 }
 236
 237 # get the borrower information.....
 238 my $balance = 0;
 239 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
 240 if ($patron) {
 241
 242     $template->param( borrowernumber => $patron->borrowernumber );
 243     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
 244
 245     my $overdues = $patron->get_overdues;
 246     my $issues = $patron->checkouts;
 247     $balance = $patron->account->balance;
 248
 249
 250     # if the expiry date is before today ie they have expired
 251     if ( $patron->is_expired ) {
 252         #borrowercard expired, no issues
 253         $template->param(
 254             noissues => ($force_allow_issue) ? 0 : "1",
 255             forceallow => $force_allow_issue,
 256             expired => "1",
 257         );
 258     }
 259     # check for NotifyBorrowerDeparture
 260     elsif ( $patron->is_going_to_expire ) {
 261         # borrower card soon to expire warn librarian
 262         $template->param( "warndeparture" => $patron->dateexpiry ,
 263                         );
 264         if (C4::Context->preference('ReturnBeforeExpiry')){
 265             $template->param("returnbeforeexpiry" => 1);
 266         }
 267     }
 268     $template->param(
 269         overduecount => $overdues->count,
 270         issuecount   => $issues->count,
 271         finetotal    => $balance,
 272     );
 273
 274     if ( $patron and $patron->is_debarred ) {
 275         $template->param(
 276             'userdebarred'    => $patron->debarred,
 277             'debarredcomment' => $patron->debarredcomment,
 278         );
 279
 280         if ( $patron->debarred ne "9999-12-31" ) {
 281             $template->param( 'userdebarreddate' => $patron->debarred );
 282         }
 283     }
 284
 285     # Calculate and display patron's age
 286     if ( !$patron->is_valid_age ) {
 287         $template->param( age_limitations => 1 );
 288         $template->param( age_low => $patron->category->dateofbirthrequired );
 289         $template->param( age_high => $patron->category->upperagelimit );
 290     }
 291
 292 }
 293
 294 #
 295 # STEP 3 : ISSUING
 296 #
 297 #
 298 if (@$barcodes) {
 299   my $checkout_infos;
 300   for my $barcode ( @$barcodes ) {
 301
 302     my $template_params = {
 303         barcode         => $barcode,
 304         onsite_checkout => $onsite_checkout,
 305     };
 306
 307     # always check for blockers on issuing
 308     my ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
 309         $patron,
 310         $barcode, $datedue,
 311         $inprocess,
 312         undef,
 313         {
 314             onsite_checkout     => $onsite_checkout,
 315             override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
 316         }
 317     );
 318
 319     my $blocker = $invalidduedate ? 1 : 0;
 320
 321     $template_params->{alert} = $alerts;
 322     $template_params->{messages} = $messages;
 323
 324     my $item = Koha::Items->find({ barcode => $barcode });
 325
 326     my $biblio;
 327     if ( $item ) {
 328         $biblio = $item->biblio;
 329     }
 330
 331     # Fix for bug 7494: optional checkout-time fallback search for a book
 332
 333     if ( $error->{'UNKNOWN_BARCODE'}
 334         && C4::Context->preference("itemBarcodeFallbackSearch")
 335         && not $batch
 336     )
 337     {
 338      $template_params->{FALLBACK} = 1;
 339
 340         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
 341         my $query = "kw=" . $barcode;
 342         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
 343
 344         # if multiple hits, offer options to librarian
 345         if ( $total_hits > 0 ) {
 346             my @barcodes;
 347             foreach my $hit ( @{$results} ) {
 348                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
 349                   TransformMarcToKoha( C4::Search::new_record_from_zebra('biblioserver',$hit) );
 350
 351                 # offer all barcodes individually
 352                 if ( $chosen->{barcode} ) {
 353                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
 354                 }
 355             }
 356             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
 357             $template_params->{options} = $items;
 358         }
 359     }
 360
 361     # Only some errors will block when performing forced onsite checkout,
 362     # for other cases all errors will block
 363     my @blocking_error_codes = ($onsite_checkout and C4::Context->preference("OnSiteCheckoutsForce")) ?
 364         qw( UNKNOWN_BARCODE ) : (keys %$error);
 365
 366     foreach my $code ( @blocking_error_codes ) {
 367         if ($error->{$code}) {
 368             $template_params->{$code} = $error->{$code};
 369             $template_params->{IMPOSSIBLE} = 1;
 370             $blocker = 1;
 371         }
 372     }
 373
 374     delete $question->{'DEBT'} if ($debt_confirmed);
 375
 376     if( $item and ( !$blocker or $force_allow_issue ) ){
 377         my $confirm_required = 0;
 378         unless($issueconfirmed){
 379             #  Get the item title for more information
 380             my $materials = $item->materials;
 381             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
 382             $materials = $descriptions->{lib} // $materials;
 383             $template_params->{ADDITIONAL_MATERIALS} = $materials;
 384             $template_params->{itemhomebranch} = $item->homebranch;
 385
 386             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 387             foreach my $needsconfirmation ( keys %$question ) {
 388                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
 389                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
 390                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
 391                 $template_params->{NEEDSCONFIRMATION} = 1;
 392                 $confirm_required = 1;
 393             }
 394         }
 395         unless($confirm_required) {
 396             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
 397             if ( !$recall_id ) {
 398                 my $item = Koha::Items->find({ barcode => $barcode });
 399                 my $recall = Koha::Recalls->find({ biblionumber => $item->biblionumber, itemnumber => [ undef, $item->itemnumber ], status => [ 'R','W' ], old => undef, borrowernumber => $patron->borrowernumber });
 400                 $recall_id = ( $recall and $recall->recall_id ) ? $recall->recall_id : undef;
 401             }
 402             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, cancel_recall => $cancel_recall, recall_id => $recall_id, } );
 403             $template_params->{issue} = $issue;
 404             $session->clear('auto_renew');
 405             $inprocess = 1;
 406         }
 407     }
 408
 409     if ($question->{RESERVE_WAITING} or $question->{RESERVED} or $question->{TRANSFERRED} or $question->{PROCESSING}){
 410         $template->param(
 411             reserveborrowernumber => $question->{'resborrowernumber'},
 412             reserve_id => $question->{reserve_id},
 413         );
 414     }
 415
 416
 417     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
 418     $patron = Koha::Patrons->find( $borrowernumber );
 419     $template_params->{issuecount} = $patron->checkouts->count;
 420
 421     if ( $item ) {
 422         $template_params->{item} = $item;
 423         $template_params->{biblio} = $biblio;
 424         $template_params->{itembiblionumber} = $biblio->biblionumber;
 425     }
 426     push @$checkout_infos, $template_params;
 427   }
 428   unless ( $batch ) {
 429     $template->param( %{$checkout_infos->[0]} );
 430     $template->param( barcode => $barcodes->[0] );
 431   } else {
 432     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
 433     $template->param(
 434         checkout_infos => $checkout_infos,
 435         confirmation_needed => $confirmation_needed,
 436     );
 437   }
 438 }
 439
 440 ##################################################################################
 441 # BUILD HTML
 442 # show all reserves of this borrower, and the position of the reservation ....
 443 if ($patron) {
 444     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
 445     my $waiting_holds = $holds->waiting;
 446     $template->param(
 447         holds_count  => $holds->count(),
 448         WaitingHolds => $waiting_holds,
 449         recalls => $patron->recalls->filter_by_current->search({},{ order_by => { -asc => 'recalldate' } }),
 450         specific_patron => 1,
 451     );
 452 }
 453
 454 if ( $patron ) {
 455     my $noissues;
 456     if ( $patron->gonenoaddress ) {
 457         $template->param( gonenoaddress => 1 );
 458         $noissues = 1;
 459     }
 460     if ( $patron->lost ) {
 461         $template->param( lost=> 1 );
 462         $noissues = 1;
 463     }
 464     if ( $patron->is_debarred ) {
 465         $template->param( is_debarred=> 1 );
 466         $noissues = 1;
 467     }
 468     my $account = $patron->account;
 469     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
 470         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
 471         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
 472         $template->param(
 473             charges => 1,
 474             chargesamount => $owing,
 475         )
 476     } elsif ( $balance < 0 ) {
 477         $template->param(
 478             credits => 1,
 479             creditsamount => -$balance,
 480         );
 481     }
 482
 483     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 484     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 485     if ( $no_issues_charge_guarantors ) {
 486         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 487
 488         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
 489             $template->param(
 490                 charges_guarantors_guarantees => $guarantors_non_issues_charges
 491             );
 492             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 493         }
 494     }
 495
 496     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 497     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 498     if ( defined $no_issues_charge_guarantees ) {
 499         my $guarantees_non_issues_charges = 0;
 500         my $guarantees = $patron->guarantee_relationships->guarantees;
 501         while ( my $g = $guarantees->next ) {
 502             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 503         }
 504         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
 505             $template->param(
 506                 charges_guarantees    => 1,
 507                 chargesamount_guarantees => $guarantees_non_issues_charges,
 508             );
 509             $noissues = 1 unless C4::Context->preference("allowfineoverride");
 510         }
 511     }
 512
 513     if ( $patron->has_overdues ) {
 514         $template->param( odues => 1 );
 515     }
 516
 517     if ( $patron->borrowernotes ) {
 518         my $borrowernotes = $patron->borrowernotes;
 519         $borrowernotes =~ s#\n#<br />#g;
 520         $template->param(
 521             notes =>1,
 522             notesmsg => $borrowernotes,
 523         )
 524     }
 525
 526     if ( $noissues ) {
 527         $template->param(
 528             noissues => ($force_allow_issue) ? 0 : 'true',
 529             forceallow => $force_allow_issue,
 530         );
 531     }
 532
 533     my $patron_messages = $patron->messages->search(
 534         {},
 535         {
 536            join => 'manager',
 537            '+select' => ['manager.surname', 'manager.firstname' ],
 538            '+as' => ['manager_surname', 'manager_firstname'],
 539         }
 540     );
 541     $template->param( patron_messages => $patron_messages );
 542
 543 }
 544
 545 my $fast_cataloging = 0;
 546 if ( Koha::BiblioFrameworks->find('FA') ) {
 547     $fast_cataloging = 1
 548 }
 549
 550 my $view = $batch
 551     ?'batch_checkout_view'
 552     : 'circview';
 553
 554 my @relatives;
 555 if ( $patron ) {
 556     if ( my @guarantors = $patron->guarantor_relationships()->guarantors->as_list ) {
 557         push( @relatives, $_->id ) for @guarantors;
 558         push( @relatives, $_->id ) for $patron->siblings->as_list;
 559     } else {
 560         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees->as_list;
 561     }
 562 }
 563 my $relatives_issues_count =
 564   Koha::Database->new()->schema()->resultset('Issue')
 565   ->count( { borrowernumber => \@relatives } );
 566
 567 if ( $patron ) {
 568     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
 569     my $roadtype = $av->count ? $av->next->lib : '';
 570     $template->param(
 571         roadtype          => $roadtype,
 572         patron            => $patron,
 573         categoryname      => $patron->category->description,
 574         expiry            => $patron->dateexpiry,
 575     );
 576 }
 577
 578 # Restore date if changed by holds and/or save stickyduedate to session
 579 if ($restoreduedatespec || $stickyduedate) {
 580     $duedatespec = $restoreduedatespec || $duedatespec;
 581
 582     if ($stickyduedate) {
 583         $session->param( 'stickyduedate', $duedatespec );
 584     }
 585 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
 586     undef $duedatespec;
 587 }
 588
 589 $template->param(
 590     borrowernumber    => $borrowernumber,
 591     branch            => $branch,
 592     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
 593     barcodes          => $barcodes,
 594     stickyduedate     => $stickyduedate,
 595     duedatespec       => $duedatespec,
 596     restoreduedatespec => $restoreduedatespec,
 597     message           => $message,
 598     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
 599     inprocess         => $inprocess,
 600     $view             => 1,
 601     batch_allowed     => $batch_allowed,
 602     batch             => $batch,
 603     AudioAlerts           => C4::Context->preference("AudioAlerts"),
 604     fast_cataloging   => $fast_cataloging,
 605     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 606     RoutingSerials => C4::Context->preference('RoutingSerials'),
 607     relatives_issues_count => $relatives_issues_count,
 608     relatives_borrowernumbers => \@relatives,
 609 );
 610
 611
 612 if ( C4::Context->preference("ExportCircHistory") ) {
 613     $template->param(csv_profiles => Koha::CsvProfiles->search({ type => 'marc' }));
 614 }
 615
 616 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
 617 $template->param(
 618     debt_confirmed            => $debt_confirmed,
 619     SpecifyDueDate            => $duedatespec_allow,
 620     PatronAutoComplete      => C4::Context->preference("PatronAutoComplete"),
 621     debarments                => scalar GetDebarments({ borrowernumber => $borrowernumber }),
 622     todaysdate                => output_pref( { dt => dt_from_string()->set(hour => 23)->set(minute => 59), dateformat => 'sql' } ),
 623     has_modifications         => $has_modifications,
 624     override_high_holds       => $override_high_holds,
 625     nopermission              => scalar $query->param('nopermission'),
 626     autoswitched              => $autoswitched,
 627     logged_in_user            => $logged_in_user,
 628 );
 629
 630 output_html_with_http_headers $query, $cookie, $template->output;