C4/HoldsQueue.pm

   1 package C4::HoldsQueue;
   2
   3 # Copyright 2011 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 # FIXME: expand perldoc, explain intended logic
  21
  22 use strict;
  23 use warnings;
  24
  25 use C4::Context;
  26 use C4::Search;
  27 use C4::Items;
  28 use C4::Branch;
  29 use C4::Circulation;
  30 use C4::Members;
  31 use C4::Biblio;
  32 use C4::Dates qw/format_date/;
  33
  34 use List::Util qw(shuffle);
  35 use List::MoreUtils qw(any);
  36 use Data::Dumper;
  37
  38 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  39 BEGIN {
  40     $VERSION = 3.03;
  41     require Exporter;
  42     @ISA = qw(Exporter);
  43     @EXPORT_OK = qw(
  44         &CreateQueue
  45         &GetHoldsQueueItems
  46
  47         &TransportCostMatrix
  48         &UpdateTransportCostMatrix
  49      );
  50 }
  51
  52
  53 =head1 FUNCTIONS
  54
  55 =head2 TransportCostMatrix
  56
  57   TransportCostMatrix();
  58
  59 Returns Transport Cost Matrix as a hashref <to branch code> => <from branch code> => cost
  60
  61 =cut
  62
  63 sub TransportCostMatrix {
  64     my $dbh   = C4::Context->dbh;
  65     my $transport_costs = $dbh->selectall_arrayref("SELECT * FROM transport_cost",{ Slice => {} });
  66
  67     my %transport_cost_matrix;
  68     foreach (@$transport_costs) {
  69         my $from = $_->{frombranch};
  70         my $to = $_->{tobranch};
  71         my $cost = $_->{cost};
  72         my $disabled = $_->{disable_transfer};
  73         $transport_cost_matrix{$to}{$from} = { cost => $cost, disable_transfer => $disabled };
  74     }
  75     return \%transport_cost_matrix;
  76 }
  77
  78 =head2 UpdateTransportCostMatrix
  79
  80   UpdateTransportCostMatrix($records);
  81
  82 Updates full Transport Cost Matrix table. $records is an arrayref of records.
  83 Records: { frombranch => <code>, tobranch => <code>, cost => <figure>, disable_transfer => <0,1> }
  84
  85 =cut
  86
  87 sub UpdateTransportCostMatrix {
  88     my ($records) = @_;
  89     my $dbh   = C4::Context->dbh;
  90
  91     my $sth = $dbh->prepare("INSERT INTO transport_cost (frombranch, tobranch, cost, disable_transfer) VALUES (?, ?, ?, ?)");
  92
  93     $dbh->do("TRUNCATE TABLE transport_cost");
  94     foreach (@$records) {
  95         my $cost = $_->{cost};
  96         my $from = $_->{frombranch};
  97         my $to = $_->{tobranch};
  98         if ($_->{disable_transfer}) {
  99             $cost ||= 0;
 100         }
 101         elsif ( !defined ($cost) || ($cost !~ m/(0|[1-9][0-9]*)(\.[0-9]*)?/o) ) {
 102             warn  "Invalid $from -> $to cost $cost - must be a number >= 0, disablig";
 103             $cost = 0;
 104             $_->{disable_transfer} = 1;
 105         }
 106         $sth->execute( $from, $to, $cost, $_->{disable_transfer} ? 1 : 0 );
 107     }
 108 }
 109
 110 =head2 GetHoldsQueueItems
 111
 112   GetHoldsQueueItems($branch);
 113
 114 Returns hold queue for a holding branch. If branch is omitted, then whole queue is returned
 115
 116 =cut
 117
 118 sub GetHoldsQueueItems {
 119     my ($branchlimit) = @_;
 120     my $dbh   = C4::Context->dbh;
 121
 122     my @bind_params = ();
 123     my $query = q/SELECT tmp_holdsqueue.*, biblio.author, items.ccode, items.itype, biblioitems.itemtype, items.location, items.enumchron, items.cn_sort, biblioitems.publishercode,biblio.copyrightdate,biblioitems.publicationyear,biblioitems.pages,biblioitems.size,biblioitems.publicationyear,biblioitems.isbn,items.copynumber
 124                   FROM tmp_holdsqueue
 125                        JOIN biblio      USING (biblionumber)
 126                   LEFT JOIN biblioitems USING (biblionumber)
 127                   LEFT JOIN items       USING (  itemnumber)
 128                 /;
 129     if ($branchlimit) {
 130         $query .=" WHERE tmp_holdsqueue.holdingbranch = ?";
 131         push @bind_params, $branchlimit;
 132     }
 133     $query .= " ORDER BY ccode, location, cn_sort, author, title, pickbranch, reservedate";
 134     my $sth = $dbh->prepare($query);
 135     $sth->execute(@bind_params);
 136     my $items = [];
 137     while ( my $row = $sth->fetchrow_hashref ){
 138         $row->{reservedate} = format_date($row->{reservedate});
 139         my $record = GetMarcBiblio($row->{biblionumber});
 140         if ($record){
 141             $row->{subtitle} = GetRecordValue('subtitle',$record,'')->[0]->{subfield};
 142             $row->{parts} = GetRecordValue('parts',$record,'')->[0]->{subfield};
 143             $row->{numbers} = GetRecordValue('numbers',$record,'')->[0]->{subfield};
 144         }
 145
 146         # return the bib-level or item-level itype per syspref
 147         if (!C4::Context->preference('item-level_itypes')) {
 148             $row->{itype} = $row->{itemtype};
 149         }
 150         delete $row->{itemtype};
 151
 152         push @$items, $row;
 153     }
 154     return $items;
 155 }
 156
 157 =head2 CreateQueue
 158
 159   CreateQueue();
 160
 161 Top level function that turns reserves into tmp_holdsqueue and hold_fill_targets.
 162
 163 =cut
 164
 165 sub CreateQueue {
 166     my $dbh   = C4::Context->dbh;
 167
 168     $dbh->do("DELETE FROM tmp_holdsqueue");  # clear the old table for new info
 169     $dbh->do("DELETE FROM hold_fill_targets");
 170
 171     my $total_bibs            = 0;
 172     my $total_requests        = 0;
 173     my $total_available_items = 0;
 174     my $num_items_mapped      = 0;
 175
 176     my $branches_to_use;
 177     my $transport_cost_matrix;
 178     my $use_transport_cost_matrix = C4::Context->preference("UseTransportCostMatrix");
 179     if ($use_transport_cost_matrix) {
 180         $transport_cost_matrix = TransportCostMatrix();
 181         unless (keys %$transport_cost_matrix) {
 182             warn "UseTransportCostMatrix set to yes, but matrix not populated";
 183             undef $transport_cost_matrix;
 184         }
 185     }
 186     unless ($transport_cost_matrix) {
 187         $branches_to_use = load_branches_to_pull_from();
 188     }
 189
 190     my $bibs_with_pending_requests = GetBibsWithPendingHoldRequests();
 191
 192     foreach my $biblionumber (@$bibs_with_pending_requests) {
 193         $total_bibs++;
 194         my $hold_requests   = GetPendingHoldRequestsForBib($biblionumber);
 195         my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_to_use);
 196         $total_requests        += scalar(@$hold_requests);
 197         $total_available_items += scalar(@$available_items);
 198
 199         my $item_map = MapItemsToHoldRequests($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix);
 200         $item_map  or next;
 201         my $item_map_size = scalar(keys %$item_map)
 202           or next;
 203
 204         $num_items_mapped += $item_map_size;
 205         CreatePicklistFromItemMap($item_map);
 206         AddToHoldTargetMap($item_map);
 207         if (($item_map_size < scalar(@$hold_requests  )) and
 208             ($item_map_size < scalar(@$available_items))) {
 209             # DOUBLE CHECK, but this is probably OK - unfilled item-level requests
 210             # FIXME
 211             #warn "unfilled requests for $biblionumber";
 212             #warn Dumper($hold_requests), Dumper($available_items), Dumper($item_map);
 213         }
 214     }
 215 }
 216
 217 =head2 GetBibsWithPendingHoldRequests
 218
 219   my $biblionumber_aref = GetBibsWithPendingHoldRequests();
 220
 221 Return an arrayref of the biblionumbers of all bibs
 222 that have one or more unfilled hold requests.
 223
 224 =cut
 225
 226 sub GetBibsWithPendingHoldRequests {
 227     my $dbh = C4::Context->dbh;
 228
 229     my $bib_query = "SELECT DISTINCT biblionumber
 230                      FROM reserves
 231                      WHERE found IS NULL
 232                      AND priority > 0
 233                      AND reservedate <= CURRENT_DATE()
 234                      AND suspend = 0
 235                      ";
 236     my $sth = $dbh->prepare($bib_query);
 237
 238     $sth->execute();
 239     my $biblionumbers = $sth->fetchall_arrayref();
 240
 241     return [ map { $_->[0] } @$biblionumbers ];
 242 }
 243
 244 =head2 GetPendingHoldRequestsForBib
 245
 246   my $requests = GetPendingHoldRequestsForBib($biblionumber);
 247
 248 Returns an arrayref of hashrefs to pending, unfilled hold requests
 249 on the bib identified by $biblionumber.  The following keys
 250 are present in each hashref:
 251
 252     biblionumber
 253     borrowernumber
 254     itemnumber
 255     priority
 256     branchcode
 257     reservedate
 258     reservenotes
 259     borrowerbranch
 260
 261 The arrayref is sorted in order of increasing priority.
 262
 263 =cut
 264
 265 sub GetPendingHoldRequestsForBib {
 266     my $biblionumber = shift;
 267
 268     my $dbh = C4::Context->dbh;
 269
 270     my $request_query = "SELECT biblionumber, borrowernumber, itemnumber, priority, reserves.branchcode,
 271                                 reservedate, reservenotes, borrowers.branchcode AS borrowerbranch
 272                          FROM reserves
 273                          JOIN borrowers USING (borrowernumber)
 274                          WHERE biblionumber = ?
 275                          AND found IS NULL
 276                          AND priority > 0
 277                          AND reservedate <= CURRENT_DATE()
 278                          AND suspend = 0
 279                          ORDER BY priority";
 280     my $sth = $dbh->prepare($request_query);
 281     $sth->execute($biblionumber);
 282
 283     my $requests = $sth->fetchall_arrayref({});
 284     return $requests;
 285
 286 }
 287
 288 =head2 GetItemsAvailableToFillHoldRequestsForBib
 289
 290   my $available_items = GetItemsAvailableToFillHoldRequestsForBib($biblionumber, $branches_ar);
 291
 292 Returns an arrayref of items available to fill hold requests
 293 for the bib identified by C<$biblionumber>.  An item is available
 294 to fill a hold request if and only if:
 295
 296     * it is not on loan
 297     * it is not withdrawn
 298     * it is not marked notforloan
 299     * it is not currently in transit
 300     * it is not lost
 301     * it is not sitting on the hold shelf
 302     * it is not damaged (unless AllowHoldsOnDamagedItems is on)
 303
 304 =cut
 305
 306 sub GetItemsAvailableToFillHoldRequestsForBib {
 307     my ($biblionumber, $branches_to_use) = @_;
 308
 309     my $dbh = C4::Context->dbh;
 310     my $items_query = "SELECT itemnumber, homebranch, holdingbranch, itemtypes.itemtype AS itype
 311                        FROM items ";
 312
 313     if (C4::Context->preference('item-level_itypes')) {
 314         $items_query .=   "LEFT JOIN itemtypes ON (itemtypes.itemtype = items.itype) ";
 315     } else {
 316         $items_query .=   "JOIN biblioitems USING (biblioitemnumber)
 317                            LEFT JOIN itemtypes USING (itemtype) ";
 318     }
 319     $items_query .=   "WHERE items.notforloan = 0
 320                        AND holdingbranch IS NOT NULL
 321                        AND itemlost = 0
 322                        AND withdrawn = 0";
 323     $items_query .= "  AND damaged = 0" unless C4::Context->preference('AllowHoldsOnDamagedItems');
 324     $items_query .= "  AND items.onloan IS NULL
 325                        AND (itemtypes.notforloan IS NULL OR itemtypes.notforloan = 0)
 326                        AND itemnumber NOT IN (
 327                            SELECT itemnumber
 328                            FROM reserves
 329                            WHERE biblionumber = ?
 330                            AND itemnumber IS NOT NULL
 331                            AND (found IS NOT NULL OR priority = 0)
 332                         )
 333                        AND items.biblionumber = ?";
 334
 335     my @params = ($biblionumber, $biblionumber);
 336     if ($branches_to_use && @$branches_to_use) {
 337         $items_query .= " AND holdingbranch IN (" . join (",", map { "?" } @$branches_to_use) . ")";
 338         push @params, @$branches_to_use;
 339     }
 340     my $sth = $dbh->prepare($items_query);
 341     $sth->execute(@params);
 342
 343     my $itm = $sth->fetchall_arrayref({});
 344     my @items = grep { ! scalar GetTransfers($_->{itemnumber}) } @$itm;
 345     return [ grep {
 346         my $rule = GetBranchItemRule($_->{homebranch}, $_->{itype});
 347         $_->{holdallowed} = $rule->{holdallowed};
 348     } @items ];
 349 }
 350
 351 =head2 MapItemsToHoldRequests
 352
 353   MapItemsToHoldRequests($hold_requests, $available_items, $branches, $transport_cost_matrix)
 354
 355 =cut
 356
 357 sub MapItemsToHoldRequests {
 358     my ($hold_requests, $available_items, $branches_to_use, $transport_cost_matrix) = @_;
 359
 360     # handle trival cases
 361     return unless scalar(@$hold_requests) > 0;
 362     return unless scalar(@$available_items) > 0;
 363
 364     # identify item-level requests
 365     my %specific_items_requested = map { $_->{itemnumber} => 1 }
 366                                    grep { defined($_->{itemnumber}) }
 367                                    @$hold_requests;
 368
 369     # group available items by itemnumber
 370     my %items_by_itemnumber = map { $_->{itemnumber} => $_ } @$available_items;
 371
 372     # items already allocated
 373     my %allocated_items = ();
 374
 375     # map of items to hold requests
 376     my %item_map = ();
 377
 378     # figure out which item-level requests can be filled
 379     my $num_items_remaining = scalar(@$available_items);
 380     foreach my $request (@$hold_requests) {
 381         last if $num_items_remaining == 0;
 382
 383         # is this an item-level request?
 384         if (defined($request->{itemnumber})) {
 385             # fill it if possible; if not skip it
 386             if (exists $items_by_itemnumber{$request->{itemnumber}} and
 387                 not exists $allocated_items{$request->{itemnumber}}) {
 388                 $item_map{$request->{itemnumber}} = {
 389                     borrowernumber => $request->{borrowernumber},
 390                     biblionumber => $request->{biblionumber},
 391                     holdingbranch =>  $items_by_itemnumber{$request->{itemnumber}}->{holdingbranch},
 392                     pickup_branch => $request->{branchcode} || $request->{borrowerbranch},
 393                     item_level => 1,
 394                     reservedate => $request->{reservedate},
 395                     reservenotes => $request->{reservenotes},
 396                 };
 397                 $allocated_items{$request->{itemnumber}}++;
 398                 $num_items_remaining--;
 399             }
 400         } else {
 401             # it's title-level request that will take up one item
 402             $num_items_remaining--;
 403         }
 404     }
 405
 406     # group available items by branch
 407     my %items_by_branch = ();
 408     foreach my $item (@$available_items) {
 409         next unless $item->{holdallowed};
 410
 411         push @{ $items_by_branch{ $item->{holdingbranch} } }, $item
 412           unless exists $allocated_items{ $item->{itemnumber} };
 413     }
 414     return \%item_map unless keys %items_by_branch;
 415
 416     # now handle the title-level requests
 417     $num_items_remaining = scalar(@$available_items) - scalar(keys %allocated_items);
 418     my $pull_branches;
 419     foreach my $request (@$hold_requests) {
 420         last if $num_items_remaining == 0;
 421         next if defined($request->{itemnumber}); # already handled these
 422
 423         # look for local match first
 424         my $pickup_branch = $request->{branchcode} || $request->{borrowerbranch};
 425         my ($itemnumber, $holdingbranch);
 426
 427         my $holding_branch_items = $items_by_branch{$pickup_branch};
 428         if ( $holding_branch_items ) {
 429             foreach my $item (@$holding_branch_items) {
 430                 if ( $request->{borrowerbranch} eq $item->{homebranch} ) {
 431                     $itemnumber = $item->{itemnumber};
 432                     last;
 433                 }
 434             }
 435             $holdingbranch = $pickup_branch;
 436             $itemnumber ||= $holding_branch_items->[0]->{itemnumber};
 437         }
 438         elsif ($transport_cost_matrix) {
 439             $pull_branches = [keys %items_by_branch];
 440             $holdingbranch = least_cost_branch( $pickup_branch, $pull_branches, $transport_cost_matrix );
 441             if ( $holdingbranch ) {
 442
 443                 my $holding_branch_items = $items_by_branch{$holdingbranch};
 444                 foreach my $item (@$holding_branch_items) {
 445                     next if $request->{borrowerbranch} ne $item->{homebranch};
 446
 447                     $itemnumber = $item->{itemnumber};
 448                     last;
 449                 }
 450             }
 451             else {
 452                 warn "No transport costs for $pickup_branch";
 453             }
 454         }
 455
 456         unless ($itemnumber) {
 457             # not found yet, fall back to basics
 458             if ($branches_to_use) {
 459                 $pull_branches = $branches_to_use;
 460             } else {
 461                 $pull_branches = [keys %items_by_branch];
 462             }
 463             PULL_BRANCHES:
 464             foreach my $branch (@$pull_branches) {
 465                 my $holding_branch_items = $items_by_branch{$branch}
 466                   or next;
 467
 468                 $holdingbranch ||= $branch;
 469                 foreach my $item (@$holding_branch_items) {
 470                     next if $pickup_branch ne $item->{homebranch};
 471
 472                     $itemnumber = $item->{itemnumber};
 473                     $holdingbranch = $branch;
 474                     last PULL_BRANCHES;
 475                 }
 476             }
 477
 478             unless ( $itemnumber ) {
 479                 foreach my $current_item ( @{ $items_by_branch{$holdingbranch} } ) {
 480                     if ( $holdingbranch && ( $current_item->{holdallowed} == 2 || $pickup_branch eq $current_item->{homebranch} ) ) {
 481                         $itemnumber = $current_item->{itemnumber};
 482                         last; # quit this loop as soon as we have a suitable item
 483                     }
 484                 }
 485             }
 486         }
 487
 488         if ($itemnumber) {
 489             my $holding_branch_items = $items_by_branch{$holdingbranch}
 490               or die "Have $itemnumber, $holdingbranch, but no items!";
 491             @$holding_branch_items = grep { $_->{itemnumber} != $itemnumber } @$holding_branch_items;
 492             delete $items_by_branch{$holdingbranch} unless @$holding_branch_items;
 493
 494             $item_map{$itemnumber} = {
 495                 borrowernumber => $request->{borrowernumber},
 496                 biblionumber => $request->{biblionumber},
 497                 holdingbranch => $holdingbranch,
 498                 pickup_branch => $pickup_branch,
 499                 item_level => 0,
 500                 reservedate => $request->{reservedate},
 501                 reservenotes => $request->{reservenotes},
 502             };
 503             $num_items_remaining--;
 504         }
 505     }
 506     return \%item_map;
 507 }
 508
 509 =head2 CreatePickListFromItemMap
 510
 511 =cut
 512
 513 sub CreatePicklistFromItemMap {
 514     my $item_map = shift;
 515
 516     my $dbh = C4::Context->dbh;
 517
 518     my $sth_load=$dbh->prepare("
 519         INSERT INTO tmp_holdsqueue (biblionumber,itemnumber,barcode,surname,firstname,phone,borrowernumber,
 520                                     cardnumber,reservedate,title, itemcallnumber,
 521                                     holdingbranch,pickbranch,notes, item_level_request)
 522         VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 523     ");
 524
 525     foreach my $itemnumber  (sort keys %$item_map) {
 526         my $mapped_item = $item_map->{$itemnumber};
 527         my $biblionumber = $mapped_item->{biblionumber};
 528         my $borrowernumber = $mapped_item->{borrowernumber};
 529         my $pickbranch = $mapped_item->{pickup_branch};
 530         my $holdingbranch = $mapped_item->{holdingbranch};
 531         my $reservedate = $mapped_item->{reservedate};
 532         my $reservenotes = $mapped_item->{reservenotes};
 533         my $item_level = $mapped_item->{item_level};
 534
 535         my $item = GetItem($itemnumber);
 536         my $barcode = $item->{barcode};
 537         my $itemcallnumber = $item->{itemcallnumber};
 538
 539         my $borrower = GetMember('borrowernumber'=>$borrowernumber);
 540         my $cardnumber = $borrower->{'cardnumber'};
 541         my $surname = $borrower->{'surname'};
 542         my $firstname = $borrower->{'firstname'};
 543         my $phone = $borrower->{'phone'};
 544
 545         my $bib = GetBiblioData($biblionumber);
 546         my $title = $bib->{title};
 547
 548         $sth_load->execute($biblionumber, $itemnumber, $barcode, $surname, $firstname, $phone, $borrowernumber,
 549                            $cardnumber, $reservedate, $title, $itemcallnumber,
 550                            $holdingbranch, $pickbranch, $reservenotes, $item_level);
 551     }
 552 }
 553
 554 =head2 AddToHoldTargetMap
 555
 556 =cut
 557
 558 sub AddToHoldTargetMap {
 559     my $item_map = shift;
 560
 561     my $dbh = C4::Context->dbh;
 562
 563     my $insert_sql = q(
 564         INSERT INTO hold_fill_targets (borrowernumber, biblionumber, itemnumber, source_branchcode, item_level_request)
 565                                VALUES (?, ?, ?, ?, ?)
 566     );
 567     my $sth_insert = $dbh->prepare($insert_sql);
 568
 569     foreach my $itemnumber (keys %$item_map) {
 570         my $mapped_item = $item_map->{$itemnumber};
 571         $sth_insert->execute($mapped_item->{borrowernumber}, $mapped_item->{biblionumber}, $itemnumber,
 572                              $mapped_item->{holdingbranch}, $mapped_item->{item_level});
 573     }
 574 }
 575
 576 # Helper functions, not part of any interface
 577
 578 sub _trim {
 579     return $_[0] unless $_[0];
 580     $_[0] =~ s/^\s+//;
 581     $_[0] =~ s/\s+$//;
 582     $_[0];
 583 }
 584
 585 sub load_branches_to_pull_from {
 586     my $static_branch_list = C4::Context->preference("StaticHoldsQueueWeight")
 587       or return;
 588
 589     my @branches_to_use = map _trim($_), split /,/, $static_branch_list;
 590
 591     @branches_to_use = shuffle(@branches_to_use) if  C4::Context->preference("RandomizeHoldsQueueWeight");
 592
 593     return \@branches_to_use;
 594 }
 595
 596 sub least_cost_branch {
 597
 598     #$from - arrayref
 599     my ($to, $from, $transport_cost_matrix) = @_;
 600
 601     # Nothing really spectacular: supply to branch, a list of potential from branches
 602     # and find the minimum from - to value from the transport_cost_matrix
 603     return $from->[0] if @$from == 1;
 604
 605     # If the pickup library is in the list of libraries to pull from,
 606     # return that library right away, it is obviously the least costly
 607     return ($to) if any { $_ eq $to } @$from;
 608
 609     my ($least_cost, @branch);
 610     foreach (@$from) {
 611         my $cell = $transport_cost_matrix->{$to}{$_};
 612         next if $cell->{disable_transfer};
 613
 614         my $cost = $cell->{cost};
 615         next unless defined $cost; # XXX should this be reported?
 616
 617         unless (defined $least_cost) {
 618             $least_cost = $cost;
 619             push @branch, $_;
 620             next;
 621         }
 622
 623         next if $cost > $least_cost;
 624
 625         if ($cost == $least_cost) {
 626             push @branch, $_;
 627             next;
 628         }
 629
 630         @branch = ($_);
 631         $least_cost = $cost;
 632     }
 633
 634     return $branch[0];
 635
 636     # XXX return a random @branch with minimum cost instead of the first one;
 637     # return $branch[0] if @branch == 1;
 638 }
 639
 640
 641 1;