C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Digest::MD5 qw(md5_base64);
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Utils qw( :all );
  30 use List::MoreUtils qw( any );
  31 use Net::LDAP;
  32 use Net::LDAP::Filter;
  33
  34 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  35
  36 BEGIN {
  37         require Exporter;
  38     $VERSION = 3.07.00.049;     # set the version for version checking
  39         @ISA    = qw(Exporter);
  40         @EXPORT = qw( checkpw_ldap );
  41 }
  42
  43 # Redefine checkpw_ldap:
  44 # connect to LDAP (named or anonymous)
  45 # ~ retrieves $userid from KOHA_CONF mapping
  46 # ~ then compares $password with userPassword
  47 # ~ then gets the LDAP entry
  48 # ~ and calls the memberadd if necessary
  49
  50 sub ldapserver_error {
  51         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  52 }
  53
  54 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  55 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  56 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  57 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  58 my $base      = $ldap->{base}           or die ldapserver_error('base');
  59 $ldapname     = $ldap->{user}           ;
  60 $ldappassword = $ldap->{pass}           ;
  61 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  62 my @mapkeys = keys %mapping;
  63 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  64 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  66
  67 my %config = (
  68         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  69     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  70        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  71 );
  72
  73 sub description {
  74         my $result = shift or return;
  75         return "LDAP error #" . $result->code
  76                         . ": " . $result->error_name . "\n"
  77                         . "# " . $result->error_text . "\n";
  78 }
  79
  80 sub search_method {
  81     my $db     = shift or return;
  82     my $userid = shift or return;
  83         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  84         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  85         my $search = $db->search(
  86                   base => $base,
  87                 filter => $filter,
  88                 # attrs => ['*'],
  89         ) or die "LDAP search failed to return object.";
  90         my $count = $search->count;
  91         if ($search->code > 0) {
  92                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  93                 return 0;
  94         }
  95         if ($count != 1) {
  96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
  97                 return 0;
  98         }
  99     return $search;
 100 }
 101
 102 sub checkpw_ldap {
 103     my ($dbh, $userid, $password) = @_;
 104     my @hosts = split(',', $prefhost);
 105     my $db = Net::LDAP->new(\@hosts);
 106         #$debug and $db->debug(5);
 107     my $userldapentry;
 108         if ( $ldap->{auth_by_bind} ) {
 109         my $principal_name = $ldap->{principal_name};
 110         if ($principal_name and $principal_name =~ /\%/) {
 111             $principal_name = sprintf($principal_name,$userid);
 112         } else {
 113             $principal_name = $userid;
 114         }
 115                 my $res = $db->bind( $principal_name, password => $password );
 116         if ( $res->code ) {
 117             $debug and warn "LDAP bind failed as kohauser $principal_name: ". description($res);
 118             return 0;
 119         }
 120
 121         # FIXME dpavlin -- we really need $userldapentry leater on even if using auth_by_bind!
 122
 123         # BUG #5094
 124         # 2010-08-04 JeremyC
 125         # a $userldapentry is only needed if either updating or replicating are enabled
 126         if($config{update} or $config{replicate}) {
 127             my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 128             $userldapentry = $search->shift_entry;
 129         }
 130
 131         } else {
 132                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 133                 if ($res->code) {               # connection refused
 134                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 135                         return 0;
 136                 }
 137         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 138         $userldapentry = $search->shift_entry;
 139                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 140                 if ($cmpmesg->code != 6) {
 141                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 142                         return 0;
 143                 }
 144         }
 145
 146     # To get here, LDAP has accepted our user's login attempt.
 147     # But we still have work to do.  See perldoc below for detailed breakdown.
 148
 149     my (%borrower);
 150         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 151
 152     if (( $borrowernumber and $config{update}   ) or
 153         (!$borrowernumber and $config{replicate})   ) {
 154         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 155         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 156     }
 157
 158     if ($borrowernumber) {
 159         if ($config{update}) { # A1, B1
 160             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 161             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 162         } else { # C1, D1
 163             # maybe update just the password?
 164                 return(1, $cardnumber, $local_userid);
 165         }
 166     } elsif ($config{replicate}) { # A2, C2
 167         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 168    } else {
 169         return 0;   # B2, D2
 170     }
 171         if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 172         my $extended_patron_attributes;
 173         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 174                 my $code = $attribute_type->{code};
 175                 if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
 176                         push @$extended_patron_attributes, { code => $code, value => $borrower{$code} };
 177                 }
 178         }
 179                 my @errors;
 180                 #Check before add
 181                 for (my $i; $i< scalar(@$extended_patron_attributes)-1;$i++) {
 182                         my $attr=$extended_patron_attributes->[$i];
 183                         unless (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 184                                 unshift @errors, $i;
 185                                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 186                         }
 187                 }
 188                 #Removing erroneous attributes
 189                 foreach my $index (@errors){
 190                         @$extended_patron_attributes=splice(@$extended_patron_attributes,$index,1);
 191                 }
 192            C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, $extended_patron_attributes);
 193         }
 194 return(1, $cardnumber, $userid);
 195 }
 196
 197 # Pass LDAP entry object and local cardnumber (userid).
 198 # Returns borrower hash.
 199 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 200 # Ensure that mandatory fields are correctly filled!
 201 #
 202 sub ldap_entry_2_hash {
 203         my $userldapentry = shift;
 204         my %borrower = ( cardnumber => shift );
 205         my %memberhash;
 206         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 207         if ($debug) {
 208                 print STDERR "\nkeys(\%\$userldapentry) = " . join(', ', keys %$userldapentry), "\n", $userldapentry->dump();
 209                 foreach (keys %$userldapentry) {
 210                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 211                         hashdump("LDAP key: ",$userldapentry->{$_});
 212                 }
 213         }
 214         my $x = $userldapentry->{attrs} or return;
 215         foreach (keys %$x) {
 216                 $memberhash{$_} = join ' ', @{$x->{$_}};
 217                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 218         }
 219         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 220                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 221         foreach my $key (keys %mapping) {
 222                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 223                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 224                 unless (defined $data) {
 225                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 226                 }
 227                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 228         }
 229         $borrower{initials} = $memberhash{initials} ||
 230                 ( substr($borrower{'firstname'},0,1)
 231                 . substr($borrower{ 'surname' },0,1)
 232                 . " ");
 233
 234         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 235         my $dbh = C4::Context->dbh;
 236         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 237         $sth->execute( uc($borrower{'categorycode'}) );
 238         unless ( my $row = $sth->fetchrow_hashref ) {
 239                 my $default = $mapping{'categorycode'}->{content};
 240                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 241                 $borrower{'categorycode'} = $default
 242         }
 243
 244         return %borrower;
 245 }
 246
 247 sub exists_local {
 248         my $arg = shift;
 249         my $dbh = C4::Context->dbh;
 250         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 251
 252         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 253         $sth->execute($arg);
 254         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 255         ($sth->rows == 1) and return $sth->fetchrow;
 256
 257         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 258         $sth->execute($arg);
 259         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 260         ($sth->rows == 1) and return $sth->fetchrow;
 261         return 0;
 262 }
 263
 264 sub _do_changepassword {
 265     my ($userid, $borrowerid, $digest) = @_;
 266     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 267     changepassword($userid, $borrowerid, $digest);
 268
 269         # Confirm changes
 270         my $sth = C4::Context->dbh->prepare("SELECT password,cardnumber FROM borrowers WHERE borrowernumber=? ");
 271         $sth->execute($borrowerid);
 272         if ($sth->rows) {
 273                 my ($md5password, $cardnum) = $sth->fetchrow;
 274         ($digest eq $md5password) and return $cardnum;
 275                 warn "Password mismatch after update to cardnumber=$cardnum (borrowernumber=$borrowerid)";
 276                 return;
 277         }
 278         die "Unexpected error after password update to userid/borrowernumber: $userid / $borrowerid.";
 279 }
 280
 281 sub update_local {
 282         my   $userid   = shift             or return;
 283         my   $digest   = md5_base64(shift) or return;
 284         my $borrowerid = shift             or return;
 285         my $borrower   = shift             or return;
 286         my @keys = keys %$borrower;
 287         my $dbh = C4::Context->dbh;
 288         my $query = "UPDATE  borrowers\nSET     " .
 289                 join(',', map {"$_=?"} @keys) .
 290                 "\nWHERE   borrowernumber=? ";
 291         my $sth = $dbh->prepare($query);
 292         if ($debug) {
 293                 print STDERR $query, "\n",
 294                         join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 295                 print STDERR "\nuserid = $userid\n";
 296         }
 297         $sth->execute(
 298                 ((map {$borrower->{$_}} @keys), $borrowerid)
 299         );
 300
 301         # MODIFY PASSWORD/LOGIN
 302         _do_changepassword($userid, $borrowerid, $digest);
 303 }
 304
 305 1;
 306 __END__
 307
 308 =head1 NAME
 309
 310 C4::Auth - Authenticates Koha users
 311
 312 =head1 SYNOPSIS
 313
 314   use C4::Auth_with_ldap;
 315
 316 =head1 LDAP Configuration
 317
 318     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 319         working LDAP servers.
 320         To use it :
 321            * Modify ldapserver element in KOHA_CONF
 322            * Establish field mapping in <mapping> element.
 323
 324         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 325         the username would match the "uid" field, and the password should match the "userpassword" field.
 326
 327         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 328         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 329
 330         mysql> show COLUMNS from borrowers;
 331                 +---------------------+--------------+------+-----+---------+----------------+
 332                 | Field               | Type         | Null | Key | Default | Extra          |
 333                 +---------------------+--------------+------+-----+---------+----------------+
 334                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 335                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 336                 | surname             | mediumtext   | NO   |     | NULL    |                |
 337                 | firstname           | text         | YES  |     | NULL    |                |
 338                 | title               | mediumtext   | YES  |     | NULL    |                |
 339                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 340                 | initials            | text         | YES  |     | NULL    |                |
 341                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 342                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 343                 | address             | mediumtext   | NO   |     | NULL    |                |
 344                 | address2            | text         | YES  |     | NULL    |                |
 345                 | city                | mediumtext   | NO   |     | NULL    |                |
 346                 | state               | mediumtext   | YES  |     | NULL    |                |
 347                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 348                 | country             | text         | YES  |     | NULL    |                |
 349                 | email               | mediumtext   | YES  |     | NULL    |                |
 350                 | phone               | text         | YES  |     | NULL    |                |
 351                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 352                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 353                 | emailpro            | text         | YES  |     | NULL    |                |
 354                 | phonepro            | text         | YES  |     | NULL    |                |
 355                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 356                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 357                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 358                 | B_address2          | text         | YES  |     | NULL    |                |
 359                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 360                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 361                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 362                 | B_country           | text         | YES  |     | NULL    |                |
 363                 | B_email             | text         | YES  |     | NULL    |                |
 364                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 365                 | dateofbirth         | date         | YES  |     | NULL    |                |
 366                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 367                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 368                 | dateenrolled        | date         | YES  |     | NULL    |                |
 369                 | dateexpiry          | date         | YES  |     | NULL    |                |
 370                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 371                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 372                 | debarred            | date         | YES  |     | NULL    |                |
 373                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 374                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 375                 | contactfirstname    | text         | YES  |     | NULL    |                |
 376                 | contacttitle        | text         | YES  |     | NULL    |                |
 377                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 378                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 379                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 380                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 381                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 382                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 383                 | password            | varchar(30)  | YES  |     | NULL    |                |
 384                 | flags               | int(11)      | YES  |     | NULL    |                |
 385                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 386                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 387                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 388                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 389                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 390                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 391                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 392                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 393                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 394                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 395                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 396                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 397                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 398                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 399                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 400                 | privacy             | int(11)      | NO   |     | 1       |                |
 401                 +---------------------+--------------+------+-----+---------+----------------+
 402                 66 rows in set (0.00 sec)
 403                 Where Null="NO", the field is required.
 404
 405 =head1 KOHA_CONF and field mapping
 406
 407 Example XML stanza for LDAP configuration in KOHA_CONF.
 408
 409  <config>
 410   ...
 411   <useldapserver>1</useldapserver>
 412   <!-- LDAP SERVER (optional) -->
 413   <ldapserver id="ldapserver">
 414     <hostname>localhost</hostname>
 415     <base>dc=metavore,dc=com</base>
 416     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 417     <pass>metavore</pass>          <!-- password, if not anonymous -->
 418     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 419     <update>1</update>             <!-- update existing users in Koha database -->
 420     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 421                                         password comparison, e.g., to use Active Directory -->
 422     <principal_name>%s@my_domain.com</principal_name>
 423                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid -->
 424     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 425       <firstname    is="givenname"      ></firstname>
 426       <surname      is="sn"             ></surname>
 427       <address      is="postaladdress"  ></address>
 428       <city         is="l"              >Athens, OH</city>
 429       <zipcode      is="postalcode"     ></zipcode>
 430       <branchcode   is="branch"         >MAIN</branchcode>
 431       <userid       is="uid"            ></userid>
 432       <password     is="userpassword"   ></password>
 433       <email        is="mail"           ></email>
 434       <categorycode is="employeetype"   >PT</categorycode>
 435       <phone        is="telephonenumber"></phone>
 436     </mapping>
 437   </ldapserver>
 438  </config>
 439
 440 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 441 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 442 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 443 patron).
 444
 445 =head1 CONFIGURATION
 446
 447 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 448 your configuration and the presence of a matching Koha user in your local DB:
 449
 450                          LOCAL_USER
 451  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 452    A1      1       1        1      OK : We're updating them anyway.
 453    A2      1       1        0      OK : We're adding them anyway.
 454    B1      1       0        1      OK : We update them.
 455    B2      1       0        0     FAIL: We cannot add new user.
 456    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 457    C2      0       1        0      OK : We add the new user.
 458    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 459    D2      0       0        0     FAIL: We cannot add new user.
 460
 461 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 462 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 463 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 464
 465 If you choose NOT to update local users, the borrowers table will not be affected at all.
 466 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 467 the local table never contained the LDAP values.
 468
 469 =head2 auth_by_bind
 470
 471 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 472
 473 =head2 principal_name
 474
 475 Provides an optional sprintf-style format for manipulating the userid before the bind.
 476 Even though the userPrincipalName is one intended target, any uniquely identifying
 477 attribute that the server allows to be used for binding could be used.
 478
 479 Currently, principal_name only operates when auth_by_bind is enabled.
 480
 481 =head2 Active Directory
 482
 483 The auth_by_bind and principal_name settings are recommended for Active Directory.
 484
 485 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 486 we would typically under openldap.  Instead of:
 487
 488     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 489
 490 We might get:
 491
 492     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 493
 494 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 495 in Koha userids.  But the userPrincipalName should be consistent, something like:
 496
 497     userPrincipalName: barnes.7@my_company.com
 498
 499 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 500 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 501 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 502 like this:
 503     <principal_name>%s@core.my_company.com</principal_name>
 504
 505 The user of the previous example, barnes.7, would then attempt to bind as:
 506     barnes.7@core.my_company.com
 507
 508 =head1 SEE ALSO
 509
 510 CGI(3)
 511
 512 Net::LDAP()
 513
 514 XML::Simple()
 515
 516 Digest::MD5(3)
 517
 518 sprintf()
 519
 520 =cut
 521
 522 # For reference, here's an important difference in the data structure we rely on.
 523 # ========================================
 524 # Using attrs instead of {asn}->attributes
 525 # ========================================
 526 #
 527 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 528 #       LDAP key: ->{             cn}->{           sss} = sss
 529 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 530 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 531 #
 532 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 533 #       LDAP key: ->{      givenname}->{Steve} = Steve
 534 #