C4/Context.pm

   1 package C4::Context;
   2
   3 # Copyright 2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use vars qw($AUTOLOAD $context @context_stack);
  23 BEGIN {
  24     if ( $ENV{'HTTP_USER_AGENT'} ) { # Only hit when plack is not enabled
  25
  26         # Redefine multi_param if cgi version is < 4.08
  27         # Remove the "CGI::param called in list context" warning in this case
  28         require CGI;    # Can't check version without the require.
  29         if ( !defined($CGI::VERSION) || $CGI::VERSION < 4.08 ) {
  30             no warnings 'redefine';
  31             *CGI::multi_param = \&CGI::param;
  32             use warnings 'redefine';
  33             $CGI::LIST_CONTEXT_WARN = 0;
  34         }
  35     }
  36 };
  37
  38 use Carp qw( carp );
  39 use DateTime::TimeZone;
  40 use Encode;
  41 use File::Spec;
  42 use POSIX;
  43 use YAML::XS;
  44 use ZOOM;
  45 use List::MoreUtils qw(any);
  46
  47 use Koha::Caches;
  48 use Koha::Config::SysPref;
  49 use Koha::Config::SysPrefs;
  50 use Koha::Config;
  51 use Koha;
  52
  53 =head1 NAME
  54
  55 C4::Context - Maintain and manipulate the context of a Koha script
  56
  57 =head1 SYNOPSIS
  58
  59   use C4::Context;
  60
  61   use C4::Context("/path/to/koha-conf.xml");
  62
  63   $config_value = C4::Context->config("config_variable");
  64
  65   $koha_preference = C4::Context->preference("preference");
  66
  67   $db_handle = C4::Context->dbh;
  68
  69   $Zconn = C4::Context->Zconn;
  70
  71 =head1 DESCRIPTION
  72
  73 When a Koha script runs, it makes use of a certain number of things:
  74 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
  75 databases, and so forth. These things make up the I<context> in which
  76 the script runs.
  77
  78 This module takes care of setting up the context for a script:
  79 figuring out which configuration file to load, and loading it, opening
  80 a connection to the right database, and so forth.
  81
  82 Most scripts will only use one context. They can simply have
  83
  84   use C4::Context;
  85
  86 at the top.
  87
  88 Other scripts may need to use several contexts. For instance, if a
  89 library has two databases, one for a certain collection, and the other
  90 for everything else, it might be necessary for a script to use two
  91 different contexts to search both databases. Such scripts should use
  92 the C<&set_context> and C<&restore_context> functions, below.
  93
  94 By default, C4::Context reads the configuration from
  95 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
  96 environment variable to the pathname of a configuration file to use.
  97
  98 =head1 METHODS
  99
 100 =cut
 101
 102 #'
 103 # In addition to what is said in the POD above, a Context object is a
 104 # reference-to-hash with the following fields:
 105 #
 106 # config
 107 #    A reference-to-hash whose keys and values are the
 108 #    configuration variables and values specified in the config
 109 #    file (/etc/koha/koha-conf.xml).
 110 # dbh
 111 #    A handle to the appropriate database for this context.
 112 # dbh_stack
 113 #    Used by &set_dbh and &restore_dbh to hold other database
 114 #    handles for this context.
 115 # Zconn
 116 #     A connection object for the Zebra server
 117
 118 $context = undef;        # Initially, no context is set
 119 @context_stack = ();        # Initially, no saved contexts
 120
 121 sub import {
 122     # Create the default context ($C4::Context::Context)
 123     # the first time the module is called
 124     # (a config file can be optionaly passed)
 125
 126     # default context already exists?
 127     return if $context;
 128
 129     # no ? so load it!
 130     my ($pkg,$config_file) = @_ ;
 131     my $new_ctx = __PACKAGE__->new($config_file);
 132     return unless $new_ctx;
 133
 134     # if successfully loaded, use it by default
 135     $new_ctx->set_context;
 136     1;
 137 }
 138
 139 =head2 new
 140
 141   $context = C4::Context->new;
 142   $context = C4::Context->new("/path/to/koha-conf.xml");
 143
 144 Allocates a new context. Initializes the context from the specified
 145 file, which defaults to either the file given by the C<$KOHA_CONF>
 146 environment variable, or F</etc/koha/koha-conf.xml>.
 147
 148 It saves the koha-conf.xml values in the declared memcached server(s)
 149 if currently available and uses those values until them expire and
 150 re-reads them.
 151
 152 C<&new> does not set this context as the new default context; for
 153 that, use C<&set_context>.
 154
 155 =cut
 156
 157 #'
 158 # Revision History:
 159 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 160 sub new {
 161     my $class = shift;
 162     my $conf_fname = shift;        # Config file to load
 163
 164     # check that the specified config file exists and is not empty
 165     undef $conf_fname unless
 166         (defined $conf_fname && -s $conf_fname);
 167     # Figure out a good config file to load if none was specified.
 168     unless ( defined $conf_fname ) {
 169         $conf_fname = Koha::Config->guess_koha_conf;
 170         unless ( $conf_fname ) {
 171             warn "unable to locate Koha configuration file koha-conf.xml";
 172             return;
 173         }
 174     }
 175
 176     my $self = {};
 177     $self->{config} = Koha::Config->get_instance($conf_fname);
 178     unless ( defined $self->{config} ) {
 179         warn "The config file ($conf_fname) has not been parsed correctly";
 180         return;
 181     }
 182
 183     $self->{"Zconn"} = undef;    # Zebra Connections
 184     $self->{"userenv"} = undef;        # User env
 185     $self->{"activeuser"} = undef;        # current active user
 186     $self->{"shelves"} = undef;
 187     $self->{tz} = undef; # local timezone object
 188
 189     bless $self, $class;
 190     return $self;
 191 }
 192
 193 =head2 set_context
 194
 195   $context = new C4::Context;
 196   $context->set_context();
 197 or
 198   set_context C4::Context $context;
 199
 200   ...
 201   restore_context C4::Context;
 202
 203 In some cases, it might be necessary for a script to use multiple
 204 contexts. C<&set_context> saves the current context on a stack, then
 205 sets the context to C<$context>, which will be used in future
 206 operations. To restore the previous context, use C<&restore_context>.
 207
 208 =cut
 209
 210 #'
 211 sub set_context
 212 {
 213     my $self = shift;
 214     my $new_context;    # The context to set
 215
 216     # Figure out whether this is a class or instance method call.
 217     #
 218     # We're going to make the assumption that control got here
 219     # through valid means, i.e., that the caller used an instance
 220     # or class method call, and that control got here through the
 221     # usual inheritance mechanisms. The caller can, of course,
 222     # break this assumption by playing silly buggers, but that's
 223     # harder to do than doing it properly, and harder to check
 224     # for.
 225     if (ref($self) eq "")
 226     {
 227         # Class method. The new context is the next argument.
 228         $new_context = shift;
 229     } else {
 230         # Instance method. The new context is $self.
 231         $new_context = $self;
 232     }
 233
 234     # Save the old context, if any, on the stack
 235     push @context_stack, $context if defined($context);
 236
 237     # Set the new context
 238     $context = $new_context;
 239 }
 240
 241 =head2 restore_context
 242
 243   &restore_context;
 244
 245 Restores the context set by C<&set_context>.
 246
 247 =cut
 248
 249 #'
 250 sub restore_context
 251 {
 252     my $self = shift;
 253
 254     if ($#context_stack < 0)
 255     {
 256         # Stack underflow.
 257         die "Context stack underflow";
 258     }
 259
 260     # Pop the old context and set it.
 261     $context = pop @context_stack;
 262
 263     # FIXME - Should this return something, like maybe the context
 264     # that was current when this was called?
 265 }
 266
 267 =head2 config
 268
 269   $value = C4::Context->config("config_variable");
 270
 271 Returns the value of a variable specified in the configuration file
 272 from which the current context was created.
 273
 274 =cut
 275
 276 sub _common_config {
 277     my ($var, $term) = @_;
 278
 279     return unless defined $context and defined $context->{config};
 280
 281     return $context->{config}->get($var, $term);
 282 }
 283
 284 sub config {
 285         return _common_config($_[1],'config');
 286 }
 287 sub zebraconfig {
 288         return _common_config($_[1],'server');
 289 }
 290
 291 =head2 preference
 292
 293   $sys_preference = C4::Context->preference('some_variable');
 294
 295 Looks up the value of the given system preference in the
 296 systempreferences table of the Koha database, and returns it. If the
 297 variable is not set or does not exist, undef is returned.
 298
 299 In case of an error, this may return 0.
 300
 301 Note: It is impossible to tell the difference between system
 302 preferences which do not exist, and those whose values are set to NULL
 303 with this method.
 304
 305 =cut
 306
 307 my $use_syspref_cache = 1;
 308 sub preference {
 309     my $self = shift;
 310     my $var  = shift;    # The system preference to return
 311
 312     return Encode::decode_utf8($ENV{"OVERRIDE_SYSPREF_$var"})
 313         if defined $ENV{"OVERRIDE_SYSPREF_$var"};
 314
 315     $var = lc $var;
 316
 317     if ($use_syspref_cache) {
 318         my $syspref_cache = Koha::Caches->get_instance('syspref');
 319         my $cached_var = $syspref_cache->get_from_cache("syspref_$var");
 320         return $cached_var if defined $cached_var;
 321     }
 322
 323     my $syspref;
 324     eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 325     my $value = $syspref ? $syspref->value() : undef;
 326
 327     if ( $use_syspref_cache ) {
 328         my $syspref_cache = Koha::Caches->get_instance('syspref');
 329         $syspref_cache->set_in_cache("syspref_$var", $value);
 330     }
 331     return $value;
 332 }
 333
 334 =head2 yaml_preference
 335
 336 Retrieves the required system preference value, and converts it
 337 from YAML into a Perl data structure. It throws an exception if
 338 the value cannot be properly decoded as YAML.
 339
 340 =cut
 341
 342 sub yaml_preference {
 343     my ( $self, $preference ) = @_;
 344
 345     my $yaml = eval { YAML::XS::Load( Encode::encode_utf8( $self->preference( $preference ) ) ); };
 346     if ($@) {
 347         warn "Unable to parse $preference syspref : $@";
 348         return;
 349     }
 350
 351     return $yaml;
 352 }
 353
 354 =head2 enable_syspref_cache
 355
 356   C4::Context->enable_syspref_cache();
 357
 358 Enable the in-memory syspref cache used by C4::Context. This is the
 359 default behavior.
 360
 361 =cut
 362
 363 sub enable_syspref_cache {
 364     my ($self) = @_;
 365     $use_syspref_cache = 1;
 366     # We need to clear the cache to have it up-to-date
 367     $self->clear_syspref_cache();
 368 }
 369
 370 =head2 disable_syspref_cache
 371
 372   C4::Context->disable_syspref_cache();
 373
 374 Disable the in-memory syspref cache used by C4::Context. This should be
 375 used with Plack and other persistent environments.
 376
 377 =cut
 378
 379 sub disable_syspref_cache {
 380     my ($self) = @_;
 381     $use_syspref_cache = 0;
 382     $self->clear_syspref_cache();
 383 }
 384
 385 =head2 clear_syspref_cache
 386
 387   C4::Context->clear_syspref_cache();
 388
 389 cleans the internal cache of sysprefs. Please call this method if
 390 you update the systempreferences table. Otherwise, your new changes
 391 will not be seen by this process.
 392
 393 =cut
 394
 395 sub clear_syspref_cache {
 396     return unless $use_syspref_cache;
 397     my $syspref_cache = Koha::Caches->get_instance('syspref');
 398     $syspref_cache->flush_all;
 399 }
 400
 401 =head2 set_preference
 402
 403   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 404
 405 This updates a preference's value both in the systempreferences table and in
 406 the sysprefs cache. If the optional parameters are provided, then the query
 407 becomes a create. It won't update the parameters (except value) for an existing
 408 preference.
 409
 410 =cut
 411
 412 sub set_preference {
 413     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 414
 415     my $variable_case = $variable;
 416     $variable = lc $variable;
 417
 418     my $syspref = Koha::Config::SysPrefs->find($variable);
 419     $type =
 420         $type    ? $type
 421       : $syspref ? $syspref->type
 422       :            undef;
 423
 424     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 425
 426     # force explicit protocol on OPACBaseURL
 427     if ( $variable eq 'opacbaseurl' && $value && substr( $value, 0, 4 ) !~ /http/ ) {
 428         $value = 'http://' . $value;
 429     }
 430
 431     if ($syspref) {
 432         $syspref->set(
 433             {   ( defined $value ? ( value       => $value )       : () ),
 434                 ( $explanation   ? ( explanation => $explanation ) : () ),
 435                 ( $type          ? ( type        => $type )        : () ),
 436                 ( $options       ? ( options     => $options )     : () ),
 437             }
 438         )->store;
 439     } else {
 440         $syspref = Koha::Config::SysPref->new(
 441             {   variable    => $variable_case,
 442                 value       => $value,
 443                 explanation => $explanation || undef,
 444                 type        => $type,
 445                 options     => $options || undef,
 446             }
 447         )->store();
 448     }
 449
 450     if ( $use_syspref_cache ) {
 451         my $syspref_cache = Koha::Caches->get_instance('syspref');
 452         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 453     }
 454
 455     return $syspref;
 456 }
 457
 458 =head2 delete_preference
 459
 460     C4::Context->delete_preference( $variable );
 461
 462 This deletes a system preference from the database. Returns a true value on
 463 success. Failure means there was an issue with the database, not that there
 464 was no syspref of the name.
 465
 466 =cut
 467
 468 sub delete_preference {
 469     my ( $self, $var ) = @_;
 470
 471     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 472         if ( $use_syspref_cache ) {
 473             my $syspref_cache = Koha::Caches->get_instance('syspref');
 474             $syspref_cache->clear_from_cache("syspref_$var");
 475         }
 476
 477         return 1;
 478     }
 479     return 0;
 480 }
 481
 482 =head2 Zconn
 483
 484   $Zconn = C4::Context->Zconn
 485
 486 Returns a connection to the Zebra database
 487
 488 C<$self>
 489
 490 C<$server> one of the servers defined in the koha-conf.xml file
 491
 492 C<$async> whether this is a asynchronous connection
 493
 494 =cut
 495
 496 sub Zconn {
 497     my ($self, $server, $async ) = @_;
 498     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 499     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 500         # if we are running the script from the commandline, lets try to use the caching
 501         return $context->{"Zconn"}->{$cache_key};
 502     }
 503     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 504     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 505     return $context->{"Zconn"}->{$cache_key};
 506 }
 507
 508 =head2 _new_Zconn
 509
 510 $context->{"Zconn"} = &_new_Zconn($server,$async);
 511
 512 Internal function. Creates a new database connection from the data given in the current context and returns it.
 513
 514 C<$server> one of the servers defined in the koha-conf.xml file
 515
 516 C<$async> whether this is a asynchronous connection
 517
 518 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 519
 520 =cut
 521
 522 sub _new_Zconn {
 523     my ( $server, $async ) = @_;
 524
 525     my $tried=0; # first attempt
 526     my $Zconn; # connection object
 527     my $elementSetName;
 528     my $syntax;
 529
 530     $server //= "biblioserver";
 531
 532     $syntax = 'xml';
 533     $elementSetName = 'marcxml';
 534
 535     my $host = _common_config($server, 'listen')->{content};
 536     my $serverinfo = _common_config($server, 'serverinfo');
 537     my $user = $serverinfo->{user};
 538     my $password = $serverinfo->{password};
 539     eval {
 540         # set options
 541         my $o = ZOOM::Options->new();
 542         $o->option(user => $user) if $user && $password;
 543         $o->option(password => $password) if $user && $password;
 544         $o->option(async => 1) if $async;
 545         $o->option(cqlfile=> _common_config($server, 'server')->{cql2rpn});
 546         $o->option(cclfile=> $serverinfo->{ccl2rpn});
 547         $o->option(preferredRecordSyntax => $syntax);
 548         $o->option(elementSetName => $elementSetName) if $elementSetName;
 549         $o->option(databaseName => _common_config($server, 'config') || 'biblios');
 550
 551         # create a new connection object
 552         $Zconn= create ZOOM::Connection($o);
 553
 554         # forge to server
 555         $Zconn->connect($host, 0);
 556
 557         # check for errors and warn
 558         if ($Zconn->errcode() !=0) {
 559             warn "something wrong with the connection: ". $Zconn->errmsg();
 560         }
 561     };
 562     return $Zconn;
 563 }
 564
 565 # _new_dbh
 566 # Internal helper function (not a method!). This creates a new
 567 # database connection from the data given in the current context, and
 568 # returns it.
 569 sub _new_dbh
 570 {
 571
 572     Koha::Database->schema({ new => 1 })->storage->dbh;
 573 }
 574
 575 =head2 dbh
 576
 577   $dbh = C4::Context->dbh;
 578
 579 Returns a database handle connected to the Koha database for the
 580 current context. If no connection has yet been made, this method
 581 creates one, and connects to the database.
 582
 583 This database handle is cached for future use: if you call
 584 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 585 times. If you need a second database handle, use C<&new_dbh> and
 586 possibly C<&set_dbh>.
 587
 588 =cut
 589
 590 #'
 591 sub dbh
 592 {
 593     my $self = shift;
 594     my $params = shift;
 595
 596     unless ( $params->{new} ) {
 597         return Koha::Database->schema->storage->dbh;
 598     }
 599
 600     return Koha::Database->schema({ new => 1 })->storage->dbh;
 601 }
 602
 603 =head2 new_dbh
 604
 605   $dbh = C4::Context->new_dbh;
 606
 607 Creates a new connection to the Koha database for the current context,
 608 and returns the database handle (a C<DBI::db> object).
 609
 610 The handle is not saved anywhere: this method is strictly a
 611 convenience function; the point is that it knows which database to
 612 connect to so that the caller doesn't have to know.
 613
 614 =cut
 615
 616 #'
 617 sub new_dbh
 618 {
 619     my $self = shift;
 620
 621     return &dbh({ new => 1 });
 622 }
 623
 624 =head2 set_dbh
 625
 626   $my_dbh = C4::Connect->new_dbh;
 627   C4::Connect->set_dbh($my_dbh);
 628   ...
 629   C4::Connect->restore_dbh;
 630
 631 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 632 C<&set_context> and C<&restore_context>.
 633
 634 C<&set_dbh> saves the current database handle on a stack, then sets
 635 the current database handle to C<$my_dbh>.
 636
 637 C<$my_dbh> is assumed to be a good database handle.
 638
 639 =cut
 640
 641 #'
 642 sub set_dbh
 643 {
 644     my $self = shift;
 645     my $new_dbh = shift;
 646
 647     # Save the current database handle on the handle stack.
 648     # We assume that $new_dbh is all good: if the caller wants to
 649     # screw himself by passing an invalid handle, that's fine by
 650     # us.
 651     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 652     $context->{"dbh"} = $new_dbh;
 653 }
 654
 655 =head2 restore_dbh
 656
 657   C4::Context->restore_dbh;
 658
 659 Restores the database handle saved by an earlier call to
 660 C<C4::Context-E<gt>set_dbh>.
 661
 662 =cut
 663
 664 #'
 665 sub restore_dbh
 666 {
 667     my $self = shift;
 668
 669     if ($#{$context->{"dbh_stack"}} < 0)
 670     {
 671         # Stack underflow
 672         die "DBH stack underflow";
 673     }
 674
 675     # Pop the old database handle and set it.
 676     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 677
 678     # FIXME - If it is determined that restore_context should
 679     # return something, then this function should, too.
 680 }
 681
 682 =head2 userenv
 683
 684   C4::Context->userenv;
 685
 686 Retrieves a hash for user environment variables.
 687
 688 This hash shall be cached for future use: if you call
 689 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 690
 691 =cut
 692
 693 #'
 694 sub userenv {
 695     my $var = $context->{"activeuser"};
 696     if (defined $var and defined $context->{"userenv"}->{$var}) {
 697         return $context->{"userenv"}->{$var};
 698     } else {
 699         return;
 700     }
 701 }
 702
 703 =head2 set_userenv
 704
 705   C4::Context->set_userenv($usernum, $userid, $usercnum,
 706                            $userfirstname, $usersurname,
 707                            $userbranch, $branchname, $userflags,
 708                            $emailaddress, $shibboleth
 709                            $desk_id, $desk_name,
 710                            $register_id, $register_name);
 711
 712 Establish a hash of user environment variables.
 713
 714 set_userenv is called in Auth.pm
 715
 716 =cut
 717
 718 #'
 719 sub set_userenv {
 720     shift @_;
 721     my (
 722         $usernum,      $userid,     $usercnum,   $userfirstname,
 723         $usersurname,  $userbranch, $branchname, $userflags,
 724         $emailaddress, $shibboleth, $desk_id,    $desk_name,
 725         $register_id,  $register_name
 726     ) = @_;
 727
 728     my $var=$context->{"activeuser"} || '';
 729     my $cell = {
 730         "number"     => $usernum,
 731         "id"         => $userid,
 732         "cardnumber" => $usercnum,
 733         "firstname"  => $userfirstname,
 734         "surname"    => $usersurname,
 735
 736         #possibly a law problem
 737         "branch"        => $userbranch,
 738         "branchname"    => $branchname,
 739         "flags"         => $userflags,
 740         "emailaddress"  => $emailaddress,
 741         "shibboleth"    => $shibboleth,
 742         "desk_id"       => $desk_id,
 743         "desk_name"     => $desk_name,
 744         "register_id"   => $register_id,
 745         "register_name" => $register_name
 746     };
 747     $context->{userenv}->{$var} = $cell;
 748     return $cell;
 749 }
 750
 751 =head2 _new_userenv
 752
 753   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
 754
 755 Builds a hash for user environment variables.
 756
 757 This hash shall be cached for future use: if you call
 758 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 759
 760 _new_userenv is called in Auth.pm
 761
 762 =cut
 763
 764 #'
 765 sub _new_userenv
 766 {
 767     shift;  # Useless except it compensates for bad calling style
 768     my ($sessionID)= @_;
 769      $context->{"activeuser"}=$sessionID;
 770 }
 771
 772 =head2 _unset_userenv
 773
 774   C4::Context->_unset_userenv;
 775
 776 Destroys the hash for activeuser user environment variables.
 777
 778 =cut
 779
 780 #'
 781
 782 sub _unset_userenv
 783 {
 784     my ($sessionID)= @_;
 785     undef $context->{activeuser} if $sessionID && $context->{activeuser} && $context->{activeuser} eq $sessionID;
 786 }
 787
 788
 789 =head2 get_versions
 790
 791   C4::Context->get_versions
 792
 793 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
 794
 795 =cut
 796
 797 #'
 798
 799 # A little example sub to show more debugging info for CGI::Carp
 800 sub get_versions {
 801     my %versions;
 802     $versions{kohaVersion}  = Koha::version();
 803     $versions{kohaDbVersion} = C4::Context->preference('version');
 804     $versions{osVersion} = join(" ", POSIX::uname());
 805     $versions{perlVersion} = $];
 806     {
 807         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
 808         $versions{mysqlVersion}  = `mysql -V`;
 809         $versions{apacheVersion} = (`apache2ctl -v`)[0];
 810         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
 811         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
 812         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
 813         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
 814     }
 815     return %versions;
 816 }
 817
 818 =head2 tz
 819
 820   C4::Context->tz
 821
 822   Returns a DateTime::TimeZone object for the system timezone
 823
 824 =cut
 825
 826 sub tz {
 827     my $self = shift;
 828     if (!defined $context->{tz}) {
 829         my $timezone = $context->{config}->timezone;
 830         $context->{tz} = DateTime::TimeZone->new(name => $timezone);
 831     }
 832     return $context->{tz};
 833 }
 834
 835
 836 =head2 IsSuperLibrarian
 837
 838     C4::Context->IsSuperLibrarian();
 839
 840 =cut
 841
 842 sub IsSuperLibrarian {
 843     my $userenv = C4::Context->userenv;
 844
 845     unless ( $userenv and exists $userenv->{flags} ) {
 846         # If we reach this without a user environment,
 847         # assume that we're running from a command-line script,
 848         # and act as a superlibrarian.
 849         carp("C4::Context->userenv not defined!");
 850         return 1;
 851     }
 852
 853     return ($userenv->{flags}//0) % 2;
 854 }
 855
 856 =head2 interface
 857
 858 Sets the current interface for later retrieval in any Perl module
 859
 860     C4::Context->interface('opac');
 861     C4::Context->interface('intranet');
 862     my $interface = C4::Context->interface;
 863
 864 =cut
 865
 866 sub interface {
 867     my ($class, $interface) = @_;
 868
 869     if (defined $interface) {
 870         $interface = lc $interface;
 871         if (   $interface eq 'api'
 872             || $interface eq 'opac'
 873             || $interface eq 'intranet'
 874             || $interface eq 'sip'
 875             || $interface eq 'cron'
 876             || $interface eq 'commandline' )
 877         {
 878             $context->{interface} = $interface;
 879         } else {
 880             warn "invalid interface : '$interface'";
 881         }
 882     }
 883
 884     return $context->{interface} // 'opac';
 885 }
 886
 887 # always returns a string for OK comparison via "eq" or "ne"
 888 sub mybranch {
 889     C4::Context->userenv           or return '';
 890     return C4::Context->userenv->{branch} || '';
 891 }
 892
 893 =head2 only_my_library
 894
 895     my $test = C4::Context->only_my_library;
 896
 897     Returns true if you enabled IndependentBranches and the current user
 898     does not have superlibrarian permissions.
 899
 900 =cut
 901
 902 sub only_my_library {
 903     return
 904          C4::Context->preference('IndependentBranches')
 905       && C4::Context->userenv
 906       && !C4::Context->IsSuperLibrarian()
 907       && C4::Context->userenv->{branch};
 908 }
 909
 910 =head3 temporary_directory
 911
 912 Returns root directory for temporary storage
 913
 914 =cut
 915
 916 sub temporary_directory {
 917     my ( $class ) = @_;
 918     return C4::Context->config('tmp_path') || File::Spec->tmpdir;
 919 }
 920
 921 =head3 set_remote_address
 922
 923 set_remote_address should be called at the beginning of every script
 924 that is *not* running under plack in order to the REMOTE_ADDR environment
 925 variable to be set correctly.
 926
 927 =cut
 928
 929 sub set_remote_address {
 930     if ( C4::Context->config('koha_trusted_proxies') ) {
 931         require CGI;
 932         my $header = CGI->http('HTTP_X_FORWARDED_FOR');
 933
 934         if ($header) {
 935             require Koha::Middleware::RealIP;
 936             $ENV{REMOTE_ADDR} = Koha::Middleware::RealIP::get_real_ip( $ENV{REMOTE_ADDR}, $header );
 937         }
 938     }
 939 }
 940
 941 =head3 https_enabled
 942
 943 https_enabled should be called when checking if a HTTPS connection
 944 is used.
 945
 946 Note that this depends on a HTTPS environmental variable being defined
 947 by the web server. This function may not return the expected result,
 948 if your web server or reverse proxies are not setting the correct
 949 X-Forwarded-Proto headers and HTTPS environmental variable.
 950
 951 Note too that the HTTPS value can vary from web server to web server.
 952 We are relying on the convention of the value being "on" or "ON" here.
 953
 954 =cut
 955
 956 sub https_enabled {
 957     my $https_enabled = 0;
 958     my $env_https = $ENV{HTTPS};
 959     if ($env_https){
 960         if ($env_https =~ /^ON$/i){
 961             $https_enabled = 1;
 962         }
 963     }
 964     return $https_enabled;
 965 }
 966
 967 1;
 968
 969 =head3 needs_install
 970
 971     if ( $context->needs_install ) { ... }
 972
 973 This method returns a boolean representing the install status of the Koha instance.
 974
 975 =cut
 976
 977 sub needs_install {
 978     my ($self) = @_;
 979     return ($self->preference('Version')) ? 0 : 1;
 980 }
 981
 982 =head3 is_psgi_or_plack
 983
 984 is_psgi_or_plack returns true if there is an environmental variable
 985 prefixed with "psgi" or "plack". This is useful for detecting whether
 986 this is a PSGI app or a CGI app, and implementing code as appropriate.
 987
 988 =cut
 989
 990 sub is_psgi_or_plack {
 991     my $is_psgi_or_plack = 0;
 992     if ( any { /(^psgi\.|^plack\.)/i } keys %ENV ) {
 993         $is_psgi_or_plack = 1;
 994     }
 995     return $is_psgi_or_plack;
 996 }
 997
 998 =head3 is_internal_PSGI_request
 999
1000 is_internal_PSGI_request is used to detect if this request was made
1001 from within the individual PSGI app or externally from the mounted PSGI
1002 app
1003
1004 =cut
1005
1006 #NOTE: This is not a very robust method but it's the best we have so far
1007 sub is_internal_PSGI_request {
1008     my $is_internal = 0;
1009     if ( (__PACKAGE__->is_psgi_or_plack) && ( $ENV{REQUEST_URI} !~ /^(\/intranet|\/opac)/ ) ){
1010         $is_internal = 1;
1011     }
1012     return $is_internal;
1013 }
1014
1015 __END__
1016
1017 =head1 ENVIRONMENT
1018
1019 =head2 C<KOHA_CONF>
1020
1021 Specifies the configuration file to read.
1022
1023 =head1 AUTHORS
1024
1025 Andrew Arensburger <arensb at ooblick dot com>
1026
1027 Joshua Ferraro <jmf at liblime dot com>
1028