C4/Auth_with_shibboleth.pm

   1 package C4::Auth_with_shibboleth;
   2
   3 # Copyright 2014 PTFS Europe
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use C4::Debug;
  23 use C4::Context;
  24 use Koha::AuthUtils qw(get_script_name);
  25 use Koha::Database;
  26 use Koha::Patrons;
  27 use C4::Members::Messaging;
  28 use Carp;
  29 use CGI;
  30 use List::Util qw(any);
  31
  32 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  33
  34 BEGIN {
  35     require Exporter;
  36     $debug   = $ENV{DEBUG};
  37     @ISA     = qw(Exporter);
  38     @EXPORT =
  39       qw(shib_ok logout_shib login_shib_url checkpw_shib get_login_shib);
  40 }
  41
  42 # Check that shib config is not malformed
  43 sub shib_ok {
  44     my $config = _get_shib_config();
  45
  46     if ($config) {
  47         return 1;
  48     }
  49
  50     return 0;
  51 }
  52
  53 # Logout from Shibboleth
  54 sub logout_shib {
  55     my ($query) = @_;
  56     my $uri = _get_uri();
  57     print $query->redirect( $uri . "/Shibboleth.sso/Logout?return=$uri" );
  58 }
  59
  60 # Returns Shibboleth login URL with callback to the requesting URL
  61 sub login_shib_url {
  62     my ($query) = @_;
  63
  64     my $param = _get_uri() . get_script_name();
  65     if ( $query->query_string() ) {
  66         $param = $param . '%3F' . $query->query_string();
  67     }
  68     my $uri = _get_uri() . "/Shibboleth.sso/Login?target=$param";
  69     return $uri;
  70 }
  71
  72 # Returns shibboleth user login
  73 sub get_login_shib {
  74
  75 # In case of a Shibboleth authentication, we expect a shibboleth user attribute
  76 # to contain the login match point of the shibboleth-authenticated user. This match
  77 # point is configured in koha-conf.xml
  78
  79 # Shibboleth attributes are mapped into http environmement variables, so we're getting
  80 # the match point of the user this way
  81
  82     # Get shibboleth config
  83     my $config = _get_shib_config();
  84
  85     my $matchAttribute = $config->{mapping}->{ $config->{matchpoint} }->{is};
  86
  87     if ( any { /(^psgi|^plack)/i } keys %ENV ) {
  88       $debug and warn $matchAttribute . " value: " . $ENV{"HTTP_".uc($matchAttribute)};
  89       return $ENV{"HTTP_".uc($matchAttribute)} || '';
  90     } else {
  91       $debug and warn $matchAttribute . " value: " . $ENV{$matchAttribute};
  92       return $ENV{$matchAttribute} || '';
  93     }
  94 }
  95
  96 # Checks for password correctness
  97 # In our case : does the given attribute match one of our users ?
  98 sub checkpw_shib {
  99     $debug and warn "checkpw_shib";
 100
 101     my ( $match ) = @_;
 102     my $config = _get_shib_config();
 103     $debug and warn "User Shibboleth-authenticated as: $match";
 104
 105     # Does the given shibboleth attribute value ($match) match a valid koha user ?
 106     my $borrower =
 107       Koha::Database->new()->schema()->resultset('Borrower')
 108       ->find( { $config->{matchpoint} => $match } );
 109     if ( defined($borrower) ) {
 110         return ( 1, $borrower->get_column('cardnumber'), $borrower->get_column('userid') );
 111     }
 112
 113     if ( $config->{'autocreate'} ) {
 114         return _autocreate( $config, $match );
 115     } else {
 116         # If we reach this point, the user is not a valid koha user
 117          $debug and warn "User with $config->{matchpoint} of $match is not a valid Koha user";
 118         return 0;
 119     }
 120 }
 121
 122 sub _autocreate {
 123     my ( $config, $match ) = @_;
 124
 125     my %borrower = ( $config->{matchpoint} => $match );
 126
 127     while ( my ( $key, $entry ) = each %{$config->{'mapping'}} ) {
 128         $borrower{$key} = ( $entry->{'is'} && $ENV{ $entry->{'is'} } ) || $entry->{'content'} || '';
 129     }
 130
 131     my $patron = Koha::Patron->new( \%borrower )->store;
 132     C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $patron->borrowernumber, categorycode => $patron->categorycode } );
 133
 134     return ( 1, $patron->cardnumber, $patron->userid );
 135 }
 136
 137 sub _get_uri {
 138
 139     my $protocol = "https://";
 140     my $interface = C4::Context->interface;
 141     $debug and warn "shibboleth interface: " . $interface;
 142
 143     my $uri;
 144     if ( $interface eq 'intranet' ) {
 145
 146         $uri = C4::Context->preference('staffClientBaseURL') // '';
 147         if ($uri eq '') {
 148             $debug and warn 'staffClientBaseURL not set!';
 149         }
 150     } else {
 151         $uri = C4::Context->preference('OPACBaseURL') // '';
 152         if ($uri eq '') {
 153             $debug and warn 'OPACBaseURL not set!';
 154         }
 155     }
 156
 157     if ($uri =~ /(.*):\/\/(.*)/) {
 158         my $oldprotocol = $1;
 159         if ($oldprotocol ne 'https') {
 160             $debug
 161                 and warn
 162                   'Shibboleth requires OPACBaseURL/staffClientBaseURL to use the https protocol!';
 163         }
 164         $uri = $2;
 165     }
 166     my $return = $protocol . $uri;
 167     return $return;
 168 }
 169
 170 sub _get_shib_config {
 171     my $config = C4::Context->config('shibboleth');
 172
 173     if ( !$config ) {
 174         carp 'shibboleth config not defined';
 175         return 0;
 176     }
 177
 178     if ( $config->{matchpoint}
 179         && defined( $config->{mapping}->{ $config->{matchpoint} }->{is} ) )
 180     {
 181         if ($debug) {
 182             warn "koha borrower field to match: " . $config->{matchpoint};
 183             warn "shibboleth attribute to match: "
 184               . $config->{mapping}->{ $config->{matchpoint} }->{is};
 185         }
 186         return $config;
 187     }
 188     else {
 189         if ( !$config->{matchpoint} ) {
 190             carp 'shibboleth matchpoint not defined';
 191         }
 192         else {
 193             carp 'shibboleth matchpoint not mapped';
 194         }
 195         return 0;
 196     }
 197 }
 198
 199 1;
 200 __END__
 201
 202 =head1 NAME
 203
 204 C4::Auth_with_shibboleth
 205
 206 =head1 SYNOPSIS
 207
 208 use C4::Auth_with_shibboleth;
 209
 210 =head1 DESCRIPTION
 211
 212 This module is specific to Shibboleth authentication in koha and relies heavily upon the native shibboleth service provider package in your operating system.
 213
 214 =head1 CONFIGURATION
 215
 216 To use this type of authentication these additional packages are required:
 217
 218 =over
 219
 220 =item *
 221
 222 libapache2-mod-shib2
 223
 224 =item *
 225
 226 libshibsp5:amd64
 227
 228 =item *
 229
 230 shibboleth-sp2-schemas
 231
 232 =back
 233
 234 We let the native shibboleth service provider packages handle all the complexities of shibboleth negotiation for us, and configuring this is beyond the scope of this documentation.
 235
 236 But to sum up, to get shibboleth working in koha, as a minimum you will need to:
 237
 238 =over
 239
 240 =item 1.
 241
 242 Create some metadata for your koha instance (if you're in a single instance setup then the default metadata available at https://youraddress.com/Shibboleth.sso/Metadata should be adequate)
 243
 244 =item 2.
 245
 246 Swap metadata with your Identidy Provider (IdP)
 247
 248 =item 3.
 249
 250 Map their attributes to what you want to see in koha
 251
 252 =item 4.
 253
 254 Tell apache that we wish to allow koha to authenticate via shibboleth.
 255
 256 This is as simple as adding the below to your virtualhost config (for CGI running):
 257
 258  <Location />
 259    AuthType shibboleth
 260    Require shibboleth
 261  </Location>
 262
 263 Or (for Plack running):
 264
 265  <Location />
 266    AuthType shibboleth
 267    Require shibboleth
 268    ShibUseEnvironment Off
 269    ShibUseHeaders On
 270  </Location>
 271
 272 =item 5.
 273
 274 Configure koha to listen for shibboleth environment variables.
 275
 276 This is as simple as enabling B<useshibboleth> in koha-conf.xml:
 277
 278  <useshibboleth>1</useshibboleth>
 279
 280 =item 6.
 281
 282 Map shibboleth attributes to koha fields, and configure authentication match point in koha-conf.xml.
 283
 284  <shibboleth>
 285    <matchpoint>userid</matchpoint> <!-- koha borrower field to match upon -->
 286    <mapping>
 287      <userid is="eduPersonID"></userid> <!-- koha borrower field to shibboleth attribute mapping -->
 288    </mapping>
 289  </shibboleth>
 290
 291 Note: The minimum you need here is a <matchpoint> block, containing a valid column name from the koha borrowers table, and a <mapping> block containing a relation between the chosen matchpoint and the shibboleth attribute name.
 292
 293 =back
 294
 295 It should be as simple as that; you should now be able to login via shibboleth in the opac.
 296
 297 If you need more help configuring your B<S>ervice B<P>rovider to authenticate against a chosen B<Id>entity B<P>rovider then it might be worth taking a look at the community wiki L<page|http://wiki.koha-community.org/wiki/Shibboleth_Configuration>
 298
 299 =head1 FUNCTIONS
 300
 301 =head2 logout_shib
 302
 303 Sends a logout signal to the native shibboleth service provider and then logs out of koha.  Depending upon the native service provider configuration and identity provider capabilities this may or may not perform a single sign out action.
 304
 305   logout_shib($query);
 306
 307 =head2 login_shib_url
 308
 309 Given a query, this will return a shibboleth login url with return code to page with given given query.
 310
 311   my $shibLoginURL = login_shib_url($query);
 312
 313 =head2 get_login_shib
 314
 315 Returns the shibboleth login attribute should it be found present in the http session
 316
 317   my $shib_login = get_login_shib();
 318
 319 =head2 checkpw_shib
 320
 321 Given a shib_login attribute, this routine checks for a matching local user and if found returns true, their cardnumber and their userid.  If a match is not found, then this returns false.
 322
 323   my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib( $shib_login );
 324
 325 =head2 _get_uri
 326
 327   _get_uri();
 328
 329 A sugar function to that simply returns the current page URI with appropriate protocol attached
 330
 331 This routine is NOT exported
 332
 333 =head2 _get_shib_config
 334
 335   my $config = _get_shib_config();
 336
 337 A sugar function that checks for a valid shibboleth configuration, and if found returns a hashref of it's contents
 338
 339 This routine is NOT exported
 340
 341 =head2 _autocreate
 342
 343   my ( $retval, $retcard, $retuserid ) = _autocreate( $config, $match );
 344
 345 Given a shibboleth attribute reference and a userid this internal routine will add the given user to Koha and return their user credentials.
 346
 347 This routine is NOT exported
 348
 349 =head1 SEE ALSO
 350
 351 =cut