C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp qw( carp );
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use Koha::Caches;
  30 use Koha::Cache::Memory::Lite;
  31
  32 our (@ISA, @EXPORT_OK);
  33 BEGIN {
  34     require Exporter;
  35     @ISA    = qw(Exporter);
  36     @EXPORT_OK = qw(
  37         getFrameworkLanguages
  38         getTranslatedLanguages
  39         getLanguages
  40         getAllLanguages
  41     );
  42     push @EXPORT_OK, qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage get_rfc4646_from_iso639);
  43 }
  44
  45 =head1 NAME
  46
  47 C4::Languages - Perl Module containing language list functions for Koha
  48
  49 =head1 SYNOPSIS
  50
  51 use C4::Languages;
  52
  53 =head1 DESCRIPTION
  54
  55 =cut
  56
  57 =head1 FUNCTIONS
  58
  59 =head2 getFrameworkLanguages
  60
  61 Returns a reference to an array of hashes:
  62
  63  my $languages = getFrameworkLanguages();
  64  for my $language(@$languages) {
  65     print "$language->{language_code}\n"; # language code in iso 639-2
  66     print "$language->{language_name}\n"; # language name in native script
  67     print "$language->{language_locale_name}\n"; # language name in current locale
  68  }
  69
  70 =cut
  71
  72 sub getFrameworkLanguages {
  73     # get a hash with all language codes, names, and locale names
  74     my $all_languages = getAllLanguages();
  75     my @languages;
  76
  77     # find the available directory names
  78     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  79     opendir (MYDIR,$dir);
  80     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  81     closedir MYDIR;
  82
  83     # pull out all data for the dir names that exist
  84     for my $dirname (@listdir) {
  85         for my $language_set (@$all_languages) {
  86
  87             if ($dirname eq $language_set->{language_code}) {
  88                 push @languages, {
  89                     'language_code'=>$dirname,
  90                     'language_description'=>$language_set->{language_description},
  91                     'native_descrition'=>$language_set->{language_native_description} }
  92             }
  93         }
  94     }
  95     return \@languages;
  96 }
  97
  98 =head2 getTranslatedLanguages
  99
 100 Returns a reference to an array of hashes:
 101
 102  my $languages = getTranslatedLanguages();
 103  print "Available translated languages:\n";
 104  for my $language(@$trlanguages) {
 105     print "$language->{language_code}\n"; # language code in iso 639-2
 106     print "$language->{language_name}\n"; # language name in native script
 107     print "$language->{language_locale_name}\n"; # language name in current locale
 108  }
 109
 110 =cut
 111
 112 sub getTranslatedLanguages {
 113     my ($interface, $theme, $current_language, $which) = @_;
 114     my @languages;
 115     my @enabled_languages =
 116       ( $interface && $interface eq 'intranet' )
 117       ? split ",", C4::Context->preference('language')
 118       : split ",", C4::Context->preference('OPACLanguages');
 119
 120     my $cache = Koha::Caches->get_instance;
 121     my $cache_key = "languages_${interface}_${theme}";
 122     if ($interface && $interface eq 'opac' ) {
 123         my $htdocs = C4::Context->config('opachtdocs');
 124         my $cached = $cache->get_from_cache($cache_key);
 125         if ( $cached ) {
 126             @languages = @{$cached};
 127         } else {
 128             @languages = _get_opac_language_dirs( $htdocs, $theme );
 129             $cache->set_in_cache($cache_key, \@languages );
 130         }
 131     }
 132     elsif ($interface && $interface eq 'intranet' ) {
 133         my $htdocs = C4::Context->config('intrahtdocs');
 134         my $cached = $cache->get_from_cache($cache_key);
 135         if ( $cached ) {
 136             @languages = @{$cached};
 137         } else {
 138             @languages = _get_intranet_language_dirs( $htdocs, $theme );
 139             $cache->set_in_cache($cache_key, \@languages );
 140         }
 141     }
 142     else {
 143         my $htdocs = C4::Context->config('intrahtdocs');
 144         push @languages, _get_intranet_language_dirs( $htdocs );
 145
 146         $htdocs = C4::Context->config('opachtdocs');
 147         push @languages, _get_opac_language_dirs( $htdocs );
 148
 149         my %seen;
 150         $seen{$_}++ for @languages;
 151         @languages = keys %seen;
 152     }
 153     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 154 }
 155
 156 =head2 getAllLanguages
 157
 158 Returns a reference to an array of hashes:
 159
 160  my $alllanguages = getAllLanguages();
 161  print "Available translated languages:\n";
 162  for my $language(@$alllanguages) {
 163     print "$language->{language_code}\n";
 164     print "$language->{language_name}\n";
 165     print "$language->{language_locale_name}\n";
 166  }
 167
 168 This routine is a wrapper for getLanguages().
 169
 170 =cut
 171
 172 sub getAllLanguages {
 173     return getLanguages(shift);
 174 }
 175
 176 =head2 getLanguages
 177
 178     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 179
 180 Returns a reference to an array of hashes of languages.
 181
 182 - If no parameter is passed to the function, it returns english languages names
 183 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 184   If a language name is not translated in $lang in database, the function returns english language name
 185 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 186
 187 =cut
 188
 189 sub getLanguages {
 190     my $lang = shift;
 191     my $isFiltered = shift;
 192
 193     my @languages_loop;
 194     my $dbh=C4::Context->dbh;
 195     my $default_language = 'en';
 196     my $current_language = $default_language;
 197     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 198     if ($lang) {
 199         $current_language = regex_lang_subtags($lang)->{'language'};
 200     }
 201     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\' ORDER BY description');
 202     $sth->execute();
 203     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 204         my $desc;
 205         # check if language name is stored in current language
 206         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 207         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 208         while (my $language_desc = $sth4->fetchrow_hashref) {
 209              $desc=$language_desc->{description};
 210         }
 211         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 212         if ($desc) {
 213             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 214         }
 215         else {
 216             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 217         }
 218         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 219         # add the correct description info
 220         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 221             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 222             my $native_description;
 223             while (my $description = $sth3->fetchrow_hashref) {
 224                 $native_description = $description->{description};
 225             }
 226
 227             # fill in the ISO6329 code
 228             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 229             # fill in the native description of the language, as well as the current language's translation of that if it exists
 230             if ($native_description) {
 231                 $language_subtag_registry->{language_description} = $native_description;
 232                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 233             }
 234             else {
 235                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 236             }
 237         }
 238         # Do not push unless valid iso639-2 code
 239         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 240             push @languages_loop, $language_subtag_registry;
 241         }
 242     }
 243     return \@languages_loop;
 244 }
 245
 246 sub _get_opac_language_dirs {
 247     my ( $htdocs, $theme ) = @_;
 248
 249     my @languages;
 250     if ( $theme and -d "$htdocs/$theme" ) {
 251         (@languages) = _get_language_dirs($htdocs,$theme);
 252     }
 253     else {
 254         for my $theme ( _get_themes('opac') ) {
 255             push @languages, _get_language_dirs($htdocs,$theme);
 256         }
 257     }
 258     return @languages;
 259 }
 260
 261
 262 sub _get_intranet_language_dirs {
 263     my ( $htdocs, $theme ) = @_;
 264
 265     my @languages;
 266     if ( $theme and -d "$htdocs/$theme" ) {
 267         @languages = _get_language_dirs($htdocs,$theme);
 268     }
 269     else {
 270         foreach my $theme ( _get_themes('intranet') ) {
 271             push @languages, _get_language_dirs($htdocs,$theme);
 272         }
 273     }
 274     return @languages;
 275 }
 276
 277 =head2 _get_themes
 278
 279 Internal function, returns an array of all available themes.
 280
 281   (@themes) = &_get_themes('opac');
 282   (@themes) = &_get_themes('intranet');
 283
 284 =cut
 285
 286 sub _get_themes {
 287     my $interface = shift;
 288     my $htdocs;
 289     my @themes;
 290     if ( $interface && $interface eq 'intranet' ) {
 291         $htdocs = C4::Context->config('intrahtdocs');
 292     }
 293     else {
 294         $htdocs = C4::Context->config('opachtdocs');
 295     }
 296     opendir D, "$htdocs";
 297     my @dirlist = readdir D;
 298     foreach my $directory (@dirlist) {
 299         # if there's an en dir, it's a valid theme
 300         -d "$htdocs/$directory/en" and push @themes, $directory;
 301     }
 302     return @themes;
 303 }
 304
 305 =head2 _get_language_dirs
 306
 307 Internal function, returns an array of directory names, excluding non-language directories
 308
 309 =cut
 310
 311 sub _get_language_dirs {
 312     my ($htdocs,$theme) = @_;
 313     $htdocs //= '';
 314     $theme //= '';
 315     my @lang_strings;
 316     opendir D, "$htdocs/$theme";
 317     for my $lang_string ( readdir D ) {
 318         next if $lang_string =~/^\./;
 319         next if $lang_string eq 'all';
 320         next if $lang_string =~/png$/;
 321         next if $lang_string =~/js$/;
 322         next if $lang_string =~/css$/;
 323         next if $lang_string =~/CVS$/;
 324         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 325         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 326         push @lang_strings, $lang_string;
 327     }
 328         return (@lang_strings);
 329 }
 330
 331 =head2 _build_languages_arrayref
 332
 333 Internal function for building the ref to array of hashes
 334
 335 FIXME: this could be rewritten and simplified using map
 336
 337 =cut
 338
 339 sub _build_languages_arrayref {
 340         my ($translated_languages,$current_language,$enabled_languages) = @_;
 341         $current_language //= '';
 342         my @translated_languages = @$translated_languages;
 343         my @languages_loop; # the final reference to an array of hashrefs
 344         my @enabled_languages = @$enabled_languages;
 345         # how many languages are enabled, if one, take note, some contexts won't need to display it
 346         my $language_groups;
 347         my $track_language_groups;
 348         my $current_language_regex = regex_lang_subtags($current_language);
 349         # Loop through the translated languages
 350         for my $translated_language (@translated_languages) {
 351             # separate the language string into its subtag types
 352             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 353
 354             # is this language string 'enabled'?
 355             for my $enabled_language (@enabled_languages) {
 356                 #warn "Checking out if $translated_language eq $enabled_language";
 357                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 358             }
 359
 360             # group this language, key by langtag
 361             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 362             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 363             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 364             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 365             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 366             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 367             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 368             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 369         }
 370         # $key is a language subtag like 'en'
 371
 372         my %idx = map { $enabled_languages->[$_] => $_ } reverse 0 .. @$enabled_languages-1;
 373         my @ordered_keys = sort {
 374             my $aa = $language_groups->{$a}->[0]->{rfc4646_subtag};
 375             my $bb = $language_groups->{$b}->[0]->{rfc4646_subtag};
 376             ( exists $idx{$aa} and exists $idx{$bb} and ( $idx{$aa} cmp $idx{$bb} ) )
 377             || ( exists $idx{$aa} and exists $idx{$bb} )
 378             || exists $idx{$bb}
 379         } keys %$language_groups;
 380
 381         for my $key ( @ordered_keys ) {
 382             my $value = $language_groups->{$key};
 383             # is this language group enabled? are any of the languages within it enabled?
 384             my $enabled;
 385             for my $enabled_language (@enabled_languages) {
 386                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 387                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 388             }
 389             push @languages_loop,  {
 390                             # this is only use if there is one
 391                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 392                             native_description => language_get_description($key,$key,'language'),
 393                             language => $key,
 394                             sublanguages_loop => $value,
 395                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 396                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 397                             group_enabled => $enabled,
 398                            };
 399         }
 400         return \@languages_loop;
 401 }
 402
 403 sub language_get_description {
 404     my ($script,$lang,$type) = @_;
 405     my $dbh = C4::Context->dbh;
 406     my $desc;
 407     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 408     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 409     $sth->execute($script,$lang,$type);
 410     while (my $descriptions = $sth->fetchrow_hashref) {
 411         $desc = $descriptions->{'description'};
 412     }
 413     unless ($desc) {
 414         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 415         $sth->execute($script,'en',$type);
 416         while (my $descriptions = $sth->fetchrow_hashref) {
 417             $desc = $descriptions->{'description'};
 418         }
 419     }
 420     return $desc;
 421 }
 422 =head2 regex_lang_subtags
 423
 424 This internal sub takes a string composed according to RFC 4646 as
 425 an input and returns a reference to a hash containing keys and values
 426 for ( language, script, region, variant, extension, privateuse )
 427
 428 =cut
 429
 430 sub regex_lang_subtags {
 431     my $string = shift;
 432
 433     # Regex for recognizing RFC 4646 well-formed tags
 434     # http://www.rfc-editor.org/rfc/rfc4646.txt
 435
 436     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 437     # The structure requires no forward references, so it reverses the order.
 438     # The uppercase comments are fragments copied from RFC 4646
 439     #
 440     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 441
 442     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 443     my $digit   = qr/[0-9]/ ;   # DIGIT
 444     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 445     my $x   = qr/[xX]/ ;    # private use singleton
 446     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 447     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 448
 449     # Now do the components. The structure is slightly different to allow for capturing the right components.
 450     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 451
 452     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 453     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 454     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 455
 456     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 457
 458     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 459
 460     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 461     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 462
 463     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 464     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 465
 466     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 467
 468     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 469     # Since these are limited, this is safe even later changes to the registry --
 470     # the only oddity is that it might change the type of the tag, and thus
 471     # the results from the capturing groups.
 472     # http://www.iana.org/assignments/language-subtag-registry
 473     # Note that these have to be compared case insensitively, requiring (?i) below.
 474
 475     my $grandfathered   = qr{(?: (?i)
 476         en $s GB $s oed
 477     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 478     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 479 )}x;
 480
 481     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 482
 483     #   |   art $s lojban
 484     #   |   cel $s gaulish
 485     #   |   en $s (?: boont | GB $s oed | scouse )
 486     #   |   no $s (?: bok | nyn)
 487     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 488
 489     # Here is the final breakdown, with capturing groups for each of these components
 490     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 491
 492     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 493
 494     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 495     my %subtag = (
 496         'rfc4646_subtag' => $string,
 497         'language' => $1,
 498         'script' => $2,
 499         'region' => $3,
 500         'variant' => $4,
 501         'extension' => $5,
 502         'privateuse' => $6,
 503     );
 504     return \%subtag;
 505 }
 506
 507 # Script Direction Resources:
 508 # http://www.w3.org/International/questions/qa-scripts
 509 sub get_bidi {
 510     my ($language_script)= @_;
 511     my $dbh = C4::Context->dbh;
 512     my $bidi;
 513     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 514     $sth->execute($language_script);
 515     while (my $result = $sth->fetchrow_hashref) {
 516         $bidi = $result->{'bidi'};
 517     }
 518     return $bidi;
 519 };
 520
 521 sub accept_language {
 522     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 523     my ($clientPreferences,$supportedLanguages) = @_;
 524     my @languages = ();
 525     if ($clientPreferences) {
 526         # There should be no whitespace anways, but a cleanliness/sanity check
 527         $clientPreferences =~ s/\s//g;
 528         # Prepare the list of client-acceptable languages
 529         foreach my $tag (split(/,/, $clientPreferences)) {
 530             my ($language, $quality) = split(/\;/, $tag);
 531             $quality =~ s/^q=//i if $quality;
 532             $quality = 1 unless $quality;
 533             next if $quality <= 0;
 534             # We want to force the wildcard to be last
 535             $quality = 0 if ($language eq '*');
 536             # Pushing lowercase language here saves processing later
 537             push(@languages, { quality => $quality,
 538                language => $language,
 539                lclanguage => lc($language) });
 540         }
 541     } else {
 542         carp "accept_language(x,y) called with no clientPreferences (x).";
 543     }
 544     # Prepare the list of server-supported languages
 545     my %supportedLanguages = ();
 546     my %secondaryLanguages = ();
 547     foreach my $language (@$supportedLanguages) {
 548         # warn "Language supported: " . $language->{language};
 549         my $subtag = $language->{rfc4646_subtag};
 550         $supportedLanguages{lc($subtag)} = $subtag;
 551         if ( $subtag =~ /^([^-]+)-?/ ) {
 552             $secondaryLanguages{lc($1)} = $subtag;
 553         }
 554     }
 555
 556     # Reverse sort the list, making best quality at the front of the array
 557     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 558     my $secondaryMatch = '';
 559     foreach my $tag (@languages) {
 560         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 561             # Client en-us eq server en-us
 562             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 563             return $supportedLanguages{$tag->{lclanguage}};
 564         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 565             # Client en eq server en-us
 566             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 567             return $supportedLanguages{$tag->{lclanguage}};
 568         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 569             # Client en-gb eq server en-us
 570             $secondaryMatch = $secondaryLanguages{$1};
 571         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 572             # FIXME: We just checked the exact same conditional!
 573             # Client en-us eq server en
 574             $secondaryMatch = $supportedLanguages{$1};
 575         } elsif ($tag->{lclanguage} eq '*') {
 576         # * matches every language not already specified.
 577         # It doesn't care which we pick, so let's pick the default,
 578         # if available, then the first in the array.
 579         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 580         return $supportedLanguages->[0];
 581         }
 582     }
 583     # No primary matches. Secondary? (ie, en-us requested and en supported)
 584     return $secondaryMatch if $secondaryMatch;
 585     return;   # else, we got nothing.
 586 }
 587
 588 =head2 getlanguage
 589
 590     Select a language based on the URL parameter 'language', a cookie,
 591     syspref available languages & browser
 592
 593 =cut
 594
 595 sub getlanguage {
 596     my ($cgi) = @_;
 597
 598     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 599     my $cache_key = "getlanguage";
 600     unless ( $cgi and $cgi->param('language') ) {
 601         my $cached = $memory_cache->get_from_cache($cache_key);
 602         return $cached if $cached;
 603     }
 604
 605     $cgi //= CGI->new;
 606     my $interface = C4::Context->interface;
 607     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 608     my $language;
 609
 610     my $preference_to_check =
 611       $interface eq 'intranet' ? 'language' : 'OPACLanguages';
 612     # Get the available/valid languages list
 613     my @languages;
 614     my $preference_value = C4::Context->preference($preference_to_check);
 615     if ($preference_value) {
 616         @languages = split /,/, $preference_value;
 617     }
 618
 619     # Chose language from the URL
 620     my $cgi_param_language = $cgi->param( 'language' );
 621     if ( defined $cgi_param_language && any { $_ eq $cgi_param_language } @languages) {
 622         $language = $cgi_param_language;
 623     }
 624
 625     # cookie
 626     if (not $language and my $cgi_cookie_language = $cgi->cookie('KohaOpacLanguage') ) {
 627         ( $language = $cgi_cookie_language ) =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 628     }
 629
 630     # HTTP_ACCEPT_LANGUAGE
 631     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 632         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 633             getTranslatedLanguages( $interface, $theme ) );
 634     }
 635
 636     # Ignore a lang not selected in sysprefs
 637     if ( $language && not any { $_ eq $language } @languages ) {
 638         $language = undef;
 639     }
 640
 641     # Pick the first selected syspref language
 642     $language = shift @languages unless $language;
 643
 644     # Fall back to English if necessary
 645     $language ||= 'en';
 646
 647     $memory_cache->set_in_cache( $cache_key, $language );
 648     return $language;
 649 }
 650
 651 =head2 get_rfc4646_from_iso639
 652
 653     Select a language rfc4646 code given an iso639 code
 654
 655 =cut
 656
 657 sub get_rfc4646_from_iso639 {
 658
 659     my $iso_code = shift;
 660     my $rfc_subtag = Koha::Database->new()->schema->resultset('LanguageRfc4646ToIso639')->find({iso639_2_code=>$iso_code});
 661     if ( $rfc_subtag ) {
 662         return $rfc_subtag->rfc4646_subtag;
 663     } else {
 664         return;
 665     }
 666
 667 }
 668
 669 1;
 670
 671 __END__
 672
 673 =head1 AUTHOR
 674
 675 Joshua Ferraro
 676
 677 =cut