C4/Breeding.pm

   1 package C4::Breeding;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Parts Copyright 2013 Prosentient Systems
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 use C4::Biblio;
  25 use C4::Koha;
  26 use C4::Charset;
  27 use MARC::File::USMARC;
  28 use C4::ImportBatch;
  29 use C4::AuthoritiesMarc; #GuessAuthTypeCode, FindDuplicateAuthority
  30 use C4::Languages;
  31 use Koha::Database;
  32 use Koha::XSLT_Handler;
  33
  34 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  35
  36 BEGIN {
  37         # set the version for version checking
  38     $VERSION = 3.07.00.049;
  39         require Exporter;
  40         @ISA = qw(Exporter);
  41     @EXPORT = qw(&BreedingSearch &Z3950Search &Z3950SearchAuth);
  42 }
  43
  44 =head1 NAME
  45
  46 C4::Breeding : module to add biblios to import_records via
  47                the breeding/reservoir API.
  48
  49 =head1 SYNOPSIS
  50
  51     Z3950Search($pars, $template);
  52     ($count, @results) = &BreedingSearch($title,$isbn,$random);
  53
  54 =head1 DESCRIPTION
  55
  56 This module contains routines related to Koha's Z39.50 search into
  57 cataloguing reservoir features.
  58
  59 =head2 BreedingSearch
  60
  61 ($count, @results) = &BreedingSearch($title,$isbn,$random);
  62 C<$title> contains the title,
  63 C<$isbn> contains isbn or issn,
  64 C<$random> contains the random seed from a z3950 search.
  65
  66 C<$count> is the number of items in C<@results>. C<@results> is an
  67 array of references-to-hash; the keys are the items from the C<import_records> and
  68 C<import_biblios> tables of the Koha database.
  69
  70 =cut
  71
  72 sub BreedingSearch {
  73     my ($search,$isbn,$z3950random) = @_;
  74     my $dbh   = C4::Context->dbh;
  75     my $count = 0;
  76     my ($query,@bind);
  77     my $sth;
  78     my @results;
  79
  80     # normalise ISBN like at import
  81     $isbn = C4::Koha::GetNormalizedISBN($isbn);
  82
  83     $query = "SELECT import_record_id, file_name, isbn, title, author
  84               FROM  import_biblios
  85               JOIN import_records USING (import_record_id)
  86               JOIN import_batches USING (import_batch_id)
  87               WHERE ";
  88     if ($z3950random) {
  89         $query .= "z3950random = ?";
  90         @bind=($z3950random);
  91     } else {
  92         @bind=();
  93         if (defined($search) && length($search)>0) {
  94             $search =~ s/(\s+)/\%/g;
  95             $query .= "title like ? OR author like ?";
  96             push(@bind,"%$search%", "%$search%");
  97         }
  98         if ($#bind!=-1 && defined($isbn) && length($isbn)>0) {
  99             $query .= " and ";
 100         }
 101         if (defined($isbn) && length($isbn)>0) {
 102             $query .= "isbn like ?";
 103             push(@bind,"$isbn%");
 104         }
 105     }
 106     $sth   = $dbh->prepare($query);
 107     $sth->execute(@bind);
 108     while (my $data = $sth->fetchrow_hashref) {
 109             $results[$count] = $data;
 110             # FIXME - hack to reflect difference in name
 111             # of columns in old marc_breeding and import_records
 112             # There needs to be more separation between column names and
 113             # field names used in the templates </soapbox>
 114             $data->{'file'} = $data->{'file_name'};
 115             $data->{'id'} = $data->{'import_record_id'};
 116             $count++;
 117     } # while
 118
 119     $sth->finish;
 120     return($count, @results);
 121 } # sub breedingsearch
 122
 123
 124 =head2 Z3950Search
 125
 126 Z3950Search($pars, $template);
 127
 128 Parameters for Z3950 search are all passed via the $pars hash. It may contain isbn, title, author, dewey, subject, lccall, controlnumber, stdid, srchany.
 129 Also it should contain an arrayref id that points to a list of id's of the z3950 targets to be queried (see z3950servers table).
 130 This code is used in acqui/z3950_search and cataloging/z3950_search.
 131 The second parameter $template is a Template object. The routine uses this parameter to store the found values into the template.
 132
 133 =cut
 134
 135 sub Z3950Search {
 136     my ($pars, $template)= @_;
 137
 138     my @id= @{$pars->{id}};
 139     my $page= $pars->{page};
 140     my $biblionumber= $pars->{biblionumber};
 141
 142     my $show_next       = 0;
 143     my $total_pages     = 0;
 144     my @results;
 145     my @breeding_loop = ();
 146     my @oConnection;
 147     my @oResult;
 148     my @errconn;
 149     my $s = 0;
 150     my $imported=0;
 151
 152     my ( $zquery, $squery ) = _build_query( $pars );
 153
 154     my $schema = Koha::Database->new()->schema();
 155     my $rs = $schema->resultset('Z3950server')->search(
 156         { id => [ @id ] },
 157         { result_class => 'DBIx::Class::ResultClass::HashRefInflator' },
 158     );
 159     my @servers = $rs->all;
 160     foreach my $server ( @servers ) {
 161         $oConnection[$s] = _create_connection( $server );
 162         $oResult[$s] =
 163             $server->{servertype} eq 'zed'?
 164                 $oConnection[$s]->search_pqf( $zquery ):
 165                 $oConnection[$s]->search(new ZOOM::Query::CQL(
 166                     _translate_query( $server, $squery )));
 167         $s++;
 168     }
 169     my $xslh = Koha::XSLT_Handler->new;
 170
 171     my $nremaining = $s;
 172     while ( $nremaining-- ) {
 173         my $k;
 174         my $event;
 175         while ( ( $k = ZOOM::event( \@oConnection ) ) != 0 ) {
 176             $event = $oConnection[ $k - 1 ]->last_event();
 177             last if $event == ZOOM::Event::ZEND;
 178         }
 179
 180         if ( $k != 0 ) {
 181             $k--;
 182             my ($error)= $oConnection[$k]->error_x(); #ignores errmsg, addinfo, diagset
 183             if ($error) {
 184                 if ($error =~ m/^(10000|10007)$/ ) {
 185                     push(@errconn, { server => $servers[$k]->{host}, error => $error } );
 186                 }
 187             }
 188             else {
 189                 my $numresults = $oResult[$k]->size();
 190                 my $i;
 191                 my $res;
 192                 if ( $numresults > 0  and $numresults >= (($page-1)*20)) {
 193                     $show_next = 1 if $numresults >= ($page*20);
 194                     $total_pages = int($numresults/20)+1 if $total_pages < ($numresults/20);
 195                     for ($i = ($page-1)*20; $i < (($numresults < ($page*20)) ? $numresults : ($page*20)); $i++) {
 196                         if ( $oResult[$k]->record($i) ) {
 197                             undef $error;
 198                             ( $res, $error ) = _handle_one_result( $oResult[$k]->record($i), $servers[$k], ++$imported, $biblionumber, $xslh ); #ignores error in sequence numbering
 199                             push @breeding_loop, $res if $res;
 200                             push @errconn, { server => $servers[$k]->{servername}, error => $error, seq => $i+1 } if $error;
 201                         }
 202                         else {
 203                             push @errconn, { 'server' => $servers[$k]->{servername}, error => ( ( $oConnection[$k]->error_x() )[0] ), seq => $i+1 };
 204                         }
 205                     }
 206                 }    #if $numresults
 207             }
 208         }    # if $k !=0
 209
 210         $template->param(
 211             numberpending => $nremaining,
 212             current_page => $page,
 213             total_pages => $total_pages,
 214             show_nextbutton => $show_next?1:0,
 215             show_prevbutton => $page!=1,
 216         );
 217     } # while nremaining
 218
 219     #close result sets and connections
 220     foreach(0..$s-1) {
 221         $oResult[$_]->destroy();
 222         $oConnection[$_]->destroy();
 223     }
 224
 225     $template->param(
 226         breeding_loop => \@breeding_loop,
 227         servers => \@servers,
 228         errconn       => \@errconn
 229     );
 230 }
 231
 232 sub _build_query {
 233     my ( $pars ) = @_;
 234
 235     my $qry_build = {
 236         isbn    => '@attr 1=7 @attr 5=1 "#term" ',
 237         issn    => '@attr 1=8 @attr 5=1 "#term" ',
 238         title   => '@attr 1=4 "#term" ',
 239         author  => '@attr 1=1003 "#term" ',
 240         dewey   => '@attr 1=16 "#term" ',
 241         subject => '@attr 1=21 "#term" ',
 242         lccall  => '@attr 1=16 @attr 2=3 @attr 3=1 @attr 4=1 @attr 5=1 '.
 243                    '@attr 6=1 "#term" ',
 244         controlnumber => '@attr 1=12 "#term" ',
 245         srchany => '@attr 1=1016 "#term" ',
 246         stdid   => '@attr 1=1007 "#term" ',
 247     };
 248
 249     my $zquery='';
 250     my $squery='';
 251     my $nterms=0;
 252     foreach my $k ( sort keys %$pars ) {
 253     #note that the sort keys forces an identical result under Perl 5.18
 254     #one of the unit tests is based on that assumption
 255         if( ( my $val=$pars->{$k} ) && $qry_build->{$k} ) {
 256             $qry_build->{$k} =~ s/#term/$val/g;
 257             $zquery .= $qry_build->{$k};
 258             $squery .= "[$k]=\"$val\" and ";
 259             $nterms++;
 260         }
 261     }
 262     $zquery = "\@and " . $zquery for 2..$nterms;
 263     $squery =~ s/ and $//;
 264     return ( $zquery, $squery );
 265 }
 266
 267 sub _handle_one_result {
 268     my ( $zoomrec, $servhref, $seq, $bib, $xslh )= @_;
 269
 270     my $raw= $zoomrec->raw();
 271     my $marcrecord;
 272     if( $servhref->{servertype} eq 'sru' ) {
 273         $marcrecord= MARC::Record->new_from_xml( $raw, 'UTF-8',
 274             $servhref->{syntax} );
 275     } else {
 276         ($marcrecord) = MarcToUTF8Record($raw, C4::Context->preference('marcflavour'), $servhref->{encoding} // "iso-5426" ); #ignores charset return values
 277     }
 278     SetUTF8Flag($marcrecord);
 279     my $error;
 280     ( $marcrecord, $error ) = _do_xslt_proc($marcrecord, $servhref, $xslh);
 281
 282     my $batch_id = GetZ3950BatchId($servhref->{servername});
 283     my $breedingid = AddBiblioToBatch($batch_id, $seq, $marcrecord, 'UTF-8', 0, 0);
 284         #FIXME passing 0 for z3950random
 285         #Will eliminate this unused field in a followup report
 286         #Last zero indicates: no update for batch record counts
 287
 288
 289     #call to TransformMarcToKoha replaced by next call
 290     #we only need six fields from the marc record
 291     my $row;
 292     $row = _add_rowdata(
 293         {
 294             biblionumber => $bib,
 295             server       => $servhref->{servername},
 296             breedingid   => $breedingid,
 297         }, $marcrecord) if $breedingid;
 298     return ( $row, $error );
 299 }
 300
 301 sub _do_xslt_proc {
 302     my ( $marc, $server, $xslh ) = @_;
 303     return $marc if !$server->{add_xslt};
 304
 305     my $htdocs = C4::Context->config('intrahtdocs');
 306     my $theme = C4::Context->preference("template"); #staff
 307     my $lang = C4::Languages::getlanguage() || 'en';
 308
 309     my @files= split ',', $server->{add_xslt};
 310     my $xml = $marc->as_xml;
 311     foreach my $f ( @files ) {
 312         $f =~ s/^\s+//; $f =~ s/\s+$//; next if !$f;
 313         $f = C4::XSLT::_get_best_default_xslt_filename(
 314             $htdocs, $theme, $lang, $f ) unless $f =~ /^\//;
 315         $xml = $xslh->transform( $xml, $f );
 316         last if $xslh->err; #skip other files
 317     }
 318     if( !$xslh->err ) {
 319         return MARC::Record->new_from_xml($xml, 'UTF-8');
 320     } else {
 321         return ( $marc, 'xslt_err' ); #original record in case of errors
 322     }
 323 }
 324
 325 sub _add_rowdata {
 326     my ($row, $record)=@_;
 327     my %fetch= (
 328         title => 'biblio.title',
 329         author => 'biblio.author',
 330         isbn =>'biblioitems.isbn',
 331         lccn =>'biblioitems.lccn', #LC control number (not call number)
 332         edition =>'biblioitems.editionstatement',
 333         date => 'biblio.copyrightdate', #MARC21
 334         date2 => 'biblioitems.publicationyear', #UNIMARC
 335     );
 336     foreach my $k (keys %fetch) {
 337         my ($t, $f)= split '\.', $fetch{$k};
 338         $row= C4::Biblio::TransformMarcToKohaOneField($t, $f, $record, $row);
 339         $row->{$k}= $row->{$f} if $k ne $f;
 340     }
 341     $row->{date}//= $row->{date2};
 342     $row->{isbn}=_isbn_replace($row->{isbn});
 343     return $row;
 344 }
 345
 346 sub _isbn_replace {
 347     my ($isbn) = @_;
 348     return unless defined $isbn;
 349     $isbn =~ s/ |-|\.//g;
 350     $isbn =~ s/\|/ \| /g;
 351     $isbn =~ s/\(/ \(/g;
 352     return $isbn;
 353 }
 354
 355 sub _create_connection {
 356     my ( $server ) = @_;
 357     my $option1= new ZOOM::Options();
 358     $option1->option( 'async' => 1 );
 359     $option1->option( 'elementSetName', 'F' );
 360     $option1->option( 'preferredRecordSyntax', $server->{syntax} );
 361     $option1->option( 'timeout', $server->{timeout} ) if $server->{timeout};
 362
 363     if( $server->{servertype} eq 'sru' ) {
 364         foreach( split ',', $server->{sru_options}//'' ) {
 365             #first remove surrounding spaces at comma and equals-sign
 366             s/^\s+|\s+$//g;
 367             my @temp= split '=', $_, 2;
 368             @temp= map { my $c=$_; $c=~s/^\s+|\s+$//g; $c; } @temp;
 369             $option1->option( $temp[0] => $temp[1] ) if @temp;
 370         }
 371     } elsif( $server->{servertype} eq 'zed' ) {
 372         $option1->option( 'databaseName',   $server->{db} );
 373         $option1->option( 'user', $server->{userid} ) if $server->{userid};
 374         $option1->option( 'password', $server->{password} ) if $server->{password};
 375     }
 376
 377     my $obj= ZOOM::Connection->create($option1);
 378     if( $server->{servertype} eq 'sru' ) {
 379         my $host= $server->{host};
 380         if( $host !~ /^https?:\/\// ) {
 381             #Normally, host will not be prefixed by protocol.
 382             #In that case we can (safely) assume http.
 383             #In case someone prefixed with https, give it a try..
 384             $host = 'http://' . $host;
 385         }
 386         $obj->connect( $host.':'.$server->{port}.'/'.$server->{db} );
 387     } else {
 388         $obj->connect( $server->{host}, $server->{port} );
 389     }
 390     return $obj;
 391 }
 392
 393 sub _translate_query { #SRU query adjusted per server cf. srufields column
 394     my ($server, $query) = @_;
 395
 396     #sru_fields is in format title=field,isbn=field,...
 397     #if a field doesn't exist, try anywhere or remove [field]=
 398     my @parts= split(',', $server->{sru_fields} );
 399     my %trans= map { if( /=/ ) { ( $`,$' ) } else { () } } @parts;
 400     my $any= $trans{srchany}?$trans{srchany}.'=':'';
 401
 402     my $q=$query;
 403     foreach my $key (keys %trans) {
 404         my $f=$trans{$key};
 405         if( $f ) {
 406             $q=~s/\[$key\]/$f/g;
 407         } else {
 408             $q=~s/\[$key\]=/$any/g;
 409         }
 410     }
 411     $q=~s/\[\w+\]=/$any/g; # remove remaining fields (not found in field list)
 412     return $q;
 413 }
 414
 415 =head2 ImportBreedingAuth
 416
 417 ImportBreedingAuth($marcrecords,$overwrite_auth,$filename,$encoding,$z3950random,$batch_type);
 418
 419     ImportBreedingAuth imports MARC records in the reservoir (import_records table).
 420     ImportBreedingAuth is based on the ImportBreeding subroutine.
 421
 422 =cut
 423
 424 sub ImportBreedingAuth {
 425     my ($marcrecords,$overwrite_auth,$filename,$encoding,$z3950random,$batch_type) = @_;
 426     my @marcarray = split /\x1D/, $marcrecords;
 427
 428     my $dbh = C4::Context->dbh;
 429
 430     my $batch_id = GetZ3950BatchId($filename);
 431     my $searchbreeding = $dbh->prepare("select import_record_id from import_auths where control_number=? and authorized_heading=?");
 432
 433 #     $encoding = C4::Context->preference("marcflavour") unless $encoding;
 434     # fields used for import results
 435     my $imported=0;
 436     my $alreadyindb = 0;
 437     my $alreadyinfarm = 0;
 438     my $notmarcrecord = 0;
 439     my $breedingid;
 440     for (my $i=0;$i<=$#marcarray;$i++) {
 441         my ($marcrecord, $charset_result, $charset_errors);
 442         ($marcrecord, $charset_result, $charset_errors) =
 443             MarcToUTF8Record($marcarray[$i]."\x1D", C4::Context->preference("marcflavour"), $encoding);
 444
 445         # Normalize the record so it doesn't have separated diacritics
 446         SetUTF8Flag($marcrecord);
 447
 448         if (scalar($marcrecord->fields()) == 0) {
 449             $notmarcrecord++;
 450         } else {
 451             my $heading;
 452             $heading = C4::AuthoritiesMarc::GetAuthorizedHeading({ record => $marcrecord });
 453
 454             my $heading_authtype_code;
 455             $heading_authtype_code = GuessAuthTypeCode($marcrecord);
 456
 457             my $controlnumber;
 458             $controlnumber = $marcrecord->field('001')->data;
 459
 460             #Check if the authority record already exists in the database...
 461             my ($duplicateauthid,$duplicateauthvalue);
 462             if ($marcrecord && $heading_authtype_code) {
 463                 ($duplicateauthid,$duplicateauthvalue) = FindDuplicateAuthority( $marcrecord, $heading_authtype_code);
 464             }
 465
 466             if ($duplicateauthid && $overwrite_auth ne 2) {
 467                 #If the authority record exists and $overwrite_auth doesn't equal 2, then mark it as already in the DB
 468                 $alreadyindb++;
 469             } else {
 470                 if ($controlnumber && $heading) {
 471                     $searchbreeding->execute($controlnumber,$heading);
 472                     ($breedingid) = $searchbreeding->fetchrow;
 473                 }
 474                 if ($breedingid && $overwrite_auth eq '0') {
 475                     $alreadyinfarm++;
 476                 } else {
 477                     if ($breedingid && $overwrite_auth eq '1') {
 478                         ModAuthorityInBatch($breedingid, $marcrecord);
 479                     } else {
 480                         my $import_id = AddAuthToBatch($batch_id, $imported, $marcrecord, $encoding, $z3950random);
 481                         $breedingid = $import_id;
 482                     }
 483                     $imported++;
 484                 }
 485             }
 486         }
 487     }
 488     return ($notmarcrecord,$alreadyindb,$alreadyinfarm,$imported,$breedingid);
 489 }
 490
 491 =head2 Z3950SearchAuth
 492
 493 Z3950SearchAuth($pars, $template);
 494
 495 Parameters for Z3950 search are all passed via the $pars hash. It may contain nameany, namepersonal, namecorp, namemeetingcon,
 496 title, uniform title, subject, subjectsubdiv, srchany.
 497 Also it should contain an arrayref id that points to a list of IDs of the z3950 targets to be queried (see z3950servers table).
 498 This code is used in cataloging/z3950_auth_search.
 499 The second parameter $template is a Template object. The routine uses this parameter to store the found values into the template.
 500
 501 =cut
 502
 503 sub Z3950SearchAuth {
 504     my ($pars, $template)= @_;
 505
 506     my $dbh   = C4::Context->dbh;
 507     my @id= @{$pars->{id}};
 508     my $random= $pars->{random};
 509     my $page= $pars->{page};
 510
 511     my $nameany= $pars->{nameany};
 512     my $authorany= $pars->{authorany};
 513     my $authorpersonal= $pars->{authorpersonal};
 514     my $authorcorp= $pars->{authorcorp};
 515     my $authormeetingcon= $pars->{authormeetingcon};
 516     my $title= $pars->{title};
 517     my $uniformtitle= $pars->{uniformtitle};
 518     my $subject= $pars->{subject};
 519     my $subjectsubdiv= $pars->{subjectsubdiv};
 520     my $srchany= $pars->{srchany};
 521
 522     my $show_next       = 0;
 523     my $total_pages     = 0;
 524     my $attr = '';
 525     my $host;
 526     my $server;
 527     my $database;
 528     my $port;
 529     my $marcdata;
 530     my @encoding;
 531     my @results;
 532     my $count;
 533     my $record;
 534     my @serverhost;
 535     my @servername;
 536     my @breeding_loop = ();
 537
 538     my @oConnection;
 539     my @oResult;
 540     my @errconn;
 541     my $s = 0;
 542     my $query;
 543     my $nterms=0;
 544
 545     if ($nameany) {
 546         $query .= " \@attr 1=1002 \"$nameany\" "; #Any name (this includes personal, corporate, meeting/conference authors, and author names in subject headings)
 547         #This attribute is supported by both the Library of Congress and Libraries Australia 08/05/2013
 548         $nterms++;
 549     }
 550
 551     if ($authorany) {
 552         $query .= " \@attr 1=1003 \"$authorany\" "; #Author-name (this includes personal, corporate, meeting/conference authors, but not author names in subject headings)
 553         #This attribute is not supported by the Library of Congress, but is supported by Libraries Australia 08/05/2013
 554         $nterms++;
 555     }
 556
 557     if ($authorcorp) {
 558         $query .= " \@attr 1=2 \"$authorcorp\" "; #1005 is another valid corporate author attribute...
 559         $nterms++;
 560     }
 561
 562     if ($authorpersonal) {
 563         $query .= " \@attr 1=1 \"$authorpersonal\" "; #1004 is another valid personal name attribute...
 564         $nterms++;
 565     }
 566
 567     if ($authormeetingcon) {
 568         $query .= " \@attr 1=3 \"$authormeetingcon\" "; #1006 is another valid meeting/conference name attribute...
 569         $nterms++;
 570     }
 571
 572     if ($subject) {
 573         $query .= " \@attr 1=21 \"$subject\" ";
 574         $nterms++;
 575     }
 576
 577     if ($subjectsubdiv) {
 578         $query .= " \@attr 1=47 \"$subjectsubdiv\" ";
 579         $nterms++;
 580     }
 581
 582     if ($title) {
 583         $query .= " \@attr 1=4 \"$title\" "; #This is a regular title search. 1=6 will give just uniform titles
 584         $nterms++;
 585     }
 586
 587      if ($uniformtitle) {
 588         $query .= " \@attr 1=6 \"$uniformtitle\" "; #This is the uniform title search
 589         $nterms++;
 590     }
 591
 592     if($srchany) {
 593         $query .= " \@attr 1=1016 \"$srchany\" ";
 594         $nterms++;
 595     }
 596
 597     for my $i (1..$nterms-1) {
 598         $query = "\@and " . $query;
 599     }
 600
 601     foreach my $servid (@id) {
 602         my $sth = $dbh->prepare("select * from z3950servers where id=?");
 603         $sth->execute($servid);
 604         while ( $server = $sth->fetchrow_hashref ) {
 605             my $option1      = new ZOOM::Options();
 606             $option1->option( 'async' => 1 );
 607             $option1->option( 'elementSetName', 'F' );
 608             $option1->option( 'databaseName',   $server->{db} );
 609             $option1->option( 'user', $server->{userid} ) if $server->{userid};
 610             $option1->option( 'password', $server->{password} ) if $server->{password};
 611             $option1->option( 'preferredRecordSyntax', $server->{syntax} );
 612             $option1->option( 'timeout', $server->{timeout} ) if $server->{timeout};
 613             $oConnection[$s] = create ZOOM::Connection($option1);
 614             $oConnection[$s]->connect( $server->{host}, $server->{port} );
 615             $serverhost[$s] = $server->{host};
 616             $servername[$s] = $server->{name};
 617             $encoding[$s]   = ($server->{encoding}?$server->{encoding}:"iso-5426");
 618             $s++;
 619         }    ## while fetch
 620     }    # foreach
 621     my $nremaining  = $s;
 622
 623     for ( my $z = 0 ; $z < $s ; $z++ ) {
 624         $oResult[$z] = $oConnection[$z]->search_pqf($query);
 625     }
 626
 627     while ( $nremaining-- ) {
 628         my $k;
 629         my $event;
 630         while ( ( $k = ZOOM::event( \@oConnection ) ) != 0 ) {
 631             $event = $oConnection[ $k - 1 ]->last_event();
 632             last if $event == ZOOM::Event::ZEND;
 633         }
 634
 635         if ( $k != 0 ) {
 636             $k--;
 637             my ($error, $errmsg, $addinfo, $diagset)= $oConnection[$k]->error_x();
 638             if ($error) {
 639                 if ($error =~ m/^(10000|10007)$/ ) {
 640                     push(@errconn, {'server' => $serverhost[$k]});
 641                 }
 642             }
 643             else {
 644                 my $numresults = $oResult[$k]->size();
 645                 my $i;
 646                 my $result = '';
 647                 if ( $numresults > 0  and $numresults >= (($page-1)*20)) {
 648                     $show_next = 1 if $numresults >= ($page*20);
 649                     $total_pages = int($numresults/20)+1 if $total_pages < ($numresults/20);
 650                     for ($i = ($page-1)*20; $i < (($numresults < ($page*20)) ? $numresults : ($page*20)); $i++) {
 651                         my $rec = $oResult[$k]->record($i);
 652                         if ($rec) {
 653                             my $marcrecord;
 654                             my $marcdata;
 655                             $marcdata   = $rec->raw();
 656
 657                             my ($charset_result, $charset_errors);
 658                             ($marcrecord, $charset_result, $charset_errors)= MarcToUTF8Record($marcdata, C4::Context->preference('marcflavour'), $encoding[$k]);
 659
 660                             my $heading;
 661                             my $heading_authtype_code;
 662                             $heading_authtype_code = GuessAuthTypeCode($marcrecord);
 663                             $heading = C4::AuthoritiesMarc::GetAuthorizedHeading({ record => $marcrecord });
 664
 665                             my ($notmarcrecord, $alreadyindb, $alreadyinfarm, $imported, $breedingid)= ImportBreedingAuth( $marcdata, 2, $serverhost[$k], $encoding[$k], $random, 'z3950' );
 666                             my %row_data;
 667                             $row_data{server}       = $servername[$k];
 668                             $row_data{breedingid}   = $breedingid;
 669                             $row_data{heading}      = $heading;
 670                             $row_data{heading_code}      = $heading_authtype_code;
 671                             push( @breeding_loop, \%row_data );
 672                         }
 673                         else {
 674                             push(@breeding_loop,{'server'=>$servername[$k],'title'=>join(': ',$oConnection[$k]->error_x()),'breedingid'=>-1});
 675                         }
 676                     }
 677                 }    #if $numresults
 678             }
 679         }    # if $k !=0
 680
 681         $template->param(
 682             numberpending => $nremaining,
 683             current_page => $page,
 684             total_pages => $total_pages,
 685             show_nextbutton => $show_next?1:0,
 686             show_prevbutton => $page!=1,
 687         );
 688     } # while nremaining
 689
 690     #close result sets and connections
 691     foreach(0..$s-1) {
 692         $oResult[$_]->destroy();
 693         $oConnection[$_]->destroy();
 694     }
 695
 696     my @servers = ();
 697     foreach my $id (@id) {
 698         push @servers, {id => $id};
 699     }
 700     $template->param(
 701         breeding_loop => \@breeding_loop,
 702         servers => \@servers,
 703         errconn       => \@errconn
 704     );
 705 }
 706
 707 1;
 708 __END__
 709