C4/Passwordrecovery.pm

   1 package C4::Passwordrecovery;
   2
   3 # Copyright 2014 Solutions InLibro inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use C4::Context;
  22
  23 use vars qw($VERSION @ISA @EXPORT);
  24
  25 BEGIN {
  26     # set the version for version checking
  27     $VERSION = 3.07.00.049;
  28     require Exporter;
  29     @ISA    = qw(Exporter);
  30     push @EXPORT, qw(
  31         &ValidateBorrowernumber
  32         &SendPasswordRecoveryEmail
  33         &GetValidLinkInfo
  34         &CompletePasswordRecovery
  35     );
  36 }
  37
  38 =head1 NAME
  39
  40 C4::Passwordrecovery - Koha password recovery module
  41
  42 =head1 SYNOPSIS
  43
  44 use C4::Passwordrecovery;
  45
  46 =head1 FUNCTIONS
  47
  48 =head2 ValidateBorrowernumber
  49
  50 $alread = ValidateBorrowernumber( $borrower_number );
  51
  52 Check if the system already start recovery
  53
  54 Returns true false
  55
  56 =cut
  57
  58 sub ValidateBorrowernumber {
  59     my ($borrower_number) = @_;
  60     my $schema = Koha::Database->new->schema;
  61
  62     my $rs = $schema->resultset('BorrowerPasswordRecovery')->search(
  63     {
  64        borrowernumber => $borrower_number,
  65        valid_until => \'> NOW()'
  66     }, {
  67         columns => 'borrowernumber'
  68     });
  69
  70     if ($rs->next){
  71         return 1;
  72     }
  73
  74     return 0;
  75 }
  76
  77 =head2 GetValidLinkInfo
  78
  79     Check if the link is still valid and return some info.
  80
  81 =cut
  82
  83 sub GetValidLinkInfo {
  84     my ($uniqueKey) = @_;
  85     my $dbh = C4::Context->dbh;
  86     my $query = '
  87     SELECT borrower_password_recovery.borrowernumber, userid
  88     FROM borrower_password_recovery, borrowers
  89     WHERE borrowers.borrowernumber = borrower_password_recovery.borrowernumber
  90     AND NOW() < valid_until
  91     AND uuid = ?
  92     ';
  93     my $sth = $dbh->prepare($query);
  94     $sth->execute($uniqueKey);
  95     return $sth->fetchrow;
  96 }
  97
  98 =head2 SendPasswordRecoveryEmail
  99
 100  It creates an email using the templates and send it to the user, using the specified email
 101
 102 =cut
 103
 104 sub SendPasswordRecoveryEmail {
 105     my $borrower = shift; # Koha::Borrower
 106     my $userEmail = shift; #to_address (the one specified in the request)
 107     my $update = shift;
 108
 109     my $schema = Koha::Database->new->schema;
 110
 111     # generate UUID
 112     my @chars = ("A".."Z", "a".."z", "0".."9");
 113     my $uuid_str;
 114     $uuid_str .= $chars[rand @chars] for 1..32;
 115
 116     # insert into database
 117     my $expirydate = DateTime->now(time_zone => C4::Context->tz())->add( days => 2 );
 118     if($update){
 119         my $rs = $schema->resultset('BorrowerPasswordRecovery')->search(
 120         {
 121             borrowernumber => $borrower->borrowernumber,
 122         });
 123         $rs->update({uuid => $uuid_str, valid_until => $expirydate->datetime()});
 124     } else {
 125          my $rs = $schema->resultset('BorrowerPasswordRecovery')->create({
 126             borrowernumber=>$borrower->borrowernumber,
 127             uuid => $uuid_str,
 128             valid_until=> $expirydate->datetime()
 129          });
 130     }
 131
 132     # create link
 133     my $uuidLink = C4::Context->preference( 'OPACBaseURL' ) . "/cgi-bin/koha/opac-password-recovery.pl?uniqueKey=$uuid_str";
 134
 135     # prepare the email
 136     my $letter = C4::Letters::GetPreparedLetter (
 137         module => 'members',
 138         letter_code => 'PASSWORD_RESET',
 139         branchcode => $borrower->branchcode,
 140         substitute => {passwordreseturl => $uuidLink, user => $borrower->userid },
 141     );
 142
 143     # define to/from emails
 144     my $kohaEmail = C4::Context->preference( 'KohaAdminEmailAddress' ); # from
 145
 146     C4::Letters::EnqueueLetter( {
 147          letter => $letter,
 148          borrowernumber => $borrower->borrowernumber,
 149          to_address => $userEmail,
 150          from_address => $kohaEmail,
 151          message_transport_type => 'email',
 152     } );
 153
 154     return 1;
 155 }
 156 =head2 CompletePasswordRecovery
 157
 158     $bool = CompletePasswordRevovery($uuid);
 159
 160     Deletes a password recovery entry.
 161
 162 =cut
 163 sub CompletePasswordRecovery{
 164     my $uniqueKey = shift;
 165     my $model = Koha::Database->new->schema->resultset('BorrowerPasswordRecovery');
 166     my $entry = $model->search({-or => [uuid => $uniqueKey, valid_until => \'< NOW()']});
 167     return $entry->delete();
 168 }
 169
 170 END { }    # module clean-up code here (global destructor)
 171
 172 1;