C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBI;
 101 use ZOOM;
 102 use XML::Simple;
 103 use C4::Boolean;
 104 use C4::Debug;
 105 use POSIX ();
 106 use DateTime::TimeZone;
 107 use Module::Load::Conditional qw(can_load);
 108 use Carp;
 109
 110 =head1 NAME
 111
 112 C4::Context - Maintain and manipulate the context of a Koha script
 113
 114 =head1 SYNOPSIS
 115
 116   use C4::Context;
 117
 118   use C4::Context("/path/to/koha-conf.xml");
 119
 120   $config_value = C4::Context->config("config_variable");
 121
 122   $koha_preference = C4::Context->preference("preference");
 123
 124   $db_handle = C4::Context->dbh;
 125
 126   $Zconn = C4::Context->Zconn;
 127
 128   $stopwordhash = C4::Context->stopwords;
 129
 130 =head1 DESCRIPTION
 131
 132 When a Koha script runs, it makes use of a certain number of things:
 133 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 134 databases, and so forth. These things make up the I<context> in which
 135 the script runs.
 136
 137 This module takes care of setting up the context for a script:
 138 figuring out which configuration file to load, and loading it, opening
 139 a connection to the right database, and so forth.
 140
 141 Most scripts will only use one context. They can simply have
 142
 143   use C4::Context;
 144
 145 at the top.
 146
 147 Other scripts may need to use several contexts. For instance, if a
 148 library has two databases, one for a certain collection, and the other
 149 for everything else, it might be necessary for a script to use two
 150 different contexts to search both databases. Such scripts should use
 151 the C<&set_context> and C<&restore_context> functions, below.
 152
 153 By default, C4::Context reads the configuration from
 154 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 155 environment variable to the pathname of a configuration file to use.
 156
 157 =head1 METHODS
 158
 159 =cut
 160
 161 #'
 162 # In addition to what is said in the POD above, a Context object is a
 163 # reference-to-hash with the following fields:
 164 #
 165 # config
 166 #    A reference-to-hash whose keys and values are the
 167 #    configuration variables and values specified in the config
 168 #    file (/etc/koha/koha-conf.xml).
 169 # dbh
 170 #    A handle to the appropriate database for this context.
 171 # dbh_stack
 172 #    Used by &set_dbh and &restore_dbh to hold other database
 173 #    handles for this context.
 174 # Zconn
 175 #     A connection object for the Zebra server
 176
 177 # Koha's main configuration file koha-conf.xml
 178 # is searched for according to this priority list:
 179 #
 180 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 181 # 2. Path supplied in KOHA_CONF environment variable.
 182 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 183 #    as value has changed from its default of
 184 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 185 #    when Koha is installed in 'standard' or 'single'
 186 #    mode.
 187 # 4. Path supplied in CONFIG_FNAME.
 188 #
 189 # The first entry that refers to a readable file is used.
 190
 191 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 192                 # Default config file, if none is specified
 193
 194 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 195                 # path to config file set by installer
 196                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 197                 # when Koha is installed in 'standard' or 'single'
 198                 # mode.  If Koha was installed in 'dev' mode,
 199                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 200                 # developers should set the KOHA_CONF environment variable
 201
 202 $context = undef;        # Initially, no context is set
 203 @context_stack = ();        # Initially, no saved contexts
 204
 205
 206 =head2 KOHAVERSION
 207
 208 returns the kohaversion stored in kohaversion.pl file
 209
 210 =cut
 211
 212 sub KOHAVERSION {
 213     my $cgidir = C4::Context->intranetdir;
 214
 215     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 216     # but distribution code does?  (Stan, 1jan08)
 217     if(-d $cgidir . "/cgi-bin"){
 218         my $cgidir .= "/cgi-bin";
 219     }
 220
 221     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 222     return kohaversion();
 223 }
 224
 225 =head2 final_linear_version
 226
 227 Returns the version number of the final update to run in updatedatabase.pl.
 228 This number is equal to the version in kohaversion.pl
 229
 230 =cut
 231
 232 sub final_linear_version {
 233     return KOHAVERSION;
 234 }
 235
 236 =head2 read_config_file
 237
 238 Reads the specified Koha config file.
 239
 240 Returns an object containing the configuration variables. The object's
 241 structure is a bit complex to the uninitiated ... take a look at the
 242 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 243 here are a few examples that may give you what you need:
 244
 245 The simple elements nested within the <config> element:
 246
 247     my $pass = $koha->{'config'}->{'pass'};
 248
 249 The <listen> elements:
 250
 251     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 252
 253 The elements nested within the <server> element:
 254
 255     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 256
 257 Returns undef in case of error.
 258
 259 =cut
 260
 261 sub read_config_file {          # Pass argument naming config file to read
 262     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 263
 264     if ($ismemcached) {
 265       $memcached->set('kohaconf',$koha);
 266     }
 267
 268     return $koha;                       # Return value: ref-to-hash holding the configuration
 269 }
 270
 271 =head2 ismemcached
 272
 273 Returns the value of the $ismemcached variable (0/1)
 274
 275 =cut
 276
 277 sub ismemcached {
 278     return $ismemcached;
 279 }
 280
 281 =head2 memcached
 282
 283 If $ismemcached is true, returns the $memcache variable.
 284 Returns undef otherwise
 285
 286 =cut
 287
 288 sub memcached {
 289     if ($ismemcached) {
 290       return $memcached;
 291     } else {
 292       return;
 293     }
 294 }
 295
 296 =head2 db_scheme2dbi
 297
 298     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 299
 300 This routines translates a database type to part of the name
 301 of the appropriate DBD driver to use when establishing a new
 302 database connection.  It recognizes 'mysql' and 'Pg'; if any
 303 other scheme is supplied it defaults to 'mysql'.
 304
 305 =cut
 306
 307 sub db_scheme2dbi {
 308     my $scheme = shift // '';
 309     return $scheme eq 'Pg' ? $scheme : 'mysql';
 310 }
 311
 312 sub import {
 313     # Create the default context ($C4::Context::Context)
 314     # the first time the module is called
 315     # (a config file can be optionaly passed)
 316
 317     # default context allready exists?
 318     return if $context;
 319
 320     # no ? so load it!
 321     my ($pkg,$config_file) = @_ ;
 322     my $new_ctx = __PACKAGE__->new($config_file);
 323     return unless $new_ctx;
 324
 325     # if successfully loaded, use it by default
 326     $new_ctx->set_context;
 327     1;
 328 }
 329
 330 =head2 new
 331
 332   $context = new C4::Context;
 333   $context = new C4::Context("/path/to/koha-conf.xml");
 334
 335 Allocates a new context. Initializes the context from the specified
 336 file, which defaults to either the file given by the C<$KOHA_CONF>
 337 environment variable, or F</etc/koha/koha-conf.xml>.
 338
 339 It saves the koha-conf.xml values in the declared memcached server(s)
 340 if currently available and uses those values until them expire and
 341 re-reads them.
 342
 343 C<&new> does not set this context as the new default context; for
 344 that, use C<&set_context>.
 345
 346 =cut
 347
 348 #'
 349 # Revision History:
 350 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 351 sub new {
 352     my $class = shift;
 353     my $conf_fname = shift;        # Config file to load
 354     my $self = {};
 355
 356     # check that the specified config file exists and is not empty
 357     undef $conf_fname unless
 358         (defined $conf_fname && -s $conf_fname);
 359     # Figure out a good config file to load if none was specified.
 360     if (!defined($conf_fname))
 361     {
 362         # If the $KOHA_CONF environment variable is set, use
 363         # that. Otherwise, use the built-in default.
 364         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 365             $conf_fname = $ENV{"KOHA_CONF"};
 366         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 367             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 368             # regex to anything else -- don't want installer to rewrite it
 369             $conf_fname = $INSTALLED_CONFIG_FNAME;
 370         } elsif (-s CONFIG_FNAME) {
 371             $conf_fname = CONFIG_FNAME;
 372         } else {
 373             warn "unable to locate Koha configuration file koha-conf.xml";
 374             return;
 375         }
 376     }
 377
 378     if ($ismemcached) {
 379         # retreive from memcached
 380         $self = $memcached->get('kohaconf');
 381         if (not defined $self) {
 382             # not in memcached yet
 383             $self = read_config_file($conf_fname);
 384         }
 385     } else {
 386         # non-memcached env, read from file
 387         $self = read_config_file($conf_fname);
 388     }
 389
 390     $self->{"config_file"} = $conf_fname;
 391     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 392     return if !defined($self->{"config"});
 393
 394     $self->{"dbh"} = undef;        # Database handle
 395     $self->{"Zconn"} = undef;    # Zebra Connections
 396     $self->{"stopwords"} = undef; # stopwords list
 397     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 398     $self->{"userenv"} = undef;        # User env
 399     $self->{"activeuser"} = undef;        # current active user
 400     $self->{"shelves"} = undef;
 401     $self->{tz} = undef; # local timezone object
 402
 403     bless $self, $class;
 404     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 405     return $self;
 406 }
 407
 408 =head2 set_context
 409
 410   $context = new C4::Context;
 411   $context->set_context();
 412 or
 413   set_context C4::Context $context;
 414
 415   ...
 416   restore_context C4::Context;
 417
 418 In some cases, it might be necessary for a script to use multiple
 419 contexts. C<&set_context> saves the current context on a stack, then
 420 sets the context to C<$context>, which will be used in future
 421 operations. To restore the previous context, use C<&restore_context>.
 422
 423 =cut
 424
 425 #'
 426 sub set_context
 427 {
 428     my $self = shift;
 429     my $new_context;    # The context to set
 430
 431     # Figure out whether this is a class or instance method call.
 432     #
 433     # We're going to make the assumption that control got here
 434     # through valid means, i.e., that the caller used an instance
 435     # or class method call, and that control got here through the
 436     # usual inheritance mechanisms. The caller can, of course,
 437     # break this assumption by playing silly buggers, but that's
 438     # harder to do than doing it properly, and harder to check
 439     # for.
 440     if (ref($self) eq "")
 441     {
 442         # Class method. The new context is the next argument.
 443         $new_context = shift;
 444     } else {
 445         # Instance method. The new context is $self.
 446         $new_context = $self;
 447     }
 448
 449     # Save the old context, if any, on the stack
 450     push @context_stack, $context if defined($context);
 451
 452     # Set the new context
 453     $context = $new_context;
 454 }
 455
 456 =head2 restore_context
 457
 458   &restore_context;
 459
 460 Restores the context set by C<&set_context>.
 461
 462 =cut
 463
 464 #'
 465 sub restore_context
 466 {
 467     my $self = shift;
 468
 469     if ($#context_stack < 0)
 470     {
 471         # Stack underflow.
 472         die "Context stack underflow";
 473     }
 474
 475     # Pop the old context and set it.
 476     $context = pop @context_stack;
 477
 478     # FIXME - Should this return something, like maybe the context
 479     # that was current when this was called?
 480 }
 481
 482 =head2 config
 483
 484   $value = C4::Context->config("config_variable");
 485
 486   $value = C4::Context->config_variable;
 487
 488 Returns the value of a variable specified in the configuration file
 489 from which the current context was created.
 490
 491 The second form is more compact, but of course may conflict with
 492 method names. If there is a configuration variable called "new", then
 493 C<C4::Config-E<gt>new> will not return it.
 494
 495 =cut
 496
 497 sub _common_config {
 498         my $var = shift;
 499         my $term = shift;
 500     return if !defined($context->{$term});
 501        # Presumably $self->{$term} might be
 502        # undefined if the config file given to &new
 503        # didn't exist, and the caller didn't bother
 504        # to check the return value.
 505
 506     # Return the value of the requested config variable
 507     return $context->{$term}->{$var};
 508 }
 509
 510 sub config {
 511         return _common_config($_[1],'config');
 512 }
 513 sub zebraconfig {
 514         return _common_config($_[1],'server');
 515 }
 516 sub ModZebrations {
 517         return _common_config($_[1],'serverinfo');
 518 }
 519
 520 =head2 preference
 521
 522   $sys_preference = C4::Context->preference('some_variable');
 523
 524 Looks up the value of the given system preference in the
 525 systempreferences table of the Koha database, and returns it. If the
 526 variable is not set or does not exist, undef is returned.
 527
 528 In case of an error, this may return 0.
 529
 530 Note: It is impossible to tell the difference between system
 531 preferences which do not exist, and those whose values are set to NULL
 532 with this method.
 533
 534 =cut
 535
 536 # FIXME: running this under mod_perl will require a means of
 537 # flushing the caching mechanism.
 538
 539 my %sysprefs;
 540 my $use_syspref_cache = 1;
 541
 542 sub preference {
 543     my $self = shift;
 544     my $var  = shift;    # The system preference to return
 545
 546     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 547         return $sysprefs{lc $var};
 548     }
 549
 550     my $dbh  = C4::Context->dbh or return 0;
 551
 552     my $value;
 553     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 554         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 555     } else {
 556         # Look up systempreferences.variable==$var
 557         my $sql = q{
 558             SELECT  value
 559             FROM    systempreferences
 560             WHERE   variable = ?
 561             LIMIT   1
 562         };
 563         $value = $dbh->selectrow_array( $sql, {}, lc $var );
 564     }
 565
 566     $sysprefs{lc $var} = $value;
 567     return $value;
 568 }
 569
 570 sub boolean_preference {
 571     my $self = shift;
 572     my $var = shift;        # The system preference to return
 573     my $it = preference($self, $var);
 574     return defined($it)? C4::Boolean::true_p($it): undef;
 575 }
 576
 577 =head2 enable_syspref_cache
 578
 579   C4::Context->enable_syspref_cache();
 580
 581 Enable the in-memory syspref cache used by C4::Context. This is the
 582 default behavior.
 583
 584 =cut
 585
 586 sub enable_syspref_cache {
 587     my ($self) = @_;
 588     $use_syspref_cache = 1;
 589 }
 590
 591 =head2 disable_syspref_cache
 592
 593   C4::Context->disable_syspref_cache();
 594
 595 Disable the in-memory syspref cache used by C4::Context. This should be
 596 used with Plack and other persistent environments.
 597
 598 =cut
 599
 600 sub disable_syspref_cache {
 601     my ($self) = @_;
 602     $use_syspref_cache = 0;
 603     $self->clear_syspref_cache();
 604 }
 605
 606 =head2 clear_syspref_cache
 607
 608   C4::Context->clear_syspref_cache();
 609
 610 cleans the internal cache of sysprefs. Please call this method if
 611 you update the systempreferences table. Otherwise, your new changes
 612 will not be seen by this process.
 613
 614 =cut
 615
 616 sub clear_syspref_cache {
 617     %sysprefs = ();
 618 }
 619
 620 =head2 set_preference
 621
 622   C4::Context->set_preference( $variable, $value );
 623
 624 This updates a preference's value both in the systempreferences table and in
 625 the sysprefs cache.
 626
 627 =cut
 628
 629 sub set_preference {
 630     my $self = shift;
 631     my $var = lc(shift);
 632     my $value = shift;
 633
 634     my $dbh = C4::Context->dbh or return 0;
 635
 636     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 637
 638     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 639
 640     my $sth = $dbh->prepare( "
 641       INSERT INTO systempreferences
 642         ( variable, value )
 643         VALUES( ?, ? )
 644         ON DUPLICATE KEY UPDATE value = VALUES(value)
 645     " );
 646
 647     if($sth->execute( $var, $value )) {
 648         $sysprefs{$var} = $value;
 649     }
 650     $sth->finish;
 651 }
 652
 653 # AUTOLOAD
 654 # This implements C4::Config->foo, and simply returns
 655 # C4::Context->config("foo"), as described in the documentation for
 656 # &config, above.
 657
 658 # FIXME - Perhaps this should be extended to check &config first, and
 659 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 660 # code, so it'd probably be best to delete it altogether so as not to
 661 # encourage people to use it.
 662 sub AUTOLOAD
 663 {
 664     my $self = shift;
 665
 666     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 667                     # leaving only the function name.
 668     return $self->config($AUTOLOAD);
 669 }
 670
 671 =head2 Zconn
 672
 673   $Zconn = C4::Context->Zconn
 674
 675 Returns a connection to the Zebra database for the current
 676 context. If no connection has yet been made, this method
 677 creates one and connects.
 678
 679 C<$self>
 680
 681 C<$server> one of the servers defined in the koha-conf.xml file
 682
 683 C<$async> whether this is a asynchronous connection
 684
 685 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 686
 687
 688 =cut
 689
 690 sub Zconn {
 691     my ($self, $server, $async, $auth, $piggyback, $syntax) = @_;
 692
 693     my $cache_key = join ('::', (map { $_ // '' } ($server, $async, $auth, $piggyback, $syntax)));
 694     if ( defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 695         return $context->{"Zconn"}->{$cache_key};
 696     # No connection object or it died. Create one.
 697     }else {
 698         # release resources if we're closing a connection and making a new one
 699         # FIXME: this needs to be smarter -- an error due to a malformed query or
 700         # a missing index does not necessarily require us to close the connection
 701         # and make a new one, particularly for a batch job.  However, at
 702         # first glance it does not look like there's a way to easily check
 703         # the basic health of a ZOOM::Connection
 704         $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key});
 705
 706         $context->{"Zconn"}->{$cache_key} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 707         return $context->{"Zconn"}->{$cache_key};
 708     }
 709 }
 710
 711 =head2 _new_Zconn
 712
 713 $context->{"Zconn"} = &_new_Zconn($server,$async);
 714
 715 Internal function. Creates a new database connection from the data given in the current context and returns it.
 716
 717 C<$server> one of the servers defined in the koha-conf.xml file
 718
 719 C<$async> whether this is a asynchronous connection
 720
 721 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 722
 723 =cut
 724
 725 sub _new_Zconn {
 726     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 727
 728     my $tried=0; # first attempt
 729     my $Zconn; # connection object
 730     my $elementSetName;
 731     my $index_mode;
 732
 733     $server //= "biblioserver";
 734     $syntax //= "XML";
 735
 736     if ( $server eq 'biblioserver' ) {
 737         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'grs1';
 738     } elsif ( $server eq 'authorityserver' ) {
 739         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 740     }
 741
 742     if ( $index_mode eq 'grs1' ) {
 743
 744         $elementSetName = 'F';
 745         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 746                 ? 'unimarc'
 747                 : 'usmarc';
 748
 749     } else {
 750
 751         $elementSetName = 'marcxml';
 752         $syntax = 'XML';
 753     }
 754
 755     my $host = $context->{'listen'}->{$server}->{'content'};
 756     my $servername = $context->{"config"}->{$server};
 757     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 758     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 759     $auth = 1 if($user && $password);
 760     retry:
 761     eval {
 762         # set options
 763         my $o = new ZOOM::Options();
 764         $o->option(user=>$user) if $auth;
 765         $o->option(password=>$password) if $auth;
 766         $o->option(async => 1) if $async;
 767         $o->option(count => $piggyback) if $piggyback;
 768         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 769         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 770         $o->option(preferredRecordSyntax => $syntax);
 771         $o->option(elementSetName => $elementSetName);
 772         $o->option(databaseName => ($servername?$servername:"biblios"));
 773
 774         # create a new connection object
 775         $Zconn= create ZOOM::Connection($o);
 776
 777         # forge to server
 778         $Zconn->connect($host, 0);
 779
 780         # check for errors and warn
 781         if ($Zconn->errcode() !=0) {
 782             warn "something wrong with the connection: ". $Zconn->errmsg();
 783         }
 784
 785     };
 786
 787     return $Zconn;
 788 }
 789
 790 # _new_dbh
 791 # Internal helper function (not a method!). This creates a new
 792 # database connection from the data given in the current context, and
 793 # returns it.
 794 sub _new_dbh
 795 {
 796
 797     ## $context
 798     ## correct name for db_scheme
 799     my $db_driver = $context->{db_driver};
 800
 801     my $db_name   = $context->config("database");
 802     my $db_host   = $context->config("hostname");
 803     my $db_port   = $context->config("port") || '';
 804     my $db_user   = $context->config("user");
 805     my $db_passwd = $context->config("pass");
 806     # MJR added or die here, as we can't work without dbh
 807     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 808     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 809
 810     # Check for the existence of a systempreference table; if we don't have this, we don't
 811     # have a valid database and should not set RaiseError in order to allow the installer
 812     # to run; installer will not run otherwise since we raise all db errors
 813
 814     eval {
 815                 local $dbh->{PrintError} = 0;
 816                 local $dbh->{RaiseError} = 1;
 817                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 818     };
 819
 820     if ($@) {
 821         $dbh->{RaiseError} = 0;
 822     }
 823
 824     if ( $db_driver eq 'mysql' ) {
 825         $dbh->{mysql_auto_reconnect} = 1;
 826     }
 827
 828         my $tz = $ENV{TZ};
 829     if ( $db_driver eq 'mysql' ) {
 830         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 831         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 832         $dbh->{'mysql_enable_utf8'}=1; #enable
 833         $dbh->do("set NAMES 'utf8'");
 834         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 835     }
 836     elsif ( $db_driver eq 'Pg' ) {
 837             $dbh->do( "set client_encoding = 'UTF8';" );
 838         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 839     }
 840     return $dbh;
 841 }
 842
 843 =head2 dbh
 844
 845   $dbh = C4::Context->dbh;
 846
 847 Returns a database handle connected to the Koha database for the
 848 current context. If no connection has yet been made, this method
 849 creates one, and connects to the database.
 850
 851 This database handle is cached for future use: if you call
 852 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 853 times. If you need a second database handle, use C<&new_dbh> and
 854 possibly C<&set_dbh>.
 855
 856 =cut
 857
 858 #'
 859 sub dbh
 860 {
 861     my $self = shift;
 862     my $params = shift;
 863     my $sth;
 864
 865     unless ( $params->{new} ) {
 866         if ( defined($context->{db_driver}) && $context->{db_driver} eq 'mysql' && $context->{"dbh"} ) {
 867             return $context->{"dbh"};
 868         } elsif ( defined($context->{"dbh"}) && $context->{"dbh"}->ping() ) {
 869             return $context->{"dbh"};
 870         }
 871     }
 872
 873     # No database handle or it died . Create one.
 874     $context->{"dbh"} = &_new_dbh();
 875
 876     return $context->{"dbh"};
 877 }
 878
 879 =head2 new_dbh
 880
 881   $dbh = C4::Context->new_dbh;
 882
 883 Creates a new connection to the Koha database for the current context,
 884 and returns the database handle (a C<DBI::db> object).
 885
 886 The handle is not saved anywhere: this method is strictly a
 887 convenience function; the point is that it knows which database to
 888 connect to so that the caller doesn't have to know.
 889
 890 =cut
 891
 892 #'
 893 sub new_dbh
 894 {
 895     my $self = shift;
 896
 897     return &_new_dbh();
 898 }
 899
 900 =head2 set_dbh
 901
 902   $my_dbh = C4::Connect->new_dbh;
 903   C4::Connect->set_dbh($my_dbh);
 904   ...
 905   C4::Connect->restore_dbh;
 906
 907 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 908 C<&set_context> and C<&restore_context>.
 909
 910 C<&set_dbh> saves the current database handle on a stack, then sets
 911 the current database handle to C<$my_dbh>.
 912
 913 C<$my_dbh> is assumed to be a good database handle.
 914
 915 =cut
 916
 917 #'
 918 sub set_dbh
 919 {
 920     my $self = shift;
 921     my $new_dbh = shift;
 922
 923     # Save the current database handle on the handle stack.
 924     # We assume that $new_dbh is all good: if the caller wants to
 925     # screw himself by passing an invalid handle, that's fine by
 926     # us.
 927     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 928     $context->{"dbh"} = $new_dbh;
 929 }
 930
 931 =head2 restore_dbh
 932
 933   C4::Context->restore_dbh;
 934
 935 Restores the database handle saved by an earlier call to
 936 C<C4::Context-E<gt>set_dbh>.
 937
 938 =cut
 939
 940 #'
 941 sub restore_dbh
 942 {
 943     my $self = shift;
 944
 945     if ($#{$context->{"dbh_stack"}} < 0)
 946     {
 947         # Stack underflow
 948         die "DBH stack underflow";
 949     }
 950
 951     # Pop the old database handle and set it.
 952     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 953
 954     # FIXME - If it is determined that restore_context should
 955     # return something, then this function should, too.
 956 }
 957
 958 =head2 queryparser
 959
 960   $queryparser = C4::Context->queryparser
 961
 962 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 963
 964 =cut
 965
 966 sub queryparser {
 967     my $self = shift;
 968     unless (defined $context->{"queryparser"}) {
 969         $context->{"queryparser"} = &_new_queryparser();
 970     }
 971
 972     return
 973       defined( $context->{"queryparser"} )
 974       ? $context->{"queryparser"}->new
 975       : undef;
 976 }
 977
 978 =head2 _new_queryparser
 979
 980 Internal helper function to create a new QueryParser object. QueryParser
 981 is loaded dynamically so as to keep the lack of the QueryParser library from
 982 getting in anyone's way.
 983
 984 =cut
 985
 986 sub _new_queryparser {
 987     my $qpmodules = {
 988         'OpenILS::QueryParser'           => undef,
 989         'Koha::QueryParser::Driver::PQF' => undef
 990     };
 991     if ( can_load( 'modules' => $qpmodules ) ) {
 992         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 993         my $config_file = $context->config('queryparser_config');
 994         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 995         if ( $QParser->load_config($config_file) ) {
 996             # TODO: allow indexes to be configured in the database
 997             return $QParser;
 998         }
 999     }
1000     return;
1001 }
1002
1003 =head2 marcfromkohafield
1004
1005   $dbh = C4::Context->marcfromkohafield;
1006
1007 Returns a hash with marcfromkohafield.
1008
1009 This hash is cached for future use: if you call
1010 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
1011
1012 =cut
1013
1014 #'
1015 sub marcfromkohafield
1016 {
1017     my $retval = {};
1018
1019     # If the hash already exists, return it.
1020     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
1021
1022     # No hash. Create one.
1023     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
1024
1025     return $context->{"marcfromkohafield"};
1026 }
1027
1028 # _new_marcfromkohafield
1029 # Internal helper function (not a method!). This creates a new
1030 # hash with stopwords
1031 sub _new_marcfromkohafield
1032 {
1033     my $dbh = C4::Context->dbh;
1034     my $marcfromkohafield;
1035     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
1036     $sth->execute;
1037     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1038         my $retval = {};
1039         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1040     }
1041     return $marcfromkohafield;
1042 }
1043
1044 =head2 stopwords
1045
1046   $dbh = C4::Context->stopwords;
1047
1048 Returns a hash with stopwords.
1049
1050 This hash is cached for future use: if you call
1051 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1052
1053 =cut
1054
1055 #'
1056 sub stopwords
1057 {
1058     my $retval = {};
1059
1060     # If the hash already exists, return it.
1061     return $context->{"stopwords"} if defined($context->{"stopwords"});
1062
1063     # No hash. Create one.
1064     $context->{"stopwords"} = &_new_stopwords();
1065
1066     return $context->{"stopwords"};
1067 }
1068
1069 # _new_stopwords
1070 # Internal helper function (not a method!). This creates a new
1071 # hash with stopwords
1072 sub _new_stopwords
1073 {
1074     my $dbh = C4::Context->dbh;
1075     my $stopwordlist;
1076     my $sth = $dbh->prepare("select word from stopwords");
1077     $sth->execute;
1078     while (my $stopword = $sth->fetchrow_array) {
1079         $stopwordlist->{$stopword} = uc($stopword);
1080     }
1081     $stopwordlist->{A} = "A" unless $stopwordlist;
1082     return $stopwordlist;
1083 }
1084
1085 =head2 userenv
1086
1087   C4::Context->userenv;
1088
1089 Retrieves a hash for user environment variables.
1090
1091 This hash shall be cached for future use: if you call
1092 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1093
1094 =cut
1095
1096 #'
1097 sub userenv {
1098     my $var = $context->{"activeuser"};
1099     if (defined $var and defined $context->{"userenv"}->{$var}) {
1100         return $context->{"userenv"}->{$var};
1101     } else {
1102         return;
1103     }
1104 }
1105
1106 =head2 set_userenv
1107
1108   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1109                   $usersurname, $userbranch, $userflags, $emailaddress, $branchprinter,
1110                   $persona);
1111
1112 Establish a hash of user environment variables.
1113
1114 set_userenv is called in Auth.pm
1115
1116 =cut
1117
1118 #'
1119 sub set_userenv {
1120     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona)= @_;
1121     my $var=$context->{"activeuser"} || '';
1122     my $cell = {
1123         "number"     => $usernum,
1124         "id"         => $userid,
1125         "cardnumber" => $usercnum,
1126         "firstname"  => $userfirstname,
1127         "surname"    => $usersurname,
1128         #possibly a law problem
1129         "branch"     => $userbranch,
1130         "branchname" => $branchname,
1131         "flags"      => $userflags,
1132         "emailaddress"     => $emailaddress,
1133         "branchprinter"    => $branchprinter,
1134         "persona"    => $persona,
1135     };
1136     $context->{userenv}->{$var} = $cell;
1137     return $cell;
1138 }
1139
1140 sub set_shelves_userenv {
1141         my ($type, $shelves) = @_ or return;
1142         my $activeuser = $context->{activeuser} or return;
1143         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1144         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1145         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1146 }
1147
1148 sub get_shelves_userenv {
1149         my $active;
1150         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1151                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1152                 return;
1153         }
1154         my $totshelves = $active->{totshelves} or undef;
1155         my $pubshelves = $active->{pubshelves} or undef;
1156         my $barshelves = $active->{barshelves} or undef;
1157         return ($totshelves, $pubshelves, $barshelves);
1158 }
1159
1160 =head2 _new_userenv
1161
1162   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1163
1164 Builds a hash for user environment variables.
1165
1166 This hash shall be cached for future use: if you call
1167 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1168
1169 _new_userenv is called in Auth.pm
1170
1171 =cut
1172
1173 #'
1174 sub _new_userenv
1175 {
1176     shift;  # Useless except it compensates for bad calling style
1177     my ($sessionID)= @_;
1178      $context->{"activeuser"}=$sessionID;
1179 }
1180
1181 =head2 _unset_userenv
1182
1183   C4::Context->_unset_userenv;
1184
1185 Destroys the hash for activeuser user environment variables.
1186
1187 =cut
1188
1189 #'
1190
1191 sub _unset_userenv
1192 {
1193     my ($sessionID)= @_;
1194     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1195 }
1196
1197
1198 =head2 get_versions
1199
1200   C4::Context->get_versions
1201
1202 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1203
1204 =cut
1205
1206 #'
1207
1208 # A little example sub to show more debugging info for CGI::Carp
1209 sub get_versions {
1210     my %versions;
1211     $versions{kohaVersion}  = KOHAVERSION();
1212     $versions{kohaDbVersion} = C4::Context->preference('version');
1213     $versions{osVersion} = join(" ", POSIX::uname());
1214     $versions{perlVersion} = $];
1215     {
1216         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1217         $versions{mysqlVersion}  = `mysql -V`;
1218         $versions{apacheVersion} = `httpd -v`;
1219         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1220         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1221         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1222     }
1223     return %versions;
1224 }
1225
1226
1227 =head2 tz
1228
1229   C4::Context->tz
1230
1231   Returns a DateTime::TimeZone object for the system timezone
1232
1233 =cut
1234
1235 sub tz {
1236     my $self = shift;
1237     if (!defined $context->{tz}) {
1238         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1239     }
1240     return $context->{tz};
1241 }
1242
1243
1244 =head2 IsSuperLibrarian
1245
1246     C4::Context->IsSuperlibrarian();
1247
1248 =cut
1249
1250 sub IsSuperLibrarian {
1251     my $userenv = C4::Context->userenv;
1252
1253     unless ( $userenv and exists $userenv->{flags} ) {
1254         # If we reach this without a user environment,
1255         # assume that we're running from a command-line script,
1256         # and act as a superlibrarian.
1257         carp("C4::Context->userenv not defined!");
1258         return 1;
1259     }
1260
1261     return ($userenv->{flags}//0) % 2;
1262 }
1263
1264 1;
1265 __END__
1266
1267 =head1 ENVIRONMENT
1268
1269 =head2 C<KOHA_CONF>
1270
1271 Specifies the configuration file to read.
1272
1273 =head1 SEE ALSO
1274
1275 XML::Simple
1276
1277 =head1 AUTHORS
1278
1279 Andrew Arensburger <arensb at ooblick dot com>
1280
1281 Joshua Ferraro <jmf at liblime dot com>
1282
1283 =cut