C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp qw( croak );
  22
  23 use C4::Context;
  24 use C4::Members::Messaging;
  25 use C4::Auth qw( checkpw_internal );
  26 use Koha::Patrons;
  27 use Koha::AuthUtils qw( hash_password );
  28 use Net::LDAP;
  29 use Net::LDAP::Filter;
  30
  31 our (@ISA, @EXPORT_OK);
  32 BEGIN {
  33         require Exporter;
  34         @ISA    = qw(Exporter);
  35         @EXPORT_OK = qw( checkpw_ldap );
  36 }
  37
  38 # Redefine checkpw_ldap:
  39 # connect to LDAP (named or anonymous)
  40 # ~ retrieves $userid from KOHA_CONF mapping
  41 # ~ then compares $password with userPassword
  42 # ~ then gets the LDAP entry
  43 # ~ and calls the memberadd if necessary
  44
  45 sub ldapserver_error {
  46         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  47 }
  48
  49 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  50 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  51 # since Bug 28278 we need to skip id in <ldapserver id="ldapserver"> which generates additional hash level
  52 if ( exists $ldap->{ldapserver} ) {
  53     $ldap = $ldap->{ldapserver}         or die ldapserver_error('id="ldapserver"');
  54 }
  55 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  56 my $base      = $ldap->{base}           or die ldapserver_error('base');
  57 $ldapname     = $ldap->{user}           ;
  58 $ldappassword = $ldap->{pass}           ;
  59 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  60 my @mapkeys = keys %mapping;
  61 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  62 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  63 #warn "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  64
  65 my %categorycode_conversions;
  66 my $default_categorycode;
  67 if(defined $ldap->{categorycode_mapping}) {
  68     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  69     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  70         $categorycode_conversions{$cat->{value}} = $cat->{content};
  71     }
  72 }
  73
  74 my %config = (
  75     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  76     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  77        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  78 );
  79
  80 sub description {
  81         my $result = shift or return;
  82         return "LDAP error #" . $result->code
  83                         . ": " . $result->error_name . "\n"
  84                         . "# " . $result->error_text . "\n";
  85 }
  86
  87 sub search_method {
  88     my $db     = shift or return;
  89     my $userid = shift or return;
  90         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  91         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  92         my $search = $db->search(
  93                   base => $base,
  94                 filter => $filter,
  95                 # attrs => ['*'],
  96     );
  97     die "LDAP search failed to return object : " . $search->error if $search->code;
  98
  99         my $count = $search->count;
 100         if ($search->code > 0) {
 101                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 102                 return 0;
 103         }
 104     if ($count == 0) {
 105         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 106         return 0;
 107     }
 108     return $search;
 109 }
 110
 111 sub checkpw_ldap {
 112     my ($dbh, $userid, $password) = @_;
 113     my @hosts = split(',', $prefhost);
 114     my $db = Net::LDAP->new(\@hosts);
 115     unless ( $db ) {
 116         warn "LDAP connexion failed";
 117         return 0;
 118     }
 119
 120     my $userldapentry;
 121
 122     # first, LDAP authentication
 123     if ( $ldap->{auth_by_bind} ) {
 124         my $principal_name;
 125         if ( $config{anonymous} ) {
 126
 127             # Perform an anonymous bind
 128             my $res = $db->bind;
 129             if ( $res->code ) {
 130                 warn "Anonymous LDAP bind failed: " . description($res);
 131                 return 0;
 132             }
 133
 134             # Perform a LDAP search for the given username
 135             my $search = search_method( $db, $userid )
 136               or return 0;    # warnings are in the sub
 137             $userldapentry = $search->shift_entry;
 138             $principal_name = $userldapentry->dn;
 139         }
 140         else {
 141             $principal_name = $ldap->{principal_name};
 142             if ( $principal_name and $principal_name =~ /\%/ ) {
 143                 $principal_name = sprintf( $principal_name, $userid );
 144             }
 145             else {
 146                 $principal_name = $userid;
 147             }
 148         }
 149
 150         # Perform a LDAP bind for the given username using the matched DN
 151         my $res = $db->bind( $principal_name, password => $password );
 152         if ( $res->code ) {
 153             if ( $config{anonymous} ) {
 154                 # With anonymous_bind approach we can be sure we have found the correct user
 155                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 156                 # or password changed). We should not fall back to local accounts in this case.
 157                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 158                 return -1;
 159             } else {
 160                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 161                 # at all, and thus we should fall back to local logins to restore previous behaviour
 162                 # see bug 12831
 163                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 164                 return 0;
 165             }
 166         }
 167         if ( !defined($userldapentry)
 168             && ( $config{update} or $config{replicate} ) )
 169         {
 170             my $search = search_method( $db, $userid ) or return 0;
 171             $userldapentry = $search->shift_entry;
 172         }
 173     } else {
 174         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 175                 if ($res->code) {               # connection refused
 176                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 177                         return 0;
 178                 }
 179         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 180         # Handle multiple branches. Same login exists several times in different branches.
 181         my $bind_ok = 0;
 182         while (my $entry = $search->shift_entry) {
 183             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 184             unless ($user_ldap_bind_ret->code) {
 185                 $userldapentry = $entry;
 186                 $bind_ok = 1;
 187                 last;
 188             }
 189         }
 190
 191         unless ($bind_ok) {
 192             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 193             return -1;
 194         }
 195
 196
 197     }
 198
 199     # To get here, LDAP has accepted our user's login attempt.
 200     # But we still have work to do.  See perldoc below for detailed breakdown.
 201
 202     my (%borrower);
 203         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 204
 205     if (( $borrowernumber and $config{update}   ) or
 206         (!$borrowernumber and $config{replicate})   ) {
 207         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 208         #warn "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 209     }
 210
 211     if ($borrowernumber) {
 212         if ($config{update}) { # A1, B1
 213             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 214             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 215         } else { # C1, D1
 216             # maybe update just the password?
 217                 return(1, $cardnumber, $local_userid);
 218         }
 219     } elsif ($config{replicate}) { # A2, C2
 220         my @columns = Koha::Patrons->columns;
 221         my $patron = Koha::Patron->new(
 222             {
 223                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 224             }
 225         )->store;
 226         die "Insert of new patron failed" unless $patron;
 227         $borrowernumber = $patron->borrowernumber;
 228         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 229    } else {
 230         return 0;   # B2, D2
 231     }
 232     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 233         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 234         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 235         while ( my $attribute_type = $attribute_types->next ) {
 236             my $code = $attribute_type->code;
 237             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 238                 next;
 239             }
 240             my $patron = Koha::Patrons->find($borrowernumber);
 241             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 242                 eval {
 243                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 244                     $patron->extended_attributes([$attribute->unblessed]);
 245                 };
 246                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 247                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 248                 }
 249             }
 250         }
 251     }
 252     return(1, $cardnumber, $userid);
 253 }
 254
 255 # Pass LDAP entry object and local cardnumber (userid).
 256 # Returns borrower hash.
 257 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 258 # Ensure that mandatory fields are correctly filled!
 259 #
 260 sub ldap_entry_2_hash {
 261         my $userldapentry = shift;
 262         my %borrower = ( cardnumber => shift );
 263         my %memberhash;
 264         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 265     #foreach (keys %$userldapentry) {
 266     #    print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 267     #}
 268         my $x = $userldapentry->{attrs} or return;
 269         foreach (keys %$x) {
 270                 $memberhash{$_} = join ' ', @{$x->{$_}};
 271         #warn sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 272         }
 273     #warn "Finished \%memberhash has ", scalar(keys %memberhash), " keys\n", "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 274         foreach my $key (keys %mapping) {
 275                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 276         #warn "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 277                 unless (defined $data) {
 278             $data = $mapping{$key}->{content} || undef;
 279                 }
 280         $borrower{$key} = $data;
 281         }
 282         $borrower{initials} = $memberhash{initials} ||
 283                 ( substr($borrower{'firstname'},0,1)
 284                 . substr($borrower{ 'surname' },0,1)
 285                 . " ");
 286
 287     # categorycode conversions
 288     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 289         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 290     }
 291     elsif($default_categorycode) {
 292         $borrower{categorycode} = $default_categorycode;
 293     }
 294
 295         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 296         my $dbh = C4::Context->dbh;
 297         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 298         $sth->execute( uc($borrower{'categorycode'}) );
 299         unless ( my $row = $sth->fetchrow_hashref ) {
 300                 my $default = $mapping{'categorycode'}->{content};
 301         #warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 302                 $borrower{'categorycode'} = $default
 303         }
 304
 305         return %borrower;
 306 }
 307
 308 sub exists_local {
 309         my $arg = shift;
 310         my $dbh = C4::Context->dbh;
 311         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 312
 313         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 314         $sth->execute($arg);
 315     #warn "Userid '$arg' exists_local? %s\n", $sth->rows;
 316         ($sth->rows == 1) and return $sth->fetchrow;
 317
 318         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 319         $sth->execute($arg);
 320     #warn "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 321         ($sth->rows == 1) and return $sth->fetchrow;
 322         return 0;
 323 }
 324
 325 # This function performs a password update, given the userid, borrowerid,
 326 # and digested password. It will verify that things are correct and return the
 327 # borrowers cardnumber. The idea is that it is used to keep the local
 328 # passwords in sync with the LDAP passwords.
 329 #
 330 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 331 #
 332 # Note: if the LDAP config has the update_password tag set to a false value,
 333 # then this will not update the password, it will simply return the cardnumber.
 334 sub _do_changepassword {
 335     my ($userid, $borrowerid, $password) = @_;
 336
 337     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 338
 339         # We don't store the password in the database
 340         my $sth = C4::Context->dbh->prepare(
 341             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 342         $sth->execute($borrowerid);
 343         die "Unable to access borrowernumber "
 344             . "with userid=$userid, "
 345             . "borrowernumber=$borrowerid"
 346           if !$sth->rows;
 347         my ($cardnum) = $sth->fetchrow;
 348         $sth = C4::Context->dbh->prepare(
 349             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 350         $sth->execute($borrowerid);
 351         return $cardnum;
 352     }
 353
 354     my $digest = hash_password($password);
 355     #warn "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 356     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 357
 358     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 359     return $cardnum if $ok;
 360
 361     warn "Password mismatch after update to borrowernumber=$borrowerid";
 362     return;
 363 }
 364
 365 sub update_local {
 366     my $userid     = shift or croak "No userid";
 367     my $password   = shift or croak "No password";
 368     my $borrowerid = shift or croak "No borrowerid";
 369     my $borrower   = shift or croak "No borrower record";
 370
 371     # skip extended patron attributes in 'borrowers' attribute update
 372     my @keys = keys %$borrower;
 373     if (C4::Context->preference('ExtendedPatronAttributes')) {
 374         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 375         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 376         while ( my $attribute_type = $attribute_types->next ) {
 377            my $code = $attribute_type->code;
 378            @keys = grep { $_ ne $code } @keys;
 379            #warn "ignoring extended patron attribute '%s' in update_local()\n", $code;
 380         }
 381     }
 382
 383     my $dbh = C4::Context->dbh;
 384     my $query = "UPDATE  borrowers\nSET     " .
 385         join(',', map {"$_=?"} @keys) .
 386         "\nWHERE   borrowernumber=? ";
 387     my $sth = $dbh->prepare($query);
 388     #warn $query, "\n", join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 389     #warn "\nuserid = $userid\n";
 390     $sth->execute(
 391         ((map {$borrower->{$_}} @keys), $borrowerid)
 392     );
 393
 394     # MODIFY PASSWORD/LOGIN if password was mapped
 395     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 396 }
 397
 398 1;
 399 __END__
 400
 401 =head1 NAME
 402
 403 C4::Auth - Authenticates Koha users
 404
 405 =head1 SYNOPSIS
 406
 407   use C4::Auth_with_ldap;
 408
 409 =head1 LDAP Configuration
 410
 411     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 412         working LDAP servers.
 413         To use it :
 414            * Modify ldapserver element in KOHA_CONF
 415            * Establish field mapping in <mapping> element.
 416
 417         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 418         the username would match the "uid" field, and the password should match the "userpassword" field.
 419
 420         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 421         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 422
 423         mysql> show COLUMNS from borrowers;
 424                 +---------------------+--------------+------+-----+---------+----------------+
 425                 | Field               | Type         | Null | Key | Default | Extra          |
 426                 +---------------------+--------------+------+-----+---------+----------------+
 427                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 428                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 429                 | surname             | mediumtext   | NO   |     | NULL    |                |
 430                 | firstname           | text         | YES  |     | NULL    |                |
 431                 | title               | mediumtext   | YES  |     | NULL    |                |
 432                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 433                 | initials            | text         | YES  |     | NULL    |                |
 434                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 435                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 436                 | address             | mediumtext   | NO   |     | NULL    |                |
 437                 | address2            | text         | YES  |     | NULL    |                |
 438                 | city                | mediumtext   | NO   |     | NULL    |                |
 439                 | state               | mediumtext   | YES  |     | NULL    |                |
 440                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 441                 | country             | text         | YES  |     | NULL    |                |
 442                 | email               | mediumtext   | YES  |     | NULL    |                |
 443                 | phone               | text         | YES  |     | NULL    |                |
 444                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 445                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 446                 | emailpro            | text         | YES  |     | NULL    |                |
 447                 | phonepro            | text         | YES  |     | NULL    |                |
 448                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 449                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 450                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 451                 | B_address2          | text         | YES  |     | NULL    |                |
 452                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 453                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 454                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 455                 | B_country           | text         | YES  |     | NULL    |                |
 456                 | B_email             | text         | YES  |     | NULL    |                |
 457                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 458                 | dateofbirth         | date         | YES  |     | NULL    |                |
 459                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 460                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 461                 | dateenrolled        | date         | YES  |     | NULL    |                |
 462                 | dateexpiry          | date         | YES  |     | NULL    |                |
 463                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 464                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 465                 | debarred            | date         | YES  |     | NULL    |                |
 466                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 467                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 468                 | contactfirstname    | text         | YES  |     | NULL    |                |
 469                 | contacttitle        | text         | YES  |     | NULL    |                |
 470                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 471                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 472                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 473                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 474                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 475                 | password            | varchar(30)  | YES  |     | NULL    |                |
 476                 | flags               | int(11)      | YES  |     | NULL    |                |
 477                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 478                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 479                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 480                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 481                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 482                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 483                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 484                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 485                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 486                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 487                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 488                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 489                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 490                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 491                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 492                 | privacy             | int(11)      | NO   |     | 1       |                |
 493                 +---------------------+--------------+------+-----+---------+----------------+
 494                 66 rows in set (0.00 sec)
 495                 Where Null="NO", the field is required.
 496
 497 =head1 KOHA_CONF and field mapping
 498
 499 Example XML stanza for LDAP configuration in KOHA_CONF.
 500
 501  <config>
 502   ...
 503   <useldapserver>1</useldapserver>
 504   <!-- LDAP SERVER (optional) -->
 505   <ldapserver id="ldapserver">
 506     <hostname>localhost</hostname>
 507     <base>dc=metavore,dc=com</base>
 508     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 509     <pass>metavore</pass>          <!-- password, if not anonymous -->
 510     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 511     <update>1</update>             <!-- update existing users in Koha database -->
 512     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 513                                         password comparison, e.g., to use Active Directory -->
 514     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 515                                             an anonymous bind, even when auth_by_bind is on -->
 516     <principal_name>%s@my_domain.com</principal_name>
 517                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 518                                         Not used with anonymous_bind. -->
 519     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 520                                               synced to the local database -->
 521     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 522       <firstname    is="givenname"      ></firstname>
 523       <surname      is="sn"             ></surname>
 524       <address      is="postaladdress"  ></address>
 525       <city         is="l"              >Athens, OH</city>
 526       <zipcode      is="postalcode"     ></zipcode>
 527       <branchcode   is="branch"         >MAIN</branchcode>
 528       <userid       is="uid"            ></userid>
 529       <password     is="userpassword"   ></password>
 530       <email        is="mail"           ></email>
 531       <categorycode is="employeetype"   >PT</categorycode>
 532       <phone        is="telephonenumber"></phone>
 533     </mapping>
 534   </ldapserver>
 535  </config>
 536
 537 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 538 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 539 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 540 patron).
 541
 542 =head1 CONFIGURATION
 543
 544 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 545 your configuration and the presence of a matching Koha user in your local DB:
 546
 547                          LOCAL_USER
 548  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 549    A1      1       1        1      OK : We're updating them anyway.
 550    A2      1       1        0      OK : We're adding them anyway.
 551    B1      1       0        1      OK : We update them.
 552    B2      1       0        0     FAIL: We cannot add new user.
 553    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 554    C2      0       1        0      OK : We add the new user.
 555    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 556    D2      0       0        0     FAIL: We cannot add new user.
 557
 558 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 559 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 560 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 561
 562 If you choose NOT to update local users, the borrowers table will not be affected at all.
 563 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 564 the local table never contained the LDAP values.
 565
 566 =head2 auth_by_bind
 567
 568 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 569
 570 =head2 principal_name
 571
 572 Provides an optional sprintf-style format for manipulating the userid before the bind.
 573 Even though the userPrincipalName is one intended target, any uniquely identifying
 574 attribute that the server allows to be used for binding could be used.
 575
 576 Currently, principal_name only operates when auth_by_bind is enabled.
 577
 578 =head2 update_password
 579
 580 If this tag is left out or set to a true value, then the user's LDAP password
 581 will be stored (hashed) in the local Koha database. If you don't want this
 582 to happen, then set the value of this to '0'. Note that if passwords are not
 583 stored locally, and the connection to the LDAP system fails, then the users
 584 will not be able to log in at all.
 585
 586 =head2 Active Directory
 587
 588 The auth_by_bind and principal_name settings are recommended for Active Directory.
 589
 590 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 591 we would typically under openldap.  Instead of:
 592
 593     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 594
 595 We might get:
 596
 597     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 598
 599 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 600 in Koha userids.  But the userPrincipalName should be consistent, something like:
 601
 602     userPrincipalName: barnes.7@my_company.com
 603
 604 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 605 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 606 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 607 like this:
 608     <principal_name>%s@core.my_company.com</principal_name>
 609
 610 The user of the previous example, barnes.7, would then attempt to bind as:
 611     barnes.7@core.my_company.com
 612
 613 =head1 SEE ALSO
 614
 615 CGI(3)
 616
 617 Net::LDAP()
 618
 619 XML::Simple()
 620
 621 Digest::MD5(3)
 622
 623 sprintf()
 624
 625 =cut
 626
 627 # For reference, here's an important difference in the data structure we rely on.
 628 # ========================================
 629 # Using attrs instead of {asn}->attributes
 630 # ========================================
 631 #
 632 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 633 #       LDAP key: ->{             cn}->{           sss} = sss
 634 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 635 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 636 #
 637 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 638 #       LDAP key: ->{      givenname}->{Steve} = Steve
 639 #