C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40         @ISA    = qw(Exporter);
  41         @EXPORT = qw( checkpw_ldap );
  42 }
  43
  44 # Redefine checkpw_ldap:
  45 # connect to LDAP (named or anonymous)
  46 # ~ retrieves $userid from KOHA_CONF mapping
  47 # ~ then compares $password with userPassword
  48 # ~ then gets the LDAP entry
  49 # ~ and calls the memberadd if necessary
  50
  51 sub ldapserver_error {
  52         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  53 }
  54
  55 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  56 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  57 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  58 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  59 my $base      = $ldap->{base}           or die ldapserver_error('base');
  60 $ldapname     = $ldap->{user}           ;
  61 $ldappassword = $ldap->{pass}           ;
  62 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  63 my @mapkeys = keys %mapping;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  65 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  66 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  67
  68 my %config = (
  69         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  70     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  71        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  72 );
  73
  74 sub description {
  75         my $result = shift or return;
  76         return "LDAP error #" . $result->code
  77                         . ": " . $result->error_name . "\n"
  78                         . "# " . $result->error_text . "\n";
  79 }
  80
  81 sub search_method {
  82     my $db     = shift or return;
  83     my $userid = shift or return;
  84         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  85         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  86         my $search = $db->search(
  87                   base => $base,
  88                 filter => $filter,
  89                 # attrs => ['*'],
  90     );
  91     die "LDAP search failed to return object : " . $search->error if $search->code;
  92
  93         my $count = $search->count;
  94         if ($search->code > 0) {
  95                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  96                 return 0;
  97         }
  98         if ($count != 1) {
  99                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 100                 return 0;
 101         }
 102     return $search;
 103 }
 104
 105 sub checkpw_ldap {
 106     my ($dbh, $userid, $password) = @_;
 107     my @hosts = split(',', $prefhost);
 108     my $db = Net::LDAP->new(\@hosts);
 109     unless ( $db ) {
 110         warn "LDAP connexion failed";
 111         return 0;
 112     }
 113
 114         #$debug and $db->debug(5);
 115     my $userldapentry;
 116
 117     if ( $ldap->{auth_by_bind} ) {
 118         my $principal_name;
 119         if ( $ldap->{anonymous_bind} ) {
 120
 121             # Perform an anonymous bind
 122             my $res = $db->bind;
 123             if ( $res->code ) {
 124                 warn "Anonymous LDAP bind failed: " . description($res);
 125                 return 0;
 126             }
 127
 128             # Perform a LDAP search for the given username
 129             my $search = search_method( $db, $userid )
 130               or return 0;    # warnings are in the sub
 131             $userldapentry = $search->shift_entry;
 132             $principal_name = $userldapentry->dn;
 133         }
 134         else {
 135             $principal_name = $ldap->{principal_name};
 136             if ( $principal_name and $principal_name =~ /\%/ ) {
 137                 $principal_name = sprintf( $principal_name, $userid );
 138             }
 139             else {
 140                 $principal_name = $userid;
 141             }
 142         }
 143
 144         # Perform a LDAP bind for the given username using the matched DN
 145         my $res = $db->bind( $principal_name, password => $password );
 146         if ( $res->code ) {
 147             if ( $ldap->{anonymous_bind} ) {
 148                 # With anonymous_bind approach we can be sure we have found the correct user
 149                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 150                 # or password changed). We should not fall back to local accounts in this case.
 151                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 152                 return -1;
 153             } else {
 154                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 155                 # at all, and thus we should fall back to local logins to restore previous behaviour
 156                 # see bug 12831
 157                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 158                 return 0;
 159             }
 160         }
 161         if ( !defined($userldapentry)
 162             && ( $config{update} or $config{replicate} ) )
 163         {
 164             my $search = search_method( $db, $userid ) or return 0;
 165             $userldapentry = $search->shift_entry;
 166         }
 167     } else {
 168                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 169                 if ($res->code) {               # connection refused
 170                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 171                         return 0;
 172                 }
 173         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 174         $userldapentry = $search->shift_entry;
 175                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 176                 if ($cmpmesg->code != 6) {
 177                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 178                         return -1;
 179                 }
 180         }
 181
 182     # To get here, LDAP has accepted our user's login attempt.
 183     # But we still have work to do.  See perldoc below for detailed breakdown.
 184
 185     my (%borrower);
 186         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 187
 188     if (( $borrowernumber and $config{update}   ) or
 189         (!$borrowernumber and $config{replicate})   ) {
 190         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 191         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 192     }
 193
 194     if ($borrowernumber) {
 195         if ($config{update}) { # A1, B1
 196             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 197             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 198         } else { # C1, D1
 199             # maybe update just the password?
 200                 return(1, $cardnumber, $local_userid);
 201         }
 202     } elsif ($config{replicate}) { # A2, C2
 203         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 204         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 205    } else {
 206         return 0;   # B2, D2
 207     }
 208     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 209         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 210             my $code = $attribute_type->{code};
 211             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 212                 next;
 213             }
 214             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 215                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, value => $borrower{$code}});
 216             } else {
 217                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 218             }
 219         }
 220     }
 221     return(1, $cardnumber, $userid);
 222 }
 223
 224 # Pass LDAP entry object and local cardnumber (userid).
 225 # Returns borrower hash.
 226 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 227 # Ensure that mandatory fields are correctly filled!
 228 #
 229 sub ldap_entry_2_hash {
 230         my $userldapentry = shift;
 231         my %borrower = ( cardnumber => shift );
 232         my %memberhash;
 233         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 234         if ($debug) {
 235                 foreach (keys %$userldapentry) {
 236                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 237                 }
 238         }
 239         my $x = $userldapentry->{attrs} or return;
 240         foreach (keys %$x) {
 241                 $memberhash{$_} = join ' ', @{$x->{$_}};
 242                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 243         }
 244         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 245                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 246         foreach my $key (keys %mapping) {
 247                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 248                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 249                 unless (defined $data) {
 250                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 251                 }
 252                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 253         }
 254         $borrower{initials} = $memberhash{initials} ||
 255                 ( substr($borrower{'firstname'},0,1)
 256                 . substr($borrower{ 'surname' },0,1)
 257                 . " ");
 258
 259         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 260         my $dbh = C4::Context->dbh;
 261         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 262         $sth->execute( uc($borrower{'categorycode'}) );
 263         unless ( my $row = $sth->fetchrow_hashref ) {
 264                 my $default = $mapping{'categorycode'}->{content};
 265                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 266                 $borrower{'categorycode'} = $default
 267         }
 268
 269         return %borrower;
 270 }
 271
 272 sub exists_local {
 273         my $arg = shift;
 274         my $dbh = C4::Context->dbh;
 275         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 276
 277         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 278         $sth->execute($arg);
 279         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 280         ($sth->rows == 1) and return $sth->fetchrow;
 281
 282         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 283         $sth->execute($arg);
 284         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 285         ($sth->rows == 1) and return $sth->fetchrow;
 286         return 0;
 287 }
 288
 289 # This function performs a password update, given the userid, borrowerid,
 290 # and digested password. It will verify that things are correct and return the
 291 # borrowers cardnumber. The idea is that it is used to keep the local
 292 # passwords in sync with the LDAP passwords.
 293 #
 294 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 295 #
 296 # Note: if the LDAP config has the update_password tag set to a false value,
 297 # then this will not update the password, it will simply return the cardnumber.
 298 sub _do_changepassword {
 299     my ($userid, $borrowerid, $password) = @_;
 300
 301     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 302
 303         # We don't store the password in the database
 304         my $sth = C4::Context->dbh->prepare(
 305             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 306         $sth->execute($borrowerid);
 307         die "Unable to access borrowernumber "
 308             . "with userid=$userid, "
 309             . "borrowernumber=$borrowerid"
 310           if !$sth->rows;
 311         my ($cardnum) = $sth->fetchrow;
 312         $sth = C4::Context->dbh->prepare(
 313             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 314         $sth->execute($borrowerid);
 315         return $cardnum;
 316     }
 317     my $digest = hash_password($password);
 318
 319     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 320     changepassword($userid, $borrowerid, $digest);
 321
 322     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 323     return $cardnum if $ok;
 324
 325     warn "Password mismatch after update to borrowernumber=$borrowerid";
 326     return;
 327 }
 328
 329 sub update_local {
 330     my $userid     = shift or croak "No userid";
 331     my $password   = shift or croak "No password";
 332     my $borrowerid = shift or croak "No borrowerid";
 333     my $borrower   = shift or croak "No borrower record";
 334
 335     my @keys = keys %$borrower;
 336     my $dbh = C4::Context->dbh;
 337     my $query = "UPDATE  borrowers\nSET     " .
 338         join(',', map {"$_=?"} @keys) .
 339         "\nWHERE   borrowernumber=? ";
 340     my $sth = $dbh->prepare($query);
 341     if ($debug) {
 342         print STDERR $query, "\n",
 343             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 344         print STDERR "\nuserid = $userid\n";
 345     }
 346     $sth->execute(
 347         ((map {$borrower->{$_}} @keys), $borrowerid)
 348     );
 349
 350     # MODIFY PASSWORD/LOGIN if password was mapped
 351     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 352 }
 353
 354 1;
 355 __END__
 356
 357 =head1 NAME
 358
 359 C4::Auth - Authenticates Koha users
 360
 361 =head1 SYNOPSIS
 362
 363   use C4::Auth_with_ldap;
 364
 365 =head1 LDAP Configuration
 366
 367     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 368         working LDAP servers.
 369         To use it :
 370            * Modify ldapserver element in KOHA_CONF
 371            * Establish field mapping in <mapping> element.
 372
 373         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 374         the username would match the "uid" field, and the password should match the "userpassword" field.
 375
 376         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 377         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 378
 379         mysql> show COLUMNS from borrowers;
 380                 +---------------------+--------------+------+-----+---------+----------------+
 381                 | Field               | Type         | Null | Key | Default | Extra          |
 382                 +---------------------+--------------+------+-----+---------+----------------+
 383                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 384                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 385                 | surname             | mediumtext   | NO   |     | NULL    |                |
 386                 | firstname           | text         | YES  |     | NULL    |                |
 387                 | title               | mediumtext   | YES  |     | NULL    |                |
 388                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 389                 | initials            | text         | YES  |     | NULL    |                |
 390                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 391                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 392                 | address             | mediumtext   | NO   |     | NULL    |                |
 393                 | address2            | text         | YES  |     | NULL    |                |
 394                 | city                | mediumtext   | NO   |     | NULL    |                |
 395                 | state               | mediumtext   | YES  |     | NULL    |                |
 396                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 397                 | country             | text         | YES  |     | NULL    |                |
 398                 | email               | mediumtext   | YES  |     | NULL    |                |
 399                 | phone               | text         | YES  |     | NULL    |                |
 400                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 401                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 402                 | emailpro            | text         | YES  |     | NULL    |                |
 403                 | phonepro            | text         | YES  |     | NULL    |                |
 404                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 405                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 406                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 407                 | B_address2          | text         | YES  |     | NULL    |                |
 408                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 409                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 410                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 411                 | B_country           | text         | YES  |     | NULL    |                |
 412                 | B_email             | text         | YES  |     | NULL    |                |
 413                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 414                 | dateofbirth         | date         | YES  |     | NULL    |                |
 415                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 416                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 417                 | dateenrolled        | date         | YES  |     | NULL    |                |
 418                 | dateexpiry          | date         | YES  |     | NULL    |                |
 419                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 420                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 421                 | debarred            | date         | YES  |     | NULL    |                |
 422                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 423                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 424                 | contactfirstname    | text         | YES  |     | NULL    |                |
 425                 | contacttitle        | text         | YES  |     | NULL    |                |
 426                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 427                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 428                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 429                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 430                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 431                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 432                 | password            | varchar(30)  | YES  |     | NULL    |                |
 433                 | flags               | int(11)      | YES  |     | NULL    |                |
 434                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 435                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 436                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 437                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 438                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 439                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 440                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 441                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 442                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 443                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 444                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 445                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 446                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 447                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 448                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 449                 | privacy             | int(11)      | NO   |     | 1       |                |
 450                 +---------------------+--------------+------+-----+---------+----------------+
 451                 66 rows in set (0.00 sec)
 452                 Where Null="NO", the field is required.
 453
 454 =head1 KOHA_CONF and field mapping
 455
 456 Example XML stanza for LDAP configuration in KOHA_CONF.
 457
 458  <config>
 459   ...
 460   <useldapserver>1</useldapserver>
 461   <!-- LDAP SERVER (optional) -->
 462   <ldapserver id="ldapserver">
 463     <hostname>localhost</hostname>
 464     <base>dc=metavore,dc=com</base>
 465     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 466     <pass>metavore</pass>          <!-- password, if not anonymous -->
 467     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 468     <update>1</update>             <!-- update existing users in Koha database -->
 469     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 470                                         password comparison, e.g., to use Active Directory -->
 471     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 472                                             an anonymous bind, even when auth_by_bind is on -->
 473     <principal_name>%s@my_domain.com</principal_name>
 474                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 475                                         Not used with anonymous_bind. -->
 476     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 477                                               synced to the local database -->
 478     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 479       <firstname    is="givenname"      ></firstname>
 480       <surname      is="sn"             ></surname>
 481       <address      is="postaladdress"  ></address>
 482       <city         is="l"              >Athens, OH</city>
 483       <zipcode      is="postalcode"     ></zipcode>
 484       <branchcode   is="branch"         >MAIN</branchcode>
 485       <userid       is="uid"            ></userid>
 486       <password     is="userpassword"   ></password>
 487       <email        is="mail"           ></email>
 488       <categorycode is="employeetype"   >PT</categorycode>
 489       <phone        is="telephonenumber"></phone>
 490     </mapping>
 491   </ldapserver>
 492  </config>
 493
 494 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 495 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 496 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 497 patron).
 498
 499 =head1 CONFIGURATION
 500
 501 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 502 your configuration and the presence of a matching Koha user in your local DB:
 503
 504                          LOCAL_USER
 505  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 506    A1      1       1        1      OK : We're updating them anyway.
 507    A2      1       1        0      OK : We're adding them anyway.
 508    B1      1       0        1      OK : We update them.
 509    B2      1       0        0     FAIL: We cannot add new user.
 510    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 511    C2      0       1        0      OK : We add the new user.
 512    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 513    D2      0       0        0     FAIL: We cannot add new user.
 514
 515 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 516 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 517 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 518
 519 If you choose NOT to update local users, the borrowers table will not be affected at all.
 520 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 521 the local table never contained the LDAP values.
 522
 523 =head2 auth_by_bind
 524
 525 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 526
 527 =head2 principal_name
 528
 529 Provides an optional sprintf-style format for manipulating the userid before the bind.
 530 Even though the userPrincipalName is one intended target, any uniquely identifying
 531 attribute that the server allows to be used for binding could be used.
 532
 533 Currently, principal_name only operates when auth_by_bind is enabled.
 534
 535 =head2 update_password
 536
 537 If this tag is left out or set to a true value, then the user's LDAP password
 538 will be stored (hashed) in the local Koha database. If you don't want this
 539 to happen, then set the value of this to '0'. Note that if passwords are not
 540 stored locally, and the connection to the LDAP system fails, then the users
 541 will not be able to log in at all.
 542
 543 =head2 Active Directory
 544
 545 The auth_by_bind and principal_name settings are recommended for Active Directory.
 546
 547 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 548 we would typically under openldap.  Instead of:
 549
 550     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 551
 552 We might get:
 553
 554     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 555
 556 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 557 in Koha userids.  But the userPrincipalName should be consistent, something like:
 558
 559     userPrincipalName: barnes.7@my_company.com
 560
 561 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 562 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 563 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 564 like this:
 565     <principal_name>%s@core.my_company.com</principal_name>
 566
 567 The user of the previous example, barnes.7, would then attempt to bind as:
 568     barnes.7@core.my_company.com
 569
 570 =head1 SEE ALSO
 571
 572 CGI(3)
 573
 574 Net::LDAP()
 575
 576 XML::Simple()
 577
 578 Digest::MD5(3)
 579
 580 sprintf()
 581
 582 =cut
 583
 584 # For reference, here's an important difference in the data structure we rely on.
 585 # ========================================
 586 # Using attrs instead of {asn}->attributes
 587 # ========================================
 588 #
 589 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 590 #       LDAP key: ->{             cn}->{           sss} = sss
 591 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 592 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 593 #
 594 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 595 #       LDAP key: ->{      givenname}->{Steve} = Steve
 596 #