C4/Templates.pm

   1 package C4::Templates;
   2
   3 use strict;
   4 use warnings;
   5 use Carp;
   6 use CGI;
   7 use List::MoreUtils qw/any/;
   8
   9 # Copyright 2009 Chris Cormack and The Koha Dev Team
  10 #
  11 # This file is part of Koha.
  12 #
  13 # Koha is free software; you can redistribute it and/or modify it under the
  14 # terms of the GNU General Public License as published by the Free Software
  15 # Foundation; either version 2 of the License, or (at your option) any later
  16 # version.
  17 #
  18 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  19 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  20 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License along with
  23 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  24 # Suite 330, Boston, MA  02111-1307 USA
  25
  26 =head1 NAME
  27
  28     Koha::Templates - Object for manipulating templates for use with Koha
  29
  30 =cut
  31
  32 use base qw(Class::Accessor);
  33 use Template;
  34 use Template::Constants qw( :debug );
  35 use C4::Languages qw(getTranslatedLanguages get_bidi regex_lang_subtags language_get_description accept_language );
  36
  37 use C4::Context;
  38
  39 __PACKAGE__->mk_accessors(qw( theme lang filename htdocs interface vars));
  40
  41
  42
  43 sub new {
  44     my $class     = shift;
  45     my $interface = shift;
  46     my $filename  = shift;
  47     my $tmplbase  = shift;
  48     my $query     = @_? shift: undef;
  49     my $htdocs;
  50     if ( $interface ne "intranet" ) {
  51         $htdocs = C4::Context->config('opachtdocs');
  52     }
  53     else {
  54         $htdocs = C4::Context->config('intrahtdocs');
  55     }
  56     my ($theme, $lang)= themelanguage( $htdocs, $tmplbase, $interface, $query);
  57     my $template = Template->new(
  58         {   EVAL_PERL    => 1,
  59             ABSOLUTE     => 1,
  60             PLUGIN_BASE => 'Koha::Template::Plugin',
  61             COMPILE_EXT => C4::Context->config('template_cache_dir')?'.ttc':'',
  62             COMPILE_DIR => C4::Context->config('template_cache_dir')?C4::Context->config('template_cache_dir'):'',,
  63             INCLUDE_PATH => [
  64                 "$htdocs/$theme/$lang/includes",
  65                 "$htdocs/$theme/en/includes"
  66             ],
  67             FILTERS => {},
  68         }
  69     ) or die Template->error();
  70     my $self = {
  71         TEMPLATE => $template,
  72         VARS     => {},
  73     };
  74     bless $self, $class;
  75     $self->theme($theme);
  76     $self->lang($lang);
  77     $self->filename($filename);
  78     $self->htdocs($htdocs);
  79     $self->interface($interface);
  80     $self->{VARS}->{"test"} = "value";
  81     return $self;
  82
  83 }
  84
  85 sub output {
  86     my $self = shift;
  87     my $vars = shift;
  88
  89 #    my $file = $self->htdocs . '/' . $self->theme .'/'.$self->lang.'/'.$self->filename;
  90     my $template = $self->{TEMPLATE};
  91     if ( $self->interface eq 'intranet' ) {
  92         $vars->{themelang} = '/intranet-tmpl';
  93     }
  94     else {
  95         $vars->{themelang} = '/opac-tmpl';
  96     }
  97     $vars->{lang} = $self->lang;
  98     $vars->{themelang} .= '/' . $self->theme . '/' . $self->lang;
  99     $vars->{yuipath} =
 100       ( C4::Context->preference("yuipath") eq "local"
 101         ? $vars->{themelang} . "/lib/yui"
 102         : C4::Context->preference("yuipath") );
 103     $vars->{interface} =
 104       ( $self->{interface} ne 'intranet' ? '/opac-tmpl' : '/intranet-tmpl' );
 105     $vars->{theme} = $self->theme;
 106     $vars->{opaccolorstylesheet} =
 107         C4::Context->preference('opaccolorstylesheet');
 108     $vars->{opacsmallimage} = C4::Context->preference('opacsmallimage');
 109     $vars->{opaclayoutstylesheet} =
 110         C4::Context->preference('opaclayoutstylesheet');
 111
 112     # add variables set via param to $vars for processing
 113     # and clean any utf8 mess
 114     for my $k ( keys %{ $self->{VARS} } ) {
 115         $vars->{$k} = $self->{VARS}->{$k};
 116         if (ref($vars->{$k}) eq 'ARRAY'){
 117             utf8_arrayref($vars->{$k});
 118         }
 119         elsif (ref($vars->{$k}) eq 'HASH'){
 120             utf8_hashref($vars->{$k});
 121         }
 122         else {
 123             utf8::encode($vars->{$k}) if utf8::is_utf8($vars->{$k});
 124         }
 125     }
 126     my $data;
 127 #    binmode( STDOUT, ":utf8" );
 128     $template->process( $self->filename, $vars, \$data )
 129       || die "Template process failed: ", $template->error();
 130     return $data;
 131 }
 132
 133 sub utf8_arrayref {
 134     my $arrayref = shift;
 135     foreach my $element (@$arrayref){
 136         if (ref($element) eq 'ARRAY'){
 137             utf8_arrayref($element);
 138             next;
 139         }
 140         if (ref($element) eq 'HASH'){
 141             utf8_hashref($element);
 142             next;
 143         }
 144         utf8::encode($element) if utf8::is_utf8($element);
 145     }
 146 }
 147
 148 sub utf8_hashref {
 149     my $hashref = shift;
 150     for my $key (keys %{$hashref}){
 151         if (ref($hashref->{$key}) eq 'ARRAY'){
 152             utf8_arrayref($hashref->{$key});
 153             next;
 154         }
 155         if (ref($hashref->{$key}) eq 'HASH'){
 156             utf8_hashref($hashref->{$key});
 157             next;
 158         }
 159         utf8::encode($hashref->{$key}) if utf8::is_utf8($hashref->{$key});
 160     }
 161 }
 162
 163
 164 # FIXME - this is a horrible hack to cache
 165 # the current known-good language, temporarily
 166 # put in place to resolve bug 4403.  It is
 167 # used only by C4::XSLT::XSLTParse4Display;
 168 # the language is set via the usual call
 169 # to themelanguage.
 170 my $_current_language = 'en';
 171
 172 sub _current_language {
 173     return $_current_language;
 174 }
 175
 176
 177 # wrapper method to allow easier transition from HTML template pro to Template Toolkit
 178 sub param {
 179     my $self = shift;
 180     while (@_) {
 181         my $key = shift;
 182         my $val = shift;
 183         if    ( ref($val) eq 'ARRAY' && !scalar @$val ) { $val = undef; }
 184         elsif ( ref($val) eq 'HASH'  && !scalar %$val ) { $val = undef; }
 185         if ( $key ) {
 186             $self->{VARS}->{$key} = $val;
 187         } else {
 188             warn "Problem = a value of $val has been passed to param without key";
 189         }
 190     }
 191 }
 192
 193
 194 =head1 NAME
 195
 196 C4::Templates - Functions for managing templates
 197
 198 =head1 FUNCTIONS
 199
 200 =cut
 201
 202 # FIXME: this is a quick fix to stop rc1 installing broken
 203 # Still trying to figure out the correct fix.
 204 my $path = C4::Context->config('intrahtdocs') . "/prog/en/includes/";
 205
 206 #---------------------------------------------------------------------------------------------------------
 207 # FIXME - POD
 208
 209 sub _get_template_file {
 210     my ($tmplbase, $interface, $query) = @_;
 211
 212     my $is_intranet = $interface eq 'intranet';
 213     my $htdocs = C4::Context->config($is_intranet ? 'intrahtdocs' : 'opachtdocs');
 214     my ($theme, $lang) = themelanguage($htdocs, $tmplbase, $interface, $query);
 215
 216     # if the template doesn't exist, load the English one as a last resort
 217     my $filename = "$htdocs/$theme/$lang/modules/$tmplbase";
 218     unless (-f $filename) {
 219         $lang = 'en';
 220         $filename = "$htdocs/$theme/$lang/modules/$tmplbase";
 221     }
 222     return ($htdocs, $theme, $lang, $filename);
 223 }
 224
 225
 226 sub gettemplate {
 227     my ( $tmplbase, $interface, $query ) = @_;
 228     ($query) or warn "no query in gettemplate";
 229     my $path = C4::Context->preference('intranet_includes') || 'includes';
 230     $tmplbase =~ s/\.tmpl$/.tt/;
 231     my ($htdocs, $theme, $lang, $filename)
 232        =  _get_template_file($tmplbase, $interface, $query);
 233     my $template = C4::Templates->new($interface, $filename, $tmplbase, $query);
 234     my $is_intranet = $interface eq 'intranet';
 235     my $themelang =
 236         ($is_intranet ? '/intranet-tmpl' : '/opac-tmpl') .
 237         "/$theme/$lang";
 238     $template->param(
 239         themelang => $themelang,
 240         yuipath   => C4::Context->preference("yuipath") eq "local"
 241                      ? "$themelang/lib/yui"
 242                      : C4::Context->preference("yuipath"),
 243         interface => $is_intranet ? '/intranet-tmpl' : '/opac-tmpl',
 244         theme     => $theme,
 245         lang      => $lang
 246     );
 247
 248     # Bidirectionality
 249     my $current_lang = regex_lang_subtags($lang);
 250     my $bidi;
 251     $bidi = get_bidi($current_lang->{script}) if $current_lang->{script};
 252     # Languages
 253     my $languages_loop = getTranslatedLanguages($interface,$theme,$lang);
 254     my $num_languages_enabled = 0;
 255     foreach my $lang (@$languages_loop) {
 256         foreach my $sublang (@{ $lang->{'sublanguages_loop'} }) {
 257             $num_languages_enabled++ if $sublang->{enabled};
 258          }
 259     }
 260     $template->param(
 261             languages_loop       => $languages_loop,
 262             bidi                 => $bidi,
 263             one_language_enabled => ($num_languages_enabled <= 1) ? 1 : 0, # deal with zero enabled langs as well
 264     ) unless @$languages_loop<2;
 265
 266     return $template;
 267 }
 268
 269
 270 #---------------------------------------------------------------------------------------------------------
 271 # FIXME - POD
 272 sub themelanguage {
 273     my ($htdocs, $tmpl, $interface, $query) = @_;
 274     ($query) or warn "no query in themelanguage";
 275
 276     # Select a language based on cookie, syspref available languages & browser
 277     my $lang = getlanguage($query, $interface);
 278
 279     # Select theme
 280     my $is_intranet = $interface eq 'intranet';
 281     my @themes = split(" ", C4::Context->preference(
 282         $is_intranet ? "template" : "opacthemes" ));
 283     push @themes, 'prog';
 284
 285     # Try to find first theme for the selected language
 286     for my $theme (@themes) {
 287         if ( -e "$htdocs/$theme/$lang/modules/$tmpl" ) {
 288             $_current_language = $lang;
 289             return ($theme, $lang)
 290         }
 291     }
 292     # Otherwise, return prog theme in English 'en'
 293     return ('prog', 'en');
 294 }
 295
 296
 297 sub setlanguagecookie {
 298     my ( $query, $language, $uri ) = @_;
 299     my $cookie = $query->cookie(
 300         -name    => 'KohaOpacLanguage',
 301         -value   => $language,
 302         -expires => '+3y'
 303     );
 304     print $query->redirect(
 305         -uri    => $uri,
 306         -cookie => $cookie
 307     );
 308 }
 309
 310
 311 sub getlanguage {
 312     my ($query, $interface) = @_;
 313
 314     # Select a language based on cookie, syspref available languages & browser
 315     my $preference_to_check =
 316       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 317     my @languages = split /,/, C4::Context->preference($preference_to_check);
 318
 319     my $lang;
 320
 321     # cookie
 322     if ( $query->cookie('KohaOpacLanguage') ) {
 323         $lang = $query->cookie('KohaOpacLanguage');
 324         $lang =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 325     }
 326
 327     # HTTP_ACCEPT_LANGUAGE
 328     if ( !$lang && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 329         $lang = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 330             getTranslatedLanguages( $interface, 'prog' ) );
 331     }
 332
 333     # Ignore a lang not selected in sysprefs
 334     if ( $lang && any { $_ eq $lang } @languages ) {
 335         return $lang;
 336     }
 337
 338     # Fall back to English if necessary
 339     return 'en';
 340 }
 341
 342 1;