C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use DateTime;
  25 use POSIX qw( floor );
  26 use Koha::DateUtils;
  27 use C4::Context;
  28 use C4::Stats;
  29 use C4::Reserves;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Members;
  33 use C4::Accounts;
  34 use C4::ItemCirculationAlertPreference;
  35 use C4::Message;
  36 use C4::Debug;
  37 use C4::Log; # logaction
  38 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  39 use C4::RotatingCollections qw(GetCollectionItemBranches);
  40 use Algorithm::CheckDigits;
  41
  42 use Data::Dumper;
  43 use Koha::Account;
  44 use Koha::AuthorisedValues;
  45 use Koha::Biblioitems;
  46 use Koha::DateUtils;
  47 use Koha::Calendar;
  48 use Koha::Checkouts;
  49 use Koha::IssuingRules;
  50 use Koha::Items;
  51 use Koha::Patrons;
  52 use Koha::Patron::Debarments;
  53 use Koha::Database;
  54 use Koha::Libraries;
  55 use Koha::Account::Lines;
  56 use Koha::Holds;
  57 use Koha::RefundLostItemFeeRules;
  58 use Koha::Account::Lines;
  59 use Koha::Account::Offsets;
  60 use Koha::Config::SysPrefs;
  61 use Koha::Charges::Fees;
  62 use Koha::Util::SystemPreferences;
  63 use Carp;
  64 use List::MoreUtils qw( uniq any );
  65 use Scalar::Util qw( looks_like_number );
  66 use Date::Calc qw(
  67   Today
  68   Today_and_Now
  69   Add_Delta_YM
  70   Add_Delta_DHMS
  71   Date_to_Days
  72   Day_of_Week
  73   Add_Delta_Days
  74 );
  75 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  76
  77 BEGIN {
  78         require Exporter;
  79         @ISA    = qw(Exporter);
  80
  81         # FIXME subs that should probably be elsewhere
  82         push @EXPORT, qw(
  83                 &barcodedecode
  84         &LostItem
  85         &ReturnLostItem
  86         &GetPendingOnSiteCheckouts
  87         );
  88
  89         # subs to deal with issuing a book
  90         push @EXPORT, qw(
  91                 &CanBookBeIssued
  92                 &CanBookBeRenewed
  93                 &AddIssue
  94                 &AddRenewal
  95                 &GetRenewCount
  96         &GetSoonestRenewDate
  97         &GetLatestAutoRenewDate
  98                 &GetIssuingCharges
  99         &GetBranchBorrowerCircRule
 100         &GetBranchItemRule
 101                 &GetBiblioIssues
 102                 &GetOpenIssue
 103         &CheckIfIssuedToPatron
 104         &IsItemIssued
 105         GetTopIssues
 106         );
 107
 108         # subs to deal with returns
 109         push @EXPORT, qw(
 110                 &AddReturn
 111         &MarkIssueReturned
 112         );
 113
 114         # subs to deal with transfers
 115         push @EXPORT, qw(
 116                 &transferbook
 117                 &GetTransfers
 118                 &GetTransfersFromTo
 119                 &updateWrongTransfer
 120                 &DeleteTransfer
 121                 &IsBranchTransferAllowed
 122                 &CreateBranchTransferLimit
 123                 &DeleteBranchTransferLimits
 124         &TransferSlip
 125         );
 126
 127     # subs to deal with offline circulation
 128     push @EXPORT, qw(
 129       &GetOfflineOperations
 130       &GetOfflineOperation
 131       &AddOfflineOperation
 132       &DeleteOfflineOperation
 133       &ProcessOfflineOperation
 134     );
 135 }
 136
 137 =head1 NAME
 138
 139 C4::Circulation - Koha circulation module
 140
 141 =head1 SYNOPSIS
 142
 143 use C4::Circulation;
 144
 145 =head1 DESCRIPTION
 146
 147 The functions in this module deal with circulation, issues, and
 148 returns, as well as general information about the library.
 149 Also deals with inventory.
 150
 151 =head1 FUNCTIONS
 152
 153 =head2 barcodedecode
 154
 155   $str = &barcodedecode($barcode, [$filter]);
 156
 157 Generic filter function for barcode string.
 158 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 159 Will do some manipulation of the barcode for systems that deliver a barcode
 160 to circulation.pl that differs from the barcode stored for the item.
 161 For proper functioning of this filter, calling the function on the
 162 correct barcode string (items.barcode) should return an unaltered barcode.
 163
 164 The optional $filter argument is to allow for testing or explicit
 165 behavior that ignores the System Pref.  Valid values are the same as the
 166 System Pref options.
 167
 168 =cut
 169
 170 # FIXME -- the &decode fcn below should be wrapped into this one.
 171 # FIXME -- these plugins should be moved out of Circulation.pm
 172 #
 173 sub barcodedecode {
 174     my ($barcode, $filter) = @_;
 175     my $branch = C4::Context::mybranch();
 176     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 177     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 178         if ($filter eq 'whitespace') {
 179                 $barcode =~ s/\s//g;
 180         } elsif ($filter eq 'cuecat') {
 181                 chomp($barcode);
 182             my @fields = split( /\./, $barcode );
 183             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 184             ($#results == 2) and return $results[2];
 185         } elsif ($filter eq 'T-prefix') {
 186                 if ($barcode =~ /^[Tt](\d)/) {
 187                         (defined($1) and $1 eq '0') and return $barcode;
 188             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 189                 }
 190         return sprintf("T%07d", $barcode);
 191         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 192         # Why drop the nonzero digit after the T?
 193         # Why pass non-digits (or empty string) to "T%07d"?
 194         } elsif ($filter eq 'libsuite8') {
 195                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 196                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 197                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 198                         }else{
 199                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 200                         }
 201                 }
 202     } elsif ($filter eq 'EAN13') {
 203         my $ean = CheckDigits('ean');
 204         if ( $ean->is_valid($barcode) ) {
 205             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 206             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 207         } else {
 208             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 209         }
 210         }
 211     return $barcode;    # return barcode, modified or not
 212 }
 213
 214 =head2 decode
 215
 216   $str = &decode($chunk);
 217
 218 Decodes a segment of a string emitted by a CueCat barcode scanner and
 219 returns it.
 220
 221 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 222 or Javascript based decoding on the client side.
 223
 224 =cut
 225
 226 sub decode {
 227     my ($encoded) = @_;
 228     my $seq =
 229       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 230     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 231     my $l = ( $#s + 1 ) % 4;
 232     if ($l) {
 233         if ( $l == 1 ) {
 234             # warn "Error: Cuecat decode parsing failed!";
 235             return;
 236         }
 237         $l = 4 - $l;
 238         $#s += $l;
 239     }
 240     my $r = '';
 241     while ( $#s >= 0 ) {
 242         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 243         $r .=
 244             chr( ( $n >> 16 ) ^ 67 )
 245          .chr( ( $n >> 8 & 255 ) ^ 67 )
 246          .chr( ( $n & 255 ) ^ 67 );
 247         @s = @s[ 4 .. $#s ];
 248     }
 249     $r = substr( $r, 0, length($r) - $l );
 250     return $r;
 251 }
 252
 253 =head2 transferbook
 254
 255   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 256                                             $barcode, $ignore_reserves);
 257
 258 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 259
 260 C<$newbranch> is the code for the branch to which the item should be transferred.
 261
 262 C<$barcode> is the barcode of the item to be transferred.
 263
 264 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 265 Otherwise, if an item is reserved, the transfer fails.
 266
 267 Returns three values:
 268
 269 =over
 270
 271 =item $dotransfer
 272
 273 is true if the transfer was successful.
 274
 275 =item $messages
 276
 277 is a reference-to-hash which may have any of the following keys:
 278
 279 =over
 280
 281 =item C<BadBarcode>
 282
 283 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 284
 285 =item C<DestinationEqualsHolding>
 286
 287 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 288
 289 =item C<WasReturned>
 290
 291 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 292
 293 =item C<ResFound>
 294
 295 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 296
 297 =item C<WasTransferred>
 298
 299 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 300
 301 =back
 302
 303 =back
 304
 305 =cut
 306
 307 sub transferbook {
 308     my ( $tbr, $barcode, $ignoreRs ) = @_;
 309     my $messages;
 310     my $dotransfer      = 1;
 311     my $item = Koha::Items->find( { barcode => $barcode } );
 312
 313     # bad barcode..
 314     unless ( $item ) {
 315         $messages->{'BadBarcode'} = $barcode;
 316         $dotransfer = 0;
 317     }
 318
 319     my $itemnumber = $item->itemnumber;
 320     my $issue = GetOpenIssue($itemnumber);
 321     # get branches of book...
 322     my $hbr = $item->homebranch;
 323     my $fbr = $item->holdingbranch;
 324
 325     # if using Branch Transfer Limits
 326     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 327         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 328         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 329             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 330                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 331                 $dotransfer = 0;
 332             }
 333         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 334             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 335             $dotransfer = 0;
 336         }
 337     }
 338
 339     # can't transfer book if is already there....
 340     if ( $fbr eq $tbr ) {
 341         $messages->{'DestinationEqualsHolding'} = 1;
 342         $dotransfer = 0;
 343     }
 344
 345     # check if it is still issued to someone, return it...
 346     if ( $issue ) {
 347         AddReturn( $barcode, $fbr );
 348         $messages->{'WasReturned'} = $issue->borrowernumber;
 349     }
 350
 351     # find reserves.....
 352     # That'll save a database query.
 353     my ( $resfound, $resrec, undef ) =
 354       CheckReserves( $itemnumber );
 355     if ( $resfound and not $ignoreRs ) {
 356         $resrec->{'ResFound'} = $resfound;
 357
 358         #         $messages->{'ResFound'} = $resrec;
 359         $dotransfer = 1;
 360     }
 361
 362     #actually do the transfer....
 363     if ($dotransfer) {
 364         ModItemTransfer( $itemnumber, $fbr, $tbr );
 365
 366         # don't need to update MARC anymore, we do it in batch now
 367         $messages->{'WasTransfered'} = 1;
 368
 369     }
 370     ModDateLastSeen( $itemnumber );
 371     return ( $dotransfer, $messages );
 372 }
 373
 374
 375 sub TooMany {
 376     my $borrower        = shift;
 377     my $biblionumber = shift;
 378         my $item                = shift;
 379     my $params = shift;
 380     my $onsite_checkout = $params->{onsite_checkout} || 0;
 381     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 382     my $cat_borrower    = $borrower->{'categorycode'};
 383     my $dbh             = C4::Context->dbh;
 384         my $branch;
 385         # Get which branchcode we need
 386         $branch = _GetCircControlBranch($item,$borrower);
 387         my $type = (C4::Context->preference('item-level_itypes'))
 388                         ? $item->{'itype'}         # item-level
 389                         : $item->{'itemtype'};     # biblio-level
 390
 391     # given branch, patron category, and item type, determine
 392     # applicable issuing rule
 393     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 394         {
 395             categorycode => $cat_borrower,
 396             itemtype     => $type,
 397             branchcode   => $branch,
 398             rule_name    => 'maxissueqty',
 399         }
 400     );
 401     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 402         {
 403             categorycode => $cat_borrower,
 404             itemtype     => $type,
 405             branchcode   => $branch,
 406             rule_name    => 'maxonsiteissueqty',
 407         }
 408     );
 409
 410
 411     # if a rule is found and has a loan limit set, count
 412     # how many loans the patron already has that meet that
 413     # rule
 414     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne '') {
 415         my @bind_params;
 416         my $count_query = q|
 417             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 418             FROM issues
 419             JOIN items USING (itemnumber)
 420         |;
 421
 422         my $rule_itemtype = $maxissueqty_rule->itemtype;
 423         unless ($rule_itemtype) {
 424             # matching rule has the default item type, so count only
 425             # those existing loans that don't fall under a more
 426             # specific rule
 427             if (C4::Context->preference('item-level_itypes')) {
 428                 $count_query .= " WHERE items.itype NOT IN (
 429                                     SELECT itemtype FROM issuingrules
 430                                     WHERE branchcode = ?
 431                                     AND   (categorycode = ? OR categorycode = ?)
 432                                     AND   itemtype <> '*'
 433                                   ) ";
 434             } else {
 435                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 436                                   WHERE biblioitems.itemtype NOT IN (
 437                                     SELECT itemtype FROM issuingrules
 438                                     WHERE branchcode = ?
 439                                     AND   (categorycode = ? OR categorycode = ?)
 440                                     AND   itemtype <> '*'
 441                                   ) ";
 442             }
 443             push @bind_params, $maxissueqty_rule->branchcode;
 444             push @bind_params, $maxissueqty_rule->categorycode;
 445             push @bind_params, $cat_borrower;
 446         } else {
 447             # rule has specific item type, so count loans of that
 448             # specific item type
 449             if (C4::Context->preference('item-level_itypes')) {
 450                 $count_query .= " WHERE items.itype = ? ";
 451             } else {
 452                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 453                                   WHERE biblioitems.itemtype= ? ";
 454             }
 455             push @bind_params, $type;
 456         }
 457
 458         $count_query .= " AND borrowernumber = ? ";
 459         push @bind_params, $borrower->{'borrowernumber'};
 460         my $rule_branch = $maxissueqty_rule->branchcode;
 461         if ($rule_branch) {
 462             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 463                 $count_query .= " AND issues.branchcode = ? ";
 464                 push @bind_params, $rule_branch;
 465             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 466                 ; # if branch is the patron's home branch, then count all loans by patron
 467             } else {
 468                 $count_query .= " AND items.homebranch = ? ";
 469                 push @bind_params, $rule_branch;
 470             }
 471         }
 472
 473         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 474
 475         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 476         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 477
 478         if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 479             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 480                 return {
 481                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 482                     count => $onsite_checkout_count,
 483                     max_allowed => $max_onsite_checkouts_allowed,
 484                 }
 485             }
 486         }
 487         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 488             my $delta = $switch_onsite_checkout ? 1 : 0;
 489             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 490                 return {
 491                     reason => 'TOO_MANY_CHECKOUTS',
 492                     count => $checkout_count,
 493                     max_allowed => $max_checkouts_allowed,
 494                 };
 495             }
 496         } elsif ( not $onsite_checkout ) {
 497             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 498                 return {
 499                     reason => 'TOO_MANY_CHECKOUTS',
 500                     count => $checkout_count - $onsite_checkout_count,
 501                     max_allowed => $max_checkouts_allowed,
 502                 };
 503             }
 504         }
 505     }
 506
 507     # Now count total loans against the limit for the branch
 508     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 509     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 510         my @bind_params = ();
 511         my $branch_count_query = q|
 512             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 513             FROM issues
 514             JOIN items USING (itemnumber)
 515             WHERE borrowernumber = ?
 516         |;
 517         push @bind_params, $borrower->{borrowernumber};
 518
 519         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 520             $branch_count_query .= " AND issues.branchcode = ? ";
 521             push @bind_params, $branch;
 522         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 523             ; # if branch is the patron's home branch, then count all loans by patron
 524         } else {
 525             $branch_count_query .= " AND items.homebranch = ? ";
 526             push @bind_params, $branch;
 527         }
 528         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 529         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 530         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 531
 532         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 533             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 534                 return {
 535                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 536                     count => $onsite_checkout_count,
 537                     max_allowed => $max_onsite_checkouts_allowed,
 538                 }
 539             }
 540         }
 541         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 542             my $delta = $switch_onsite_checkout ? 1 : 0;
 543             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 544                 return {
 545                     reason => 'TOO_MANY_CHECKOUTS',
 546                     count => $checkout_count,
 547                     max_allowed => $max_checkouts_allowed,
 548                 };
 549             }
 550         } elsif ( not $onsite_checkout ) {
 551             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 552                 return {
 553                     reason => 'TOO_MANY_CHECKOUTS',
 554                     count => $checkout_count - $onsite_checkout_count,
 555                     max_allowed => $max_checkouts_allowed,
 556                 };
 557             }
 558         }
 559     }
 560
 561     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 562         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 563     }
 564
 565     # OK, the patron can issue !!!
 566     return;
 567 }
 568
 569 =head2 CanBookBeIssued
 570
 571   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 572                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 573
 574 Check if a book can be issued.
 575
 576 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 577
 578 IMPORTANT: The assumption by users of this routine is that causes blocking
 579 the issue are keyed by uppercase labels and other returned
 580 data is keyed in lower case!
 581
 582 =over 4
 583
 584 =item C<$patron> is a Koha::Patron
 585
 586 =item C<$barcode> is the bar code of the book being issued.
 587
 588 =item C<$duedates> is a DateTime object.
 589
 590 =item C<$inprocess> boolean switch
 591
 592 =item C<$ignore_reserves> boolean switch
 593
 594 =item C<$params> Hashref of additional parameters
 595
 596 Available keys:
 597     override_high_holds - Ignore high holds
 598     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 599
 600 =back
 601
 602 Returns :
 603
 604 =over 4
 605
 606 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 607 Possible values are :
 608
 609 =back
 610
 611 =head3 INVALID_DATE
 612
 613 sticky due date is invalid
 614
 615 =head3 GNA
 616
 617 borrower gone with no address
 618
 619 =head3 CARD_LOST
 620
 621 borrower declared it's card lost
 622
 623 =head3 DEBARRED
 624
 625 borrower debarred
 626
 627 =head3 UNKNOWN_BARCODE
 628
 629 barcode unknown
 630
 631 =head3 NOT_FOR_LOAN
 632
 633 item is not for loan
 634
 635 =head3 WTHDRAWN
 636
 637 item withdrawn.
 638
 639 =head3 RESTRICTED
 640
 641 item is restricted (set by ??)
 642
 643 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 644 could be prevented, but ones that can be overriden by the operator.
 645
 646 Possible values are :
 647
 648 =head3 DEBT
 649
 650 borrower has debts.
 651
 652 =head3 RENEW_ISSUE
 653
 654 renewing, not issuing
 655
 656 =head3 ISSUED_TO_ANOTHER
 657
 658 issued to someone else.
 659
 660 =head3 RESERVED
 661
 662 reserved for someone else.
 663
 664 =head3 INVALID_DATE
 665
 666 sticky due date is invalid or due date in the past
 667
 668 =head3 TOO_MANY
 669
 670 if the borrower borrows to much things
 671
 672 =cut
 673
 674 sub CanBookBeIssued {
 675     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 676     my %needsconfirmation;    # filled with problems that needs confirmations
 677     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 678     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 679     my %messages;             # filled with information messages that should be displayed.
 680
 681     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 682     my $override_high_holds = $params->{override_high_holds} || 0;
 683
 684     my $item_object = Koha::Items->find({barcode => $barcode });
 685
 686     # MANDATORY CHECKS - unless item exists, nothing else matters
 687     unless ( $item_object ) {
 688         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 689     }
 690     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 691
 692     my $item_unblessed = $item_object->unblessed; # Transition...
 693     my $issue = $item_object->checkout;
 694     my $biblio = $item_object->biblio;
 695
 696     my $biblioitem = $biblio->biblioitem;
 697     my $effective_itemtype = $item_object->effective_itemtype;
 698     my $dbh             = C4::Context->dbh;
 699     my $patron_unblessed = $patron->unblessed;
 700
 701     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 702     #
 703     # DUE DATE is OK ? -- should already have checked.
 704     #
 705     if ($duedate && ref $duedate ne 'DateTime') {
 706         $duedate = dt_from_string($duedate);
 707     }
 708     my $now = DateTime->now( time_zone => C4::Context->tz() );
 709     unless ( $duedate ) {
 710         my $issuedate = $now->clone();
 711
 712         my $branch = $circ_library;
 713         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $branch, $patron_unblessed );
 714
 715         # Offline circ calls AddIssue directly, doesn't run through here
 716         #  So issuingimpossible should be ok.
 717     }
 718
 719     my $fees = Koha::Charges::Fees->new(
 720         {
 721             patron    => $patron,
 722             library   => $circ_library,
 723             item      => $item_object,
 724             to_date   => $duedate,
 725         }
 726     );
 727
 728     if ($duedate) {
 729         my $today = $now->clone();
 730         $today->truncate( to => 'minute');
 731         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 732             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 733         }
 734     } else {
 735             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 736     }
 737
 738     #
 739     # BORROWER STATUS
 740     #
 741     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 742         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 743         &UpdateStats({
 744                      branch => C4::Context->userenv->{'branch'},
 745                      type => 'localuse',
 746                      itemnumber => $item_object->itemnumber,
 747                      itemtype => $effective_itemtype,
 748                      borrowernumber => $patron->borrowernumber,
 749                      ccode => $item_object->ccode}
 750                     );
 751         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 752         return( { STATS => 1 }, {});
 753     }
 754
 755     if ( $patron->gonenoaddress == 1 ) {
 756         $issuingimpossible{GNA} = 1;
 757     }
 758
 759     if ( $patron->lost == 1 ) {
 760         $issuingimpossible{CARD_LOST} = 1;
 761     }
 762     if ( $patron->is_debarred ) {
 763         $issuingimpossible{DEBARRED} = 1;
 764     }
 765
 766     if ( $patron->is_expired ) {
 767         $issuingimpossible{EXPIRED} = 1;
 768     }
 769
 770     #
 771     # BORROWER STATUS
 772     #
 773
 774     # DEBTS
 775     my $account = $patron->account;
 776     my $balance = $account->balance;
 777     my $non_issues_charges = $account->non_issues_charges;
 778     my $other_charges = $balance - $non_issues_charges;
 779
 780     my $amountlimit = C4::Context->preference("noissuescharge");
 781     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 782     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 783
 784     # Check the debt of this patrons guarantees
 785     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 786     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 787     if ( defined $no_issues_charge_guarantees ) {
 788         my @guarantees = $patron->guarantees();
 789         my $guarantees_non_issues_charges;
 790         foreach my $g ( @guarantees ) {
 791             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 792         }
 793
 794         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 795             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 796         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 797             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 798         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 799             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 800         }
 801     }
 802
 803     if ( C4::Context->preference("IssuingInProcess") ) {
 804         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 805             $issuingimpossible{DEBT} = $non_issues_charges;
 806         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 807             $needsconfirmation{DEBT} = $non_issues_charges;
 808         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 809             $needsconfirmation{DEBT} = $non_issues_charges;
 810         }
 811     }
 812     else {
 813         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 814             $needsconfirmation{DEBT} = $non_issues_charges;
 815         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 816             $issuingimpossible{DEBT} = $non_issues_charges;
 817         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 818             $needsconfirmation{DEBT} = $non_issues_charges;
 819         }
 820     }
 821
 822     if ($balance > 0 && $other_charges > 0) {
 823         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 824     }
 825
 826     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 827     $patron_unblessed = $patron->unblessed;
 828
 829     if ( my $debarred_date = $patron->is_debarred ) {
 830          # patron has accrued fine days or has a restriction. $count is a date
 831         if ($debarred_date eq '9999-12-31') {
 832             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 833         }
 834         else {
 835             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 836         }
 837     } elsif ( my $num_overdues = $patron->has_overdues ) {
 838         ## patron has outstanding overdue loans
 839         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 840             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 841         }
 842         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 843             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 844         }
 845     }
 846
 847     #
 848     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 849     #
 850     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 851
 852         # Already issued to current borrower.
 853         # If it is an on-site checkout if it can be switched to a normal checkout
 854         # or ask whether the loan should be renewed
 855
 856         if ( $issue->onsite_checkout
 857                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 858             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 859         } else {
 860             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 861                 $patron->borrowernumber,
 862                 $item_object->itemnumber,
 863             );
 864             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 865                 if ( $renewerror eq 'onsite_checkout' ) {
 866                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 867                 }
 868                 else {
 869                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 870                 }
 871             }
 872             else {
 873                 $needsconfirmation{RENEW_ISSUE} = 1;
 874             }
 875         }
 876     }
 877     elsif ( $issue ) {
 878
 879         # issued to someone else
 880
 881         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 882
 883         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 884
 885         unless ( $can_be_returned ) {
 886             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 887             $issuingimpossible{branch_to_return} = $message;
 888         } else {
 889             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 890                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 891             } else {
 892             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 893             $needsconfirmation{issued_firstname} = $patron->firstname;
 894             $needsconfirmation{issued_surname} = $patron->surname;
 895             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 896             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 897             }
 898         }
 899     }
 900
 901     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 902     #
 903     my $switch_onsite_checkout = (
 904           C4::Context->preference('SwitchOnSiteCheckouts')
 905       and $issue
 906       and $issue->onsite_checkout
 907       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 908     my $toomany = TooMany( $patron_unblessed, $item_object->biblionumber, $item_unblessed, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 909     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 910     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 911         if ( $toomany->{max_allowed} == 0 ) {
 912             $needsconfirmation{PATRON_CANT} = 1;
 913         }
 914         if ( C4::Context->preference("AllowTooManyOverride") ) {
 915             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 916             $needsconfirmation{current_loan_count} = $toomany->{count};
 917             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 918         } else {
 919             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 920             $issuingimpossible{current_loan_count} = $toomany->{count};
 921             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 922         }
 923     }
 924
 925     #
 926     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 927     #
 928     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 929     my $wants_check = $patron->wants_check_for_previous_checkout;
 930     $needsconfirmation{PREVISSUE} = 1
 931         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 932
 933     #
 934     # ITEM CHECKING
 935     #
 936     if ( $item_object->notforloan )
 937     {
 938         if(!C4::Context->preference("AllowNotForLoanOverride")){
 939             $issuingimpossible{NOT_FOR_LOAN} = 1;
 940             $issuingimpossible{item_notforloan} = $item_object->notforloan;
 941         }else{
 942             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 943             $needsconfirmation{item_notforloan} = $item_object->notforloan;
 944         }
 945     }
 946     else {
 947         # we have to check itemtypes.notforloan also
 948         if (C4::Context->preference('item-level_itypes')){
 949             # this should probably be a subroutine
 950             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 951             $sth->execute($effective_itemtype);
 952             my $notforloan=$sth->fetchrow_hashref();
 953             if ($notforloan->{'notforloan'}) {
 954                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 955                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 956                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 957                 } else {
 958                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 959                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 960                 }
 961             }
 962         }
 963         else {
 964             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 965             if ( $itemtype and $itemtype->notforloan == 1){
 966                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 967                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 968                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 969                 } else {
 970                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 971                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 972                 }
 973             }
 974         }
 975     }
 976     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
 977     {
 978         $issuingimpossible{WTHDRAWN} = 1;
 979     }
 980     if (   $item_object->restricted
 981         && $item_object->restricted == 1 )
 982     {
 983         $issuingimpossible{RESTRICTED} = 1;
 984     }
 985     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 986         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
 987         my $code = $av->count ? $av->next->lib : '';
 988         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 989         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 990     }
 991     if ( C4::Context->preference("IndependentBranches") ) {
 992         my $userenv = C4::Context->userenv;
 993         unless ( C4::Context->IsSuperLibrarian() ) {
 994             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 995             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
 996                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 997                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
 998             }
 999             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1000               if ( $patron->branchcode ne $userenv->{branch} );
1001         }
1002     }
1003     #
1004     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1005     #
1006     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1007
1008     if ( $rentalConfirmation ){
1009         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1010         my $itemtype = Koha::ItemTypes->find( $item_object->itype ); # GetItem sets effective itemtype
1011         $rentalCharge += $fees->accumulate_rentalcharge({ from => dt_from_string(), to => $duedate });
1012         if ( $rentalCharge > 0 ){
1013             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1014         }
1015     }
1016
1017     unless ( $ignore_reserves ) {
1018         # See if the item is on reserve.
1019         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1020         if ($restype) {
1021             my $resbor = $res->{'borrowernumber'};
1022             if ( $resbor ne $patron->borrowernumber ) {
1023                 my $patron = Koha::Patrons->find( $resbor );
1024                 if ( $restype eq "Waiting" )
1025                 {
1026                     # The item is on reserve and waiting, but has been
1027                     # reserved by some other patron.
1028                     $needsconfirmation{RESERVE_WAITING} = 1;
1029                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1030                     $needsconfirmation{'ressurname'} = $patron->surname;
1031                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1032                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1033                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1034                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1035                 }
1036                 elsif ( $restype eq "Reserved" ) {
1037                     # The item is on reserve for someone else.
1038                     $needsconfirmation{RESERVED} = 1;
1039                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1040                     $needsconfirmation{'ressurname'} = $patron->surname;
1041                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1042                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1043                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1044                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1045                 }
1046             }
1047         }
1048     }
1049
1050     ## CHECK AGE RESTRICTION
1051     my $agerestriction  = $biblioitem->agerestriction;
1052     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1053     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1054         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1055             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1056         }
1057         else {
1058             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1059         }
1060     }
1061
1062     ## check for high holds decreasing loan period
1063     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1064         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1065
1066         if ( $check->{exceeded} ) {
1067             if ($override_high_holds) {
1068                 $alerts{HIGHHOLDS} = {
1069                     num_holds  => $check->{outstanding},
1070                     duration   => $check->{duration},
1071                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1072                 };
1073             }
1074             else {
1075                 $needsconfirmation{HIGHHOLDS} = {
1076                     num_holds  => $check->{outstanding},
1077                     duration   => $check->{duration},
1078                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1079                 };
1080             }
1081         }
1082     }
1083
1084     if (
1085         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1086         # don't do the multiple loans per bib check if we've
1087         # already determined that we've got a loan on the same item
1088         !$issuingimpossible{NO_MORE_RENEWALS} &&
1089         !$needsconfirmation{RENEW_ISSUE}
1090     ) {
1091         # Check if borrower has already issued an item from the same biblio
1092         # Only if it's not a subscription
1093         my $biblionumber = $item_object->biblionumber;
1094         require C4::Serials;
1095         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1096         unless ($is_a_subscription) {
1097             # FIXME Should be $patron->checkouts($args);
1098             my $checkouts = Koha::Checkouts->search(
1099                 {
1100                     borrowernumber => $patron->borrowernumber,
1101                     biblionumber   => $biblionumber,
1102                 },
1103                 {
1104                     join => 'item',
1105                 }
1106             );
1107             # if we get here, we don't already have a loan on this item,
1108             # so if there are any loans on this bib, ask for confirmation
1109             if ( $checkouts->count ) {
1110                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1111             }
1112         }
1113     }
1114
1115     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1116 }
1117
1118 =head2 CanBookBeReturned
1119
1120   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1121
1122 Check whether the item can be returned to the provided branch
1123
1124 =over 4
1125
1126 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1127
1128 =item C<$branch> is the branchcode where the return is taking place
1129
1130 =back
1131
1132 Returns:
1133
1134 =over 4
1135
1136 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1137
1138 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1139
1140 =back
1141
1142 =cut
1143
1144 sub CanBookBeReturned {
1145   my ($item, $branch) = @_;
1146   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1147
1148   # assume return is allowed to start
1149   my $allowed = 1;
1150   my $message;
1151
1152   # identify all cases where return is forbidden
1153   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1154      $allowed = 0;
1155      $message = $item->{'homebranch'};
1156   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1157      $allowed = 0;
1158      $message = $item->{'holdingbranch'};
1159   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1160      $allowed = 0;
1161      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1162   }
1163
1164   return ($allowed, $message);
1165 }
1166
1167 =head2 CheckHighHolds
1168
1169     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1170     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1171     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1172
1173 =cut
1174
1175 sub checkHighHolds {
1176     my ( $item, $borrower ) = @_;
1177     my $branch = _GetCircControlBranch( $item, $borrower );
1178     my $item_object = Koha::Items->find( $item->{itemnumber} );
1179
1180     my $return_data = {
1181         exceeded    => 0,
1182         outstanding => 0,
1183         duration    => 0,
1184         due_date    => undef,
1185     };
1186
1187     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1188
1189     if ( $holds->count() ) {
1190         $return_data->{outstanding} = $holds->count();
1191
1192         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1193         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1194         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1195
1196         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1197
1198         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1199
1200             # static means just more than a given number of holds on the record
1201
1202             # If the number of holds is less than the threshold, we can stop here
1203             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1204                 return $return_data;
1205             }
1206         }
1207         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1208
1209             # dynamic means X more than the number of holdable items on the record
1210
1211             # let's get the items
1212             my @items = $holds->next()->biblio()->items()->as_list;
1213
1214             # Remove any items with status defined to be ignored even if the would not make item unholdable
1215             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1216                 @items = grep { !$_->$status } @items;
1217             }
1218
1219             # Remove any items that are not holdable for this patron
1220             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber )->{status} eq 'OK' } @items;
1221
1222             my $items_count = scalar @items;
1223
1224             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1225
1226             # If the number of holds is less than the count of items we have
1227             # plus the number of holds allowed above that count, we can stop here
1228             if ( $holds->count() <= $threshold ) {
1229                 return $return_data;
1230             }
1231         }
1232
1233         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1234
1235         my $calendar = Koha::Calendar->new( branchcode => $branch );
1236
1237         my $itype = $item_object->effective_itemtype;
1238         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branch, $borrower );
1239
1240         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1241
1242         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1243         $reduced_datedue->set_hour($orig_due->hour);
1244         $reduced_datedue->set_minute($orig_due->minute);
1245         $reduced_datedue->truncate( to => 'minute' );
1246
1247         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1248             $return_data->{exceeded} = 1;
1249             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1250             $return_data->{due_date} = $reduced_datedue;
1251         }
1252     }
1253
1254     return $return_data;
1255 }
1256
1257 =head2 AddIssue
1258
1259   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1260
1261 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1262
1263 =over 4
1264
1265 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1266
1267 =item C<$barcode> is the barcode of the item being issued.
1268
1269 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1270 Calculated if empty.
1271
1272 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1273
1274 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1275 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1276
1277 AddIssue does the following things :
1278
1279   - step 01: check that there is a borrowernumber & a barcode provided
1280   - check for RENEWAL (book issued & being issued to the same patron)
1281       - renewal YES = Calculate Charge & renew
1282       - renewal NO  =
1283           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1284           * RESERVE PLACED ?
1285               - fill reserve if reserve to this patron
1286               - cancel reserve or not, otherwise
1287           * TRANSFERT PENDING ?
1288               - complete the transfert
1289           * ISSUE THE BOOK
1290
1291 =back
1292
1293 =cut
1294
1295 sub AddIssue {
1296     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1297
1298     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1299     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1300     my $auto_renew = $params && $params->{auto_renew};
1301     my $dbh          = C4::Context->dbh;
1302     my $barcodecheck = CheckValidBarcode($barcode);
1303
1304     my $issue;
1305
1306     if ( $datedue && ref $datedue ne 'DateTime' ) {
1307         $datedue = dt_from_string($datedue);
1308     }
1309
1310     # $issuedate defaults to today.
1311     if ( !defined $issuedate ) {
1312         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1313     }
1314     else {
1315         if ( ref $issuedate ne 'DateTime' ) {
1316             $issuedate = dt_from_string($issuedate);
1317
1318         }
1319     }
1320
1321     # Stop here if the patron or barcode doesn't exist
1322     if ( $borrower && $barcode && $barcodecheck ) {
1323         # find which item we issue
1324         my $item_object = Koha::Items->find({ barcode => $barcode })
1325           or return;    # if we don't get an Item, abort.
1326         my $item_unblessed = $item_object->unblessed;
1327
1328         my $branch = _GetCircControlBranch( $item_unblessed, $borrower );
1329
1330         # get actual issuing if there is one
1331         my $actualissue = $item_object->checkout;
1332
1333         # check if we just renew the issue.
1334         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1335                 and not $switch_onsite_checkout ) {
1336             $datedue = AddRenewal(
1337                 $borrower->{'borrowernumber'},
1338                 $item_object->itemnumber,
1339                 $branch,
1340                 $datedue,
1341                 $issuedate,    # here interpreted as the renewal date
1342             );
1343         }
1344         else {
1345             unless ($datedue) {
1346                 my $itype = $item_object->effective_itemtype;
1347                 $datedue = CalcDateDue( $issuedate, $itype, $branch, $borrower );
1348
1349             }
1350             $datedue->truncate( to => 'minute' );
1351
1352             my $patron = Koha::Patrons->find( $borrower );
1353             my $library = Koha::Libraries->find( $branch );
1354             my $fees = Koha::Charges::Fees->new(
1355                 {
1356                     patron    => $patron,
1357                     library   => $library,
1358                     item      => $item_object,
1359                     to_date   => $datedue,
1360                 }
1361             );
1362
1363             # it's NOT a renewal
1364             if ( $actualissue and not $switch_onsite_checkout ) {
1365                 # This book is currently on loan, but not to the person
1366                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1367                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1368                 return unless $allowed;
1369                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1370             }
1371
1372             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1373
1374             # Starting process for transfer job (checking transfert and validate it if we have one)
1375             my ($datesent) = GetTransfers( $item_object->itemnumber );
1376             if ($datesent) {
1377                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1378                 my $sth = $dbh->prepare(
1379                     "UPDATE branchtransfers
1380                         SET datearrived = now(),
1381                         tobranch = ?,
1382                         comments = 'Forced branchtransfer'
1383                     WHERE itemnumber= ? AND datearrived IS NULL"
1384                 );
1385                 $sth->execute( C4::Context->userenv->{'branch'},
1386                     $item_object->itemnumber );
1387             }
1388
1389             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1390             unless ($auto_renew) {
1391                 my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1392                     {   categorycode => $borrower->{categorycode},
1393                         itemtype     => $item_object->effective_itemtype,
1394                         branchcode   => $branch
1395                     }
1396                 );
1397
1398                 $auto_renew = $issuing_rule->auto_renew if $issuing_rule;
1399             }
1400
1401             # Record in the database the fact that the book was issued.
1402             unless ($datedue) {
1403                 my $itype = $item_object->effective_itemtype;
1404                 $datedue = CalcDateDue( $issuedate, $itype, $branch, $borrower );
1405
1406             }
1407             $datedue->truncate( to => 'minute' );
1408
1409             my $issue_attributes = {
1410                 borrowernumber  => $borrower->{'borrowernumber'},
1411                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1412                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1413                 branchcode      => C4::Context->userenv->{'branch'},
1414                 onsite_checkout => $onsite_checkout,
1415                 auto_renew      => $auto_renew ? 1 : 0,
1416             };
1417
1418             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1419             if ($issue) {
1420                 $issue->set($issue_attributes)->store;
1421             }
1422             else {
1423                 $issue = Koha::Checkout->new(
1424                     {
1425                         itemnumber => $item_object->itemnumber,
1426                         %$issue_attributes,
1427                     }
1428                 )->store;
1429             }
1430             if ( $item_object->location eq 'CART' && $item_object->permanent_location ne 'CART'  ) {
1431             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1432                 CartToShelf( $item_object->itemnumber );
1433             }
1434
1435             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1436                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1437             }
1438
1439             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1440             if ( $item_object->itemlost ) {
1441                 if (
1442                     Koha::RefundLostItemFeeRules->should_refund(
1443                         {
1444                             current_branch      => C4::Context->userenv->{branch},
1445                             item_home_branch    => $item_object->homebranch,
1446                             item_holding_branch => $item_object->holdingbranch,
1447                         }
1448                     )
1449                   )
1450                 {
1451                     _FixAccountForLostAndReturned( $item_object->itemnumber, undef,
1452                         $item_object->barcode );
1453                 }
1454             }
1455
1456             ModItem(
1457                 {
1458                     issues        => $item_object->issues + 1,
1459                     holdingbranch => C4::Context->userenv->{'branch'},
1460                     itemlost      => 0,
1461                     onloan        => $datedue->ymd(),
1462                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1463                 },
1464                 $item_object->biblionumber,
1465                 $item_object->itemnumber,
1466                 { log_action => 0 }
1467             );
1468             ModDateLastSeen( $item_object->itemnumber );
1469
1470             # If it costs to borrow this book, charge it to the patron's account.
1471             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1472             if ( $charge > 0 ) {
1473                 my $description = "Rental";
1474                 AddIssuingCharge( $issue, $charge, $description );
1475             }
1476
1477             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1478             if ( $itemtype_object ) {
1479                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1480                 if ( $accumulate_charge > 0 ) {
1481                     AddIssuingCharge( $issue, $accumulate_charge, 'Daily rental' ) if $accumulate_charge > 0;
1482                     $charge += $accumulate_charge;
1483                     $item_unblessed->{charge} = $charge;
1484                 }
1485             }
1486
1487             # Record the fact that this book was issued.
1488             &UpdateStats(
1489                 {
1490                     branch => C4::Context->userenv->{'branch'},
1491                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1492                     amount         => $charge,
1493                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1494                     itemnumber     => $item_object->itemnumber,
1495                     itemtype       => $item_object->effective_itemtype,
1496                     location       => $item_object->location,
1497                     borrowernumber => $borrower->{'borrowernumber'},
1498                     ccode          => $item_object->ccode,
1499                 }
1500             );
1501
1502             # Send a checkout slip.
1503             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1504             my %conditions        = (
1505                 branchcode   => $branch,
1506                 categorycode => $borrower->{categorycode},
1507                 item_type    => $item_object->effective_itemtype,
1508                 notification => 'CHECKOUT',
1509             );
1510             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1511                 SendCirculationAlert(
1512                     {
1513                         type     => 'CHECKOUT',
1514                         item     => $item_object->unblessed,
1515                         borrower => $borrower,
1516                         branch   => $branch,
1517                     }
1518                 );
1519             }
1520             logaction(
1521                 "CIRCULATION", "ISSUE",
1522                 $borrower->{'borrowernumber'},
1523                 $item_object->itemnumber,
1524             ) if C4::Context->preference("IssueLog");
1525         }
1526     }
1527     return $issue;
1528 }
1529
1530 =head2 GetLoanLength
1531
1532   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1533
1534 Get loan length for an itemtype, a borrower type and a branch
1535
1536 =cut
1537
1538 sub GetLoanLength {
1539     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1540     my $dbh = C4::Context->dbh;
1541     my $sth = $dbh->prepare(qq{
1542         SELECT issuelength, lengthunit, renewalperiod
1543         FROM issuingrules
1544         WHERE   categorycode=?
1545             AND itemtype=?
1546             AND branchcode=?
1547             AND issuelength IS NOT NULL
1548     });
1549
1550     # try to find issuelength & return the 1st available.
1551     # check with borrowertype, itemtype and branchcode, then without one of those parameters
1552     $sth->execute( $borrowertype, $itemtype, $branchcode );
1553     my $loanlength = $sth->fetchrow_hashref;
1554
1555     return $loanlength
1556       if defined($loanlength) && defined $loanlength->{issuelength};
1557
1558     $sth->execute( $borrowertype, '*', $branchcode );
1559     $loanlength = $sth->fetchrow_hashref;
1560     return $loanlength
1561       if defined($loanlength) && defined $loanlength->{issuelength};
1562
1563     $sth->execute( '*', $itemtype, $branchcode );
1564     $loanlength = $sth->fetchrow_hashref;
1565     return $loanlength
1566       if defined($loanlength) && defined $loanlength->{issuelength};
1567
1568     $sth->execute( '*', '*', $branchcode );
1569     $loanlength = $sth->fetchrow_hashref;
1570     return $loanlength
1571       if defined($loanlength) && defined $loanlength->{issuelength};
1572
1573     $sth->execute( $borrowertype, $itemtype, '*' );
1574     $loanlength = $sth->fetchrow_hashref;
1575     return $loanlength
1576       if defined($loanlength) && defined $loanlength->{issuelength};
1577
1578     $sth->execute( $borrowertype, '*', '*' );
1579     $loanlength = $sth->fetchrow_hashref;
1580     return $loanlength
1581       if defined($loanlength) && defined $loanlength->{issuelength};
1582
1583     $sth->execute( '*', $itemtype, '*' );
1584     $loanlength = $sth->fetchrow_hashref;
1585     return $loanlength
1586       if defined($loanlength) && defined $loanlength->{issuelength};
1587
1588     $sth->execute( '*', '*', '*' );
1589     $loanlength = $sth->fetchrow_hashref;
1590     return $loanlength
1591       if defined($loanlength) && defined $loanlength->{issuelength};
1592
1593     # if no rule is set => 0 day (hardcoded)
1594     return {
1595         issuelength => 0,
1596         renewalperiod => 0,
1597         lengthunit => 'days',
1598     };
1599
1600 }
1601
1602
1603 =head2 GetHardDueDate
1604
1605   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1606
1607 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1608
1609 =cut
1610
1611 sub GetHardDueDate {
1612     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1613
1614     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1615         {   categorycode => $borrowertype,
1616             itemtype     => $itemtype,
1617             branchcode   => $branchcode
1618         }
1619     );
1620
1621
1622     if ( defined( $issuing_rule ) ) {
1623         if ( $issuing_rule->hardduedate ) {
1624             return (dt_from_string($issuing_rule->hardduedate, 'iso'),$issuing_rule->hardduedatecompare);
1625         } else {
1626             return (undef, undef);
1627         }
1628     }
1629 }
1630
1631 =head2 GetBranchBorrowerCircRule
1632
1633   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1634
1635 Retrieves circulation rule attributes that apply to the given
1636 branch and patron category, regardless of item type.
1637 The return value is a hashref containing the following key:
1638
1639 patron_maxissueqty - maximum number of loans that a
1640 patron of the given category can have at the given
1641 branch.  If the value is undef, no limit.
1642
1643 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1644 patron of the given category can have at the given
1645 branch.  If the value is undef, no limit.
1646
1647 This will check for different branch/category combinations in the following order:
1648 branch and category
1649 branch only
1650 category only
1651 default branch and category
1652
1653 If no rule has been found in the database, it will default to
1654 the buillt in rule:
1655
1656 patron_maxissueqty - undef
1657 patron_maxonsiteissueqty - undef
1658
1659 C<$branchcode> and C<$categorycode> should contain the
1660 literal branch code and patron category code, respectively - no
1661 wildcards.
1662
1663 =cut
1664
1665 sub GetBranchBorrowerCircRule {
1666     my ( $branchcode, $categorycode ) = @_;
1667
1668     # Initialize default values
1669     my $rules = {
1670         patron_maxissueqty       => undef,
1671         patron_maxonsiteissueqty => undef,
1672     };
1673
1674     # Search for rules!
1675     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1676         my $rule = Koha::CirculationRules->get_effective_rule(
1677             {
1678                 categorycode => $categorycode,
1679                 itemtype     => undef,
1680                 branchcode   => $branchcode,
1681                 rule_name    => $rule_name,
1682             }
1683         );
1684
1685         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1686     }
1687
1688     return $rules;
1689 }
1690
1691 =head2 GetBranchItemRule
1692
1693   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1694
1695 Retrieves circulation rule attributes that apply to the given
1696 branch and item type, regardless of patron category.
1697
1698 The return value is a hashref containing the following keys:
1699
1700 holdallowed => Hold policy for this branch and itemtype. Possible values:
1701   0: No holds allowed.
1702   1: Holds allowed only by patrons that have the same homebranch as the item.
1703   2: Holds allowed from any patron.
1704
1705 returnbranch => branch to which to return item.  Possible values:
1706   noreturn: do not return, let item remain where checked in (floating collections)
1707   homebranch: return to item's home branch
1708   holdingbranch: return to issuer branch
1709
1710 This searches branchitemrules in the following order:
1711
1712   * Same branchcode and itemtype
1713   * Same branchcode, itemtype '*'
1714   * branchcode '*', same itemtype
1715   * branchcode and itemtype '*'
1716
1717 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1718
1719 =cut
1720
1721 sub GetBranchItemRule {
1722     my ( $branchcode, $itemtype ) = @_;
1723
1724     # Search for rules!
1725     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1726         {
1727             branchcode => $branchcode,
1728             itemtype => $itemtype,
1729             rule_name => 'holdallowed',
1730         }
1731     );
1732     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1733         {
1734             branchcode => $branchcode,
1735             itemtype => $itemtype,
1736             rule_name => 'hold_fulfillment_policy',
1737         }
1738     );
1739     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1740         {
1741             branchcode => $branchcode,
1742             itemtype => $itemtype,
1743             rule_name => 'returnbranch',
1744         }
1745     );
1746
1747     # built-in default circulation rule
1748     my $rules;
1749     $rules->{holdallowed} = defined $holdallowed_rule
1750         ? $holdallowed_rule->rule_value
1751         : 2;
1752     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1753         ? $hold_fulfillment_policy_rule->rule_value
1754         : 'any';
1755     $rules->{returnbranch} = defined $returnbranch_rule
1756         ? $returnbranch_rule->rule_value
1757         : 'homebranch';
1758
1759     return $rules;
1760 }
1761
1762 =head2 AddReturn
1763
1764   ($doreturn, $messages, $iteminformation, $borrower) =
1765       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1766
1767 Returns a book.
1768
1769 =over 4
1770
1771 =item C<$barcode> is the bar code of the book being returned.
1772
1773 =item C<$branch> is the code of the branch where the book is being returned.
1774
1775 =item C<$exemptfine> indicates that overdue charges for the item will be
1776 removed. Optional.
1777
1778 =item C<$return_date> allows the default return date to be overridden
1779 by the given return date. Optional.
1780
1781 =back
1782
1783 C<&AddReturn> returns a list of four items:
1784
1785 C<$doreturn> is true iff the return succeeded.
1786
1787 C<$messages> is a reference-to-hash giving feedback on the operation.
1788 The keys of the hash are:
1789
1790 =over 4
1791
1792 =item C<BadBarcode>
1793
1794 No item with this barcode exists. The value is C<$barcode>.
1795
1796 =item C<NotIssued>
1797
1798 The book is not currently on loan. The value is C<$barcode>.
1799
1800 =item C<withdrawn>
1801
1802 This book has been withdrawn/cancelled. The value should be ignored.
1803
1804 =item C<Wrongbranch>
1805
1806 This book has was returned to the wrong branch.  The value is a hashref
1807 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1808 contain the branchcode of the incorrect and correct return library, respectively.
1809
1810 =item C<ResFound>
1811
1812 The item was reserved. The value is a reference-to-hash whose keys are
1813 fields from the reserves table of the Koha database, and
1814 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1815 either C<Waiting>, C<Reserved>, or 0.
1816
1817 =item C<WasReturned>
1818
1819 Value 1 if return is successful.
1820
1821 =item C<NeedsTransfer>
1822
1823 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1824
1825 =back
1826
1827 C<$iteminformation> is a reference-to-hash, giving information about the
1828 returned item from the issues table.
1829
1830 C<$borrower> is a reference-to-hash, giving information about the
1831 patron who last borrowed the book.
1832
1833 =cut
1834
1835 sub AddReturn {
1836     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1837
1838     if ($branch and not Koha::Libraries->find($branch)) {
1839         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1840         undef $branch;
1841     }
1842     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1843     $return_date //= dt_from_string();
1844     my $messages;
1845     my $patron;
1846     my $doreturn       = 1;
1847     my $validTransfert = 0;
1848     my $stat_type = 'return';
1849
1850     # get information on item
1851     my $item = Koha::Items->find({ barcode => $barcode });
1852     unless ($item) {
1853         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1854     }
1855
1856     my $itemnumber = $item->itemnumber;
1857     my $itemtype = $item->effective_itemtype;
1858
1859     my $issue  = $item->checkout;
1860     if ( $issue ) {
1861         $patron = $issue->patron
1862             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1863                 . Dumper($issue->unblessed) . "\n";
1864     } else {
1865         $messages->{'NotIssued'} = $barcode;
1866         ModItem({ onloan => undef }, $item->biblionumber, $item->itemnumber) if defined $item->onloan;
1867         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1868         $doreturn = 0;
1869         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1870         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1871         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1872            $messages->{'LocalUse'} = 1;
1873            $stat_type = 'localuse';
1874         }
1875     }
1876
1877     my $item_unblessed = $item->unblessed;
1878         # full item data, but no borrowernumber or checkout info (no issue)
1879     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1880         # get the proper branch to which to return the item
1881     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1882         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1883
1884     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1885     my $patron_unblessed = $patron ? $patron->unblessed : {};
1886
1887     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1888     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1889     if ($update_loc_rules) {
1890         if (defined $update_loc_rules->{_ALL_}) {
1891             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1892             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1893             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1894                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1895                 ModItem( { location => $update_loc_rules->{_ALL_} }, undef, $itemnumber );
1896             }
1897         }
1898         else {
1899             foreach my $key ( keys %$update_loc_rules ) {
1900                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1901                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1902                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1903                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1904                     ModItem( { location => $update_loc_rules->{$key} }, undef, $itemnumber );
1905                     last;
1906                 }
1907             }
1908         }
1909     }
1910
1911     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1912     if ($yaml) {
1913         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1914         my $rules;
1915         eval { $rules = YAML::Load($yaml); };
1916         if ($@) {
1917             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1918         }
1919         else {
1920             foreach my $key ( keys %$rules ) {
1921                 if ( $item->notforloan eq $key ) {
1922                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1923                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber, { log_action => 0 } );
1924                     last;
1925                 }
1926             }
1927         }
1928     }
1929
1930     # check if the return is allowed at this branch
1931     my ($returnallowed, $message) = CanBookBeReturned($item_unblessed, $branch);
1932     unless ($returnallowed){
1933         $messages->{'Wrongbranch'} = {
1934             Wrongbranch => $branch,
1935             Rightbranch => $message
1936         };
1937         $doreturn = 0;
1938         return ( $doreturn, $messages, $issue, $patron_unblessed);
1939     }
1940
1941     if ( $item->withdrawn ) { # book has been cancelled
1942         $messages->{'withdrawn'} = 1;
1943         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1944     }
1945
1946     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1947         $doreturn = 0;
1948     }
1949
1950     # case of a return of document (deal with issues and holdingbranch)
1951     if ($doreturn) {
1952         my $is_overdue;
1953         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1954         $patron or warn "AddReturn without current borrower";
1955         $is_overdue = $issue->is_overdue( $return_date );
1956
1957         if ($patron) {
1958             eval {
1959                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1960             };
1961             unless ( $@ ) {
1962                 if ( C4::Context->preference('CalculateFinesOnReturn') && $is_overdue && !$item->itemlost ) {
1963                     _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed, return_date => $return_date } );
1964                 }
1965             } else {
1966                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
1967
1968                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
1969             }
1970
1971             # FIXME is the "= 1" right?  This could be the borrower hash.
1972             $messages->{'WasReturned'} = 1;
1973
1974         }
1975
1976         ModItem( { onloan => undef }, $item->biblionumber, $item->itemnumber, { log_action => 0 } );
1977     }
1978
1979     # the holdingbranch is updated if the document is returned to another location.
1980     # this is always done regardless of whether the item was on loan or not
1981     my $item_holding_branch = $item->holdingbranch;
1982     if ($item->holdingbranch ne $branch) {
1983         UpdateHoldingbranch($branch, $item->itemnumber);
1984         $item_unblessed->{'holdingbranch'} = $branch; # update item data holdingbranch too # FIXME I guess this is for the _debar_user_on_return call later
1985     }
1986
1987     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
1988     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
1989
1990     # check if we have a transfer for this document
1991     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
1992
1993     # if we have a transfer to do, we update the line of transfers with the datearrived
1994     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
1995     if ($datesent) {
1996         if ( $tobranch eq $branch ) {
1997             my $sth = C4::Context->dbh->prepare(
1998                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
1999             );
2000             $sth->execute( $item->itemnumber );
2001             # if we have a reservation with valid transfer, we can set it's status to 'W'
2002             C4::Reserves::ModReserveStatus($item->itemnumber, 'W');
2003         } else {
2004             $messages->{'WrongTransfer'}     = $tobranch;
2005             $messages->{'WrongTransferItem'} = $item->itemnumber;
2006         }
2007         $validTransfert = 1;
2008     }
2009
2010     # fix up the accounts.....
2011     if ( $item->itemlost ) {
2012         $messages->{'WasLost'} = 1;
2013         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2014             if (
2015                 Koha::RefundLostItemFeeRules->should_refund(
2016                     {
2017                         current_branch      => C4::Context->userenv->{branch},
2018                         item_home_branch    => $item->homebranch,
2019                         item_holding_branch => $item_holding_branch
2020                     }
2021                 )
2022               )
2023             {
2024                 _FixAccountForLostAndReturned( $item->itemnumber,
2025                     $borrowernumber, $barcode );
2026                 $messages->{'LostItemFeeRefunded'} = 1;
2027             }
2028         }
2029     }
2030
2031     # fix up the overdues in accounts...
2032     if ($borrowernumber) {
2033         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine );
2034         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->itemnumber...) failed!";  # zero is OK, check defined
2035
2036         if ( $issue and $issue->is_overdue ) {
2037         # fix fine days
2038             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item_unblessed, dt_from_string($issue->date_due), $return_date );
2039             if ($reminder){
2040                 $messages->{'PrevDebarred'} = $debardate;
2041             } else {
2042                 $messages->{'Debarred'} = $debardate if $debardate;
2043             }
2044         # there's no overdue on the item but borrower had been previously debarred
2045         } elsif ( $issue->date_due and $patron->debarred ) {
2046              if ( $patron->debarred eq "9999-12-31") {
2047                 $messages->{'ForeverDebarred'} = $patron->debarred;
2048              } else {
2049                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2050                   $borrower_debar_dt->truncate(to => 'day');
2051                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2052                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2053                       $messages->{'PrevDebarred'} = $patron->debarred;
2054                   }
2055              }
2056         }
2057     }
2058
2059     # find reserves.....
2060     # if we don't have a reserve with the status W, we launch the Checkreserves routine
2061     my ($resfound, $resrec);
2062     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2063     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2064     if ($resfound) {
2065           $resrec->{'ResFound'} = $resfound;
2066         $messages->{'ResFound'} = $resrec;
2067     }
2068
2069     # Record the fact that this book was returned.
2070     UpdateStats({
2071         branch         => $branch,
2072         type           => $stat_type,
2073         itemnumber     => $itemnumber,
2074         itemtype       => $itemtype,
2075         borrowernumber => $borrowernumber,
2076         ccode          => $item->ccode,
2077     });
2078
2079     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2080     if ( $patron ) {
2081         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2082         my %conditions = (
2083             branchcode   => $branch,
2084             categorycode => $patron->categorycode,
2085             item_type    => $itemtype,
2086             notification => 'CHECKIN',
2087         );
2088         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2089             SendCirculationAlert({
2090                 type     => 'CHECKIN',
2091                 item     => $item_unblessed,
2092                 borrower => $patron->unblessed,
2093                 branch   => $branch,
2094             });
2095         }
2096
2097         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2098             if C4::Context->preference("ReturnLog");
2099         }
2100
2101     # Remove any OVERDUES related debarment if the borrower has no overdues
2102     if ( $borrowernumber
2103       && $patron->debarred
2104       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2105       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2106       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2107     ) {
2108         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2109     }
2110
2111     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2112     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2113         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType");
2114         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2115             (C4::Context->preference("UseBranchTransferLimits") and
2116              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2117            )) {
2118             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s)", $item->itemnumber,$branch, $returnbranch;
2119             $debug and warn "item: " . Dumper($item_unblessed);
2120             ModItemTransfer($item->itemnumber, $branch, $returnbranch);
2121             $messages->{'WasTransfered'} = 1;
2122         } else {
2123             $messages->{'NeedsTransfer'} = $returnbranch;
2124         }
2125     }
2126
2127     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2128 }
2129
2130 =head2 MarkIssueReturned
2131
2132   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2133
2134 Unconditionally marks an issue as being returned by
2135 moving the C<issues> row to C<old_issues> and
2136 setting C<returndate> to the current date.
2137
2138 if C<$returndate> is specified (in iso format), it is used as the date
2139 of the return.
2140
2141 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2142 the old_issue is immediately anonymised
2143
2144 Ideally, this function would be internal to C<C4::Circulation>,
2145 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2146 and offline_circ/process_koc.pl.
2147
2148 =cut
2149
2150 sub MarkIssueReturned {
2151     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2152
2153     # Retrieve the issue
2154     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2155     my $issue_id = $issue->issue_id;
2156
2157     my $anonymouspatron;
2158     if ( $privacy == 2 ) {
2159         # The default of 0 will not work due to foreign key constraints
2160         # The anonymisation will fail if AnonymousPatron is not a valid entry
2161         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2162         # Note that a warning should appear on the about page (System information tab).
2163         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2164         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2165             unless Koha::Patrons->find( $anonymouspatron );
2166     }
2167
2168     my $schema = Koha::Database->schema;
2169
2170     # FIXME Improve the return value and handle it from callers
2171     $schema->txn_do(sub {
2172
2173         # Update the returndate value
2174         if ( $returndate ) {
2175             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2176         }
2177         else {
2178             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2179         }
2180
2181         # Create the old_issues entry
2182         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2183
2184         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2185         if ( $privacy == 2) {
2186             $old_checkout->borrowernumber($anonymouspatron)->store;
2187         }
2188
2189         # And finally delete the issue
2190         $issue->delete;
2191
2192         ModItem( { 'onloan' => undef }, undef, $itemnumber, { log_action => 0 } );
2193
2194         if ( C4::Context->preference('StoreLastBorrower') ) {
2195             my $item = Koha::Items->find( $itemnumber );
2196             my $patron = Koha::Patrons->find( $borrowernumber );
2197             $item->last_returned_by( $patron );
2198         }
2199     });
2200
2201     return $issue_id;
2202 }
2203
2204 =head2 _debar_user_on_return
2205
2206     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2207
2208 C<$borrower> borrower hashref
2209
2210 C<$item> item hashref
2211
2212 C<$datedue> date due DateTime object
2213
2214 C<$returndate> DateTime object representing the return time
2215
2216 Internal function, called only by AddReturn that calculates and updates
2217  the user fine days, and debars them if necessary.
2218
2219 Should only be called for overdue returns
2220
2221 =cut
2222
2223 sub _debar_user_on_return {
2224     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2225
2226     my $branchcode = _GetCircControlBranch( $item, $borrower );
2227     $return_date //= dt_from_string();
2228
2229     my $circcontrol = C4::Context->preference('CircControl');
2230     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2231         {   categorycode => $borrower->{categorycode},
2232             itemtype     => $item->{itype},
2233             branchcode   => $branchcode
2234         }
2235     );
2236     my $finedays = $issuing_rule ? $issuing_rule->finedays : undef;
2237     my $unit     = $issuing_rule ? $issuing_rule->lengthunit : undef;
2238     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2239
2240     if ($finedays) {
2241
2242         # finedays is in days, so hourly loans must multiply by 24
2243         # thus 1 hour late equals 1 day suspension * finedays rate
2244         $finedays = $finedays * 24 if ( $unit eq 'hours' );
2245
2246         # grace period is measured in the same units as the loan
2247         my $grace =
2248           DateTime::Duration->new( $unit => $issuing_rule->firstremind );
2249
2250         my $deltadays = DateTime::Duration->new(
2251             days => $chargeable_units
2252         );
2253         if ( $deltadays->subtract($grace)->is_positive() ) {
2254             my $suspension_days = $deltadays * $finedays;
2255
2256             # If the max suspension days is < than the suspension days
2257             # the suspension days is limited to this maximum period.
2258             my $max_sd = $issuing_rule->maxsuspensiondays;
2259             if ( defined $max_sd ) {
2260                 $max_sd = DateTime::Duration->new( days => $max_sd );
2261                 $suspension_days = $max_sd
2262                   if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2263             }
2264
2265             my ( $has_been_extended, $is_a_reminder );
2266             if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2267                 my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2268                 if ( $debarment ) {
2269                     $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2270                     $has_been_extended = 1;
2271                 }
2272             }
2273
2274             if ( $issuing_rule->suspension_chargeperiod > 1 ) {
2275                 # No need to / 1 and do not consider / 0
2276                 $suspension_days = DateTime::Duration->new(
2277                     days => floor( $suspension_days->in_units('days') / $issuing_rule->suspension_chargeperiod )
2278                 );
2279             }
2280
2281             my $new_debar_dt;
2282             # Use the calendar or not to calculate the debarment date
2283             if ( C4::Context->preference('finesCalendar') eq 'noFinesWhenClosed' ) {
2284                 my $calendar = Koha::Calendar->new(
2285                     branchcode => $branchcode,
2286                     days_mode  => 'Calendar'
2287                 );
2288                 $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2289             }
2290             else {
2291                 $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2292             }
2293
2294             Koha::Patron::Debarments::AddUniqueDebarment({
2295                 borrowernumber => $borrower->{borrowernumber},
2296                 expiration     => $new_debar_dt->ymd(),
2297                 type           => 'SUSPENSION',
2298             });
2299             # if borrower was already debarred but does not get an extra debarment
2300             my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2301             my $new_debarment_str;
2302             if ( $borrower->{debarred} eq $patron->is_debarred ) {
2303                 $is_a_reminder = 1;
2304                 $new_debarment_str = $borrower->{debarred};
2305             } else {
2306                 $new_debarment_str = $new_debar_dt->ymd();
2307             }
2308             # FIXME Should return a DateTime object
2309             return $new_debarment_str, $is_a_reminder;
2310         }
2311     }
2312     return;
2313 }
2314
2315 =head2 _FixOverduesOnReturn
2316
2317    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine);
2318
2319 C<$borrowernumber> borrowernumber
2320
2321 C<$itemnumber> itemnumber
2322
2323 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2324
2325 Internal function
2326
2327 =cut
2328
2329 sub _FixOverduesOnReturn {
2330     my ( $borrowernumber, $item, $exemptfine ) = @_;
2331     unless( $borrowernumber ) {
2332         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2333         return;
2334     }
2335     unless( $item ) {
2336         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2337         return;
2338     }
2339
2340     my $schema = Koha::Database->schema;
2341
2342     my $result = $schema->txn_do(
2343         sub {
2344             # check for overdue fine
2345             my $accountlines = Koha::Account::Lines->search(
2346                 {
2347                     borrowernumber => $borrowernumber,
2348                     itemnumber     => $item,
2349                     accounttype    => 'OVERDUE',
2350                     status         => 'UNRETURNED'
2351                 }
2352             );
2353             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2354
2355             my $accountline = $accountlines->next;
2356             if ($exemptfine) {
2357                 my $amountoutstanding = $accountline->amountoutstanding;
2358
2359                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2360                 my $credit = $account->add_credit(
2361                     {
2362                         amount     => $amountoutstanding,
2363                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2364                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2365                         interface  => C4::Context->interface,
2366                         type       => 'forgiven',
2367                         item_id    => $item
2368                     }
2369                 );
2370
2371                 $credit->apply({ debits => $accountlines->reset, offset_type => 'Forgiven' });
2372
2373                 $accountline->status('FORGIVEN');
2374
2375                 if (C4::Context->preference("FinesLog")) {
2376                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2377                 }
2378             } else {
2379                 $accountline->status('RETURNED');
2380             }
2381
2382             return $accountline->store();
2383         }
2384     );
2385
2386     return $result;
2387 }
2388
2389 =head2 _FixAccountForLostAndReturned
2390
2391   &_FixAccountForLostAndReturned($itemnumber, [$borrowernumber, $barcode]);
2392
2393 Calculates the charge for a book lost and returned.
2394
2395 Internal function, not exported, called only by AddReturn.
2396
2397 =cut
2398
2399 sub _FixAccountForLostAndReturned {
2400     my $itemnumber     = shift or return;
2401     my $borrowernumber = @_ ? shift : undef;
2402     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2403
2404     my $credit;
2405
2406     # check for charge made for lost book
2407     my $accountlines = Koha::Account::Lines->search(
2408         {
2409             itemnumber  => $itemnumber,
2410             accounttype => 'LOST',
2411         },
2412         {
2413             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2414         }
2415     );
2416
2417     return unless $accountlines->count > 0;
2418     my $accountline     = $accountlines->next;
2419     my $total_to_refund = 0;
2420
2421     return unless $accountline->borrowernumber;
2422     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2423     return unless $patron; # Patron has been deleted, nobody to credit the return to
2424
2425     my $account = $patron->account;
2426
2427     # Use cases
2428     if ( $accountline->amount > $accountline->amountoutstanding ) {
2429         # some amount has been cancelled. collect the offsets that are not writeoffs
2430         # this works because the only way to subtract from this kind of a debt is
2431         # using the UI buttons 'Pay' and 'Write off'
2432         my $credits_offsets = Koha::Account::Offsets->search({
2433             debit_id  => $accountline->id,
2434             credit_id => { '!=' => undef }, # it is not the debit itself
2435             type      => { '!=' => 'Writeoff' },
2436             amount    => { '<'  => 0 } # credits are negative on the DB
2437         });
2438
2439         $total_to_refund = ( $credits_offsets->count > 0 )
2440                             ? $credits_offsets->total * -1 # credits are negative on the DB
2441                             : 0;
2442     }
2443
2444     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2445
2446     if ( $credit_total > 0 ) {
2447         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2448         $credit = $account->add_credit(
2449             {   amount      => $credit_total,
2450                 description => 'Item Returned ' . $item_id,
2451                 type        => 'lost_item_return',
2452                 interface   => C4::Context->interface,
2453                 library_id  => $branchcode
2454             }
2455         );
2456
2457         # TODO: ->apply should just accept the accountline
2458         $credit->apply( { debits => $accountlines->reset } );
2459     }
2460
2461     # Manually set the accounttype
2462     $accountline->discard_changes->accounttype('LR');
2463     $accountline->store;
2464
2465     ModItem( { paidfor => '' }, undef, $itemnumber, { log_action => 0 } );
2466
2467     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2468         $account->reconcile_balance;
2469     }
2470
2471     return ($credit) ? $credit->id : undef;
2472 }
2473
2474 =head2 _GetCircControlBranch
2475
2476    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2477
2478 Internal function :
2479
2480 Return the library code to be used to determine which circulation
2481 policy applies to a transaction.  Looks up the CircControl and
2482 HomeOrHoldingBranch system preferences.
2483
2484 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2485
2486 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2487
2488 =cut
2489
2490 sub _GetCircControlBranch {
2491     my ($item, $borrower) = @_;
2492     my $circcontrol = C4::Context->preference('CircControl');
2493     my $branch;
2494
2495     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2496         $branch= C4::Context->userenv->{'branch'};
2497     } elsif ($circcontrol eq 'PatronLibrary') {
2498         $branch=$borrower->{branchcode};
2499     } else {
2500         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2501         $branch = $item->{$branchfield};
2502         # default to item home branch if holdingbranch is used
2503         # and is not defined
2504         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2505             $branch = $item->{homebranch};
2506         }
2507     }
2508     return $branch;
2509 }
2510
2511 =head2 GetOpenIssue
2512
2513   $issue = GetOpenIssue( $itemnumber );
2514
2515 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2516
2517 C<$itemnumber> is the item's itemnumber
2518
2519 Returns a hashref
2520
2521 =cut
2522
2523 sub GetOpenIssue {
2524   my ( $itemnumber ) = @_;
2525   return unless $itemnumber;
2526   my $dbh = C4::Context->dbh;
2527   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2528   $sth->execute( $itemnumber );
2529   return $sth->fetchrow_hashref();
2530
2531 }
2532
2533 =head2 GetBiblioIssues
2534
2535   $issues = GetBiblioIssues($biblionumber);
2536
2537 this function get all issues from a biblionumber.
2538
2539 Return:
2540 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2541 tables issues and the firstname,surname & cardnumber from borrowers.
2542
2543 =cut
2544
2545 sub GetBiblioIssues {
2546     my $biblionumber = shift;
2547     return unless $biblionumber;
2548     my $dbh   = C4::Context->dbh;
2549     my $query = "
2550         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2551         FROM issues
2552             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2553             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2554             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2555             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2556         WHERE biblio.biblionumber = ?
2557         UNION ALL
2558         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2559         FROM old_issues
2560             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2561             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2562             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2563             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2564         WHERE biblio.biblionumber = ?
2565         ORDER BY timestamp
2566     ";
2567     my $sth = $dbh->prepare($query);
2568     $sth->execute($biblionumber, $biblionumber);
2569
2570     my @issues;
2571     while ( my $data = $sth->fetchrow_hashref ) {
2572         push @issues, $data;
2573     }
2574     return \@issues;
2575 }
2576
2577 =head2 GetUpcomingDueIssues
2578
2579   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2580
2581 =cut
2582
2583 sub GetUpcomingDueIssues {
2584     my $params = shift;
2585
2586     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2587     my $dbh = C4::Context->dbh;
2588
2589     my $statement = <<END_SQL;
2590 SELECT *
2591 FROM (
2592     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2593     FROM issues
2594     LEFT JOIN items USING (itemnumber)
2595     LEFT OUTER JOIN branches USING (branchcode)
2596     WHERE returndate is NULL
2597 ) tmp
2598 WHERE days_until_due >= 0 AND days_until_due <= ?
2599 END_SQL
2600
2601     my @bind_parameters = ( $params->{'days_in_advance'} );
2602
2603     my $sth = $dbh->prepare( $statement );
2604     $sth->execute( @bind_parameters );
2605     my $upcoming_dues = $sth->fetchall_arrayref({});
2606
2607     return $upcoming_dues;
2608 }
2609
2610 =head2 CanBookBeRenewed
2611
2612   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2613
2614 Find out whether a borrowed item may be renewed.
2615
2616 C<$borrowernumber> is the borrower number of the patron who currently
2617 has the item on loan.
2618
2619 C<$itemnumber> is the number of the item to renew.
2620
2621 C<$override_limit>, if supplied with a true value, causes
2622 the limit on the number of times that the loan can be renewed
2623 (as controlled by the item type) to be ignored. Overriding also allows
2624 to renew sooner than "No renewal before" and to manually renew loans
2625 that are automatically renewed.
2626
2627 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2628 item must currently be on loan to the specified borrower; renewals
2629 must be allowed for the item's type; and the borrower must not have
2630 already renewed the loan. $error will contain the reason the renewal can not proceed
2631
2632 =cut
2633
2634 sub CanBookBeRenewed {
2635     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2636
2637     my $dbh    = C4::Context->dbh;
2638     my $renews = 1;
2639
2640     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2641     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2642     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2643     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2644
2645     my $patron = $issue->patron or return;
2646
2647     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2648
2649     # This item can fill one or more unfilled reserve, can those unfilled reserves
2650     # all be filled by other available items?
2651     if ( $resfound
2652         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2653     {
2654         my $schema = Koha::Database->new()->schema();
2655
2656         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2657         if ($item_holds) {
2658             # There is an item level hold on this item, no other item can fill the hold
2659             $resfound = 1;
2660         }
2661         else {
2662
2663             # Get all other items that could possibly fill reserves
2664             my @itemnumbers = $schema->resultset('Item')->search(
2665                 {
2666                     biblionumber => $resrec->{biblionumber},
2667                     onloan       => undef,
2668                     notforloan   => 0,
2669                     -not         => { itemnumber => $itemnumber }
2670                 },
2671                 { columns => 'itemnumber' }
2672             )->get_column('itemnumber')->all();
2673
2674             # Get all other reserves that could have been filled by this item
2675             my @borrowernumbers;
2676             while (1) {
2677                 my ( $reserve_found, $reserve, undef ) =
2678                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2679
2680                 if ($reserve_found) {
2681                     push( @borrowernumbers, $reserve->{borrowernumber} );
2682                 }
2683                 else {
2684                     last;
2685                 }
2686             }
2687
2688             # If the count of the union of the lists of reservable items for each borrower
2689             # is equal or greater than the number of borrowers, we know that all reserves
2690             # can be filled with available items. We can get the union of the sets simply
2691             # by pushing all the elements onto an array and removing the duplicates.
2692             my @reservable;
2693             my %patrons;
2694             ITEM: foreach my $itemnumber (@itemnumbers) {
2695                 my $item = Koha::Items->find( $itemnumber );
2696                 next if IsItemOnHoldAndFound( $itemnumber );
2697                 for my $borrowernumber (@borrowernumbers) {
2698                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2699                     next unless IsAvailableForItemLevelRequest($item, $patron);
2700                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2701
2702                     push @reservable, $itemnumber;
2703                     if (@reservable >= @borrowernumbers) {
2704                         $resfound = 0;
2705                         last ITEM;
2706                     }
2707                     last;
2708                 }
2709             }
2710         }
2711     }
2712     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2713
2714     return ( 1, undef ) if $override_limit;
2715
2716     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2717     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2718         {   categorycode => $patron->categorycode,
2719             itemtype     => $item->effective_itemtype,
2720             branchcode   => $branchcode
2721         }
2722     );
2723
2724     return ( 0, "too_many" )
2725       if not $issuing_rule or $issuing_rule->renewalsallowed <= $issue->renewals;
2726
2727     my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2728     my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2729     $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2730     my $restricted  = $patron->is_debarred;
2731     my $hasoverdues = $patron->has_overdues;
2732
2733     if ( $restricted and $restrictionblockrenewing ) {
2734         return ( 0, 'restriction');
2735     } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2736         return ( 0, 'overdue');
2737     }
2738
2739     if ( $issue->auto_renew ) {
2740
2741         if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2742             return ( 0, 'auto_account_expired' );
2743         }
2744
2745         if ( defined $issuing_rule->no_auto_renewal_after
2746                 and $issuing_rule->no_auto_renewal_after ne "" ) {
2747             # Get issue_date and add no_auto_renewal_after
2748             # If this is greater than today, it's too late for renewal.
2749             my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2750             $maximum_renewal_date->add(
2751                 $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
2752             );
2753             my $now = dt_from_string;
2754             if ( $now >= $maximum_renewal_date ) {
2755                 return ( 0, "auto_too_late" );
2756             }
2757         }
2758         if ( defined $issuing_rule->no_auto_renewal_after_hard_limit
2759                       and $issuing_rule->no_auto_renewal_after_hard_limit ne "" ) {
2760             # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2761             if ( dt_from_string >= dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit ) ) {
2762                 return ( 0, "auto_too_late" );
2763             }
2764         }
2765
2766         if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2767             my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2768             my $amountoutstanding = $patron->account->balance;
2769             if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2770                 return ( 0, "auto_too_much_oweing" );
2771             }
2772         }
2773     }
2774
2775     if ( defined $issuing_rule->norenewalbefore
2776         and $issuing_rule->norenewalbefore ne "" )
2777     {
2778
2779         # Calculate soonest renewal by subtracting 'No renewal before' from due date
2780         my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2781             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
2782
2783         # Depending on syspref reset the exact time, only check the date
2784         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2785             and $issuing_rule->lengthunit eq 'days' )
2786         {
2787             $soonestrenewal->truncate( to => 'day' );
2788         }
2789
2790         if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2791         {
2792             return ( 0, "auto_too_soon" ) if $issue->auto_renew;
2793             return ( 0, "too_soon" );
2794         }
2795         elsif ( $issue->auto_renew ) {
2796             return ( 0, "auto_renew" );
2797         }
2798     }
2799
2800     # Fallback for automatic renewals:
2801     # If norenewalbefore is undef, don't renew before due date.
2802     if ( $issue->auto_renew ) {
2803         my $now = dt_from_string;
2804         return ( 0, "auto_renew" )
2805           if $now >= dt_from_string( $issue->date_due, 'sql' );
2806         return ( 0, "auto_too_soon" );
2807     }
2808
2809     return ( 1, undef );
2810 }
2811
2812 =head2 AddRenewal
2813
2814   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2815
2816 Renews a loan.
2817
2818 C<$borrowernumber> is the borrower number of the patron who currently
2819 has the item.
2820
2821 C<$itemnumber> is the number of the item to renew.
2822
2823 C<$branch> is the library where the renewal took place (if any).
2824            The library that controls the circ policies for the renewal is retrieved from the issues record.
2825
2826 C<$datedue> can be a DateTime object used to set the due date.
2827
2828 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2829 this parameter is not supplied, lastreneweddate is set to the current date.
2830
2831 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2832 from the book's item type.
2833
2834 =cut
2835
2836 sub AddRenewal {
2837     my $borrowernumber  = shift;
2838     my $itemnumber      = shift or return;
2839     my $branch          = shift;
2840     my $datedue         = shift;
2841     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz);
2842
2843     my $item_object   = Koha::Items->find($itemnumber) or return;
2844     my $biblio = $item_object->biblio;
2845     my $issue  = $item_object->checkout;
2846     my $item_unblessed = $item_object->unblessed;
2847
2848     my $dbh = C4::Context->dbh;
2849
2850     return unless $issue;
2851
2852     $borrowernumber ||= $issue->borrowernumber;
2853
2854     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2855         carp 'Invalid date passed to AddRenewal.';
2856         return;
2857     }
2858
2859     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2860     my $patron_unblessed = $patron->unblessed;
2861
2862     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
2863
2864     if ( C4::Context->preference('CalculateFinesOnReturn') && $issue->is_overdue ) {
2865         _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
2866     }
2867     _FixOverduesOnReturn( $borrowernumber, $itemnumber );
2868
2869     # If the due date wasn't specified, calculate it by adding the
2870     # book's loan length to today's date or the current due date
2871     # based on the value of the RenewalPeriodBase syspref.
2872     my $itemtype = $item_object->effective_itemtype;
2873     unless ($datedue) {
2874
2875         $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2876                                         dt_from_string( $issue->date_due, 'sql' ) :
2877                                         DateTime->now( time_zone => C4::Context->tz());
2878         $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
2879     }
2880
2881     my $fees = Koha::Charges::Fees->new(
2882         {
2883             patron    => $patron,
2884             library   => $circ_library,
2885             item      => $item_object,
2886             from_date => dt_from_string( $issue->date_due, 'sql' ),
2887             to_date   => dt_from_string($datedue),
2888         }
2889     );
2890
2891     # Update the issues record to have the new due date, and a new count
2892     # of how many times it has been renewed.
2893     my $renews = $issue->renewals + 1;
2894     my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2895                             WHERE borrowernumber=?
2896                             AND itemnumber=?"
2897     );
2898
2899     $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2900
2901     # Update the renewal count on the item, and tell zebra to reindex
2902     $renews = $item_object->renewals + 1;
2903     ModItem( { renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $item_object->biblionumber, $itemnumber, { log_action => 0 } );
2904
2905     # Charge a new rental fee, if applicable
2906     my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2907     if ( $charge > 0 ) {
2908         my $description = "Renewal of Rental Item " . $biblio->title . " " .$item_object->barcode;
2909         AddIssuingCharge($issue, $charge, $description);
2910     }
2911
2912     # Charge a new accumulate rental fee, if applicable
2913     my $itemtype_object = Koha::ItemTypes->find( $itemtype );
2914     if ( $itemtype_object ) {
2915         my $accumulate_charge = $fees->accumulate_rentalcharge();
2916         if ( $accumulate_charge > 0 ) {
2917             my $type_desc = "Renewal of Daily Rental Item " . $biblio->title . " $item_unblessed->{'barcode'}";
2918             AddIssuingCharge( $issue, $accumulate_charge, $type_desc )
2919         }
2920         $charge += $accumulate_charge;
2921     }
2922
2923     # Send a renewal slip according to checkout alert preferencei
2924     if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2925         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2926         my %conditions        = (
2927             branchcode   => $branch,
2928             categorycode => $patron->categorycode,
2929             item_type    => $itemtype,
2930             notification => 'CHECKOUT',
2931         );
2932         if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2933             SendCirculationAlert(
2934                 {
2935                     type     => 'RENEWAL',
2936                     item     => $item_unblessed,
2937                     borrower => $patron->unblessed,
2938                     branch   => $branch,
2939                 }
2940             );
2941         }
2942     }
2943
2944     # Remove any OVERDUES related debarment if the borrower has no overdues
2945     if ( $patron
2946       && $patron->is_debarred
2947       && ! $patron->has_overdues
2948       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2949     ) {
2950         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2951     }
2952
2953     unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
2954         $branch = C4::Context->userenv ? C4::Context->userenv->{branch} : $branch;
2955     }
2956
2957     # Add the renewal to stats
2958     UpdateStats(
2959         {
2960             branch         => $branch,
2961             type           => 'renew',
2962             amount         => $charge,
2963             itemnumber     => $itemnumber,
2964             itemtype       => $itemtype,
2965             location       => $item_object->location,
2966             borrowernumber => $borrowernumber,
2967             ccode          => $item_object->ccode,
2968         }
2969     );
2970
2971     #Log the renewal
2972     logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
2973     return $datedue;
2974 }
2975
2976 sub GetRenewCount {
2977     # check renewal status
2978     my ( $bornum, $itemno ) = @_;
2979     my $dbh           = C4::Context->dbh;
2980     my $renewcount    = 0;
2981     my $renewsallowed = 0;
2982     my $renewsleft    = 0;
2983
2984     my $patron = Koha::Patrons->find( $bornum );
2985     my $item   = Koha::Items->find($itemno);
2986
2987     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
2988
2989     # Look in the issues table for this item, lent to this borrower,
2990     # and not yet returned.
2991
2992     # FIXME - I think this function could be redone to use only one SQL call.
2993     my $sth = $dbh->prepare(
2994         "select * from issues
2995                                 where (borrowernumber = ?)
2996                                 and (itemnumber = ?)"
2997     );
2998     $sth->execute( $bornum, $itemno );
2999     my $data = $sth->fetchrow_hashref;
3000     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3001     # $item and $borrower should be calculated
3002     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3003
3004     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3005         {   categorycode => $patron->categorycode,
3006             itemtype     => $item->effective_itemtype,
3007             branchcode   => $branchcode
3008         }
3009     );
3010
3011     $renewsallowed = $issuing_rule ? $issuing_rule->renewalsallowed : 0;
3012     $renewsleft    = $renewsallowed - $renewcount;
3013     if($renewsleft < 0){ $renewsleft = 0; }
3014     return ( $renewcount, $renewsallowed, $renewsleft );
3015 }
3016
3017 =head2 GetSoonestRenewDate
3018
3019   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3020
3021 Find out the soonest possible renew date of a borrowed item.
3022
3023 C<$borrowernumber> is the borrower number of the patron who currently
3024 has the item on loan.
3025
3026 C<$itemnumber> is the number of the item to renew.
3027
3028 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3029 renew date, based on the value "No renewal before" of the applicable
3030 issuing rule. Returns the current date if the item can already be
3031 renewed, and returns undefined if the borrower, loan, or item
3032 cannot be found.
3033
3034 =cut
3035
3036 sub GetSoonestRenewDate {
3037     my ( $borrowernumber, $itemnumber ) = @_;
3038
3039     my $dbh = C4::Context->dbh;
3040
3041     my $item      = Koha::Items->find($itemnumber)      or return;
3042     my $itemissue = $item->checkout or return;
3043
3044     $borrowernumber ||= $itemissue->borrowernumber;
3045     my $patron = Koha::Patrons->find( $borrowernumber )
3046       or return;
3047
3048     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3049     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3050         {   categorycode => $patron->categorycode,
3051             itemtype     => $item->effective_itemtype,
3052             branchcode   => $branchcode
3053         }
3054     );
3055
3056     my $now = dt_from_string;
3057     return $now unless $issuing_rule;
3058
3059     if ( defined $issuing_rule->norenewalbefore
3060         and $issuing_rule->norenewalbefore ne "" )
3061     {
3062         my $soonestrenewal =
3063           dt_from_string( $itemissue->date_due )->subtract(
3064             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
3065
3066         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3067             and $issuing_rule->lengthunit eq 'days' )
3068         {
3069             $soonestrenewal->truncate( to => 'day' );
3070         }
3071         return $soonestrenewal if $now < $soonestrenewal;
3072     }
3073     return $now;
3074 }
3075
3076 =head2 GetLatestAutoRenewDate
3077
3078   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3079
3080 Find out the latest possible auto renew date of a borrowed item.
3081
3082 C<$borrowernumber> is the borrower number of the patron who currently
3083 has the item on loan.
3084
3085 C<$itemnumber> is the number of the item to renew.
3086
3087 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3088 auto renew date, based on the value "No auto renewal after" and the "No auto
3089 renewal after (hard limit) of the applicable issuing rule.
3090 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3091 or item cannot be found.
3092
3093 =cut
3094
3095 sub GetLatestAutoRenewDate {
3096     my ( $borrowernumber, $itemnumber ) = @_;
3097
3098     my $dbh = C4::Context->dbh;
3099
3100     my $item      = Koha::Items->find($itemnumber)  or return;
3101     my $itemissue = $item->checkout                 or return;
3102
3103     $borrowernumber ||= $itemissue->borrowernumber;
3104     my $patron = Koha::Patrons->find( $borrowernumber )
3105       or return;
3106
3107     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3108     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3109         {   categorycode => $patron->categorycode,
3110             itemtype     => $item->effective_itemtype,
3111             branchcode   => $branchcode
3112         }
3113     );
3114
3115     return unless $issuing_rule;
3116     return
3117       if ( not $issuing_rule->no_auto_renewal_after
3118             or $issuing_rule->no_auto_renewal_after eq '' )
3119       and ( not $issuing_rule->no_auto_renewal_after_hard_limit
3120              or $issuing_rule->no_auto_renewal_after_hard_limit eq '' );
3121
3122     my $maximum_renewal_date;
3123     if ( $issuing_rule->no_auto_renewal_after ) {
3124         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3125         $maximum_renewal_date->add(
3126             $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
3127         );
3128     }
3129
3130     if ( $issuing_rule->no_auto_renewal_after_hard_limit ) {
3131         my $dt = dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit );
3132         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3133     }
3134     return $maximum_renewal_date;
3135 }
3136
3137
3138 =head2 GetIssuingCharges
3139
3140   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3141
3142 Calculate how much it would cost for a given patron to borrow a given
3143 item, including any applicable discounts.
3144
3145 C<$itemnumber> is the item number of item the patron wishes to borrow.
3146
3147 C<$borrowernumber> is the patron's borrower number.
3148
3149 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3150 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3151 if it's a video).
3152
3153 =cut
3154
3155 sub GetIssuingCharges {
3156
3157     # calculate charges due
3158     my ( $itemnumber, $borrowernumber ) = @_;
3159     my $charge = 0;
3160     my $dbh    = C4::Context->dbh;
3161     my $item_type;
3162
3163     # Get the book's item type and rental charge (via its biblioitem).
3164     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3165         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3166     $charge_query .= (C4::Context->preference('item-level_itypes'))
3167         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3168         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3169
3170     $charge_query .= ' WHERE items.itemnumber =?';
3171
3172     my $sth = $dbh->prepare($charge_query);
3173     $sth->execute($itemnumber);
3174     if ( my $item_data = $sth->fetchrow_hashref ) {
3175         $item_type = $item_data->{itemtype};
3176         $charge    = $item_data->{rentalcharge};
3177         my $branch = C4::Context::mybranch();
3178         my $discount_query = q|SELECT rentaldiscount,
3179             issuingrules.itemtype, issuingrules.branchcode
3180             FROM borrowers
3181             LEFT JOIN issuingrules ON borrowers.categorycode = issuingrules.categorycode
3182             WHERE borrowers.borrowernumber = ?
3183             AND (issuingrules.itemtype = ? OR issuingrules.itemtype = '*')
3184             AND (issuingrules.branchcode = ? OR issuingrules.branchcode = '*')|;
3185         my $discount_sth = $dbh->prepare($discount_query);
3186         $discount_sth->execute( $borrowernumber, $item_type, $branch );
3187         my $discount_rules = $discount_sth->fetchall_arrayref({});
3188         if (@{$discount_rules}) {
3189             # We may have multiple rules so get the most specific
3190             my $discount = _get_discount_from_rule($discount_rules, $branch, $item_type);
3191             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3192         }
3193         if ($charge) {
3194             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3195         }
3196     }
3197
3198     return ( $charge, $item_type );
3199 }
3200
3201 # Select most appropriate discount rule from those returned
3202 sub _get_discount_from_rule {
3203     my ($rules_ref, $branch, $itemtype) = @_;
3204     my $discount;
3205
3206     if (@{$rules_ref} == 1) { # only 1 applicable rule use it
3207         $discount = $rules_ref->[0]->{rentaldiscount};
3208         return (defined $discount) ? $discount : 0;
3209     }
3210     # could have up to 4 does one match $branch and $itemtype
3211     my @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq $itemtype } @{$rules_ref};
3212     if (@d) {
3213         $discount = $d[0]->{rentaldiscount};
3214         return (defined $discount) ? $discount : 0;
3215     }
3216     # do we have item type + all branches
3217     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq $itemtype } @{$rules_ref};
3218     if (@d) {
3219         $discount = $d[0]->{rentaldiscount};
3220         return (defined $discount) ? $discount : 0;
3221     }
3222     # do we all item types + this branch
3223     @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq q{*} } @{$rules_ref};
3224     if (@d) {
3225         $discount = $d[0]->{rentaldiscount};
3226         return (defined $discount) ? $discount : 0;
3227     }
3228     # so all and all (surely we wont get here)
3229     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq q{*} } @{$rules_ref};
3230     if (@d) {
3231         $discount = $d[0]->{rentaldiscount};
3232         return (defined $discount) ? $discount : 0;
3233     }
3234     # none of the above
3235     return 0;
3236 }
3237
3238 =head2 AddIssuingCharge
3239
3240   &AddIssuingCharge( $checkout, $charge, [$description] )
3241
3242 =cut
3243
3244 sub AddIssuingCharge {
3245     my ( $checkout, $charge, $description ) = @_;
3246
3247     # FIXME What if checkout does not exist?
3248
3249     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3250     my $accountline = $account->add_debit(
3251         {
3252             amount      => $charge,
3253             description => $description,
3254             note        => undef,
3255             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3256             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3257             interface   => C4::Context->interface,
3258             type        => 'rent',
3259             item_id     => $checkout->itemnumber,
3260             issue_id    => $checkout->issue_id,
3261         }
3262     );
3263 }
3264
3265 =head2 GetTransfers
3266
3267   GetTransfers($itemnumber);
3268
3269 =cut
3270
3271 sub GetTransfers {
3272     my ($itemnumber) = @_;
3273
3274     my $dbh = C4::Context->dbh;
3275
3276     my $query = '
3277         SELECT datesent,
3278                frombranch,
3279                tobranch,
3280                branchtransfer_id
3281         FROM branchtransfers
3282         WHERE itemnumber = ?
3283           AND datearrived IS NULL
3284         ';
3285     my $sth = $dbh->prepare($query);
3286     $sth->execute($itemnumber);
3287     my @row = $sth->fetchrow_array();
3288     return @row;
3289 }
3290
3291 =head2 GetTransfersFromTo
3292
3293   @results = GetTransfersFromTo($frombranch,$tobranch);
3294
3295 Returns the list of pending transfers between $from and $to branch
3296
3297 =cut
3298
3299 sub GetTransfersFromTo {
3300     my ( $frombranch, $tobranch ) = @_;
3301     return unless ( $frombranch && $tobranch );
3302     my $dbh   = C4::Context->dbh;
3303     my $query = "
3304         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3305         FROM   branchtransfers
3306         WHERE  frombranch=?
3307           AND  tobranch=?
3308           AND datearrived IS NULL
3309     ";
3310     my $sth = $dbh->prepare($query);
3311     $sth->execute( $frombranch, $tobranch );
3312     my @gettransfers;
3313
3314     while ( my $data = $sth->fetchrow_hashref ) {
3315         push @gettransfers, $data;
3316     }
3317     return (@gettransfers);
3318 }
3319
3320 =head2 DeleteTransfer
3321
3322   &DeleteTransfer($itemnumber);
3323
3324 =cut
3325
3326 sub DeleteTransfer {
3327     my ($itemnumber) = @_;
3328     return unless $itemnumber;
3329     my $dbh          = C4::Context->dbh;
3330     my $sth          = $dbh->prepare(
3331         "DELETE FROM branchtransfers
3332          WHERE itemnumber=?
3333          AND datearrived IS NULL "
3334     );
3335     return $sth->execute($itemnumber);
3336 }
3337
3338 =head2 SendCirculationAlert
3339
3340 Send out a C<check-in> or C<checkout> alert using the messaging system.
3341
3342 B<Parameters>:
3343
3344 =over 4
3345
3346 =item type
3347
3348 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3349
3350 =item item
3351
3352 Hashref of information about the item being checked in or out.
3353
3354 =item borrower
3355
3356 Hashref of information about the borrower of the item.
3357
3358 =item branch
3359
3360 The branchcode from where the checkout or check-in took place.
3361
3362 =back
3363
3364 B<Example>:
3365
3366     SendCirculationAlert({
3367         type     => 'CHECKOUT',
3368         item     => $item,
3369         borrower => $borrower,
3370         branch   => $branch,
3371     });
3372
3373 =cut
3374
3375 sub SendCirculationAlert {
3376     my ($opts) = @_;
3377     my ($type, $item, $borrower, $branch) =
3378         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3379     my %message_name = (
3380         CHECKIN  => 'Item_Check_in',
3381         CHECKOUT => 'Item_Checkout',
3382         RENEWAL  => 'Item_Checkout',
3383     );
3384     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3385         borrowernumber => $borrower->{borrowernumber},
3386         message_name   => $message_name{$type},
3387     });
3388     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3389
3390     my $schema = Koha::Database->new->schema;
3391     my @transports = keys %{ $borrower_preferences->{transports} };
3392
3393     # From the MySQL doc:
3394     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3395     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3396     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3397     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3398
3399     for my $mtt (@transports) {
3400         my $letter =  C4::Letters::GetPreparedLetter (
3401             module => 'circulation',
3402             letter_code => $type,
3403             branchcode => $branch,
3404             message_transport_type => $mtt,
3405             lang => $borrower->{lang},
3406             tables => {
3407                 $issues_table => $item->{itemnumber},
3408                 'items'       => $item->{itemnumber},
3409                 'biblio'      => $item->{biblionumber},
3410                 'biblioitems' => $item->{biblionumber},
3411                 'borrowers'   => $borrower,
3412                 'branches'    => $branch,
3413             }
3414         ) or next;
3415
3416         $schema->storage->txn_begin;
3417         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3418         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3419         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3420         unless ( $message ) {
3421             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3422             C4::Message->enqueue($letter, $borrower, $mtt);
3423         } else {
3424             $message->append($letter);
3425             $message->update;
3426         }
3427         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3428         $schema->storage->txn_commit;
3429     }
3430
3431     return;
3432 }
3433
3434 =head2 updateWrongTransfer
3435
3436   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3437
3438 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3439
3440 =cut
3441
3442 sub updateWrongTransfer {
3443         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3444         my $dbh = C4::Context->dbh;
3445 # first step validate the actual line of transfert .
3446         my $sth =
3447                 $dbh->prepare(
3448                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3449                 );
3450                 $sth->execute($FromLibrary,$itemNumber);
3451
3452 # second step create a new line of branchtransfer to the right location .
3453         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3454
3455 #third step changing holdingbranch of item
3456         UpdateHoldingbranch($FromLibrary,$itemNumber);
3457 }
3458
3459 =head2 UpdateHoldingbranch
3460
3461   $items = UpdateHoldingbranch($branch,$itmenumber);
3462
3463 Simple methode for updating hodlingbranch in items BDD line
3464
3465 =cut
3466
3467 sub UpdateHoldingbranch {
3468         my ( $branch,$itemnumber ) = @_;
3469     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3470 }
3471
3472 =head2 CalcDateDue
3473
3474 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3475
3476 this function calculates the due date given the start date and configured circulation rules,
3477 checking against the holidays calendar as per the 'useDaysMode' syspref.
3478 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3479 C<$itemtype>  = itemtype code of item in question
3480 C<$branch>  = location whose calendar to use
3481 C<$borrower> = Borrower object
3482 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3483
3484 =cut
3485
3486 sub CalcDateDue {
3487     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3488
3489     $isrenewal ||= 0;
3490
3491     # loanlength now a href
3492     my $loanlength =
3493             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3494
3495     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3496             ? qq{renewalperiod}
3497             : qq{issuelength};
3498
3499     my $datedue;
3500     if ( $startdate ) {
3501         if (ref $startdate ne 'DateTime' ) {
3502             $datedue = dt_from_string($datedue);
3503         } else {
3504             $datedue = $startdate->clone;
3505         }
3506     } else {
3507         $datedue =
3508           DateTime->now( time_zone => C4::Context->tz() )
3509           ->truncate( to => 'minute' );
3510     }
3511
3512
3513     # calculate the datedue as normal
3514     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3515     {    # ignoring calendar
3516         if ( $loanlength->{lengthunit} eq 'hours' ) {
3517             $datedue->add( hours => $loanlength->{$length_key} );
3518         } else {    # days
3519             $datedue->add( days => $loanlength->{$length_key} );
3520             $datedue->set_hour(23);
3521             $datedue->set_minute(59);
3522         }
3523     } else {
3524         my $dur;
3525         if ($loanlength->{lengthunit} eq 'hours') {
3526             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3527         }
3528         else { # days
3529             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3530         }
3531         my $calendar = Koha::Calendar->new( branchcode => $branch );
3532         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3533         if ($loanlength->{lengthunit} eq 'days') {
3534             $datedue->set_hour(23);
3535             $datedue->set_minute(59);
3536         }
3537     }
3538
3539     # if Hard Due Dates are used, retrieve them and apply as necessary
3540     my ( $hardduedate, $hardduedatecompare ) =
3541       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3542     if ($hardduedate) {    # hardduedates are currently dates
3543         $hardduedate->truncate( to => 'minute' );
3544         $hardduedate->set_hour(23);
3545         $hardduedate->set_minute(59);
3546         my $cmp = DateTime->compare( $hardduedate, $datedue );
3547
3548 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3549 # if the calculated date is before the 'after' Hard Due Date (floor), override
3550 # if the hard due date is set to 'exactly', overrride
3551         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3552             $datedue = $hardduedate->clone;
3553         }
3554
3555         # in all other cases, keep the date due as it is
3556
3557     }
3558
3559     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3560     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3561         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3562         if( $expiry_dt ) { #skip empty expiry date..
3563             $expiry_dt->set( hour => 23, minute => 59);
3564             my $d1= $datedue->clone->set_time_zone('floating');
3565             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3566                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3567             }
3568         }
3569         if ( C4::Context->preference('useDaysMode') ne 'Days' ) {
3570           my $calendar = Koha::Calendar->new( branchcode => $branch );
3571           if ( $calendar->is_holiday($datedue) ) {
3572               # Don't return on a closed day
3573               $datedue = $calendar->prev_open_day( $datedue );
3574           }
3575         }
3576     }
3577
3578     return $datedue;
3579 }
3580
3581
3582 sub CheckValidBarcode{
3583 my ($barcode) = @_;
3584 my $dbh = C4::Context->dbh;
3585 my $query=qq|SELECT count(*)
3586              FROM items
3587              WHERE barcode=?
3588             |;
3589 my $sth = $dbh->prepare($query);
3590 $sth->execute($barcode);
3591 my $exist=$sth->fetchrow ;
3592 return $exist;
3593 }
3594
3595 =head2 IsBranchTransferAllowed
3596
3597   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3598
3599 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3600
3601 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3602 Koha::Item->can_be_transferred.
3603
3604 =cut
3605
3606 sub IsBranchTransferAllowed {
3607         my ( $toBranch, $fromBranch, $code ) = @_;
3608
3609         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3610
3611         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3612         my $dbh = C4::Context->dbh;
3613
3614         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3615         $sth->execute( $toBranch, $fromBranch, $code );
3616         my $limit = $sth->fetchrow_hashref();
3617
3618         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3619         if ( $limit->{'limitId'} ) {
3620                 return 0;
3621         } else {
3622                 return 1;
3623         }
3624 }
3625
3626 =head2 CreateBranchTransferLimit
3627
3628   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3629
3630 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3631
3632 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3633
3634 =cut
3635
3636 sub CreateBranchTransferLimit {
3637    my ( $toBranch, $fromBranch, $code ) = @_;
3638    return unless defined($toBranch) && defined($fromBranch);
3639    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3640
3641    my $dbh = C4::Context->dbh;
3642
3643    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3644    return $sth->execute( $code, $toBranch, $fromBranch );
3645 }
3646
3647 =head2 DeleteBranchTransferLimits
3648
3649     my $result = DeleteBranchTransferLimits($frombranch);
3650
3651 Deletes all the library transfer limits for one library.  Returns the
3652 number of limits deleted, 0e0 if no limits were deleted, or undef if
3653 no arguments are supplied.
3654
3655 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3656     fromBranch => $fromBranch
3657     })->delete.
3658
3659 =cut
3660
3661 sub DeleteBranchTransferLimits {
3662     my $branch = shift;
3663     return unless defined $branch;
3664     my $dbh    = C4::Context->dbh;
3665     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3666     return $sth->execute($branch);
3667 }
3668
3669 sub ReturnLostItem{
3670     my ( $borrowernumber, $itemnum ) = @_;
3671
3672     MarkIssueReturned( $borrowernumber, $itemnum );
3673     my $patron = Koha::Patrons->find( $borrowernumber );
3674     my $item = Koha::Items->find($itemnum);
3675     my $old_note = ($item->paidfor && ($item->paidfor ne q{})) ? $item->paidfor.' / ' : q{};
3676     my @datearr = localtime(time);
3677     my $date = ( 1900 + $datearr[5] ) . "-" . ( $datearr[4] + 1 ) . "-" . $datearr[3];
3678     my $bor = $patron->firstname . ' ' . $patron->surname . ' ' . $patron->cardnumber;
3679     ModItem({ paidfor =>  $old_note."Paid for by $bor $date" }, undef, $itemnum);
3680 }
3681
3682
3683 sub LostItem{
3684     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3685
3686     unless ( $mark_lost_from ) {
3687         # Temporary check to avoid regressions
3688         die q|LostItem called without $mark_lost_from, check the API.|;
3689     }
3690
3691     my $mark_returned;
3692     if ( $force_mark_returned ) {
3693         $mark_returned = 1;
3694     } else {
3695         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3696         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3697     }
3698
3699     my $dbh = C4::Context->dbh();
3700     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3701                            FROM issues
3702                            JOIN items USING (itemnumber)
3703                            JOIN biblio USING (biblionumber)
3704                            WHERE issues.itemnumber=?");
3705     $sth->execute($itemnumber);
3706     my $issues=$sth->fetchrow_hashref();
3707
3708     # If a borrower lost the item, add a replacement cost to the their record
3709     if ( my $borrowernumber = $issues->{borrowernumber} ){
3710         my $patron = Koha::Patrons->find( $borrowernumber );
3711
3712         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 0); # 1, 0 = exemptfine, no-dropbox
3713         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3714
3715         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3716             C4::Accounts::chargelostitem($borrowernumber, $itemnumber, $issues->{'replacementprice'}, "$issues->{'title'} $issues->{'barcode'} $issues->{'itemcallnumber'}");
3717             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3718             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3719         }
3720
3721         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3722     }
3723
3724     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3725     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3726         ModItem({holdingbranch => $frombranch}, undef, $itemnumber);
3727     }
3728     my $transferdeleted = DeleteTransfer($itemnumber);
3729 }
3730
3731 sub GetOfflineOperations {
3732     my $dbh = C4::Context->dbh;
3733     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3734     $sth->execute(C4::Context->userenv->{'branch'});
3735     my $results = $sth->fetchall_arrayref({});
3736     return $results;
3737 }
3738
3739 sub GetOfflineOperation {
3740     my $operationid = shift;
3741     return unless $operationid;
3742     my $dbh = C4::Context->dbh;
3743     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3744     $sth->execute( $operationid );
3745     return $sth->fetchrow_hashref;
3746 }
3747
3748 sub AddOfflineOperation {
3749     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3750     my $dbh = C4::Context->dbh;
3751     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3752     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3753     return "Added.";
3754 }
3755
3756 sub DeleteOfflineOperation {
3757     my $dbh = C4::Context->dbh;
3758     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3759     $sth->execute( shift );
3760     return "Deleted.";
3761 }
3762
3763 sub ProcessOfflineOperation {
3764     my $operation = shift;
3765
3766     my $report;
3767     if ( $operation->{action} eq 'return' ) {
3768         $report = ProcessOfflineReturn( $operation );
3769     } elsif ( $operation->{action} eq 'issue' ) {
3770         $report = ProcessOfflineIssue( $operation );
3771     } elsif ( $operation->{action} eq 'payment' ) {
3772         $report = ProcessOfflinePayment( $operation );
3773     }
3774
3775     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3776
3777     return $report;
3778 }
3779
3780 sub ProcessOfflineReturn {
3781     my $operation = shift;
3782
3783     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3784
3785     if ( $item ) {
3786         my $itemnumber = $item->itemnumber;
3787         my $issue = GetOpenIssue( $itemnumber );
3788         if ( $issue ) {
3789             MarkIssueReturned(
3790                 $issue->{borrowernumber},
3791                 $itemnumber,
3792                 $operation->{timestamp},
3793             );
3794             ModItem(
3795                 { renewals => 0, onloan => undef },
3796                 $issue->{'biblionumber'},
3797                 $itemnumber,
3798                 { log_action => 0 }
3799             );
3800             return "Success.";
3801         } else {
3802             return "Item not issued.";
3803         }
3804     } else {
3805         return "Item not found.";
3806     }
3807 }
3808
3809 sub ProcessOfflineIssue {
3810     my $operation = shift;
3811
3812     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3813
3814     if ( $patron ) {
3815         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3816         unless ($item) {
3817             return "Barcode not found.";
3818         }
3819         my $itemnumber = $item->itemnumber;
3820         my $issue = GetOpenIssue( $itemnumber );
3821
3822         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3823             MarkIssueReturned(
3824                 $issue->{borrowernumber},
3825                 $itemnumber,
3826                 $operation->{timestamp},
3827             );
3828         }
3829         AddIssue(
3830             $patron->unblessed,
3831             $operation->{'barcode'},
3832             undef,
3833             1,
3834             $operation->{timestamp},
3835             undef,
3836         );
3837         return "Success.";
3838     } else {
3839         return "Borrower not found.";
3840     }
3841 }
3842
3843 sub ProcessOfflinePayment {
3844     my $operation = shift;
3845
3846     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
3847
3848     $patron->account->pay(
3849         {
3850             amount     => $operation->{amount},
3851             library_id => $operation->{branchcode},
3852             interface  => 'koc'
3853         }
3854     );
3855
3856     return "Success.";
3857 }
3858
3859 =head2 TransferSlip
3860
3861   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3862
3863   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3864
3865 =cut
3866
3867 sub TransferSlip {
3868     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3869
3870     my $item =
3871       $itemnumber
3872       ? Koha::Items->find($itemnumber)
3873       : Koha::Items->find( { barcode => $barcode } );
3874
3875     $item or return;
3876
3877     return C4::Letters::GetPreparedLetter (
3878         module => 'circulation',
3879         letter_code => 'TRANSFERSLIP',
3880         branchcode => $branch,
3881         tables => {
3882             'branches'    => $to_branch,
3883             'biblio'      => $item->biblionumber,
3884             'items'       => $item->unblessed,
3885         },
3886     );
3887 }
3888
3889 =head2 CheckIfIssuedToPatron
3890
3891   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3892
3893   Return 1 if any record item is issued to patron, otherwise return 0
3894
3895 =cut
3896
3897 sub CheckIfIssuedToPatron {
3898     my ($borrowernumber, $biblionumber) = @_;
3899
3900     my $dbh = C4::Context->dbh;
3901     my $query = q|
3902         SELECT COUNT(*) FROM issues
3903         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3904         WHERE items.biblionumber = ?
3905         AND issues.borrowernumber = ?
3906     |;
3907     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3908     return 1 if $is_issued;
3909     return;
3910 }
3911
3912 =head2 IsItemIssued
3913
3914   IsItemIssued( $itemnumber )
3915
3916   Return 1 if the item is on loan, otherwise return 0
3917
3918 =cut
3919
3920 sub IsItemIssued {
3921     my $itemnumber = shift;
3922     my $dbh = C4::Context->dbh;
3923     my $sth = $dbh->prepare(q{
3924         SELECT COUNT(*)
3925         FROM issues
3926         WHERE itemnumber = ?
3927     });
3928     $sth->execute($itemnumber);
3929     return $sth->fetchrow;
3930 }
3931
3932 =head2 GetAgeRestriction
3933
3934   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
3935   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
3936
3937   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
3938   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
3939
3940 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
3941 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
3942 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
3943          Negative days mean the borrower has gone past the age restriction age.
3944
3945 =cut
3946
3947 sub GetAgeRestriction {
3948     my ($record_restrictions, $borrower) = @_;
3949     my $markers = C4::Context->preference('AgeRestrictionMarker');
3950
3951     # Split $record_restrictions to something like FSK 16 or PEGI 6
3952     my @values = split ' ', uc($record_restrictions);
3953     return unless @values;
3954
3955     # Search first occurrence of one of the markers
3956     my @markers = split /\|/, uc($markers);
3957     return unless @markers;
3958
3959     my $index            = 0;
3960     my $restriction_year = 0;
3961     for my $value (@values) {
3962         $index++;
3963         for my $marker (@markers) {
3964             $marker =~ s/^\s+//;    #remove leading spaces
3965             $marker =~ s/\s+$//;    #remove trailing spaces
3966             if ( $marker eq $value ) {
3967                 if ( $index <= $#values ) {
3968                     $restriction_year += $values[$index];
3969                 }
3970                 last;
3971             }
3972             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
3973
3974                 # Perhaps it is something like "K16" (as in Finland)
3975                 $restriction_year += $1;
3976                 last;
3977             }
3978         }
3979         last if ( $restriction_year > 0 );
3980     }
3981
3982     #Check if the borrower is age restricted for this material and for how long.
3983     if ($restriction_year && $borrower) {
3984         if ( $borrower->{'dateofbirth'} ) {
3985             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
3986             $alloweddate[0] += $restriction_year;
3987
3988             #Prevent runime eror on leap year (invalid date)
3989             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
3990                 $alloweddate[2] = 28;
3991             }
3992
3993             #Get how many days the borrower has to reach the age restriction
3994             my @Today = split /-/, DateTime->today->ymd();
3995             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
3996             #Negative days means the borrower went past the age restriction age
3997             return ($restriction_year, $daysToAgeRestriction);
3998         }
3999     }
4000
4001     return ($restriction_year);
4002 }
4003
4004
4005 =head2 GetPendingOnSiteCheckouts
4006
4007 =cut
4008
4009 sub GetPendingOnSiteCheckouts {
4010     my $dbh = C4::Context->dbh;
4011     return $dbh->selectall_arrayref(q|
4012         SELECT
4013           items.barcode,
4014           items.biblionumber,
4015           items.itemnumber,
4016           items.itemnotes,
4017           items.itemcallnumber,
4018           items.location,
4019           issues.date_due,
4020           issues.branchcode,
4021           issues.date_due < NOW() AS is_overdue,
4022           biblio.author,
4023           biblio.title,
4024           borrowers.firstname,
4025           borrowers.surname,
4026           borrowers.cardnumber,
4027           borrowers.borrowernumber
4028         FROM items
4029         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4030         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4031         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4032         WHERE issues.onsite_checkout = 1
4033     |, { Slice => {} } );
4034 }
4035
4036 sub GetTopIssues {
4037     my ($params) = @_;
4038
4039     my ($count, $branch, $itemtype, $ccode, $newness)
4040         = @$params{qw(count branch itemtype ccode newness)};
4041
4042     my $dbh = C4::Context->dbh;
4043     my $query = q{
4044         SELECT * FROM (
4045         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4046           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4047           i.ccode, SUM(i.issues) AS count
4048         FROM biblio b
4049         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4050         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4051     };
4052
4053     my (@where_strs, @where_args);
4054
4055     if ($branch) {
4056         push @where_strs, 'i.homebranch = ?';
4057         push @where_args, $branch;
4058     }
4059     if ($itemtype) {
4060         if (C4::Context->preference('item-level_itypes')){
4061             push @where_strs, 'i.itype = ?';
4062             push @where_args, $itemtype;
4063         } else {
4064             push @where_strs, 'bi.itemtype = ?';
4065             push @where_args, $itemtype;
4066         }
4067     }
4068     if ($ccode) {
4069         push @where_strs, 'i.ccode = ?';
4070         push @where_args, $ccode;
4071     }
4072     if ($newness) {
4073         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4074         push @where_args, $newness;
4075     }
4076
4077     if (@where_strs) {
4078         $query .= 'WHERE ' . join(' AND ', @where_strs);
4079     }
4080
4081     $query .= q{
4082         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4083           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4084           i.ccode
4085         ORDER BY count DESC
4086     };
4087
4088     $query .= q{ ) xxx WHERE count > 0 };
4089     $count = int($count);
4090     if ($count > 0) {
4091         $query .= "LIMIT $count";
4092     }
4093
4094     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4095
4096     return @$rows;
4097 }
4098
4099 sub _CalculateAndUpdateFine {
4100     my ($params) = @_;
4101
4102     my $borrower    = $params->{borrower};
4103     my $item        = $params->{item};
4104     my $issue       = $params->{issue};
4105     my $return_date = $params->{return_date};
4106
4107     unless ($borrower) { carp "No borrower passed in!" && return; }
4108     unless ($item)     { carp "No item passed in!"     && return; }
4109     unless ($issue)    { carp "No issue passed in!"    && return; }
4110
4111     my $datedue = dt_from_string( $issue->date_due );
4112
4113     # we only need to calculate and change the fines if we want to do that on return
4114     # Should be on for hourly loans
4115     my $control = C4::Context->preference('CircControl');
4116     my $control_branchcode =
4117         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4118       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4119       :                                     $issue->branchcode;
4120
4121     my $date_returned = $return_date ? $return_date : dt_from_string();
4122
4123     my ( $amount, $unitcounttotal, $unitcount  ) =
4124       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4125
4126     if ( C4::Context->preference('finesMode') eq 'production' ) {
4127         if ( $amount > 0 ) {
4128             C4::Overdues::UpdateFine({
4129                 issue_id       => $issue->issue_id,
4130                 itemnumber     => $issue->itemnumber,
4131                 borrowernumber => $issue->borrowernumber,
4132                 amount         => $amount,
4133                 due            => output_pref($datedue),
4134             });
4135         }
4136         elsif ($return_date) {
4137
4138             # Backdated returns may have fines that shouldn't exist,
4139             # so in this case, we need to drop those fines to 0
4140
4141             C4::Overdues::UpdateFine({
4142                 issue_id       => $issue->issue_id,
4143                 itemnumber     => $issue->itemnumber,
4144                 borrowernumber => $issue->borrowernumber,
4145                 amount         => 0,
4146                 due            => output_pref($datedue),
4147             });
4148         }
4149     }
4150 }
4151
4152 sub _item_denied_renewal {
4153     my ($params) = @_;
4154
4155     my $item = $params->{item};
4156     return unless $item;
4157
4158     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4159     return unless $denyingrules;
4160     foreach my $field (keys %$denyingrules) {
4161         my $val = $item->$field;
4162         if( !defined $val) {
4163             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4164                 return 1;
4165             }
4166         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4167            # If the results matches the values in the syspref
4168            # We return true if match found
4169             return 1;
4170         }
4171     }
4172     return 0;
4173 }
4174
4175
4176 1;
4177
4178 __END__
4179
4180 =head1 AUTHOR
4181
4182 Koha Development Team <http://koha-community.org/>
4183
4184 =cut