C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79
  80         # Redefine multi_param if cgi version is < 4.08
  81         # Remove the "CGI::param called in list context" warning in this case
  82         if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  83             no warnings 'redefine';
  84             *CGI::multi_param = \&CGI::param;
  85             use warnings 'redefine';
  86             $CGI::LIST_CONTEXT_WARN = 0;
  87         }
  88     }   # else there is no browser to send fatals to!
  89
  90     # Check if there are memcached servers set
  91     $servers = $ENV{'MEMCACHED_SERVERS'};
  92     if ($servers) {
  93         # Load required libraries and create the memcached object
  94         require Cache::Memcached;
  95         $memcached = Cache::Memcached->new({
  96         servers => [ $servers ],
  97         debug   => 0,
  98         compress_threshold => 10_000,
  99         expire_time => 600,
 100         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
 101     });
 102         # Verify memcached available (set a variable and test the output)
 103     $ismemcached = $memcached->set('ismemcached','1');
 104     }
 105
 106 }
 107
 108 use Encode;
 109 use ZOOM;
 110 use XML::Simple;
 111 use Koha::Cache;
 112 use POSIX ();
 113 use DateTime::TimeZone;
 114 use Module::Load::Conditional qw(can_load);
 115 use Carp;
 116
 117 use C4::Boolean;
 118 use C4::Debug;
 119 use Koha;
 120 use Koha::Config::SysPref;
 121 use Koha::Config::SysPrefs;
 122
 123 =head1 NAME
 124
 125 C4::Context - Maintain and manipulate the context of a Koha script
 126
 127 =head1 SYNOPSIS
 128
 129   use C4::Context;
 130
 131   use C4::Context("/path/to/koha-conf.xml");
 132
 133   $config_value = C4::Context->config("config_variable");
 134
 135   $koha_preference = C4::Context->preference("preference");
 136
 137   $db_handle = C4::Context->dbh;
 138
 139   $Zconn = C4::Context->Zconn;
 140
 141 =head1 DESCRIPTION
 142
 143 When a Koha script runs, it makes use of a certain number of things:
 144 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 145 databases, and so forth. These things make up the I<context> in which
 146 the script runs.
 147
 148 This module takes care of setting up the context for a script:
 149 figuring out which configuration file to load, and loading it, opening
 150 a connection to the right database, and so forth.
 151
 152 Most scripts will only use one context. They can simply have
 153
 154   use C4::Context;
 155
 156 at the top.
 157
 158 Other scripts may need to use several contexts. For instance, if a
 159 library has two databases, one for a certain collection, and the other
 160 for everything else, it might be necessary for a script to use two
 161 different contexts to search both databases. Such scripts should use
 162 the C<&set_context> and C<&restore_context> functions, below.
 163
 164 By default, C4::Context reads the configuration from
 165 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 166 environment variable to the pathname of a configuration file to use.
 167
 168 =head1 METHODS
 169
 170 =cut
 171
 172 #'
 173 # In addition to what is said in the POD above, a Context object is a
 174 # reference-to-hash with the following fields:
 175 #
 176 # config
 177 #    A reference-to-hash whose keys and values are the
 178 #    configuration variables and values specified in the config
 179 #    file (/etc/koha/koha-conf.xml).
 180 # dbh
 181 #    A handle to the appropriate database for this context.
 182 # dbh_stack
 183 #    Used by &set_dbh and &restore_dbh to hold other database
 184 #    handles for this context.
 185 # Zconn
 186 #     A connection object for the Zebra server
 187
 188 # Koha's main configuration file koha-conf.xml
 189 # is searched for according to this priority list:
 190 #
 191 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 192 # 2. Path supplied in KOHA_CONF environment variable.
 193 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 194 #    as value has changed from its default of
 195 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 196 #    when Koha is installed in 'standard' or 'single'
 197 #    mode.
 198 # 4. Path supplied in CONFIG_FNAME.
 199 #
 200 # The first entry that refers to a readable file is used.
 201
 202 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 203                 # Default config file, if none is specified
 204
 205 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 206                 # path to config file set by installer
 207                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 208                 # when Koha is installed in 'standard' or 'single'
 209                 # mode.  If Koha was installed in 'dev' mode,
 210                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 211                 # developers should set the KOHA_CONF environment variable
 212
 213 $context = undef;        # Initially, no context is set
 214 @context_stack = ();        # Initially, no saved contexts
 215
 216
 217 =head2 read_config_file
 218
 219 Reads the specified Koha config file.
 220
 221 Returns an object containing the configuration variables. The object's
 222 structure is a bit complex to the uninitiated ... take a look at the
 223 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 224 here are a few examples that may give you what you need:
 225
 226 The simple elements nested within the <config> element:
 227
 228     my $pass = $koha->{'config'}->{'pass'};
 229
 230 The <listen> elements:
 231
 232     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 233
 234 The elements nested within the <server> element:
 235
 236     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 237
 238 Returns undef in case of error.
 239
 240 =cut
 241
 242 sub read_config_file {          # Pass argument naming config file to read
 243     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 244
 245     if ($ismemcached) {
 246       $memcached->set('kohaconf',$koha);
 247     }
 248
 249     return $koha;                       # Return value: ref-to-hash holding the configuration
 250 }
 251
 252 =head2 ismemcached
 253
 254 Returns the value of the $ismemcached variable (0/1)
 255
 256 =cut
 257
 258 sub ismemcached {
 259     return $ismemcached;
 260 }
 261
 262 =head2 memcached
 263
 264 If $ismemcached is true, returns the $memcache variable.
 265 Returns undef otherwise
 266
 267 =cut
 268
 269 sub memcached {
 270     if ($ismemcached) {
 271       return $memcached;
 272     } else {
 273       return;
 274     }
 275 }
 276
 277 =head2 db_scheme2dbi
 278
 279     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 280
 281 This routines translates a database type to part of the name
 282 of the appropriate DBD driver to use when establishing a new
 283 database connection.  It recognizes 'mysql' and 'Pg'; if any
 284 other scheme is supplied it defaults to 'mysql'.
 285
 286 =cut
 287
 288 sub db_scheme2dbi {
 289     my $scheme = shift // '';
 290     return $scheme eq 'Pg' ? $scheme : 'mysql';
 291 }
 292
 293 sub import {
 294     # Create the default context ($C4::Context::Context)
 295     # the first time the module is called
 296     # (a config file can be optionaly passed)
 297
 298     # default context already exists?
 299     return if $context;
 300
 301     # no ? so load it!
 302     my ($pkg,$config_file) = @_ ;
 303     my $new_ctx = __PACKAGE__->new($config_file);
 304     return unless $new_ctx;
 305
 306     # if successfully loaded, use it by default
 307     $new_ctx->set_context;
 308     1;
 309 }
 310
 311 =head2 new
 312
 313   $context = new C4::Context;
 314   $context = new C4::Context("/path/to/koha-conf.xml");
 315
 316 Allocates a new context. Initializes the context from the specified
 317 file, which defaults to either the file given by the C<$KOHA_CONF>
 318 environment variable, or F</etc/koha/koha-conf.xml>.
 319
 320 It saves the koha-conf.xml values in the declared memcached server(s)
 321 if currently available and uses those values until them expire and
 322 re-reads them.
 323
 324 C<&new> does not set this context as the new default context; for
 325 that, use C<&set_context>.
 326
 327 =cut
 328
 329 #'
 330 # Revision History:
 331 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 332 sub new {
 333     my $class = shift;
 334     my $conf_fname = shift;        # Config file to load
 335     my $self = {};
 336
 337     # check that the specified config file exists and is not empty
 338     undef $conf_fname unless
 339         (defined $conf_fname && -s $conf_fname);
 340     # Figure out a good config file to load if none was specified.
 341     if (!defined($conf_fname))
 342     {
 343         # If the $KOHA_CONF environment variable is set, use
 344         # that. Otherwise, use the built-in default.
 345         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 346             $conf_fname = $ENV{"KOHA_CONF"};
 347         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 348             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 349             # regex to anything else -- don't want installer to rewrite it
 350             $conf_fname = $INSTALLED_CONFIG_FNAME;
 351         } elsif (-s CONFIG_FNAME) {
 352             $conf_fname = CONFIG_FNAME;
 353         } else {
 354             warn "unable to locate Koha configuration file koha-conf.xml";
 355             return;
 356         }
 357     }
 358
 359     if ($ismemcached) {
 360         # retrieve from memcached
 361         $self = $memcached->get('kohaconf');
 362         if (not defined $self) {
 363             # not in memcached yet
 364             $self = read_config_file($conf_fname);
 365         }
 366     } else {
 367         # non-memcached env, read from file
 368         $self = read_config_file($conf_fname);
 369     }
 370
 371     $self->{"config_file"} = $conf_fname;
 372     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 373     return if !defined($self->{"config"});
 374
 375     $self->{"Zconn"} = undef;    # Zebra Connections
 376     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 377     $self->{"userenv"} = undef;        # User env
 378     $self->{"activeuser"} = undef;        # current active user
 379     $self->{"shelves"} = undef;
 380     $self->{tz} = undef; # local timezone object
 381
 382     bless $self, $class;
 383     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 384     return $self;
 385 }
 386
 387 =head2 set_context
 388
 389   $context = new C4::Context;
 390   $context->set_context();
 391 or
 392   set_context C4::Context $context;
 393
 394   ...
 395   restore_context C4::Context;
 396
 397 In some cases, it might be necessary for a script to use multiple
 398 contexts. C<&set_context> saves the current context on a stack, then
 399 sets the context to C<$context>, which will be used in future
 400 operations. To restore the previous context, use C<&restore_context>.
 401
 402 =cut
 403
 404 #'
 405 sub set_context
 406 {
 407     my $self = shift;
 408     my $new_context;    # The context to set
 409
 410     # Figure out whether this is a class or instance method call.
 411     #
 412     # We're going to make the assumption that control got here
 413     # through valid means, i.e., that the caller used an instance
 414     # or class method call, and that control got here through the
 415     # usual inheritance mechanisms. The caller can, of course,
 416     # break this assumption by playing silly buggers, but that's
 417     # harder to do than doing it properly, and harder to check
 418     # for.
 419     if (ref($self) eq "")
 420     {
 421         # Class method. The new context is the next argument.
 422         $new_context = shift;
 423     } else {
 424         # Instance method. The new context is $self.
 425         $new_context = $self;
 426     }
 427
 428     # Save the old context, if any, on the stack
 429     push @context_stack, $context if defined($context);
 430
 431     # Set the new context
 432     $context = $new_context;
 433 }
 434
 435 =head2 restore_context
 436
 437   &restore_context;
 438
 439 Restores the context set by C<&set_context>.
 440
 441 =cut
 442
 443 #'
 444 sub restore_context
 445 {
 446     my $self = shift;
 447
 448     if ($#context_stack < 0)
 449     {
 450         # Stack underflow.
 451         die "Context stack underflow";
 452     }
 453
 454     # Pop the old context and set it.
 455     $context = pop @context_stack;
 456
 457     # FIXME - Should this return something, like maybe the context
 458     # that was current when this was called?
 459 }
 460
 461 =head2 config
 462
 463   $value = C4::Context->config("config_variable");
 464
 465   $value = C4::Context->config_variable;
 466
 467 Returns the value of a variable specified in the configuration file
 468 from which the current context was created.
 469
 470 The second form is more compact, but of course may conflict with
 471 method names. If there is a configuration variable called "new", then
 472 C<C4::Config-E<gt>new> will not return it.
 473
 474 =cut
 475
 476 sub _common_config {
 477         my $var = shift;
 478         my $term = shift;
 479     return if !defined($context->{$term});
 480        # Presumably $self->{$term} might be
 481        # undefined if the config file given to &new
 482        # didn't exist, and the caller didn't bother
 483        # to check the return value.
 484
 485     # Return the value of the requested config variable
 486     return $context->{$term}->{$var};
 487 }
 488
 489 sub config {
 490         return _common_config($_[1],'config');
 491 }
 492 sub zebraconfig {
 493         return _common_config($_[1],'server');
 494 }
 495 sub ModZebrations {
 496         return _common_config($_[1],'serverinfo');
 497 }
 498
 499 =head2 preference
 500
 501   $sys_preference = C4::Context->preference('some_variable');
 502
 503 Looks up the value of the given system preference in the
 504 systempreferences table of the Koha database, and returns it. If the
 505 variable is not set or does not exist, undef is returned.
 506
 507 In case of an error, this may return 0.
 508
 509 Note: It is impossible to tell the difference between system
 510 preferences which do not exist, and those whose values are set to NULL
 511 with this method.
 512
 513 =cut
 514
 515 my $syspref_cache = Koha::Cache->get_instance();
 516 my $use_syspref_cache = 1;
 517 sub preference {
 518     my $self = shift;
 519     my $var  = shift;    # The system preference to return
 520
 521     $var = lc $var;
 522
 523     return $ENV{"OVERRIDE_SYSPREF_$var"}
 524         if defined $ENV{"OVERRIDE_SYSPREF_$var"};
 525
 526     my $cached_var = $use_syspref_cache
 527         ? $syspref_cache->get_from_cache("syspref_$var")
 528         : undef;
 529     return $cached_var if defined $cached_var;
 530
 531     my $syspref;
 532     eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 533     my $value = $syspref ? $syspref->value() : undef;
 534
 535     if ( $use_syspref_cache ) {
 536         $syspref_cache->set_in_cache("syspref_$var", $value);
 537     }
 538     return $value;
 539 }
 540
 541 sub boolean_preference {
 542     my $self = shift;
 543     my $var = shift;        # The system preference to return
 544     my $it = preference($self, $var);
 545     return defined($it)? C4::Boolean::true_p($it): undef;
 546 }
 547
 548 =head2 enable_syspref_cache
 549
 550   C4::Context->enable_syspref_cache();
 551
 552 Enable the in-memory syspref cache used by C4::Context. This is the
 553 default behavior.
 554
 555 =cut
 556
 557 sub enable_syspref_cache {
 558     my ($self) = @_;
 559     $use_syspref_cache = 1;
 560     # We need to clear the cache to have it up-to-date
 561     $self->clear_syspref_cache();
 562 }
 563
 564 =head2 disable_syspref_cache
 565
 566   C4::Context->disable_syspref_cache();
 567
 568 Disable the in-memory syspref cache used by C4::Context. This should be
 569 used with Plack and other persistent environments.
 570
 571 =cut
 572
 573 sub disable_syspref_cache {
 574     my ($self) = @_;
 575     $use_syspref_cache = 0;
 576     $self->clear_syspref_cache();
 577 }
 578
 579 =head2 clear_syspref_cache
 580
 581   C4::Context->clear_syspref_cache();
 582
 583 cleans the internal cache of sysprefs. Please call this method if
 584 you update the systempreferences table. Otherwise, your new changes
 585 will not be seen by this process.
 586
 587 =cut
 588
 589 sub clear_syspref_cache {
 590     return unless $use_syspref_cache;
 591     $syspref_cache->flush_all;
 592 }
 593
 594 =head2 set_preference
 595
 596   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 597
 598 This updates a preference's value both in the systempreferences table and in
 599 the sysprefs cache. If the optional parameters are provided, then the query
 600 becomes a create. It won't update the parameters (except value) for an existing
 601 preference.
 602
 603 =cut
 604
 605 sub set_preference {
 606     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 607
 608     $variable = lc $variable;
 609
 610     my $syspref = Koha::Config::SysPrefs->find($variable);
 611     $type =
 612         $type    ? $type
 613       : $syspref ? $syspref->type
 614       :            undef;
 615
 616     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 617
 618     # force explicit protocol on OPACBaseURL
 619     if ( $variable eq 'opacbaseurl' && substr( $value, 0, 4 ) !~ /http/ ) {
 620         $value = 'http://' . $value;
 621     }
 622
 623     if ($syspref) {
 624         $syspref->set(
 625             {   ( defined $value ? ( value       => $value )       : () ),
 626                 ( $explanation   ? ( explanation => $explanation ) : () ),
 627                 ( $type          ? ( type        => $type )        : () ),
 628                 ( $options       ? ( options     => $options )     : () ),
 629             }
 630         )->store;
 631     } else {
 632         $syspref = Koha::Config::SysPref->new(
 633             {   variable    => $variable,
 634                 value       => $value,
 635                 explanation => $explanation || undef,
 636                 type        => $type,
 637                 options     => $options || undef,
 638             }
 639         )->store();
 640     }
 641
 642     if ( $use_syspref_cache ) {
 643         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 644     }
 645
 646     return $syspref;
 647 }
 648
 649 =head2 delete_preference
 650
 651     C4::Context->delete_preference( $variable );
 652
 653 This deletes a system preference from the database. Returns a true value on
 654 success. Failure means there was an issue with the database, not that there
 655 was no syspref of the name.
 656
 657 =cut
 658
 659 sub delete_preference {
 660     my ( $self, $var ) = @_;
 661
 662     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 663         if ( $use_syspref_cache ) {
 664             $syspref_cache->clear_from_cache("syspref_$var");
 665         }
 666
 667         return 1;
 668     }
 669     return 0;
 670 }
 671
 672 =head2 Zconn
 673
 674   $Zconn = C4::Context->Zconn
 675
 676 Returns a connection to the Zebra database
 677
 678 C<$self>
 679
 680 C<$server> one of the servers defined in the koha-conf.xml file
 681
 682 C<$async> whether this is a asynchronous connection
 683
 684 =cut
 685
 686 sub Zconn {
 687     my ($self, $server, $async ) = @_;
 688     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 689     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 690         # if we are running the script from the commandline, lets try to use the caching
 691         return $context->{"Zconn"}->{$cache_key};
 692     }
 693     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 694     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 695     return $context->{"Zconn"}->{$cache_key};
 696 }
 697
 698 =head2 _new_Zconn
 699
 700 $context->{"Zconn"} = &_new_Zconn($server,$async);
 701
 702 Internal function. Creates a new database connection from the data given in the current context and returns it.
 703
 704 C<$server> one of the servers defined in the koha-conf.xml file
 705
 706 C<$async> whether this is a asynchronous connection
 707
 708 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 709
 710 =cut
 711
 712 sub _new_Zconn {
 713     my ( $server, $async ) = @_;
 714
 715     my $tried=0; # first attempt
 716     my $Zconn; # connection object
 717     my $elementSetName;
 718     my $index_mode;
 719     my $syntax;
 720
 721     $server //= "biblioserver";
 722
 723     if ( $server eq 'biblioserver' ) {
 724         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 725     } elsif ( $server eq 'authorityserver' ) {
 726         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 727     }
 728
 729     if ( $index_mode eq 'grs1' ) {
 730         $elementSetName = 'F';
 731         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 732                 ? 'unimarc'
 733                 : 'usmarc';
 734
 735     } else { # $index_mode eq 'dom'
 736         $syntax = 'xml';
 737         $elementSetName = 'marcxml';
 738     }
 739
 740     my $host = $context->{'listen'}->{$server}->{'content'};
 741     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 742     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 743     eval {
 744         # set options
 745         my $o = new ZOOM::Options();
 746         $o->option(user => $user) if $user && $password;
 747         $o->option(password => $password) if $user && $password;
 748         $o->option(async => 1) if $async;
 749         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 750         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 751         $o->option(preferredRecordSyntax => $syntax);
 752         $o->option(elementSetName => $elementSetName) if $elementSetName;
 753         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 754
 755         # create a new connection object
 756         $Zconn= create ZOOM::Connection($o);
 757
 758         # forge to server
 759         $Zconn->connect($host, 0);
 760
 761         # check for errors and warn
 762         if ($Zconn->errcode() !=0) {
 763             warn "something wrong with the connection: ". $Zconn->errmsg();
 764         }
 765     };
 766     return $Zconn;
 767 }
 768
 769 # _new_dbh
 770 # Internal helper function (not a method!). This creates a new
 771 # database connection from the data given in the current context, and
 772 # returns it.
 773 sub _new_dbh
 774 {
 775
 776     Koha::Database->schema({ new => 1 })->storage->dbh;
 777 }
 778
 779 =head2 dbh
 780
 781   $dbh = C4::Context->dbh;
 782
 783 Returns a database handle connected to the Koha database for the
 784 current context. If no connection has yet been made, this method
 785 creates one, and connects to the database.
 786
 787 This database handle is cached for future use: if you call
 788 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 789 times. If you need a second database handle, use C<&new_dbh> and
 790 possibly C<&set_dbh>.
 791
 792 =cut
 793
 794 #'
 795 sub dbh
 796 {
 797     my $self = shift;
 798     my $params = shift;
 799     my $sth;
 800
 801     unless ( $params->{new} ) {
 802         return Koha::Database->schema->storage->dbh;
 803     }
 804
 805     return Koha::Database->schema({ new => 1 })->storage->dbh;
 806 }
 807
 808 =head2 new_dbh
 809
 810   $dbh = C4::Context->new_dbh;
 811
 812 Creates a new connection to the Koha database for the current context,
 813 and returns the database handle (a C<DBI::db> object).
 814
 815 The handle is not saved anywhere: this method is strictly a
 816 convenience function; the point is that it knows which database to
 817 connect to so that the caller doesn't have to know.
 818
 819 =cut
 820
 821 #'
 822 sub new_dbh
 823 {
 824     my $self = shift;
 825
 826     return &dbh({ new => 1 });
 827 }
 828
 829 =head2 set_dbh
 830
 831   $my_dbh = C4::Connect->new_dbh;
 832   C4::Connect->set_dbh($my_dbh);
 833   ...
 834   C4::Connect->restore_dbh;
 835
 836 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 837 C<&set_context> and C<&restore_context>.
 838
 839 C<&set_dbh> saves the current database handle on a stack, then sets
 840 the current database handle to C<$my_dbh>.
 841
 842 C<$my_dbh> is assumed to be a good database handle.
 843
 844 =cut
 845
 846 #'
 847 sub set_dbh
 848 {
 849     my $self = shift;
 850     my $new_dbh = shift;
 851
 852     # Save the current database handle on the handle stack.
 853     # We assume that $new_dbh is all good: if the caller wants to
 854     # screw himself by passing an invalid handle, that's fine by
 855     # us.
 856     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 857     $context->{"dbh"} = $new_dbh;
 858 }
 859
 860 =head2 restore_dbh
 861
 862   C4::Context->restore_dbh;
 863
 864 Restores the database handle saved by an earlier call to
 865 C<C4::Context-E<gt>set_dbh>.
 866
 867 =cut
 868
 869 #'
 870 sub restore_dbh
 871 {
 872     my $self = shift;
 873
 874     if ($#{$context->{"dbh_stack"}} < 0)
 875     {
 876         # Stack underflow
 877         die "DBH stack underflow";
 878     }
 879
 880     # Pop the old database handle and set it.
 881     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 882
 883     # FIXME - If it is determined that restore_context should
 884     # return something, then this function should, too.
 885 }
 886
 887 =head2 queryparser
 888
 889   $queryparser = C4::Context->queryparser
 890
 891 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 892
 893 =cut
 894
 895 sub queryparser {
 896     my $self = shift;
 897     unless (defined $context->{"queryparser"}) {
 898         $context->{"queryparser"} = &_new_queryparser();
 899     }
 900
 901     return
 902       defined( $context->{"queryparser"} )
 903       ? $context->{"queryparser"}->new
 904       : undef;
 905 }
 906
 907 =head2 _new_queryparser
 908
 909 Internal helper function to create a new QueryParser object. QueryParser
 910 is loaded dynamically so as to keep the lack of the QueryParser library from
 911 getting in anyone's way.
 912
 913 =cut
 914
 915 sub _new_queryparser {
 916     my $qpmodules = {
 917         'OpenILS::QueryParser'           => undef,
 918         'Koha::QueryParser::Driver::PQF' => undef
 919     };
 920     if ( can_load( 'modules' => $qpmodules ) ) {
 921         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 922         my $config_file = $context->config('queryparser_config');
 923         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 924         if ( $QParser->load_config($config_file) ) {
 925             # Set 'keyword' as the default search class
 926             $QParser->default_search_class('keyword');
 927             # TODO: allow indexes to be configured in the database
 928             return $QParser;
 929         }
 930     }
 931     return;
 932 }
 933
 934 =head2 marcfromkohafield
 935
 936   $dbh = C4::Context->marcfromkohafield;
 937
 938 Returns a hash with marcfromkohafield.
 939
 940 This hash is cached for future use: if you call
 941 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
 942
 943 =cut
 944
 945 #'
 946 sub marcfromkohafield
 947 {
 948     my $retval = {};
 949
 950     # If the hash already exists, return it.
 951     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
 952
 953     # No hash. Create one.
 954     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
 955
 956     return $context->{"marcfromkohafield"};
 957 }
 958
 959 # _new_marcfromkohafield
 960 sub _new_marcfromkohafield
 961 {
 962     my $dbh = C4::Context->dbh;
 963     my $marcfromkohafield;
 964     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
 965     $sth->execute;
 966     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
 967         my $retval = {};
 968         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
 969     }
 970     return $marcfromkohafield;
 971 }
 972
 973 =head2 userenv
 974
 975   C4::Context->userenv;
 976
 977 Retrieves a hash for user environment variables.
 978
 979 This hash shall be cached for future use: if you call
 980 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 981
 982 =cut
 983
 984 #'
 985 sub userenv {
 986     my $var = $context->{"activeuser"};
 987     if (defined $var and defined $context->{"userenv"}->{$var}) {
 988         return $context->{"userenv"}->{$var};
 989     } else {
 990         return;
 991     }
 992 }
 993
 994 =head2 set_userenv
 995
 996   C4::Context->set_userenv($usernum, $userid, $usercnum,
 997                            $userfirstname, $usersurname,
 998                            $userbranch, $branchname, $userflags,
 999                            $emailaddress, $branchprinter, $persona);
1000
1001 Establish a hash of user environment variables.
1002
1003 set_userenv is called in Auth.pm
1004
1005 =cut
1006
1007 #'
1008 sub set_userenv {
1009     shift @_;
1010     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
1011     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
1012     @_;
1013     my $var=$context->{"activeuser"} || '';
1014     my $cell = {
1015         "number"     => $usernum,
1016         "id"         => $userid,
1017         "cardnumber" => $usercnum,
1018         "firstname"  => $userfirstname,
1019         "surname"    => $usersurname,
1020         #possibly a law problem
1021         "branch"     => $userbranch,
1022         "branchname" => $branchname,
1023         "flags"      => $userflags,
1024         "emailaddress"     => $emailaddress,
1025         "branchprinter"    => $branchprinter,
1026         "persona"    => $persona,
1027         "shibboleth" => $shibboleth,
1028     };
1029     $context->{userenv}->{$var} = $cell;
1030     return $cell;
1031 }
1032
1033 sub set_shelves_userenv {
1034         my ($type, $shelves) = @_ or return;
1035         my $activeuser = $context->{activeuser} or return;
1036         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1037         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1038         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1039 }
1040
1041 sub get_shelves_userenv {
1042         my $active;
1043         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1044                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1045                 return;
1046         }
1047         my $totshelves = $active->{totshelves} or undef;
1048         my $pubshelves = $active->{pubshelves} or undef;
1049         my $barshelves = $active->{barshelves} or undef;
1050         return ($totshelves, $pubshelves, $barshelves);
1051 }
1052
1053 =head2 _new_userenv
1054
1055   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1056
1057 Builds a hash for user environment variables.
1058
1059 This hash shall be cached for future use: if you call
1060 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1061
1062 _new_userenv is called in Auth.pm
1063
1064 =cut
1065
1066 #'
1067 sub _new_userenv
1068 {
1069     shift;  # Useless except it compensates for bad calling style
1070     my ($sessionID)= @_;
1071      $context->{"activeuser"}=$sessionID;
1072 }
1073
1074 =head2 _unset_userenv
1075
1076   C4::Context->_unset_userenv;
1077
1078 Destroys the hash for activeuser user environment variables.
1079
1080 =cut
1081
1082 #'
1083
1084 sub _unset_userenv
1085 {
1086     my ($sessionID)= @_;
1087     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1088 }
1089
1090
1091 =head2 get_versions
1092
1093   C4::Context->get_versions
1094
1095 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1096
1097 =cut
1098
1099 #'
1100
1101 # A little example sub to show more debugging info for CGI::Carp
1102 sub get_versions {
1103     my %versions;
1104     $versions{kohaVersion}  = Koha::version();
1105     $versions{kohaDbVersion} = C4::Context->preference('version');
1106     $versions{osVersion} = join(" ", POSIX::uname());
1107     $versions{perlVersion} = $];
1108     {
1109         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1110         $versions{mysqlVersion}  = `mysql -V`;
1111         $versions{apacheVersion} = (`apache2ctl -v`)[0];
1112         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
1113         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1114         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1115         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1116     }
1117     return %versions;
1118 }
1119
1120
1121 =head2 tz
1122
1123   C4::Context->tz
1124
1125   Returns a DateTime::TimeZone object for the system timezone
1126
1127 =cut
1128
1129 sub tz {
1130     my $self = shift;
1131     if (!defined $context->{tz}) {
1132         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1133     }
1134     return $context->{tz};
1135 }
1136
1137
1138 =head2 IsSuperLibrarian
1139
1140     C4::Context->IsSuperLibrarian();
1141
1142 =cut
1143
1144 sub IsSuperLibrarian {
1145     my $userenv = C4::Context->userenv;
1146
1147     unless ( $userenv and exists $userenv->{flags} ) {
1148         # If we reach this without a user environment,
1149         # assume that we're running from a command-line script,
1150         # and act as a superlibrarian.
1151         carp("C4::Context->userenv not defined!");
1152         return 1;
1153     }
1154
1155     return ($userenv->{flags}//0) % 2;
1156 }
1157
1158 =head2 interface
1159
1160 Sets the current interface for later retrieval in any Perl module
1161
1162     C4::Context->interface('opac');
1163     C4::Context->interface('intranet');
1164     my $interface = C4::Context->interface;
1165
1166 =cut
1167
1168 sub interface {
1169     my ($class, $interface) = @_;
1170
1171     if (defined $interface) {
1172         $interface = lc $interface;
1173         if ($interface eq 'opac' || $interface eq 'intranet' || $interface eq 'sip' || $interface eq 'commandline') {
1174             $context->{interface} = $interface;
1175         } else {
1176             warn "invalid interface : '$interface'";
1177         }
1178     }
1179
1180     return $context->{interface} // 'opac';
1181 }
1182
1183 1;
1184 __END__
1185
1186 =head1 ENVIRONMENT
1187
1188 =head2 C<KOHA_CONF>
1189
1190 Specifies the configuration file to read.
1191
1192 =head1 SEE ALSO
1193
1194 XML::Simple
1195
1196 =head1 AUTHORS
1197
1198 Andrew Arensburger <arensb at ooblick dot com>
1199
1200 Joshua Ferraro <jmf at liblime dot com>
1201