C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22
  23 BEGIN {
  24         if ($ENV{'HTTP_USER_AGENT'})    {
  25                 require CGI::Carp;
  26         # FIXME for future reference, CGI::Carp doc says
  27         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  28                 import CGI::Carp qw(fatalsToBrowser);
  29                         sub handle_errors {
  30                             my $msg = shift;
  31                             my $debug_level;
  32                             eval {C4::Context->dbh();};
  33                             if ($@){
  34                                 $debug_level = 1;
  35                             }
  36                             else {
  37                                 $debug_level =  C4::Context->preference("DebugLevel");
  38                             }
  39
  40                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  41                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  42                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  43                        <head><title>Koha Error</title></head>
  44                        <body>
  45                 );
  46                                 if ($debug_level eq "2"){
  47                                         # debug 2 , print extra info too.
  48                                         my %versions = get_versions();
  49
  50                 # a little example table with various version info";
  51                                         print "
  52                                                 <h1>Koha error</h1>
  53                                                 <p>The following fatal error has occurred:</p>
  54                         <pre><code>$msg</code></pre>
  55                                                 <table>
  56                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  57                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  58                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  59                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  60                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  61                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  62                                                 </table>";
  63
  64                                 } elsif ($debug_level eq "1"){
  65                                         print "
  66                                                 <h1>Koha error</h1>
  67                                                 <p>The following fatal error has occurred:</p>
  68                         <pre><code>$msg</code></pre>";
  69                                 } else {
  70                                         print "<p>production mode - trapped fatal error</p>";
  71                                 }
  72                 print "</body></html>";
  73                         }
  74                 #CGI::Carp::set_message(\&handle_errors);
  75                 ## give a stack backtrace if KOHA_BACKTRACES is set
  76                 ## can't rely on DebugLevel for this, as we're not yet connected
  77                 if ($ENV{KOHA_BACKTRACES}) {
  78                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  79                 }
  80     }   # else there is no browser to send fatals to!
  81
  82     # Check if there are memcached servers set
  83     $servers = $ENV{'MEMCACHED_SERVERS'};
  84     if ($servers) {
  85         # Load required libraries and create the memcached object
  86         require Cache::Memcached;
  87         $memcached = Cache::Memcached->new({
  88         servers => [ $servers ],
  89         debug   => 0,
  90         compress_threshold => 10_000,
  91         expire_time => 600,
  92         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  93     });
  94         # Verify memcached available (set a variable and test the output)
  95     $ismemcached = $memcached->set('ismemcached','1');
  96     }
  97
  98     $VERSION = '3.07.00.049';
  99 }
 100
 101 use DBI;
 102 use ZOOM;
 103 use XML::Simple;
 104 use C4::Boolean;
 105 use C4::Debug;
 106 use POSIX ();
 107 use DateTime::TimeZone;
 108
 109 =head1 NAME
 110
 111 C4::Context - Maintain and manipulate the context of a Koha script
 112
 113 =head1 SYNOPSIS
 114
 115   use C4::Context;
 116
 117   use C4::Context("/path/to/koha-conf.xml");
 118
 119   $config_value = C4::Context->config("config_variable");
 120
 121   $koha_preference = C4::Context->preference("preference");
 122
 123   $db_handle = C4::Context->dbh;
 124
 125   $Zconn = C4::Context->Zconn;
 126
 127   $stopwordhash = C4::Context->stopwords;
 128
 129 =head1 DESCRIPTION
 130
 131 When a Koha script runs, it makes use of a certain number of things:
 132 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 133 databases, and so forth. These things make up the I<context> in which
 134 the script runs.
 135
 136 This module takes care of setting up the context for a script:
 137 figuring out which configuration file to load, and loading it, opening
 138 a connection to the right database, and so forth.
 139
 140 Most scripts will only use one context. They can simply have
 141
 142   use C4::Context;
 143
 144 at the top.
 145
 146 Other scripts may need to use several contexts. For instance, if a
 147 library has two databases, one for a certain collection, and the other
 148 for everything else, it might be necessary for a script to use two
 149 different contexts to search both databases. Such scripts should use
 150 the C<&set_context> and C<&restore_context> functions, below.
 151
 152 By default, C4::Context reads the configuration from
 153 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 154 environment variable to the pathname of a configuration file to use.
 155
 156 =head1 METHODS
 157
 158 =cut
 159
 160 #'
 161 # In addition to what is said in the POD above, a Context object is a
 162 # reference-to-hash with the following fields:
 163 #
 164 # config
 165 #    A reference-to-hash whose keys and values are the
 166 #    configuration variables and values specified in the config
 167 #    file (/etc/koha/koha-conf.xml).
 168 # dbh
 169 #    A handle to the appropriate database for this context.
 170 # dbh_stack
 171 #    Used by &set_dbh and &restore_dbh to hold other database
 172 #    handles for this context.
 173 # Zconn
 174 #     A connection object for the Zebra server
 175
 176 # Koha's main configuration file koha-conf.xml
 177 # is searched for according to this priority list:
 178 #
 179 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 180 # 2. Path supplied in KOHA_CONF environment variable.
 181 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 182 #    as value has changed from its default of
 183 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 184 #    when Koha is installed in 'standard' or 'single'
 185 #    mode.
 186 # 4. Path supplied in CONFIG_FNAME.
 187 #
 188 # The first entry that refers to a readable file is used.
 189
 190 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 191                 # Default config file, if none is specified
 192
 193 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 194                 # path to config file set by installer
 195                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 196                 # when Koha is installed in 'standard' or 'single'
 197                 # mode.  If Koha was installed in 'dev' mode,
 198                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 199                 # developers should set the KOHA_CONF environment variable
 200
 201 $context = undef;        # Initially, no context is set
 202 @context_stack = ();        # Initially, no saved contexts
 203
 204
 205 =head2 KOHAVERSION
 206
 207 returns the kohaversion stored in kohaversion.pl file
 208
 209 =cut
 210
 211 sub KOHAVERSION {
 212     my $cgidir = C4::Context->intranetdir;
 213
 214     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 215     # but distribution code does?  (Stan, 1jan08)
 216     if(-d $cgidir . "/cgi-bin"){
 217         my $cgidir .= "/cgi-bin";
 218     }
 219
 220     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 221     return kohaversion();
 222 }
 223 =head2 read_config_file
 224
 225 Reads the specified Koha config file.
 226
 227 Returns an object containing the configuration variables. The object's
 228 structure is a bit complex to the uninitiated ... take a look at the
 229 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 230 here are a few examples that may give you what you need:
 231
 232 The simple elements nested within the <config> element:
 233
 234     my $pass = $koha->{'config'}->{'pass'};
 235
 236 The <listen> elements:
 237
 238     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 239
 240 The elements nested within the <server> element:
 241
 242     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 243
 244 Returns undef in case of error.
 245
 246 =cut
 247
 248 sub read_config_file {          # Pass argument naming config file to read
 249     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 250
 251     if ($ismemcached) {
 252       $memcached->set('kohaconf',$koha);
 253     }
 254
 255     return $koha;                       # Return value: ref-to-hash holding the configuration
 256 }
 257
 258 =head2 ismemcached
 259
 260 Returns the value of the $ismemcached variable (0/1)
 261
 262 =cut
 263
 264 sub ismemcached {
 265     return $ismemcached;
 266 }
 267
 268 =head2 memcached
 269
 270 If $ismemcached is true, returns the $memcache variable.
 271 Returns undef otherwise
 272
 273 =cut
 274
 275 sub memcached {
 276     if ($ismemcached) {
 277       return $memcached;
 278     } else {
 279       return;
 280     }
 281 }
 282
 283 # db_scheme2dbi
 284 # Translates the full text name of a database into de appropiate dbi name
 285 #
 286 sub db_scheme2dbi {
 287     my $name = shift;
 288     # for instance, we support only mysql, so don't care checking
 289     return "mysql";
 290     for ($name) {
 291 # FIXME - Should have other databases.
 292         if (/mysql/) { return("mysql"); }
 293         if (/Postgres|Pg|PostgresSQL/) { return("Pg"); }
 294         if (/oracle/) { return("Oracle"); }
 295     }
 296     return;         # Just in case
 297 }
 298
 299 sub import {
 300     # Create the default context ($C4::Context::Context)
 301     # the first time the module is called
 302     # (a config file can be optionaly passed)
 303
 304     # default context allready exists?
 305     return if $context;
 306
 307     # no ? so load it!
 308     my ($pkg,$config_file) = @_ ;
 309     my $new_ctx = __PACKAGE__->new($config_file);
 310     return unless $new_ctx;
 311
 312     # if successfully loaded, use it by default
 313     $new_ctx->set_context;
 314     1;
 315 }
 316
 317 =head2 new
 318
 319   $context = new C4::Context;
 320   $context = new C4::Context("/path/to/koha-conf.xml");
 321
 322 Allocates a new context. Initializes the context from the specified
 323 file, which defaults to either the file given by the C<$KOHA_CONF>
 324 environment variable, or F</etc/koha/koha-conf.xml>.
 325
 326 It saves the koha-conf.xml values in the declared memcached server(s)
 327 if currently available and uses those values until them expire and
 328 re-reads them.
 329
 330 C<&new> does not set this context as the new default context; for
 331 that, use C<&set_context>.
 332
 333 =cut
 334
 335 #'
 336 # Revision History:
 337 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 338 sub new {
 339     my $class = shift;
 340     my $conf_fname = shift;        # Config file to load
 341     my $self = {};
 342
 343     # check that the specified config file exists and is not empty
 344     undef $conf_fname unless
 345         (defined $conf_fname && -s $conf_fname);
 346     # Figure out a good config file to load if none was specified.
 347     if (!defined($conf_fname))
 348     {
 349         # If the $KOHA_CONF environment variable is set, use
 350         # that. Otherwise, use the built-in default.
 351         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 352             $conf_fname = $ENV{"KOHA_CONF"};
 353         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 354             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 355             # regex to anything else -- don't want installer to rewrite it
 356             $conf_fname = $INSTALLED_CONFIG_FNAME;
 357         } elsif (-s CONFIG_FNAME) {
 358             $conf_fname = CONFIG_FNAME;
 359         } else {
 360             warn "unable to locate Koha configuration file koha-conf.xml";
 361             return;
 362         }
 363     }
 364
 365     if ($ismemcached) {
 366         # retreive from memcached
 367         $self = $memcached->get('kohaconf');
 368         if (not defined $self) {
 369             # not in memcached yet
 370             $self = read_config_file($conf_fname);
 371         }
 372     } else {
 373         # non-memcached env, read from file
 374         $self = read_config_file($conf_fname);
 375     }
 376
 377     $self->{"config_file"} = $conf_fname;
 378     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 379     return if !defined($self->{"config"});
 380
 381     $self->{"dbh"} = undef;        # Database handle
 382     $self->{"Zconn"} = undef;    # Zebra Connections
 383     $self->{"stopwords"} = undef; # stopwords list
 384     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 385     $self->{"userenv"} = undef;        # User env
 386     $self->{"activeuser"} = undef;        # current active user
 387     $self->{"shelves"} = undef;
 388     $self->{tz} = undef; # local timezone object
 389
 390     bless $self, $class;
 391     return $self;
 392 }
 393
 394 =head2 set_context
 395
 396   $context = new C4::Context;
 397   $context->set_context();
 398 or
 399   set_context C4::Context $context;
 400
 401   ...
 402   restore_context C4::Context;
 403
 404 In some cases, it might be necessary for a script to use multiple
 405 contexts. C<&set_context> saves the current context on a stack, then
 406 sets the context to C<$context>, which will be used in future
 407 operations. To restore the previous context, use C<&restore_context>.
 408
 409 =cut
 410
 411 #'
 412 sub set_context
 413 {
 414     my $self = shift;
 415     my $new_context;    # The context to set
 416
 417     # Figure out whether this is a class or instance method call.
 418     #
 419     # We're going to make the assumption that control got here
 420     # through valid means, i.e., that the caller used an instance
 421     # or class method call, and that control got here through the
 422     # usual inheritance mechanisms. The caller can, of course,
 423     # break this assumption by playing silly buggers, but that's
 424     # harder to do than doing it properly, and harder to check
 425     # for.
 426     if (ref($self) eq "")
 427     {
 428         # Class method. The new context is the next argument.
 429         $new_context = shift;
 430     } else {
 431         # Instance method. The new context is $self.
 432         $new_context = $self;
 433     }
 434
 435     # Save the old context, if any, on the stack
 436     push @context_stack, $context if defined($context);
 437
 438     # Set the new context
 439     $context = $new_context;
 440 }
 441
 442 =head2 restore_context
 443
 444   &restore_context;
 445
 446 Restores the context set by C<&set_context>.
 447
 448 =cut
 449
 450 #'
 451 sub restore_context
 452 {
 453     my $self = shift;
 454
 455     if ($#context_stack < 0)
 456     {
 457         # Stack underflow.
 458         die "Context stack underflow";
 459     }
 460
 461     # Pop the old context and set it.
 462     $context = pop @context_stack;
 463
 464     # FIXME - Should this return something, like maybe the context
 465     # that was current when this was called?
 466 }
 467
 468 =head2 config
 469
 470   $value = C4::Context->config("config_variable");
 471
 472   $value = C4::Context->config_variable;
 473
 474 Returns the value of a variable specified in the configuration file
 475 from which the current context was created.
 476
 477 The second form is more compact, but of course may conflict with
 478 method names. If there is a configuration variable called "new", then
 479 C<C4::Config-E<gt>new> will not return it.
 480
 481 =cut
 482
 483 sub _common_config {
 484         my $var = shift;
 485         my $term = shift;
 486     return if !defined($context->{$term});
 487        # Presumably $self->{$term} might be
 488        # undefined if the config file given to &new
 489        # didn't exist, and the caller didn't bother
 490        # to check the return value.
 491
 492     # Return the value of the requested config variable
 493     return $context->{$term}->{$var};
 494 }
 495
 496 sub config {
 497         return _common_config($_[1],'config');
 498 }
 499 sub zebraconfig {
 500         return _common_config($_[1],'server');
 501 }
 502 sub ModZebrations {
 503         return _common_config($_[1],'serverinfo');
 504 }
 505
 506 =head2 preference
 507
 508   $sys_preference = C4::Context->preference('some_variable');
 509
 510 Looks up the value of the given system preference in the
 511 systempreferences table of the Koha database, and returns it. If the
 512 variable is not set or does not exist, undef is returned.
 513
 514 In case of an error, this may return 0.
 515
 516 Note: It is impossible to tell the difference between system
 517 preferences which do not exist, and those whose values are set to NULL
 518 with this method.
 519
 520 =cut
 521
 522 # FIXME: running this under mod_perl will require a means of
 523 # flushing the caching mechanism.
 524
 525 my %sysprefs;
 526 my $use_syspref_cache = 1;
 527
 528 sub preference {
 529     my $self = shift;
 530     my $var  = lc(shift);                          # The system preference to return
 531
 532     if ($use_syspref_cache && exists $sysprefs{$var}) {
 533         return $sysprefs{$var};
 534     }
 535
 536     my $dbh  = C4::Context->dbh or return 0;
 537
 538     # Look up systempreferences.variable==$var
 539     my $sql = <<'END_SQL';
 540         SELECT    value
 541         FROM    systempreferences
 542         WHERE    variable=?
 543         LIMIT    1
 544 END_SQL
 545     $sysprefs{$var} = $dbh->selectrow_array( $sql, {}, $var );
 546     return $sysprefs{$var};
 547 }
 548
 549 sub boolean_preference {
 550     my $self = shift;
 551     my $var = shift;        # The system preference to return
 552     my $it = preference($self, $var);
 553     return defined($it)? C4::Boolean::true_p($it): undef;
 554 }
 555
 556 =head2 enable_syspref_cache
 557
 558   C4::Context->enable_syspref_cache();
 559
 560 Enable the in-memory syspref cache used by C4::Context. This is the
 561 default behavior.
 562
 563 =cut
 564
 565 sub enable_syspref_cache {
 566     my ($self) = @_;
 567     $use_syspref_cache = 1;
 568 }
 569
 570 =head2 disable_syspref_cache
 571
 572   C4::Context->disable_syspref_cache();
 573
 574 Disable the in-memory syspref cache used by C4::Context. This should be
 575 used with Plack and other persistent environments.
 576
 577 =cut
 578
 579 sub disable_syspref_cache {
 580     my ($self) = @_;
 581     $use_syspref_cache = 0;
 582     $self->clear_syspref_cache();
 583 }
 584
 585 =head2 clear_syspref_cache
 586
 587   C4::Context->clear_syspref_cache();
 588
 589 cleans the internal cache of sysprefs. Please call this method if
 590 you update the systempreferences table. Otherwise, your new changes
 591 will not be seen by this process.
 592
 593 =cut
 594
 595 sub clear_syspref_cache {
 596     %sysprefs = ();
 597 }
 598
 599 =head2 set_preference
 600
 601   C4::Context->set_preference( $variable, $value );
 602
 603 This updates a preference's value both in the systempreferences table and in
 604 the sysprefs cache.
 605
 606 =cut
 607
 608 sub set_preference {
 609     my $self = shift;
 610     my $var = lc(shift);
 611     my $value = shift;
 612
 613     my $dbh = C4::Context->dbh or return 0;
 614
 615     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 616
 617     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 618
 619     my $sth = $dbh->prepare( "
 620       INSERT INTO systempreferences
 621         ( variable, value )
 622         VALUES( ?, ? )
 623         ON DUPLICATE KEY UPDATE value = VALUES(value)
 624     " );
 625
 626     if($sth->execute( $var, $value )) {
 627         $sysprefs{$var} = $value;
 628     }
 629     $sth->finish;
 630 }
 631
 632 # AUTOLOAD
 633 # This implements C4::Config->foo, and simply returns
 634 # C4::Context->config("foo"), as described in the documentation for
 635 # &config, above.
 636
 637 # FIXME - Perhaps this should be extended to check &config first, and
 638 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 639 # code, so it'd probably be best to delete it altogether so as not to
 640 # encourage people to use it.
 641 sub AUTOLOAD
 642 {
 643     my $self = shift;
 644
 645     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 646                     # leaving only the function name.
 647     return $self->config($AUTOLOAD);
 648 }
 649
 650 =head2 Zconn
 651
 652   $Zconn = C4::Context->Zconn
 653
 654 Returns a connection to the Zebra database for the current
 655 context. If no connection has yet been made, this method
 656 creates one and connects.
 657
 658 C<$self>
 659
 660 C<$server> one of the servers defined in the koha-conf.xml file
 661
 662 C<$async> whether this is a asynchronous connection
 663
 664 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 665
 666
 667 =cut
 668
 669 sub Zconn {
 670     my $self=shift;
 671     my $server=shift;
 672     my $async=shift;
 673     my $auth=shift;
 674     my $piggyback=shift;
 675     my $syntax=shift;
 676     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 677         return $context->{"Zconn"}->{$server};
 678     # No connection object or it died. Create one.
 679     }else {
 680         # release resources if we're closing a connection and making a new one
 681         # FIXME: this needs to be smarter -- an error due to a malformed query or
 682         # a missing index does not necessarily require us to close the connection
 683         # and make a new one, particularly for a batch job.  However, at
 684         # first glance it does not look like there's a way to easily check
 685         # the basic health of a ZOOM::Connection
 686         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 687
 688         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 689         $context->{ Zconn }->{ $server }->option(
 690             preferredRecordSyntax => C4::Context->preference("marcflavour") );
 691         return $context->{"Zconn"}->{$server};
 692     }
 693 }
 694
 695 =head2 _new_Zconn
 696
 697 $context->{"Zconn"} = &_new_Zconn($server,$async);
 698
 699 Internal function. Creates a new database connection from the data given in the current context and returns it.
 700
 701 C<$server> one of the servers defined in the koha-conf.xml file
 702
 703 C<$async> whether this is a asynchronous connection
 704
 705 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 706
 707 =cut
 708
 709 sub _new_Zconn {
 710     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 711
 712     my $tried=0; # first attempt
 713     my $Zconn; # connection object
 714     $server = "biblioserver" unless $server;
 715     $syntax = "usmarc" unless $syntax;
 716
 717     my $host = $context->{'listen'}->{$server}->{'content'};
 718     my $servername = $context->{"config"}->{$server};
 719     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 720     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 721  $auth = 1 if($user && $password);
 722     retry:
 723     eval {
 724         # set options
 725         my $o = new ZOOM::Options();
 726         $o->option(user=>$user) if $auth;
 727         $o->option(password=>$password) if $auth;
 728         $o->option(async => 1) if $async;
 729         $o->option(count => $piggyback) if $piggyback;
 730         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 731         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 732         $o->option(preferredRecordSyntax => $syntax);
 733         $o->option(elementSetName => "F"); # F for 'full' as opposed to B for 'brief'
 734         $o->option(databaseName => ($servername?$servername:"biblios"));
 735
 736         # create a new connection object
 737         $Zconn= create ZOOM::Connection($o);
 738
 739         # forge to server
 740         $Zconn->connect($host, 0);
 741
 742         # check for errors and warn
 743         if ($Zconn->errcode() !=0) {
 744             warn "something wrong with the connection: ". $Zconn->errmsg();
 745         }
 746
 747     };
 748 #     if ($@) {
 749 #         # Koha manages the Zebra server -- this doesn't work currently for me because of permissions issues
 750 #         # Also, I'm skeptical about whether it's the best approach
 751 #         warn "problem with Zebra";
 752 #         if ( C4::Context->preference("ManageZebra") ) {
 753 #             if ($@->code==10000 && $tried==0) { ##No connection try restarting Zebra
 754 #                 $tried=1;
 755 #                 warn "trying to restart Zebra";
 756 #                 my $res=system("zebrasrv -f $ENV{'KOHA_CONF'} >/koha/log/zebra-error.log");
 757 #                 goto "retry";
 758 #             } else {
 759 #                 warn "Error ", $@->code(), ": ", $@->message(), "\n";
 760 #                 $Zconn="error";
 761 #                 return $Zconn;
 762 #             }
 763 #         }
 764 #     }
 765     return $Zconn;
 766 }
 767
 768 # _new_dbh
 769 # Internal helper function (not a method!). This creates a new
 770 # database connection from the data given in the current context, and
 771 # returns it.
 772 sub _new_dbh
 773 {
 774
 775     ## $context
 776     ## correct name for db_schme
 777     my $db_driver;
 778     if ($context->config("db_scheme")){
 779         $db_driver=db_scheme2dbi($context->config("db_scheme"));
 780     }else{
 781         $db_driver="mysql";
 782     }
 783
 784     my $db_name   = $context->config("database");
 785     my $db_host   = $context->config("hostname");
 786     my $db_port   = $context->config("port") || '';
 787     my $db_user   = $context->config("user");
 788     my $db_passwd = $context->config("pass");
 789     # MJR added or die here, as we can't work without dbh
 790     my $dbh= DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 791     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 792         my $tz = $ENV{TZ};
 793     if ( $db_driver eq 'mysql' ) {
 794         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 795         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 796         $dbh->{'mysql_enable_utf8'}=1; #enable
 797         $dbh->do("set NAMES 'utf8'");
 798         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 799     }
 800     elsif ( $db_driver eq 'Pg' ) {
 801             $dbh->do( "set client_encoding = 'UTF8';" );
 802         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 803     }
 804     return $dbh;
 805 }
 806
 807 =head2 dbh
 808
 809   $dbh = C4::Context->dbh;
 810
 811 Returns a database handle connected to the Koha database for the
 812 current context. If no connection has yet been made, this method
 813 creates one, and connects to the database.
 814
 815 This database handle is cached for future use: if you call
 816 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 817 times. If you need a second database handle, use C<&new_dbh> and
 818 possibly C<&set_dbh>.
 819
 820 =cut
 821
 822 #'
 823 sub dbh
 824 {
 825     my $self = shift;
 826     my $sth;
 827
 828     if (defined($context->{"dbh"}) && $context->{"dbh"}->ping()) {
 829         return $context->{"dbh"};
 830     }
 831
 832     # No database handle or it died . Create one.
 833     $context->{"dbh"} = &_new_dbh();
 834
 835     return $context->{"dbh"};
 836 }
 837
 838 =head2 new_dbh
 839
 840   $dbh = C4::Context->new_dbh;
 841
 842 Creates a new connection to the Koha database for the current context,
 843 and returns the database handle (a C<DBI::db> object).
 844
 845 The handle is not saved anywhere: this method is strictly a
 846 convenience function; the point is that it knows which database to
 847 connect to so that the caller doesn't have to know.
 848
 849 =cut
 850
 851 #'
 852 sub new_dbh
 853 {
 854     my $self = shift;
 855
 856     return &_new_dbh();
 857 }
 858
 859 =head2 set_dbh
 860
 861   $my_dbh = C4::Connect->new_dbh;
 862   C4::Connect->set_dbh($my_dbh);
 863   ...
 864   C4::Connect->restore_dbh;
 865
 866 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 867 C<&set_context> and C<&restore_context>.
 868
 869 C<&set_dbh> saves the current database handle on a stack, then sets
 870 the current database handle to C<$my_dbh>.
 871
 872 C<$my_dbh> is assumed to be a good database handle.
 873
 874 =cut
 875
 876 #'
 877 sub set_dbh
 878 {
 879     my $self = shift;
 880     my $new_dbh = shift;
 881
 882     # Save the current database handle on the handle stack.
 883     # We assume that $new_dbh is all good: if the caller wants to
 884     # screw himself by passing an invalid handle, that's fine by
 885     # us.
 886     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 887     $context->{"dbh"} = $new_dbh;
 888 }
 889
 890 =head2 restore_dbh
 891
 892   C4::Context->restore_dbh;
 893
 894 Restores the database handle saved by an earlier call to
 895 C<C4::Context-E<gt>set_dbh>.
 896
 897 =cut
 898
 899 #'
 900 sub restore_dbh
 901 {
 902     my $self = shift;
 903
 904     if ($#{$context->{"dbh_stack"}} < 0)
 905     {
 906         # Stack underflow
 907         die "DBH stack underflow";
 908     }
 909
 910     # Pop the old database handle and set it.
 911     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 912
 913     # FIXME - If it is determined that restore_context should
 914     # return something, then this function should, too.
 915 }
 916
 917 =head2 marcfromkohafield
 918
 919   $dbh = C4::Context->marcfromkohafield;
 920
 921 Returns a hash with marcfromkohafield.
 922
 923 This hash is cached for future use: if you call
 924 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 925
 926 =cut
 927
 928 #'
 929 sub marcfromkohafield
 930 {
 931     my $retval = {};
 932
 933     # If the hash already exists, return it.
 934     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 935
 936     # No hash. Create one.
 937     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 938
 939     return $context->{"marcfromkohafield"};
 940 }
 941
 942 # _new_marcfromkohafield
 943 # Internal helper function (not a method!). This creates a new
 944 # hash with stopwords
 945 sub _new_marcfromkohafield
 946 {
 947     my $dbh = C4::Context->dbh;
 948     my $marcfromkohafield;
 949     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 950     $sth->execute;
 951     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 952         my $retval = {};
 953         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 954     }
 955     return $marcfromkohafield;
 956 }
 957
 958 =head2 stopwords
 959
 960   $dbh = C4::Context->stopwords;
 961
 962 Returns a hash with stopwords.
 963
 964 This hash is cached for future use: if you call
 965 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
 966
 967 =cut
 968
 969 #'
 970 sub stopwords
 971 {
 972     my $retval = {};
 973
 974     # If the hash already exists, return it.
 975     return $context->{"stopwords"} if defined($context->{"stopwords"});
 976
 977     # No hash. Create one.
 978     $context->{"stopwords"} = &_new_stopwords();
 979
 980     return $context->{"stopwords"};
 981 }
 982
 983 # _new_stopwords
 984 # Internal helper function (not a method!). This creates a new
 985 # hash with stopwords
 986 sub _new_stopwords
 987 {
 988     my $dbh = C4::Context->dbh;
 989     my $stopwordlist;
 990     my $sth = $dbh->prepare("select word from stopwords");
 991     $sth->execute;
 992     while (my $stopword = $sth->fetchrow_array) {
 993         $stopwordlist->{$stopword} = uc($stopword);
 994     }
 995     $stopwordlist->{A} = "A" unless $stopwordlist;
 996     return $stopwordlist;
 997 }
 998
 999 =head2 userenv
1000
1001   C4::Context->userenv;
1002
1003 Retrieves a hash for user environment variables.
1004
1005 This hash shall be cached for future use: if you call
1006 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1007
1008 =cut
1009
1010 #'
1011 sub userenv {
1012     my $var = $context->{"activeuser"};
1013     return $context->{"userenv"}->{$var} if (defined $var and defined $context->{"userenv"}->{$var});
1014     # insecure=1 management
1015     if ($context->{"dbh"} && $context->preference('insecure') eq 'yes') {
1016         my %insecure;
1017         $insecure{flags} = '16382';
1018         $insecure{branchname} ='Insecure';
1019         $insecure{number} ='0';
1020         $insecure{cardnumber} ='0';
1021         $insecure{id} = 'insecure';
1022         $insecure{branch} = 'INS';
1023         $insecure{emailaddress} = 'test@mode.insecure.com';
1024         return \%insecure;
1025     } else {
1026         return;
1027     }
1028 }
1029
1030 =head2 set_userenv
1031
1032   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1033                   $usersurname, $userbranch, $userflags, $emailaddress);
1034
1035 Establish a hash of user environment variables.
1036
1037 set_userenv is called in Auth.pm
1038
1039 =cut
1040
1041 #'
1042 sub set_userenv {
1043     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter)= @_;
1044     my $var=$context->{"activeuser"} || '';
1045     my $cell = {
1046         "number"     => $usernum,
1047         "id"         => $userid,
1048         "cardnumber" => $usercnum,
1049         "firstname"  => $userfirstname,
1050         "surname"    => $usersurname,
1051         #possibly a law problem
1052         "branch"     => $userbranch,
1053         "branchname" => $branchname,
1054         "flags"      => $userflags,
1055         "emailaddress"     => $emailaddress,
1056         "branchprinter"    => $branchprinter
1057     };
1058     $context->{userenv}->{$var} = $cell;
1059     return $cell;
1060 }
1061
1062 sub set_shelves_userenv {
1063         my ($type, $shelves) = @_ or return;
1064         my $activeuser = $context->{activeuser} or return;
1065         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1066         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1067         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1068 }
1069
1070 sub get_shelves_userenv {
1071         my $active;
1072         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1073                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1074                 return;
1075         }
1076         my $totshelves = $active->{totshelves} or undef;
1077         my $pubshelves = $active->{pubshelves} or undef;
1078         my $barshelves = $active->{barshelves} or undef;
1079         return ($totshelves, $pubshelves, $barshelves);
1080 }
1081
1082 =head2 _new_userenv
1083
1084   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1085
1086 Builds a hash for user environment variables.
1087
1088 This hash shall be cached for future use: if you call
1089 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1090
1091 _new_userenv is called in Auth.pm
1092
1093 =cut
1094
1095 #'
1096 sub _new_userenv
1097 {
1098     shift;  # Useless except it compensates for bad calling style
1099     my ($sessionID)= @_;
1100      $context->{"activeuser"}=$sessionID;
1101 }
1102
1103 =head2 _unset_userenv
1104
1105   C4::Context->_unset_userenv;
1106
1107 Destroys the hash for activeuser user environment variables.
1108
1109 =cut
1110
1111 #'
1112
1113 sub _unset_userenv
1114 {
1115     my ($sessionID)= @_;
1116     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1117 }
1118
1119
1120 =head2 get_versions
1121
1122   C4::Context->get_versions
1123
1124 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1125
1126 =cut
1127
1128 #'
1129
1130 # A little example sub to show more debugging info for CGI::Carp
1131 sub get_versions {
1132     my %versions;
1133     $versions{kohaVersion}  = KOHAVERSION();
1134     $versions{kohaDbVersion} = C4::Context->preference('version');
1135     $versions{osVersion} = join(" ", POSIX::uname());
1136     $versions{perlVersion} = $];
1137     {
1138         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1139         $versions{mysqlVersion}  = `mysql -V`;
1140         $versions{apacheVersion} = `httpd -v`;
1141         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1142         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1143         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1144     }
1145     return %versions;
1146 }
1147
1148
1149 =head2 tz
1150
1151   C4::Context->tz
1152
1153   Returns a DateTime::TimeZone object for the system timezone
1154
1155 =cut
1156
1157 sub tz {
1158     my $self = shift;
1159     if (!defined $context->{tz}) {
1160         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1161     }
1162     return $context->{tz};
1163 }
1164
1165
1166
1167 1;
1168 __END__
1169
1170 =head1 ENVIRONMENT
1171
1172 =head2 C<KOHA_CONF>
1173
1174 Specifies the configuration file to read.
1175
1176 =head1 SEE ALSO
1177
1178 XML::Simple
1179
1180 =head1 AUTHORS
1181
1182 Andrew Arensburger <arensb at ooblick dot com>
1183
1184 Joshua Ferraro <jmf at liblime dot com>
1185
1186 =cut