C4/Members/Attributes.pm

   1 package C4::Members::Attributes;
   2
   3 # Copyright (C) 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Text::CSV;      # Don't be tempted to use Text::CSV::Unicode -- even in binary mode it fails.
  24 use C4::Context;
  25 use C4::Members::AttributeTypes;
  26
  27 use vars qw($VERSION @ISA @EXPORT_OK @EXPORT %EXPORT_TAGS);
  28 our ($csv, $AttributeTypes);
  29
  30 BEGIN {
  31     # set the version for version checking
  32     $VERSION = 3.01;
  33     @ISA = qw(Exporter);
  34     @EXPORT_OK = qw(GetBorrowerAttributes CheckUniqueness SetBorrowerAttributes
  35                     extended_attributes_code_value_arrayref extended_attributes_merge
  36                                         SearchIdMatchingAttribute);
  37     %EXPORT_TAGS = ( all => \@EXPORT_OK );
  38 }
  39
  40 =head1 NAME
  41
  42 C4::Members::Attributes - manage extend patron attributes
  43
  44 =head1 SYNOPSIS
  45
  46   use C4::Members::Attributes;
  47   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
  48
  49 =head1 FUNCTIONS
  50
  51 =head2 GetBorrowerAttributes
  52
  53   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber[, $opac_only]);
  54
  55 Retrieve an arrayref of extended attributes associated with the
  56 patron specified by C<$borrowernumber>.  Each entry in the arrayref
  57 is a hashref containing the following keys:
  58
  59 code (attribute type code)
  60 description (attribute type description)
  61 value (attribute value)
  62 value_description (attribute value description (if associated with an authorised value))
  63 password (password, if any, associated with attribute
  64
  65 If the C<$opac_only> parameter is present and has a true value, only the attributes
  66 marked for OPAC display are returned.
  67
  68 =cut
  69
  70 sub GetBorrowerAttributes {
  71     my $borrowernumber = shift;
  72     my $opac_only = @_ ? shift : 0;
  73
  74     my $dbh = C4::Context->dbh();
  75     my $query = "SELECT code, description, attribute, lib, password
  76                  FROM borrower_attributes
  77                  JOIN borrower_attribute_types USING (code)
  78                  LEFT JOIN authorised_values ON (category = authorised_value_category AND attribute = authorised_value)
  79                  WHERE borrowernumber = ?";
  80     $query .= "\nAND opac_display = 1" if $opac_only;
  81     $query .= "\nORDER BY code, attribute";
  82     my $sth = $dbh->prepare_cached($query);
  83     $sth->execute($borrowernumber);
  84     my @results = ();
  85     while (my $row = $sth->fetchrow_hashref()) {
  86         push @results, {
  87             code              => $row->{'code'},
  88             description       => $row->{'description'},
  89             value             => $row->{'attribute'},
  90             value_description => $row->{'lib'},
  91             password          => $row->{'password'},
  92         }
  93     }
  94     return \@results;
  95 }
  96
  97 =head2 SearchIdMatchingAttribute
  98
  99   my $matching_records = C4::Members::Attributes::SearchIdMatchingAttribute($filter);
 100
 101 =cut
 102
 103 sub SearchIdMatchingAttribute{
 104     my $filter = shift;
 105     my $finalfilter=$filter->[0];
 106     my $dbh   = C4::Context->dbh();
 107     my $query = qq{
 108 SELECT borrowernumber
 109 FROM borrower_attributes
 110 JOIN borrower_attribute_types USING (code)
 111 WHERE staff_searchable = 1
 112 AND attribute like ?};
 113     my $sth = $dbh->prepare_cached($query);
 114     $sth->execute("%$finalfilter%");
 115     return $sth->fetchall_arrayref;
 116 }
 117
 118 =head2 CheckUniqueness
 119
 120   my $ok = CheckUniqueness($code, $value[, $borrowernumber]);
 121
 122 Given an attribute type and value, verify if would violate
 123 a unique_id restriction if added to the patron.  The
 124 optional C<$borrowernumber> is the patron that the attribute
 125 value would be added to, if known.
 126
 127 Returns false if the C<$code> is not valid or the
 128 value would violate the uniqueness constraint.
 129
 130 =cut
 131
 132 sub CheckUniqueness {
 133     my $code = shift;
 134     my $value = shift;
 135     my $borrowernumber = @_ ? shift : undef;
 136
 137     my $attr_type = C4::Members::AttributeTypes->fetch($code);
 138
 139     return 0 unless defined $attr_type;
 140     return 1 unless $attr_type->unique_id();
 141
 142     my $dbh = C4::Context->dbh;
 143     my $sth;
 144     if (defined($borrowernumber)) {
 145         $sth = $dbh->prepare("SELECT COUNT(*)
 146                               FROM borrower_attributes
 147                               WHERE code = ?
 148                               AND attribute = ?
 149                               AND borrowernumber <> ?");
 150         $sth->execute($code, $value, $borrowernumber);
 151     } else {
 152         $sth = $dbh->prepare("SELECT COUNT(*)
 153                               FROM borrower_attributes
 154                               WHERE code = ?
 155                               AND attribute = ?");
 156         $sth->execute($code, $value);
 157     }
 158     my ($count) = $sth->fetchrow_array;
 159     return ($count == 0);
 160 }
 161
 162 =head2 SetBorrowerAttributes
 163
 164   SetBorrowerAttributes($borrowernumber, [ { code => 'CODE', value => 'value', password => 'password' }, ... ] );
 165
 166 Set patron attributes for the patron identified by C<$borrowernumber>,
 167 replacing any that existed previously.
 168
 169 =cut
 170
 171 sub SetBorrowerAttributes {
 172     my $borrowernumber = shift;
 173     my $attr_list = shift;
 174
 175     my $dbh = C4::Context->dbh;
 176     my $delsth = $dbh->prepare("DELETE FROM borrower_attributes WHERE borrowernumber = ?");
 177     $delsth->execute($borrowernumber);
 178
 179     my $sth = $dbh->prepare("INSERT INTO borrower_attributes (borrowernumber, code, attribute, password)
 180                              VALUES (?, ?, ?, ?)");
 181     foreach my $attr (@$attr_list) {
 182         $attr->{password} = undef unless exists $attr->{password};
 183         $sth->execute($borrowernumber, $attr->{code}, $attr->{value}, $attr->{password});
 184     }
 185 }
 186
 187 =head2 extended_attributes_code_value_arrayref
 188
 189    my $patron_attributes = "homeroom:1150605,grade:01,extradata:foobar";
 190    my $aref = extended_attributes_code_value_arrayref($patron_attributes);
 191
 192 Takes a comma-delimited CSV-style string argument and returns the kind of data structure that SetBorrowerAttributes wants,
 193 namely a reference to array of hashrefs like:
 194  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 195
 196 Caches Text::CSV parser object for efficiency.
 197
 198 =cut
 199
 200 sub extended_attributes_code_value_arrayref {
 201     my $string = shift or return;
 202     $csv or $csv = Text::CSV->new({binary => 1});  # binary needed for non-ASCII Unicode
 203     my $ok   = $csv->parse($string);  # parse field again to get subfields!
 204     my @list = $csv->fields();
 205     # TODO: error handling (check $ok)
 206     return [
 207         sort {&_sort_by_code($a,$b)}
 208         map { map { my @arr = split /:/, $_, 2; { code => $arr[0], value => $arr[1] } } $_ }
 209         @list
 210     ];
 211     # nested map because of split
 212 }
 213
 214 =head2 extended_attributes_merge
 215
 216   my $old_attributes = extended_attributes_code_value_arrayref("homeroom:224,grade:04,deanslist:2007,deanslist:2008,somedata:xxx");
 217   my $new_attributes = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2009,extradata:foobar");
 218   my $merged = extended_attributes_merge($patron_attributes, $new_attributes, 1);
 219
 220   # assuming deanslist is a repeatable code, value same as:
 221   # $merged = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2007,deanslist:2008,deanslist:2009,extradata:foobar,somedata:xxx");
 222
 223 Takes three arguments.  The first two are references to array of hashrefs, each like:
 224  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 225
 226 The third option specifies whether repeatable codes are clobbered or collected.  True for non-clobber.
 227
 228 Returns one reference to (merged) array of hashref.
 229
 230 Caches results of C4::Members::AttributeTypes::GetAttributeTypes_hashref(1) for efficiency.
 231
 232 =cut
 233
 234 sub extended_attributes_merge {
 235     my $old = shift or return;
 236     my $new = shift or return $old;
 237     my $keep = @_ ? shift : 0;
 238     $AttributeTypes or $AttributeTypes = C4::Members::AttributeTypes::GetAttributeTypes_hashref(1);
 239     my @merged = @$old;
 240     foreach my $att (@$new) {
 241         unless ($att->{code}) {
 242             warn "Cannot merge element: no 'code' defined";
 243             next;
 244         }
 245         unless ($AttributeTypes->{$att->{code}}) {
 246             warn "Cannot merge element: unrecognized code = '$att->{code}'";
 247             next;
 248         }
 249         unless ($AttributeTypes->{$att->{code}}->{repeatable} and $keep) {
 250             @merged = grep {$att->{code} ne $_->{code}} @merged;    # filter out any existing attributes of the same code
 251         }
 252         push @merged, $att;
 253     }
 254     return [( sort {&_sort_by_code($a,$b)} @merged )];
 255 }
 256
 257 sub _sort_by_code {
 258     my ($x, $y) = @_;
 259     defined ($x->{code}) or return -1;
 260     defined ($y->{code}) or return 1;
 261     return $x->{code} cmp $y->{code} || $x->{value} cmp $y->{value};
 262 }
 263
 264 =head1 AUTHOR
 265
 266 Koha Development Team <http://koha-community.org/>
 267
 268 Galen Charlton <galen.charlton@liblime.com>
 269
 270 =cut
 271
 272 1;