C4/ItemType.pm

   1 package C4::ItemType;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17
  18 use strict;
  19 use warnings;
  20 use C4::Context;
  21
  22 our $AUTOLOAD;
  23
  24
  25
  26
  27 =head1 NAME
  28
  29 C4::ItemType - objects from the itemtypes table
  30
  31 =head1 SYNOPSIS
  32
  33     use C4::ItemType;
  34     my @itemtypes = C4::ItemType->all;
  35     print join("\n", map { $_->description } @itemtypes), "\n";
  36
  37 =head1 DESCRIPTION
  38
  39 Objects of this class represent a row in the C<itemtypes> table.
  40
  41 Currently, the bare minimum for using this as a read-only data source has
  42 been implemented.  The API was designed to make it easy to transition to
  43 an ORM later on.
  44
  45 =head1 API
  46
  47 =head2 Class Methods
  48
  49 =cut
  50
  51 =head3 C4::ItemType->new(\%opts)
  52
  53 Given a hashref, a new (in-memory) C4::ItemType object will be instantiated.
  54 The database is not touched.
  55
  56 =cut
  57
  58 sub new {
  59     my ($class, $opts) = @_;
  60     bless $opts => $class;
  61 }
  62
  63
  64
  65
  66 =head3 C4::ItemType->all
  67
  68 This returns all the itemtypes as objects.  By default they're ordered by
  69 C<description>.
  70
  71 =cut
  72
  73 sub all {
  74     my ($class) = @_;
  75     my $dbh = C4::Context->dbh;
  76     return    map { $class->new($_) }    @{$dbh->selectall_arrayref(
  77         # The itemtypes table is small enough for
  78         # `SELECT *` to be harmless.
  79         "SELECT * FROM itemtypes ORDER BY description",
  80         { Slice => {} },
  81     )};
  82 }
  83
  84
  85
  86
  87 =head2 Object Methods
  88
  89 These are read-only accessors for attributes of a C4::ItemType object.
  90
  91 =head3 $itemtype->itemtype
  92
  93 =head3 $itemtype->description
  94
  95 =head3 $itemtype->renewalsallowed
  96
  97 =head3 $itemtype->rentalcharge
  98
  99 =head3 $itemtype->notforloan
 100
 101 =head3 $itemtype->imageurl
 102
 103 =head3 $itemtype->summary
 104
 105 =cut
 106
 107 sub AUTOLOAD {
 108     my $self = shift;
 109     my $attr = $AUTOLOAD;
 110     $attr =~ s/.*://;
 111     if (exists $self->{$attr}) {
 112         return $self->{$attr};
 113     } else {
 114         return undef;
 115     }
 116 }
 117
 118 sub DESTROY { }
 119
 120
 121
 122 # ack itemtypes | grep '\.pm' | awk '{ print $1 }' | sed 's/:.*$//' | sort | uniq | sed -e 's,/,::,g' -e 's/\.pm//' -e 's/^/L<C4::/' -e 's/$/>,/'
 123
 124 =head1 SEE ALSO
 125
 126 The following modules make reference to the C<itemtypes> table.
 127
 128 L<C4::Biblio>,
 129 L<C4::Circulation>,
 130 L<C4::Context>,
 131 L<C4::Items>,
 132 L<C4::Koha>,
 133 L<C4::Labels>,
 134 L<C4::Overdues>,
 135 L<C4::Reserves>,
 136 L<C4::Search>,
 137 L<C4::VirtualShelves::Page>,
 138 L<C4::VirtualShelves>,
 139 L<C4::XSLT>
 140
 141
 142
 143 =head1 AUTHOR
 144
 145 John Beppu <john.beppu@liblime.com>
 146
 147 =cut
 148
 149 1;