C4/Overdues.pm

   1 package C4::Overdues;
   2
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 # copyright 2010 BibLibre
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use Date::Calc qw/Today Date_to_Days/;
  25 use Date::Manip qw/UnixDate/;
  26 use List::MoreUtils qw( uniq );
  27 use POSIX qw( floor ceil );
  28 use Locale::Currency::Format 1.28;
  29 use Carp;
  30
  31 use C4::Circulation;
  32 use C4::Context;
  33 use C4::Accounts;
  34 use C4::Log; # logaction
  35 use C4::Debug;
  36 use Koha::DateUtils;
  37 use Koha::Account::Lines;
  38 use Koha::Account::Offsets;
  39 use Koha::IssuingRules;
  40 use Koha::Libraries;
  41
  42 use vars qw(@ISA @EXPORT);
  43
  44 BEGIN {
  45     require Exporter;
  46     @ISA = qw(Exporter);
  47
  48     # subs to rename (and maybe merge some...)
  49     push @EXPORT, qw(
  50       &CalcFine
  51       &Getoverdues
  52       &checkoverdues
  53       &UpdateFine
  54       &GetFine
  55       &get_chargeable_units
  56       &GetOverduesForBranch
  57       &GetOverdueMessageTransportTypes
  58       &parse_overdues_letter
  59     );
  60
  61     # subs to remove
  62     push @EXPORT, qw(
  63       &BorType
  64     );
  65
  66     # check that an equivalent don't exist already before moving
  67
  68     # subs to move to Circulation.pm
  69     push @EXPORT, qw(
  70       &GetIssuesIteminfo
  71     );
  72 }
  73
  74 =head1 NAME
  75
  76 C4::Circulation::Fines - Koha module dealing with fines
  77
  78 =head1 SYNOPSIS
  79
  80   use C4::Overdues;
  81
  82 =head1 DESCRIPTION
  83
  84 This module contains several functions for dealing with fines for
  85 overdue items. It is primarily used by the 'misc/fines2.pl' script.
  86
  87 =head1 FUNCTIONS
  88
  89 =head2 Getoverdues
  90
  91   $overdues = Getoverdues( { minimumdays => 1, maximumdays => 30 } );
  92
  93 Returns the list of all overdue books, with their itemtype.
  94
  95 C<$overdues> is a reference-to-array. Each element is a
  96 reference-to-hash whose keys are the fields of the issues table in the
  97 Koha database.
  98
  99 =cut
 100
 101 #'
 102 sub Getoverdues {
 103     my $params = shift;
 104     my $dbh = C4::Context->dbh;
 105     my $statement;
 106     if ( C4::Context->preference('item-level_itypes') ) {
 107         $statement = "
 108    SELECT issues.*, items.itype as itemtype, items.homebranch, items.barcode, items.itemlost, items.replacementprice
 109      FROM issues
 110 LEFT JOIN items       USING (itemnumber)
 111     WHERE date_due < NOW()
 112 ";
 113     } else {
 114         $statement = "
 115    SELECT issues.*, biblioitems.itemtype, items.itype, items.homebranch, items.barcode, items.itemlost, replacementprice
 116      FROM issues
 117 LEFT JOIN items       USING (itemnumber)
 118 LEFT JOIN biblioitems USING (biblioitemnumber)
 119     WHERE date_due < NOW()
 120 ";
 121     }
 122
 123     my @bind_parameters;
 124     if ( exists $params->{'minimumdays'} and exists $params->{'maximumdays'} ) {
 125         $statement .= ' AND TO_DAYS( NOW() )-TO_DAYS( date_due ) BETWEEN ? and ? ';
 126         push @bind_parameters, $params->{'minimumdays'}, $params->{'maximumdays'};
 127     } elsif ( exists $params->{'minimumdays'} ) {
 128         $statement .= ' AND ( TO_DAYS( NOW() )-TO_DAYS( date_due ) ) > ? ';
 129         push @bind_parameters, $params->{'minimumdays'};
 130     } elsif ( exists $params->{'maximumdays'} ) {
 131         $statement .= ' AND ( TO_DAYS( NOW() )-TO_DAYS( date_due ) ) < ? ';
 132         push @bind_parameters, $params->{'maximumdays'};
 133     }
 134     $statement .= 'ORDER BY borrowernumber';
 135     my $sth = $dbh->prepare( $statement );
 136     $sth->execute( @bind_parameters );
 137     return $sth->fetchall_arrayref({});
 138 }
 139
 140
 141 =head2 checkoverdues
 142
 143     ($count, $overdueitems) = checkoverdues($borrowernumber);
 144
 145 Returns a count and a list of overdueitems for a given borrowernumber
 146
 147 =cut
 148
 149 sub checkoverdues {
 150     my $borrowernumber = shift or return;
 151     my $sth = C4::Context->dbh->prepare(
 152         "SELECT biblio.*, items.*, issues.*,
 153                 biblioitems.volume,
 154                 biblioitems.number,
 155                 biblioitems.itemtype,
 156                 biblioitems.isbn,
 157                 biblioitems.issn,
 158                 biblioitems.publicationyear,
 159                 biblioitems.publishercode,
 160                 biblioitems.volumedate,
 161                 biblioitems.volumedesc,
 162                 biblioitems.collectiontitle,
 163                 biblioitems.collectionissn,
 164                 biblioitems.collectionvolume,
 165                 biblioitems.editionstatement,
 166                 biblioitems.editionresponsibility,
 167                 biblioitems.illus,
 168                 biblioitems.pages,
 169                 biblioitems.notes,
 170                 biblioitems.size,
 171                 biblioitems.place,
 172                 biblioitems.lccn,
 173                 biblioitems.url,
 174                 biblioitems.cn_source,
 175                 biblioitems.cn_class,
 176                 biblioitems.cn_item,
 177                 biblioitems.cn_suffix,
 178                 biblioitems.cn_sort,
 179                 biblioitems.totalissues
 180          FROM issues
 181          LEFT JOIN items       ON issues.itemnumber      = items.itemnumber
 182          LEFT JOIN biblio      ON items.biblionumber     = biblio.biblionumber
 183          LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 184             WHERE issues.borrowernumber  = ?
 185             AND   issues.date_due < NOW()"
 186     );
 187     $sth->execute($borrowernumber);
 188     my $results = $sth->fetchall_arrayref({});
 189     return ( scalar(@$results), $results);  # returning the count and the results is silly
 190 }
 191
 192 =head2 CalcFine
 193
 194     ($amount, $units_minus_grace, $chargeable_units) = &CalcFine($item,
 195                                   $categorycode, $branch,
 196                                   $start_dt, $end_dt );
 197
 198 Calculates the fine for a book.
 199
 200 The issuingrules table in the Koha database is a fine matrix, listing
 201 the penalties for each type of patron for each type of item and each branch (e.g., the
 202 standard fine for books might be $0.50, but $1.50 for DVDs, or staff
 203 members might get a longer grace period between the first and second
 204 reminders that a book is overdue).
 205
 206
 207 C<$item> is an item object (hashref).
 208
 209 C<$categorycode> is the category code (string) of the patron who currently has
 210 the book.
 211
 212 C<$branchcode> is the library (string) whose issuingrules govern this transaction.
 213
 214 C<$start_date> & C<$end_date> are DateTime objects
 215 defining the date range over which to determine the fine.
 216
 217 Fines scripts should just supply the date range over which to calculate the fine.
 218
 219 C<&CalcFine> returns three values:
 220
 221 C<$amount> is the fine owed by the patron (see above).
 222
 223 C<$units_minus_grace> is the number of chargeable units minus the grace period
 224
 225 C<$chargeable_units> is the number of chargeable units (days between start and end dates, Calendar adjusted where needed,
 226 minus any applicable grace period, or hours)
 227
 228 FIXME: previously attempted to return C<$message> as a text message, either "First Notice", "Second Notice",
 229 or "Final Notice".  But CalcFine never defined any value.
 230
 231 =cut
 232
 233 sub CalcFine {
 234     my ( $item, $bortype, $branchcode, $due_dt, $end_date  ) = @_;
 235     my $start_date = $due_dt->clone();
 236     # get issuingrules (fines part will be used)
 237     my $itemtype = $item->{itemtype} || $item->{itype};
 238     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule({ categorycode => $bortype, itemtype => $itemtype, branchcode => $branchcode });
 239
 240     $itemtype = Koha::ItemTypes->find($itemtype);
 241
 242     return unless $issuing_rule; # If not rule exist, there is no fine
 243
 244     my $fine_unit = $issuing_rule->lengthunit || 'days';
 245
 246     my $chargeable_units = get_chargeable_units($fine_unit, $start_date, $end_date, $branchcode);
 247     my $units_minus_grace = $chargeable_units - $issuing_rule->firstremind;
 248     my $amount = 0;
 249     if ( $issuing_rule->chargeperiod && ( $units_minus_grace > 0 ) ) {
 250         my $units = C4::Context->preference('FinesIncludeGracePeriod') ? $chargeable_units : $units_minus_grace;
 251         my $charge_periods = $units / $issuing_rule->chargeperiod;
 252         # If chargeperiod_charge_at = 1, we charge a fine at the start of each charge period
 253         # if chargeperiod_charge_at = 0, we charge at the end of each charge period
 254         $charge_periods = $issuing_rule->chargeperiod_charge_at == 1 ? ceil($charge_periods) : floor($charge_periods);
 255         $amount = $charge_periods * $issuing_rule->fine;
 256     } # else { # a zero (or null) chargeperiod or negative units_minus_grace value means no charge. }
 257
 258     $amount = $issuing_rule->overduefinescap if $issuing_rule->overduefinescap && $amount > $issuing_rule->overduefinescap;
 259
 260     # This must be moved to Koha::Item (see also similar code in C4::Accounts::chargelostitem
 261     $item->{replacementprice} ||= $itemtype->defaultreplacecost
 262       if $itemtype
 263       && $item->{replacementprice} == 0
 264       && C4::Context->preference("useDefaultReplacementCost");
 265
 266     $amount = $item->{replacementprice} if ( $issuing_rule->cap_fine_to_replacement_price && $item->{replacementprice} && $amount > $item->{replacementprice} );
 267
 268     $debug and warn sprintf("CalcFine returning (%s, %s, %s)", $amount, $units_minus_grace, $chargeable_units);
 269     return ($amount, $units_minus_grace, $chargeable_units);
 270 }
 271
 272
 273 =head2 get_chargeable_units
 274
 275     get_chargeable_units($unit, $start_date_ $end_date, $branchcode);
 276
 277 return integer value of units between C<$start_date> and C<$end_date>, factoring in holidays for C<$branchcode>.
 278
 279 C<$unit> is 'days' or 'hours' (default is 'days').
 280
 281 C<$start_date> and C<$end_date> are the two DateTimes to get the number of units between.
 282
 283 C<$branchcode> is the branch whose calendar to use for finding holidays.
 284
 285 =cut
 286
 287 sub get_chargeable_units {
 288     my ($unit, $date_due, $date_returned, $branchcode) = @_;
 289
 290     # If the due date is later than the return date
 291     return 0 unless ( $date_returned > $date_due );
 292
 293     my $charge_units = 0;
 294     my $charge_duration;
 295     if ($unit eq 'hours') {
 296         if(C4::Context->preference('finesCalendar') eq 'noFinesWhenClosed') {
 297             my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 298             $charge_duration = $calendar->hours_between( $date_due, $date_returned );
 299         } else {
 300             $charge_duration = $date_returned->delta_ms( $date_due );
 301         }
 302         if($charge_duration->in_units('hours') == 0 && $charge_duration->in_units('seconds') > 0){
 303             return 1;
 304         }
 305         return $charge_duration->in_units('hours');
 306     }
 307     else { # days
 308         if(C4::Context->preference('finesCalendar') eq 'noFinesWhenClosed') {
 309             my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 310             $charge_duration = $calendar->days_between( $date_due, $date_returned );
 311         } else {
 312             $charge_duration = $date_returned->delta_days( $date_due );
 313         }
 314         return $charge_duration->in_units('days');
 315     }
 316 }
 317
 318
 319 =head2 GetSpecialHolidays
 320
 321     &GetSpecialHolidays($date_dues,$itemnumber);
 322
 323 return number of special days  between date of the day and date due
 324
 325 C<$date_dues> is the envisaged date of book return.
 326
 327 C<$itemnumber> is the book's item number.
 328
 329 =cut
 330
 331 sub GetSpecialHolidays {
 332     my ( $date_dues, $itemnumber ) = @_;
 333
 334     # calcul the today date
 335     my $today = join "-", &Today();
 336
 337     # return the holdingbranch
 338     my $iteminfo = GetIssuesIteminfo($itemnumber);
 339
 340     # use sql request to find all date between date_due and today
 341     my $dbh = C4::Context->dbh;
 342     my $query =
 343       qq|SELECT DATE_FORMAT(concat(year,'-',month,'-',day),'%Y-%m-%d') as date
 344 FROM `special_holidays`
 345 WHERE DATE_FORMAT(concat(year,'-',month,'-',day),'%Y-%m-%d') >= ?
 346 AND   DATE_FORMAT(concat(year,'-',month,'-',day),'%Y-%m-%d') <= ?
 347 AND branchcode=?
 348 |;
 349     my @result = GetWdayFromItemnumber($itemnumber);
 350     my @result_date;
 351     my $wday;
 352     my $dateinsec;
 353     my $sth = $dbh->prepare($query);
 354     $sth->execute( $date_dues, $today, $iteminfo->{'branchcode'} )
 355       ;    # FIXME: just use NOW() in SQL instead of passing in $today
 356
 357     while ( my $special_date = $sth->fetchrow_hashref ) {
 358         push( @result_date, $special_date );
 359     }
 360
 361     my $specialdaycount = scalar(@result_date);
 362
 363     for ( my $i = 0 ; $i < scalar(@result_date) ; $i++ ) {
 364         $dateinsec = UnixDate( $result_date[$i]->{'date'}, "%o" );
 365         ( undef, undef, undef, undef, undef, undef, $wday, undef, undef ) =
 366           localtime($dateinsec);
 367         for ( my $j = 0 ; $j < scalar(@result) ; $j++ ) {
 368             if ( $wday == ( $result[$j]->{'weekday'} ) ) {
 369                 $specialdaycount--;
 370             }
 371         }
 372     }
 373
 374     return $specialdaycount;
 375 }
 376
 377 =head2 GetRepeatableHolidays
 378
 379     &GetRepeatableHolidays($date_dues, $itemnumber, $difference,);
 380
 381 return number of day closed between date of the day and date due
 382
 383 C<$date_dues> is the envisaged date of book return.
 384
 385 C<$itemnumber> is item number.
 386
 387 C<$difference> numbers of between day date of the day and date due
 388
 389 =cut
 390
 391 sub GetRepeatableHolidays {
 392     my ( $date_dues, $itemnumber, $difference ) = @_;
 393     my $dateinsec = UnixDate( $date_dues, "%o" );
 394     my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) =
 395       localtime($dateinsec);
 396     my @result = GetWdayFromItemnumber($itemnumber);
 397     my @dayclosedcount;
 398     my $j;
 399
 400     for ( my $i = 0 ; $i < scalar(@result) ; $i++ ) {
 401         my $k = $wday;
 402
 403         for ( $j = 0 ; $j < $difference ; $j++ ) {
 404             if ( $result[$i]->{'weekday'} == $k ) {
 405                 push( @dayclosedcount, $k );
 406             }
 407             $k++;
 408             ( $k = 0 ) if ( $k eq 7 );
 409         }
 410     }
 411     return scalar(@dayclosedcount);
 412 }
 413
 414
 415 =head2 GetWayFromItemnumber
 416
 417     &Getwdayfromitemnumber($itemnumber);
 418
 419 return the different week day from repeatable_holidays table
 420
 421 C<$itemnumber> is  item number.
 422
 423 =cut
 424
 425 sub GetWdayFromItemnumber {
 426     my ($itemnumber) = @_;
 427     my $iteminfo = GetIssuesIteminfo($itemnumber);
 428     my @result;
 429     my $query = qq|SELECT weekday
 430     FROM repeatable_holidays
 431     WHERE branchcode=?
 432 |;
 433     my $sth = C4::Context->dbh->prepare($query);
 434
 435     $sth->execute( $iteminfo->{'branchcode'} );
 436     while ( my $weekday = $sth->fetchrow_hashref ) {
 437         push( @result, $weekday );
 438     }
 439     return @result;
 440 }
 441
 442
 443 =head2 GetIssuesIteminfo
 444
 445     &GetIssuesIteminfo($itemnumber);
 446
 447 return all data from issues about item
 448
 449 C<$itemnumber> is  item number.
 450
 451 =cut
 452
 453 sub GetIssuesIteminfo {
 454     my ($itemnumber) = @_;
 455     my $dbh          = C4::Context->dbh;
 456     my $query        = qq|SELECT *
 457     FROM issues
 458     WHERE itemnumber=?
 459     |;
 460     my $sth = $dbh->prepare($query);
 461     $sth->execute($itemnumber);
 462     my ($issuesinfo) = $sth->fetchrow_hashref;
 463     return $issuesinfo;
 464 }
 465
 466
 467 =head2 UpdateFine
 468
 469     &UpdateFine(
 470         {
 471             issue_id       => $issue_id,
 472             itemnumber     => $itemnumber,
 473             borrowernumber => $borrowernumber,
 474             amount         => $amount,
 475             due            => $date_due
 476         }
 477     );
 478
 479 (Note: the following is mostly conjecture and guesswork.)
 480
 481 Updates the fine owed on an overdue book.
 482
 483 C<$itemnumber> is the book's item number.
 484
 485 C<$borrowernumber> is the borrower number of the patron who currently
 486 has the book on loan.
 487
 488 C<$amount> is the current amount owed by the patron.
 489
 490 C<$due> is the due date formatted to the currently specified date format
 491
 492 C<&UpdateFine> looks up the amount currently owed on the given item
 493 and sets it to C<$amount>, creating, if necessary, a new entry in the
 494 accountlines table of the Koha database.
 495
 496 =cut
 497
 498 #
 499 # Question: Why should the caller have to
 500 # specify both the item number and the borrower number? A book can't
 501 # be on loan to two different people, so the item number should be
 502 # sufficient.
 503 #
 504 # Possible Answer: You might update a fine for a damaged item, *after* it is returned.
 505 #
 506 sub UpdateFine {
 507     my ($params) = @_;
 508
 509     my $issue_id       = $params->{issue_id};
 510     my $itemnum        = $params->{itemnumber};
 511     my $borrowernumber = $params->{borrowernumber};
 512     my $amount         = $params->{amount};
 513     my $due            = $params->{due};
 514
 515     $debug and warn "UpdateFine({ itemnumber => $itemnum, borrowernumber => $borrowernumber, due => $due, issue_id => $issue_id})";
 516
 517     unless ( $issue_id ) {
 518         carp("No issue_id passed in!");
 519         return;
 520     }
 521
 522     my $dbh = C4::Context->dbh;
 523     # FIXME - What exactly is this query supposed to do? It looks up an
 524     # entry in accountlines that matches the given item and borrower
 525     # numbers, where the description contains $due, and where the
 526     # account type has one of several values, but what does this _mean_?
 527     # Does it look up existing fines for this item?
 528     # FIXME - What are these various account types? ("FU", "O", "F", "M")
 529     #   "L"   is LOST item
 530     #   "A"   is Account Management Fee
 531     #   "N"   is New Card
 532     #   "M"   is Sundry
 533     #   "F"   is Fine ??
 534     #   "FU"  is Fine UPDATE??
 535     #   "Pay" is Payment
 536     #   "REF" is Cash Refund
 537     my $sth = $dbh->prepare(
 538         "SELECT * FROM accountlines
 539         WHERE borrowernumber=? AND
 540         (( accounttype IN ('F','M') AND amountoutstanding<>0 ) OR
 541            accounttype = 'FU' )"
 542     );
 543     $sth->execute( $borrowernumber );
 544     my $data;
 545     my $total_amount_other = 0.00;
 546     my $due_qr = qr/$due/;
 547     # Cycle through the fines and
 548     # - find line that relates to the requested $itemnum
 549     # - accumulate fines for other items
 550     # so we can update $itemnum fine taking in account fine caps
 551     while (my $rec = $sth->fetchrow_hashref) {
 552         if ( $rec->{issue_id} == $issue_id && $rec->{accounttype} eq 'FU' ) {
 553             if ($data) {
 554                 warn "Not a unique accountlines record for issue_id $issue_id";
 555                 #FIXME Should we still count this one in total_amount ??
 556             }
 557             else {
 558                 $data = $rec;
 559                 next;
 560             }
 561         }
 562         $total_amount_other += $rec->{'amountoutstanding'};
 563     }
 564
 565     if (my $maxfine = C4::Context->preference('MaxFine')) {
 566         if ($total_amount_other + $amount > $maxfine) {
 567             my $new_amount = $maxfine - $total_amount_other;
 568             return if $new_amount <= 0.00;
 569             warn "Reducing fine for item $itemnum borrower $borrowernumber from $amount to $new_amount - MaxFine reached";
 570             $amount = $new_amount;
 571         }
 572     }
 573
 574     if ( $data ) {
 575         if ( $data->{'amount'} != $amount ) {
 576             my $accountline = Koha::Account::Lines->find( $data->{accountlines_id} );
 577             $accountline->adjust({ amount => $amount, type => 'fine_update' });
 578         }
 579     } else {
 580         if ( $amount ) { # Don't add new fines with an amount of 0
 581             my $sth4 = $dbh->prepare(
 582                 "SELECT title FROM biblio LEFT JOIN items ON biblio.biblionumber=items.biblionumber WHERE items.itemnumber=?"
 583             );
 584             $sth4->execute($itemnum);
 585             my $title = $sth4->fetchrow;
 586             my $desc = "$title $due";
 587
 588             my $account = Koha::Account->new({ patron_id => $borrowernumber });
 589             my $accountline = $account->add_debit(
 590                 {
 591                     amount      => $amount,
 592                     description => $desc,
 593                     note        => undef,
 594                     user_id     => undef,
 595                     library_id  => undef,
 596                     type        => 'fine',
 597                     item_id     => $itemnum,
 598                     issue_id    => $issue_id,
 599                 }
 600             );
 601         }
 602     }
 603 }
 604
 605 =head2 BorType
 606
 607     $borrower = &BorType($borrowernumber);
 608
 609 Looks up a patron by borrower number.
 610
 611 C<$borrower> is a reference-to-hash whose keys are all of the fields
 612 from the borrowers and categories tables of the Koha database. Thus,
 613 C<$borrower> contains all information about both the borrower and
 614 category they belong to.
 615
 616 =cut
 617
 618 sub BorType {
 619     my ($borrowernumber) = @_;
 620     my $dbh              = C4::Context->dbh;
 621     my $sth              = $dbh->prepare(
 622         "SELECT * from borrowers
 623       LEFT JOIN categories ON borrowers.categorycode=categories.categorycode
 624       WHERE borrowernumber=?"
 625     );
 626     $sth->execute($borrowernumber);
 627     return $sth->fetchrow_hashref;
 628 }
 629
 630 =head2 GetFine
 631
 632     $data->{'sum(amountoutstanding)'} = &GetFine($itemnum,$borrowernumber);
 633
 634 return the total of fine
 635
 636 C<$itemnum> is item number
 637
 638 C<$borrowernumber> is the borrowernumber
 639
 640 =cut
 641
 642 sub GetFine {
 643     my ( $itemnum, $borrowernumber ) = @_;
 644     my $dbh   = C4::Context->dbh();
 645     my $query = q|SELECT sum(amountoutstanding) as fineamount FROM accountlines
 646     where accounttype like 'F%'
 647   AND amountoutstanding > 0 AND borrowernumber=?|;
 648     my @query_param;
 649     push @query_param, $borrowernumber;
 650     if (defined $itemnum )
 651     {
 652         $query .= " AND itemnumber=?";
 653         push @query_param, $itemnum;
 654     }
 655     my $sth = $dbh->prepare($query);
 656     $sth->execute( @query_param );
 657     my $fine = $sth->fetchrow_hashref();
 658     if ($fine->{fineamount}) {
 659         return $fine->{fineamount};
 660     }
 661     return 0;
 662 }
 663
 664 =head2 GetBranchcodesWithOverdueRules
 665
 666     my @branchcodes = C4::Overdues::GetBranchcodesWithOverdueRules()
 667
 668 returns a list of branch codes for branches with overdue rules defined.
 669
 670 =cut
 671
 672 sub GetBranchcodesWithOverdueRules {
 673     my $dbh               = C4::Context->dbh;
 674     my $branchcodes = $dbh->selectcol_arrayref(q|
 675         SELECT DISTINCT(branchcode)
 676         FROM overduerules
 677         WHERE delay1 IS NOT NULL
 678         ORDER BY branchcode
 679     |);
 680     if ( $branchcodes->[0] eq '' ) {
 681         # If a default rule exists, all branches should be returned
 682         return map { $_->branchcode } Koha::Libraries->search({}, { order_by => 'branchname' });
 683     }
 684     return @$branchcodes;
 685 }
 686
 687 =head2 GetOverduesForBranch
 688
 689 Sql request for display all information for branchoverdues.pl
 690 2 possibilities : with or without location .
 691 display is filtered by branch
 692
 693 FIXME: This function should be renamed.
 694
 695 =cut
 696
 697 sub GetOverduesForBranch {
 698     my ( $branch, $location) = @_;
 699         my $itype_link =  (C4::Context->preference('item-level_itypes')) ?  " items.itype " :  " biblioitems.itemtype ";
 700     my $dbh = C4::Context->dbh;
 701     my $select = "
 702     SELECT
 703             borrowers.cardnumber,
 704             borrowers.borrowernumber,
 705             borrowers.surname,
 706             borrowers.firstname,
 707             borrowers.phone,
 708             borrowers.email,
 709                biblio.title,
 710                biblio.author,
 711                biblio.biblionumber,
 712                issues.date_due,
 713                issues.returndate,
 714                issues.branchcode,
 715              branches.branchname,
 716                 items.barcode,
 717                 items.homebranch,
 718                 items.itemcallnumber,
 719                 items.location,
 720                 items.itemnumber,
 721             itemtypes.description,
 722          accountlines.amountoutstanding
 723     FROM  accountlines
 724     LEFT JOIN issues      ON    issues.itemnumber     = accountlines.itemnumber
 725                           AND   issues.borrowernumber = accountlines.borrowernumber
 726     LEFT JOIN borrowers   ON borrowers.borrowernumber = accountlines.borrowernumber
 727     LEFT JOIN items       ON     items.itemnumber     = issues.itemnumber
 728     LEFT JOIN biblio      ON      biblio.biblionumber =  items.biblionumber
 729     LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber
 730     LEFT JOIN itemtypes   ON itemtypes.itemtype       = $itype_link
 731     LEFT JOIN branches    ON  branches.branchcode     = issues.branchcode
 732     WHERE (accountlines.amountoutstanding  != '0.000000')
 733       AND (accountlines.accounttype         = 'FU'      )
 734       AND (issues.branchcode =  ?   )
 735       AND (issues.date_due  < NOW())
 736     ";
 737     if ($location) {
 738         my $q = "$select AND items.location = ? ORDER BY borrowers.surname, borrowers.firstname";
 739         return @{ $dbh->selectall_arrayref($q, { Slice => {} }, $branch, $location ) };
 740     } else {
 741         my $q = "$select ORDER BY borrowers.surname, borrowers.firstname";
 742         return @{ $dbh->selectall_arrayref($q, { Slice => {} }, $branch ) };
 743     }
 744 }
 745
 746 =head2 GetOverdueMessageTransportTypes
 747
 748     my $message_transport_types = GetOverdueMessageTransportTypes( $branchcode, $categorycode, $letternumber);
 749
 750     return a arrayref with all message_transport_type for given branchcode, categorycode and letternumber(1,2 or 3)
 751
 752 =cut
 753
 754 sub GetOverdueMessageTransportTypes {
 755     my ( $branchcode, $categorycode, $letternumber ) = @_;
 756     return unless $categorycode and $letternumber;
 757     my $dbh = C4::Context->dbh;
 758     my $sth = $dbh->prepare("
 759         SELECT message_transport_type
 760         FROM overduerules odr LEFT JOIN overduerules_transport_types ott USING (overduerules_id)
 761         WHERE branchcode = ?
 762           AND categorycode = ?
 763           AND letternumber = ?
 764     ");
 765     $sth->execute( $branchcode, $categorycode, $letternumber );
 766     my @mtts;
 767     while ( my $mtt = $sth->fetchrow ) {
 768         push @mtts, $mtt;
 769     }
 770
 771     # Put 'print' in first if exists
 772     # It avoid to sent a print notice with an email or sms template is no email or sms is defined
 773     @mtts = uniq( 'print', @mtts )
 774         if grep {/^print$/} @mtts;
 775
 776     return \@mtts;
 777 }
 778
 779 =head2 parse_overdues_letter
 780
 781 parses the letter template, replacing the placeholders with data
 782 specific to this patron, biblio, or item for overdues
 783
 784 named parameters:
 785   letter - required hashref
 786   borrowernumber - required integer
 787   substitute - optional hashref of other key/value pairs that should
 788     be substituted in the letter content
 789
 790 returns the C<letter> hashref, with the content updated to reflect the
 791 substituted keys and values.
 792
 793 =cut
 794
 795 sub parse_overdues_letter {
 796     my $params = shift;
 797     foreach my $required (qw( letter_code borrowernumber )) {
 798         return unless ( exists $params->{$required} && $params->{$required} );
 799     }
 800
 801     my $patron = Koha::Patrons->find( $params->{borrowernumber} );
 802
 803     my $substitute = $params->{'substitute'} || {};
 804
 805     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 806     if ( my $p = $params->{'branchcode'} ) {
 807         $tables{'branches'} = $p;
 808     }
 809
 810     my $active_currency = Koha::Acquisition::Currencies->get_active;
 811
 812     my $currency_format;
 813     $currency_format = $active_currency->currency if defined($active_currency);
 814
 815     my @item_tables;
 816     if ( my $i = $params->{'items'} ) {
 817         foreach my $item (@$i) {
 818             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 819             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 820             # if active currency isn't correct ISO code fallback to sprintf
 821             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 822
 823             push @item_tables, {
 824                 'biblio' => $item->{'biblionumber'},
 825                 'biblioitems' => $item->{'biblionumber'},
 826                 'items' => $item,
 827                 'issues' => $item->{'itemnumber'},
 828             };
 829         }
 830     }
 831
 832     return C4::Letters::GetPreparedLetter (
 833         module => 'circulation',
 834         letter_code => $params->{'letter_code'},
 835         branchcode => $params->{'branchcode'},
 836         lang => $patron->lang,
 837         tables => \%tables,
 838         loops => {
 839             overdues => [ map { $_->{items}->{itemnumber} } @item_tables ],
 840         },
 841         substitute => $substitute,
 842         repeat => { item => \@item_tables },
 843         message_transport_type => $params->{message_transport_type},
 844     );
 845 }
 846
 847 1;
 848 __END__
 849
 850 =head1 AUTHOR
 851
 852 Koha Development Team <http://koha-community.org/>
 853
 854 =cut